@etherisc/gif-next 0.0.2-ce8407f-016 → 0.0.2-ce8fb44-591

package/contracts/types/ChainId.sol

@@ -1,38 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-/// @dev bytes5 (uint40) allows for chain ids up to 13 digits
-type ChainId is bytes5;
-
-// type bindings
-using {eqChainId as ==, neChainId as !=, ChainIdLib.toInt} for ChainId global;
-
-// general pure free functions
-/// @dev Converts the uint256 to a ChainId.
-function toChainId(uint256 chainId) pure returns (ChainId) {
-    return ChainId.wrap(bytes5(uint40(chainId)));
-}
-
-/// @dev Return the ChainId for the chain the contract is deployed to
-function thisChainId() view returns (ChainId) {
-    return toChainId(block.chainid);
-}
-
-// pure free functions for operators
-/// @dev Returns true if the values are equal (==).
-function eqChainId(ChainId a, ChainId b) pure returns (bool isSame) {
-    return ChainId.unwrap(a) == ChainId.unwrap(b);
-}
-
-/// @dev Returns true if the values are not equal (!=).
-function neChainId(ChainId a, ChainId b) pure returns (bool isDifferent) {
-    return ChainId.unwrap(a) != ChainId.unwrap(b);
-}
-
-// library functions that operate on user defined type
-library ChainIdLib {
-    /// @dev Converts the ChainId to a uint256.
-    function toInt(ChainId chainId) internal pure returns (uint256) {
-        return uint256(uint40(ChainId.unwrap(chainId)));
-    }
-}

package/contracts/types/Fee.sol

@@ -1,56 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {UFixed, UFixedMathLib} from "./UFixed.sol";
-
-struct Fee {
-    UFixed fractionalFee;
-    uint256 fixedFee;
-}
-
-library FeeLib {
-
-    function calculateFee(
-        Fee memory fee,
-        uint256 amount
-    )
-        public
-        pure
-        returns (
-            uint256 feeAmount, 
-            uint256 netAmount
-        )
-    {
-        UFixed fractionalAmount = UFixedMathLib.toUFixed(amount) *
-            fee.fractionalFee;
-        feeAmount = fractionalAmount.toInt() + fee.fixedFee;
-        netAmount = amount - feeAmount;
-    }
-
-    /// @dev Converts the uint256 to a fee struct.
-    function toFee(
-        UFixed fractionalFee,
-        uint256 fixedFee
-    ) public pure returns (Fee memory fee) {
-        return Fee(fractionalFee, fixedFee);
-    }
-
-    /// @dev Return the percent fee struct (x%, 0)
-    function percentageFee(uint8 percent) public pure returns (Fee memory fee) {
-        return Fee(UFixedMathLib.toUFixed(percent, -2), 0);
-    }
-
-    /// @dev Return a zero fee struct (0, 0)
-    function zeroFee() public pure returns (Fee memory fee) {
-        return Fee(UFixed.wrap(0), 0);
-    }
-
-    // pure free functions for operators
-    function feeIsSame(Fee memory a, Fee memory b) public pure returns (bool isSame) {
-        return a.fixedFee == b.fixedFee && a.fractionalFee == b.fractionalFee;
-    }
-
-    function feeIsZero(Fee memory fee) public pure returns (bool) {
-        return fee.fixedFee == 0 && UFixed.unwrap(fee.fractionalFee) == 0;
-    }
-}

package/contracts/types/NftIdSet.sol

@@ -1,60 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {NftId} from "../types/NftId.sol";
-
-// based on https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/utils/structs/EnumerableSet.sol
-library LibNftIdSet {
-
-    struct Set {
-        NftId[] ids;
-        mapping(NftId nftid => uint256 index) at;
-    }
-
-    function add(Set storage set, NftId nftId) external returns(bool added) {
-        if (set.at[nftId] == 0) {
-            set.ids.push(nftId);
-            set.at[nftId] = set.ids.length;
-            return true;
-        } else {
-            return false;
-        }
-    }
-
-    function remove(Set storage set, NftId nftId) external returns(bool removed) {
-        uint256 nftIdIndex = set.at[nftId];
-
-        if (nftIdIndex > 0) {
-            uint256 toDeleteIndex = nftIdIndex - 1;
-            uint256 lastIndex = set.ids.length - 1;
-
-            if (lastIndex != toDeleteIndex) {
-                NftId lastId = set.ids[lastIndex];
-                set.ids[toDeleteIndex] = lastId;
-                set.at[lastId] = nftIdIndex; // Replace lastValue's index to valueIndex
-            }
-
-            set.ids.pop();
-            delete set.at[nftId];
-            return true;
-        } else {
-            return false;
-        }
-    }
-
-    function isEmpty(Set storage set) external view returns(bool empty) {
-        return set.ids.length == 0;
-    }
-
-    function contains(Set storage set, NftId nftId) external view returns(bool inSet) {
-        return set.at[nftId] > 0;
-    }
-
-    function getLength(Set storage set) external view returns(uint256 length) {
-        return set.ids.length;
-    }
-
-    function getElementAt(Set storage set, uint256 index) external view returns(NftId nftId) {
-        return set.ids[index];
-    }
-}

package/contracts/types/NumberId.sol

@@ -1,52 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-// uint32 allows for 4'294'967'296 individual items
-type NumberId is uint32;
-
-// type bindings
-using {
-    eqNumberId as ==, 
-    neNumberId as !=, 
-    NumberIdLib.eqz,
-    NumberIdLib.gtz,
-    NumberIdLib.toInt
-} for NumberId global;
-
-
-// pure free functions for operators
-function eqNumberId(NumberId a, NumberId b) pure returns (bool isSame) {
-    return NumberId.unwrap(a) == NumberId.unwrap(b);
-}
-
-function neNumberId(NumberId a, NumberId b) pure returns (bool isDifferent) {
-    return NumberId.unwrap(a) != NumberId.unwrap(b);
-}
-
-// library functions that operate on user defined type
-library NumberIdLib {
-    /// @dev Converts the NumberId to a uint.
-    function zero() public pure returns (NumberId) {
-        return NumberId.wrap(0);
-    }
-
-    /// @dev Converts an uint into a NumberId.
-    function toNumberId(uint256 a) public pure returns (NumberId) {
-        return NumberId.wrap(uint32(a));
-    }
-
-    /// @dev Converts the NumberId to a uint.
-    function toInt(NumberId a) public pure returns (uint32) {
-        return uint32(NumberId.unwrap(a));
-    }
-
-    /// @dev Returns true if the value is non-zero (> 0).
-    function gtz(NumberId a) public pure returns (bool) {
-        return NumberId.unwrap(a) > 0;
-    }
-
-    /// @dev Returns true if the value is zero (== 0).
-    function eqz(NumberId a) public pure returns (bool) {
-        return NumberId.unwrap(a) == 0;
-    }
-}

package/contracts/types/ObjectType.sol

@@ -1,152 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-type ObjectType is uint8;
-
-// type bindings
-using {
-    eqObjectType as ==,
-    neObjectType as !=,
-    ObjectTypeLib.toInt,
-    ObjectTypeLib.gtz
-} for ObjectType global;
-
-// general pure free functions
-
-function PROTOCOL() pure returns (ObjectType) {
-    return toObjectType(10);
-}
-
-function ROLE() pure returns (ObjectType) {
-    return toObjectType(20);
-}
-
-function TARGET() pure returns (ObjectType) {
-    return toObjectType(30);
-}
-
-function REGISTRY() pure returns (ObjectType) {
-    return toObjectType(40);
-}
-
-function TOKEN() pure returns (ObjectType) {
-    return toObjectType(50);
-}
-
-function SERVICE() pure returns (ObjectType) {
-    return toObjectType(60);
-}
-
-function INSTANCE() pure returns (ObjectType) {
-    return toObjectType(70);
-}
-
-function STAKE() pure returns (ObjectType) {
-    return toObjectType(80);
-}
-
-function COMPONENT() pure returns (ObjectType) {
-    return toObjectType(100);
-}
-
-// TODO replace by PRODUCT_SETUP
-function TREASURY() pure returns (ObjectType) {
-    return toObjectType(101);
-}
-
-function PRODUCT_SETUP() pure returns (ObjectType) {
-    return toObjectType(101);
-}
-
-function PRODUCT() pure returns (ObjectType) {
-    return toObjectType(110);
-}
-
-function DISTRIBUTION() pure returns (ObjectType) {
-    return toObjectType(120);
-}
-
-function DISTRIBUTION_TYPE() pure returns (ObjectType) {
-    return toObjectType(121);
-}
-
-function DISTRIBUTOR() pure returns (ObjectType) {
-    return toObjectType(122);
-}
-
-function REFERRAL() pure returns (ObjectType) {
-    return toObjectType(123);
-}
-
-function ORACLE() pure returns (ObjectType) {
-    return toObjectType(130);
-}
-
-function POOL() pure returns (ObjectType) {
-    return toObjectType(140);
-}
-
-function RISK() pure returns (ObjectType) {
-    return toObjectType(200);
-}
-
-function POLICY() pure returns (ObjectType) {
-    return toObjectType(210);
-}
-
-function BUNDLE() pure returns (ObjectType) {
-    return toObjectType(220);
-}
-
-function CLAIM() pure returns (ObjectType) {
-    return toObjectType(211);
-}
-
-function PAYOUT() pure returns (ObjectType) {
-    return toObjectType(212);
-}
-
-/// @dev Converts the uint8 to a ObjectType.
-function toObjectType(uint256 objectType) pure returns (ObjectType) {
-    return ObjectType.wrap(uint8(objectType));
-}
-
-/// @dev Return the ObjectType zero (0)
-function zeroObjectType() pure returns (ObjectType) {
-    return ObjectType.wrap(0);
-}
-
-// pure free functions for operators
-function eqObjectType(ObjectType a, ObjectType b) pure returns (bool isSame) {
-    return ObjectType.unwrap(a) == ObjectType.unwrap(b);
-}
-
-function neObjectType(
-    ObjectType a,
-    ObjectType b
-) pure returns (bool isDifferent) {
-    return ObjectType.unwrap(a) != ObjectType.unwrap(b);
-}
-
-// library functions that operate on user defined type
-library ObjectTypeLib {
-    /// @dev Converts the NftId to a uint256.
-    function toInt(ObjectType objectType) public pure returns (uint96) {
-        return uint96(ObjectType.unwrap(objectType));
-    }
-
-    /// @dev Returns true if the value is non-zero (> 0).
-    function gtz(ObjectType a) public pure returns (bool) {
-        return ObjectType.unwrap(a) > 0;
-    }
-
-    /// @dev Returns true if the value is zero (== 0).
-    function eqz(ObjectType a) public pure returns (bool) {
-        return ObjectType.unwrap(a) == 0;
-    }
-
-    /// @dev Returns true if the values are equal (==).
-    function eq(ObjectType a, ObjectType b) public pure returns (bool isSame) {
-        return eqObjectType(a, b);
-    }
-}

package/contracts/types/RoleId.sol

@@ -1,75 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {Key32, KeyId, Key32Lib} from "./Key32.sol";
-import {ROLE} from "./ObjectType.sol";
-
-type RoleId is uint64;
-
-// type bindings
-using {
-    eqRoleId as ==, 
-    neRoleId as !=,
-    RoleIdLib.eqz,
-    RoleIdLib.gtz,
-    RoleIdLib.toInt,
-    RoleIdLib.toKey32
-} for RoleId global;
-
-// general pure free functions
-function DISTRIBUTION_OWNER_ROLE_NAME() pure returns (string memory) { return "DistributionOwnerRole"; }
-function ORACLE_OWNER_ROLE_NAME() pure returns (string memory) { return "OracleOwnerRole"; }
-function POOL_OWNER_ROLE_NAME() pure returns (string memory) { return "PoolOwnerRole"; }
-function PRODUCT_OWNER_ROLE_NAME() pure returns (string memory) { return "ProductOwnerRole"; }
-
-// function DISTRIBUTION_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId("DistributionOwnerRole"); }
-// function ORACLE_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId("OracleOwnerRole"); }
-// function POOL_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId("PoolOwnerRole"); }
-// function PRODUCT_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId("ProductOwnerRole"); }
-
-// @dev Returns true iff role ids a and b are identical
-function eqRoleId(RoleId a, RoleId b) pure returns (bool isSame) {
-    return RoleId.unwrap(a) == RoleId.unwrap(b);
-}
-
-// @dev Returns true iff role ids a and b are different
-function neRoleId(RoleId a, RoleId b) pure returns (bool isDifferent) {
-    return RoleId.unwrap(a) != RoleId.unwrap(b);
-}
-
-library RoleIdLib {
-/// @dev Converts the RoleId to a uint.
-    function zero() public pure returns (RoleId) {
-        return RoleId.wrap(0);
-    }
-
-    /// @dev Converts an uint into a RoleId.
-    function toRoleId(uint256 a) public pure returns (RoleId) {
-        return RoleId.wrap(uint64(a));
-    }
-
-    /// @dev Converts the RoleId to a uint.
-    function toInt(RoleId a) public pure returns (uint64) {
-        return uint64(RoleId.unwrap(a));
-    }
-
-    /// @dev Returns true if the value is non-zero (> 0).
-    function gtz(RoleId a) public pure returns (bool) {
-        return RoleId.unwrap(a) > 0;
-    }
-
-    /// @dev Returns true if the value is zero (== 0).
-    function eqz(RoleId a) public pure returns (bool) {
-        return RoleId.unwrap(a) == 0;
-    }
-
-    /// @dev Returns the key32 value for the specified id and object type.
-    function toKey32(RoleId a) public pure returns (Key32 key) {
-        return Key32Lib.toKey32(ROLE(), toKeyId(a));
-    }
-
-    /// @dev Returns the key id value for the specified id
-    function toKeyId(RoleId a) public pure returns (KeyId keyId) {
-        return KeyId.wrap(bytes31(uint248(RoleId.unwrap(a))));
-    }
-}

package/contracts/types/UFixed.sol

@@ -1,209 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {Math} from "@openzeppelin/contracts/utils/math/Math.sol";
-
-/// @dev UFixed is a fixed point number with 18 decimals precision.
-type UFixed is uint256;
-
-using {
-    addUFixed as +,
-    subUFixed as -,
-    mulUFixed as *,
-    divUFixed as /,
-    gtUFixed as >,
-    gteUFixed as >=,
-    ltUFixed as <,
-    lteUFixed as <=,
-    eqUFixed as ==,
-    UFixedMathLib.toInt
-} for UFixed global;
-
-function addUFixed(UFixed a, UFixed b) pure returns (UFixed) {
-    return UFixed.wrap(UFixed.unwrap(a) + UFixed.unwrap(b));
-}
-
-function subUFixed(UFixed a, UFixed b) pure returns (UFixed) {
-    require(a >= b, "ERROR:UFM-010:NEGATIVE_RESULT");
-    return UFixed.wrap(UFixed.unwrap(a) - UFixed.unwrap(b));
-}
-
-function mulUFixed(UFixed a, UFixed b) pure returns (UFixed) {
-    return
-        UFixed.wrap(Math.mulDiv(UFixed.unwrap(a), UFixed.unwrap(b), 10 ** 18));
-}
-
-function divUFixed(UFixed a, UFixed b) pure returns (UFixed) {
-    require(UFixed.unwrap(b) > 0, "ERROR:UFM-020:DIVISOR_ZERO");
-
-    return
-        UFixed.wrap(Math.mulDiv(UFixed.unwrap(a), 10 ** 18, UFixed.unwrap(b)));
-}
-
-function gtUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
-    return UFixed.unwrap(a) > UFixed.unwrap(b);
-}
-
-function gteUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
-    return UFixed.unwrap(a) >= UFixed.unwrap(b);
-}
-
-function ltUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
-    return UFixed.unwrap(a) < UFixed.unwrap(b);
-}
-
-function lteUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
-    return UFixed.unwrap(a) <= UFixed.unwrap(b);
-}
-
-function eqUFixed(UFixed a, UFixed b) pure returns (bool isEqual) {
-    return UFixed.unwrap(a) == UFixed.unwrap(b);
-}
-
-function gtzUFixed(UFixed a) pure returns (bool isZero) {
-    return UFixed.unwrap(a) > 0;
-}
-
-function eqzUFixed(UFixed a) pure returns (bool isZero) {
-    return UFixed.unwrap(a) == 0;
-}
-
-function deltaUFixed(UFixed a, UFixed b) pure returns (UFixed) {
-    if (a > b) {
-        return a - b;
-    }
-
-    return b - a;
-}
-
-library UFixedMathLib {
-    int8 public constant EXP = 18;
-    uint256 public constant MULTIPLIER = 10 ** uint256(int256(EXP));
-    uint256 public constant MULTIPLIER_HALF = MULTIPLIER / 2;
-
-    /// @dev returns the rounding mode DOWN - 0.4 becomes 0, 0.5 becomes 0, 0.6 becomes 0
-    function ROUNDING_DOWN() public pure returns (uint8) {
-        return uint8(0);
-    }
-
-    /// @dev returns the rounding mode UP - 0.4 becomes 1, 0.5 becomes 1, 0.6 becomes 1
-    function ROUNDING_UP() public pure returns (uint8) {
-        return uint8(1);
-    }
-
-    /// @dev returns the rounding mode HALF_UP - 0.4 becomes 0, 0.5 becomes 1, 0.6 becomes 1
-    function ROUNDING_HALF_UP() public pure returns (uint8) {
-        return uint8(2);
-    }
-
-    /// @dev Converts the uint256 to a UFixed.
-    function toUFixed(uint256 a) public pure returns (UFixed) {
-        return UFixed.wrap(a * MULTIPLIER);
-    }
-
-    /// @dev Converts the uint256 to a UFixed with given exponent.
-    function toUFixed(uint256 a, int8 exp) public pure returns (UFixed) {
-        require(EXP + exp >= 0, "ERROR:FM-010:EXPONENT_TOO_SMALL");
-        require(EXP + exp <= 64, "ERROR:FM-011:EXPONENT_TOO_LARGE");
-
-        return UFixed.wrap(a * 10 ** uint8(EXP + exp));
-    }
-
-    /// @dev returns the decimals precision of the UFixed type
-    function decimals() public pure returns (uint256) {
-        return uint8(EXP);
-    }
-
-    /// @dev Converts a UFixed to a uint256.
-    function toInt(UFixed a) public pure returns (uint256) {
-        return toIntWithRounding(a, ROUNDING_HALF_UP());
-    }
-
-    /// @dev Converts a UFixed to a uint256 with given rounding mode.
-    function toIntWithRounding(UFixed a, uint8 rounding) public pure returns (uint256) {
-        if (rounding == ROUNDING_HALF_UP()) {
-            return
-                Math.mulDiv(
-                    UFixed.unwrap(a) + MULTIPLIER_HALF,
-                    1,
-                    MULTIPLIER,
-                    Math.Rounding.Down
-                );
-        } else if (rounding == ROUNDING_DOWN()) {
-            return
-                Math.mulDiv(
-                    UFixed.unwrap(a),
-                    1,
-                    MULTIPLIER,
-                    Math.Rounding.Down
-                );
-        } else {
-            return
-                Math.mulDiv(UFixed.unwrap(a), 1, MULTIPLIER, Math.Rounding.Up);
-        }
-    }
-
-    /// @dev adds two UFixed numbers
-    function add(UFixed a, UFixed b) public pure returns (UFixed) {
-        return addUFixed(a, b);
-    }
-
-    /// @dev subtracts two UFixed numbers
-    function sub(UFixed a, UFixed b) public pure returns (UFixed) {
-        return subUFixed(a, b);
-    }
-
-    /// @dev multiplies two UFixed numbers
-    function mul(UFixed a, UFixed b) public pure returns (UFixed) {
-        return mulUFixed(a, b);
-    }
-
-    /// @dev divides two UFixed numbers
-    function div(UFixed a, UFixed b) public pure returns (UFixed) {
-        return divUFixed(a, b);
-    }
-
-    /// @dev return true if UFixed a is greater than UFixed b
-    function gt(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
-        return gtUFixed(a, b);
-    }
-
-    /// @dev return true if UFixed a is greater than or equal to UFixed b
-    function gte(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
-        return gteUFixed(a, b);
-    }
-
-    /// @dev return true if UFixed a is less than UFixed b
-    function lt(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
-        return ltUFixed(a, b);
-    }
-
-    /// @dev return true if UFixed a is less than or equal to UFixed b
-    function lte(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
-        return lteUFixed(a, b);
-    }
-
-    /// @dev return true if UFixed a is equal to UFixed b
-    function eq(UFixed a, UFixed b) public pure returns (bool isEqual) {
-        return eqUFixed(a, b);
-    }
-
-    /// @dev return true if UFixed a is not zero
-    function gtz(UFixed a) public pure returns (bool isZero) {
-        return gtzUFixed(a);
-    }
-
-    /// @dev return true if UFixed a is zero
-    function eqz(UFixed a) public pure returns (bool isZero) {
-        return eqzUFixed(a);
-    }
-
-    function zero() public pure returns (UFixed) {
-        return UFixed.wrap(0);
-    }
-
-    /// @dev return the absolute delta between two UFixed numbers
-    function delta(UFixed a, UFixed b) public pure returns (UFixed) {
-        return deltaUFixed(a, b);
-    }
-}