@etherisc/gif-next 0.0.2-ce8407f-016 → 0.0.2-ce87da3-250

package/contracts/components/IPoolComponent.sol

@@ -0,0 +1,87 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Fee} from "../types/Fee.sol";
+import {IComponent} from "./IComponent.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+import {NftId} from "../types/NftId.sol";
+import {UFixed} from "../types/UFixed.sol";
+
+/// @dev pool components hold and manage the collateral to cover active policies
+/// pools come in different flavors
+interface IPoolComponent is IComponent {
+
+    event LogUnderwrittenByPool(NftId policyNftId, uint256 collateralizationAmount, address pool);
+
+    error ErrorPoolNotPoolService(address service);
+
+    function getSetupInfo() external view returns (ISetup.PoolSetupInfo memory setupInfo);
+
+    function setFees(
+        Fee memory poolFee,
+        Fee memory stakingFee,
+        Fee memory performanceFee
+    ) external;
+
+    /// @dev sets an additional bundle fee, this fee is added on top of the poolFee and deducted from the premium amounts.
+    /// via these fees individual bundler owner may earn income per policy in the context of peer to peer pools
+    function setBundleFee(
+        NftId bundleNftId, 
+        Fee memory fee
+    ) external;
+
+    /// @dev this is a callback function that is called by the product service when underwriting a policy.
+    /// the pool has the option to check the details and object to underwriting by reverting.
+    /// the function is only called for "active" pools that ask to be involved/notified
+    /// by product related state changes.
+    function verifyApplication(
+        NftId applicationNftId, 
+        bytes memory policyData,
+        bytes memory bundleFilter,
+        uint256 collateralizationAmount
+    ) external;
+
+    function lockBundle(NftId bundleNftId) external;
+
+    function unlockBundle(NftId bundleNftId) external;
+
+    /// @dev defines the multiplier to calculate the required collateral to cover a given sum insured amount
+    /// default implementation returns 100%
+    function getCollateralizationLevel() external view returns (UFixed collateralizationLevel);
+
+    /// @dev defines the amount of collateral held in the pool.
+    /// if the value is < 100% the pool is required to hold a policy that covers the locally missing collateral
+    /// default implementation returns 100%
+    function getRetentionLevel() external view returns (UFixed retentionLevel);
+
+    /// @dev declares if pool intercept transfers of bundle nft ids
+    /// - yes: pool may block transfer of bundle ownership or simply updates some bookkeeping related to bundle ownership. callback function is nftTransferFrom
+    /// - no: pool is not involved in transfer of bundle ownership
+    /// default implementation returns false (no)
+    function isInterceptingBundleTransfers() external view returns (bool);
+
+    /// @dev declares if pool relies on external management of collateral (yes/no): 
+    /// - yes: underwriting of new policies does not require an actual token balance, instead it is assumed that the pool owner will manage funds externally and inject enough tokens to allow process confirmed payouts
+    /// - no: the pool smart contract ensures that the necessary capacity of the pool prior to underwriting.
+    /// default implementation returns false (no)
+    function isExternallyManaged() external view returns (bool);
+
+    /// @dev declares if pool component is actively involved in underwriting (yes/no): 
+    /// - yes: verifying pools components actively confirm underwriting applications, ie the pool component logic explicitly needs to confirm the locking of collateral to cover the sum insured of the policy
+    /// - no: underwriting a policy does not require any interaction with the pool component if the covering bundle can provide the necessary captial
+    /// default implementation returnsfalse (no)
+    function isVerifyingApplications() external view returns (bool);
+
+    /// @dev returns true iff the policy application data in policyData matches
+    /// with the bundle filter criteria encoded in bundleFilter
+    /// this is a callback function that is only called if a pool declares itself as a verifying pool
+    /// default implementation returns true
+    function policyMatchesBundle(
+        bytes memory policyData,
+        bytes memory bundleFilter
+    )
+        external
+        view
+        returns (bool isMatching);
+
+}

package/contracts/components/IProductComponent.sol

@@ -0,0 +1,39 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Fee} from "../types/Fee.sol";
+import {IComponent} from "./IComponent.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+import {NftId} from "../types/NftId.sol";
+import {ReferralId} from "../types/Referral.sol";
+import {RiskId} from "../types/RiskId.sol";
+
+interface IProductComponent is IComponent {
+
+    function getSetupInfo() external view returns (ISetup.ProductSetupInfo memory setupInfo);
+
+    function setFees(
+        Fee memory productFee,
+        Fee memory processingFee
+    ) external;
+
+    function calculatePremium(
+        uint256 sumInsuredAmount,
+        RiskId riskId,
+        uint256 lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    ) external view returns (uint256 premiumAmount);
+
+    function calculateNetPremium(
+        uint256 sumInsuredAmount,
+        RiskId riskId,
+        uint256 lifetime,
+        bytes memory applicationData
+    ) external view returns (uint256 netPremiumAmount);    
+
+    
+    function getPoolNftId() external view returns (NftId poolNftId);
+    function getDistributionNftId() external view returns (NftId distributionNftId);
+}

package/contracts/components/Pool.sol

@@ -0,0 +1,254 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {POOL} from "../types/ObjectType.sol";
+import {IPoolService} from "../instance/service/IPoolService.sol";
+import {IBundleService} from "../instance/service/IBundleService.sol";
+import {NftId, NftIdLib} from "../types/NftId.sol";
+import {Fee, FeeLib} from "../types/Fee.sol";
+import {UFixed} from "../types/UFixed.sol";
+import {IPoolComponent} from "./IPoolComponent.sol";
+import {Component} from "./Component.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+
+import {ISetup} from "../instance/module/ISetup.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+
+
+abstract contract Pool is
+    Component, 
+    IPoolComponent 
+{
+    // keccak256(abi.encode(uint256(keccak256("etherisc.storage.Pool")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant POOL_STORAGE_LOCATION_V1 = 0x25e3e51823fbfffb988e0a2744bb93722d9f3e906c07cc0a9e77884c46c58300;
+
+    struct PoolStorage {
+        UFixed _collateralizationLevel;
+        UFixed _retentionLevel;
+
+        bool _isExternallyManaged;
+        bool _isInterceptingBundleTransfers;
+        bool _isVerifyingApplications;
+
+        Fee _initialPoolFee;
+        Fee _initialStakingFee;
+        Fee _initialPerformanceFee;
+
+        TokenHandler _tokenHandler;
+
+        // may be used to interact with instance by derived contracts
+        IPoolService _poolService;
+        IBundleService _bundleService;
+    }
+
+    modifier onlyPoolService() {
+        if(msg.sender != address(_getPoolStorage()._poolService)) {
+            revert ErrorPoolNotPoolService(msg.sender);
+        }
+        _;
+    }
+
+
+    function initializePool(
+        address registry,
+        NftId instanceNftId,
+        string memory name,
+        // TODO refactor into tokenNftId
+        address token,
+        bool isInterceptingNftTransfers,
+        bool isExternallyManaging,
+        bool isVerifying,
+        UFixed collateralizationLevel,
+        UFixed retentionLevel,
+        address initialOwner,
+        bytes memory data
+    )
+        public
+        virtual
+        onlyInitializing()
+    {
+        initializeComponent(registry, instanceNftId, name, token, POOL(), isInterceptingNftTransfers, initialOwner, data);
+
+        PoolStorage storage $ = _getPoolStorage();
+        // TODO add validation
+        $._tokenHandler = new TokenHandler(token);
+        $._isExternallyManaged = isExternallyManaging;
+        $._isVerifyingApplications = isVerifying;
+        $._collateralizationLevel = collateralizationLevel;
+        $._retentionLevel = retentionLevel;
+        $._initialPoolFee = FeeLib.zeroFee();
+        $._initialStakingFee = FeeLib.zeroFee();
+        $._initialPerformanceFee = FeeLib.zeroFee();
+        $._poolService = getInstance().getPoolService();
+        $._bundleService = getInstance().getBundleService();
+
+        registerInterface(type(IPoolComponent).interfaceId);
+    }
+
+    /**
+     * @dev see {IPool.verifyApplication}. 
+     * Default implementation that only writes a {LogUnderwrittenByPool} entry.
+     */
+    function verifyApplication(
+        NftId applicationNftId, 
+        bytes memory applicationData,
+        bytes memory bundleFilter,
+        uint256 collateralizationAmount
+    )
+        external
+        restricted()
+        virtual override 
+    {
+        require(
+            policyMatchesBundle(applicationData, bundleFilter),
+            "ERROR:POL-020:POLICY_BUNDLE_MISMATCH"
+        );
+
+        emit LogUnderwrittenByPool(applicationNftId, collateralizationAmount, address(this));
+    }
+
+
+    function isInterceptingBundleTransfers() external view override returns (bool) {
+        return isNftInterceptor();
+    }
+
+
+    function isExternallyManaged() external view override returns (bool) {
+        return _getPoolStorage()._isExternallyManaged;
+    }
+
+
+    function getRetentionLevel() external view override returns (UFixed retentionLevel) {
+        return _getPoolStorage()._retentionLevel;
+    }
+
+
+    function getCollateralizationLevel() external view override returns (UFixed collateralizationLevel) {
+        return _getPoolStorage()._collateralizationLevel;
+    }
+
+
+    function isVerifyingApplications() external view override returns (bool isConfirmingApplication) {
+        return _getPoolStorage()._isVerifyingApplications;
+    }
+
+
+    /// @dev see {IPoolComponent.policyMatchesBundle}. 
+    /// Default implementation always returns true
+    function policyMatchesBundle(
+        bytes memory, // policyData
+        bytes memory // bundleFilter
+    )
+        public
+        pure
+        virtual override
+        returns (bool isMatching)
+    {
+        return true;
+    }
+
+
+    function setFees(
+        Fee memory poolFee,
+        Fee memory stakingFee,
+        Fee memory performanceFee
+    )
+        external
+        onlyOwner
+        restricted()
+        override
+    {
+        _getPoolStorage()._poolService.setFees(poolFee, stakingFee, performanceFee);
+    }
+
+    function setBundleFee(
+        NftId bundleNftId, 
+        Fee memory fee
+    )
+        external
+        override
+        // TODO add onlyBundleOwner
+    {
+        _getPoolStorage()._bundleService.setBundleFee(bundleNftId, fee);
+    }
+
+    function lockBundle(
+        NftId bundleNftId
+    )
+        external
+        override
+        // TODO add onlyBundleOwner
+    {
+        _getPoolStorage()._bundleService.lockBundle(bundleNftId);
+    }
+
+    function unlockBundle(
+        NftId bundleNftId
+    )
+        external
+        override
+        // TODO add onlyBundleOwner
+    {
+        _getPoolStorage()._bundleService.unlockBundle(bundleNftId);
+    }
+
+    function getSetupInfo() public view returns (ISetup.PoolSetupInfo memory setupInfo) {
+        InstanceReader reader = getInstance().getInstanceReader();
+        setupInfo = reader.getPoolSetupInfo(getNftId());
+
+        // fallback to initial setup info (wallet is always != address(0))
+        if(setupInfo.wallet == address(0)) {
+            setupInfo = _getInitialSetupInfo();
+        }
+    }
+
+    function _getInitialSetupInfo() internal view returns (ISetup.PoolSetupInfo memory) {
+        PoolStorage storage $ = _getPoolStorage();
+        return ISetup.PoolSetupInfo(
+            getProductNftId(),
+            $._tokenHandler,
+            isNftInterceptor(),
+            $._isExternallyManaged,
+            $._isVerifyingApplications,
+            $._collateralizationLevel,
+            $._retentionLevel,
+            $._initialPoolFee,
+            $._initialStakingFee,
+            $._initialPerformanceFee,
+            getWallet()
+        );
+    }
+
+    // Internals
+
+    function _createBundle(
+        address bundleOwner,
+        Fee memory fee,
+        uint256 amount,
+        uint256 lifetime, 
+        bytes memory filter
+    )
+        internal
+        returns(NftId bundleNftId)
+    {
+        bundleNftId = _getPoolStorage()._bundleService.createBundle(
+            bundleOwner,
+            fee,
+            amount,
+            lifetime,
+            filter);
+
+        // TODO add logging
+    }
+
+    function getContractLocation(bytes memory name) external pure returns (bytes32 hash) {
+        return keccak256(abi.encode(uint256(keccak256(name)) - 1)) & ~bytes32(uint256(0xff));
+    }
+
+    function _getPoolStorage() private pure returns (PoolStorage storage $) {
+        assembly {
+            $.slot := POOL_STORAGE_LOCATION_V1
+        }
+    }
+}

package/contracts/components/Product.sol

@@ -0,0 +1,285 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {IRisk} from "../instance/module/IRisk.sol";
+import {IApplicationService} from "../instance/service/IApplicationService.sol";
+import {IPolicyService} from "../instance/service/IPolicyService.sol";
+import {IClaimService} from "../instance/service/IClaimService.sol";
+import {IProductComponent} from "./IProductComponent.sol";
+import {NftId, NftIdLib} from "../types/NftId.sol";
+import {PRODUCT, APPLICATION, POLICY, CLAIM } from "../types/ObjectType.sol";
+import {ReferralId} from "../types/Referral.sol";
+import {RiskId, RiskIdLib} from "../types/RiskId.sol";
+import {StateId} from "../types/StateId.sol";
+import {Timestamp} from "../types/Timestamp.sol";
+import {Fee} from "../types/Fee.sol";
+import {Component} from "./Component.sol";
+
+import {TokenHandler} from "../shared/TokenHandler.sol";
+
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+import {Pool} from "../components/Pool.sol";
+import {Distribution} from "../components/Distribution.sol";
+
+abstract contract Product is
+    Component, 
+    IProductComponent
+{
+    // keccak256(abi.encode(uint256(keccak256("etherisc.storage.Product")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant PRODUCT_STORAGE_LOCATION_V1 = 0x0bb7aafdb8e380f81267337bc5b5dfdf76e6d3a380ecadb51ec665246d9d6800;
+
+    struct ProductStorage {
+        IApplicationService _applicationService;
+        IPolicyService _policyService;
+        IClaimService _claimService;
+        Pool _pool;
+        Distribution _distribution;
+        Fee _initialProductFee;
+        Fee _initialProcessingFee;
+        TokenHandler _tokenHandler;
+        NftId _poolNftId;
+        NftId _distributionNftId;
+    }
+
+    function initializeProduct(
+        address registry,
+        NftId instanceNftId,
+        string memory name,
+        address token,
+        bool isInterceptor,
+        address pool,
+        address distribution,
+        Fee memory productFee,
+        Fee memory processingFee,
+        address initialOwner,
+        bytes memory data
+    )
+        public
+        virtual
+        onlyInitializing()
+    {
+        initializeComponent(registry, instanceNftId, name, token, PRODUCT(), isInterceptor, initialOwner, data);
+
+        ProductStorage storage $ = _getProductStorage();
+        // TODO add validation
+        // TODO refactor to go via registry
+        $._applicationService = IApplicationService(getServiceAddress(APPLICATION())); 
+        $._policyService = IPolicyService(getServiceAddress(POLICY())); 
+        $._claimService = IClaimService(getServiceAddress(CLAIM())); 
+        $._pool = Pool(pool);
+        $._distribution = Distribution(distribution);
+        $._initialProductFee = productFee;
+        $._initialProcessingFee = processingFee;  
+        $._tokenHandler = new TokenHandler(token);
+        $._poolNftId = getRegistry().getNftId(pool);
+        $._distributionNftId = getRegistry().getNftId(distribution);
+
+        registerInterface(type(IProductComponent).interfaceId);  
+    }
+
+
+    function calculatePremium(
+        uint256 sumInsuredAmount,
+        RiskId riskId,
+        uint256 lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        external 
+        view 
+        override 
+        returns (uint256 premiumAmount)
+    {
+        (premiumAmount,,,,) = _getProductStorage()._policyService.calculatePremium(
+            riskId,
+            sumInsuredAmount,
+            lifetime,
+            applicationData,
+            bundleNftId,
+            referralId
+        );
+    }
+
+
+    function calculateNetPremium(
+        uint256 sumInsuredAmount,
+        RiskId riskId,
+        uint256 lifetime,
+        bytes memory applicationData
+    )
+        external
+        view
+        virtual override
+        returns (uint256 netPremiumAmount)
+    {
+        // default 10% of sum insured
+        return sumInsuredAmount / 10;
+    }
+
+    function _toRiskId(string memory riskName) internal pure returns (RiskId riskId) {
+        return RiskIdLib.toRiskId(riskName);
+    }
+
+    function _createRisk(
+        RiskId id,
+        bytes memory data
+    ) internal {
+        getProductService().createRisk(
+            id,
+            data
+        );
+    }
+
+    function _updateRisk(
+        RiskId id,
+        bytes memory data
+    ) internal {
+        getProductService().updateRisk(
+            id,
+            data
+        );
+    }
+
+    function _updateRiskState(
+        RiskId id,
+        StateId state
+    ) internal {
+        getProductService().updateRiskState(
+            id,
+            state
+        );
+    }
+
+    function _getRiskInfo(RiskId id) internal view returns (IRisk.RiskInfo memory info) {
+        return getInstance().getInstanceReader().getRiskInfo(id);
+    }
+
+    function _createApplication(
+        address applicationOwner,
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        uint256 lifetime,
+        NftId bundleNftId,
+        ReferralId referralId,
+        bytes memory applicationData
+    )
+        internal
+        returns (NftId applicationNftId) 
+    {
+        return _getProductStorage()._applicationService.create(
+            applicationOwner,
+            riskId,
+            sumInsuredAmount,
+            lifetime,
+            bundleNftId,
+            referralId,
+            applicationData
+        );
+    }
+
+    function _underwrite(
+        NftId policyNftId,
+        bool requirePremiumPayment,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _getProductStorage()._policyService.underwrite(
+            policyNftId, 
+            requirePremiumPayment, 
+            activateAt);
+    }
+
+    function _collectPremium(
+        NftId policyNftId,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _getProductStorage()._policyService.collectPremium(
+            policyNftId, 
+            activateAt);
+    }
+
+    function _activate(
+        NftId policyNftId,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _getProductStorage()._policyService.activate(
+            policyNftId, 
+            activateAt);
+    }
+
+    function _close(
+        NftId policyNftId
+    )
+        internal
+    {
+        _getProductStorage()._policyService.close(policyNftId);
+    }
+
+    function getPoolNftId() external view override returns (NftId poolNftId) {
+        return getRegistry().getNftId(address(_getProductStorage()._pool));
+    }
+
+    function getDistributionNftId() external view override returns (NftId distributionNftId) {
+        return getRegistry().getNftId(address(_getProductStorage()._distribution));
+    }
+
+    // from product component
+    function setFees(
+        Fee memory productFee,
+        Fee memory processingFee
+    )
+        external
+        onlyOwner
+        restricted()
+        override
+    {
+        getProductService().setFees(productFee, processingFee);
+    }
+
+    function getSetupInfo() public view returns (ISetup.ProductSetupInfo memory setupInfo) {
+        InstanceReader reader = getInstance().getInstanceReader();
+        setupInfo = reader.getProductSetupInfo(getNftId());
+
+        // fallback to initial setup info (wallet is always != address(0))
+        if(setupInfo.wallet == address(0)) {
+            setupInfo = _getInitialSetupInfo();
+        }
+    }
+
+    function _getInitialSetupInfo() internal view returns (ISetup.ProductSetupInfo memory setupInfo) {
+        ProductStorage storage $ = _getProductStorage();
+
+        ISetup.DistributionSetupInfo memory distributionSetupInfo = $._distribution.getSetupInfo();
+        ISetup.PoolSetupInfo memory poolSetupInfo = $._pool.getSetupInfo();
+
+        return ISetup.ProductSetupInfo(
+            getToken(),
+            $._tokenHandler,
+            $._distributionNftId,
+            $._poolNftId,
+            distributionSetupInfo.distributionFee, 
+            $._initialProductFee,
+            $._initialProcessingFee,
+            poolSetupInfo.poolFee, 
+            poolSetupInfo.stakingFee, 
+            poolSetupInfo.performanceFee,
+            false,
+            getWallet()
+        );
+    }
+
+    function _getProductStorage() private pure returns (ProductStorage storage $) {
+        assembly {
+            $.slot := PRODUCT_STORAGE_LOCATION_V1
+        }
+    }
+}