@etherisc/gif-next 0.0.2-ce2fc91-485 → 0.0.2-ce8407f-016

package/contracts/instance/InstanceAccessManager.sol

@@ -0,0 +1,288 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {EnumerableSet} from "@openzeppelin5/contracts/utils/structs/EnumerableSet.sol";
+import {ShortString, ShortStrings} from "@openzeppelin5/contracts/utils/ShortStrings.sol";
+
+import {AccessManagedSimple} from "./AccessManagedSimple.sol";
+import {AccessManagerSimple} from "./AccessManagerSimple.sol";
+import {IBundle} from "./module/IBundle.sol";
+import {IPolicy} from "./module/IPolicy.sol";
+import {IRisk} from "./module/IRisk.sol";
+import {ISetup} from "./module/ISetup.sol";
+import {Key32, KeyId, Key32Lib} from "../types/Key32.sol";
+import {KeyValueStore} from "./base/KeyValueStore.sol";
+import {NftId} from "../types/NftId.sol";
+import {NumberId} from "../types/NumberId.sol";
+import {ObjectType, BUNDLE, DISTRIBUTION, POLICY, POOL, ROLE, PRODUCT, TARGET} from "../types/ObjectType.sol";
+import {RiskId, RiskIdLib} from "../types/RiskId.sol";
+import {RoleId, RoleIdLib} from "../types/RoleId.sol";
+import {StateId, ACTIVE} from "../types/StateId.sol";
+import {Timestamp, TimestampLib} from "../types/Timestamp.sol";
+
+contract InstanceAccessManager is
+    AccessManagedSimple
+{
+    string public constant ADMIN_ROLE_NAME = "AdminRole";
+    string public constant PUBLIC_ROLE_NAME = "PublicRole";
+
+    uint64 public constant CUSTOM_ROLE_ID_MIN = 10000;
+    uint32 public constant EXECUTION_DELAY = 0;
+
+    struct RoleInfo {
+        ShortString name;
+        bool isCustom;
+        bool isLocked;
+        Timestamp createdAt;
+        Timestamp updatedAt;
+    }
+
+    struct TargetInfo {
+        ShortString name;
+        bool isCustom;
+        bool isLocked;
+        Timestamp createdAt;
+        Timestamp updatedAt;
+    }
+
+    error ErrorRoleIdInvalid(RoleId roleId);
+    error ErrorRoleIdTooBig(RoleId roleId);
+    error ErrorRoleIdTooSmall(RoleId roleId);
+    error ErrorRoleIdAlreadyExists(RoleId roleId, ShortString name);
+    error ErrorRoleIdNotActive(RoleId roleId);
+    error ErrorRoleNameEmpty(RoleId roleId);
+    error ErrorRoleNameNotUnique(RoleId roleId, ShortString name);
+    error ErrorRoleInvalidUpdate(RoleId roleId, bool isCustom);
+    error ErrorRoleIsCustomIsImmutable(RoleId roleId, bool isCustom, bool isCustomExisting);
+    error ErrorSetLockedForNonexstentRole(RoleId roleId);
+    error ErrorGrantNonexstentRole(RoleId roleId);
+    error ErrorRevokeNonexstentRole(RoleId roleId);
+    error ErrorRenounceNonexstentRole(RoleId roleId);
+
+    error ErrorTargetAddressZero();
+    error ErrorTargetAlreadyExists(address target, ShortString name);
+    error ErrorTargetNameEmpty(address target);
+    error ErrorTargetNameExists(address target, address existingTarget, ShortString name);
+    error ErrorSetLockedForNonexstentTarget(address target);
+
+    // role specific state
+    mapping(RoleId roleId => RoleInfo info) internal _role;
+    mapping(RoleId roleId => EnumerableSet.AddressSet roleMembers) internal _roleMembers; 
+    mapping(ShortString name => RoleId roleId) internal _roleForName;
+    RoleId [] internal _roles;
+
+    // target specific state
+    mapping(address target => TargetInfo info) internal _target;
+    mapping(ShortString name => address target) internal _targetForName;
+    address [] internal _targets;
+
+    AccessManagerSimple internal _accessManager;
+
+    constructor(address accessManager)
+        AccessManagedSimple(accessManager)
+    {
+        _accessManager = AccessManagerSimple(accessManager);
+
+        _createRole(RoleIdLib.toRoleId(_accessManager.ADMIN_ROLE()), ADMIN_ROLE_NAME, false, false);
+        _createRole(RoleIdLib.toRoleId(_accessManager.PUBLIC_ROLE()), PUBLIC_ROLE_NAME, false, false);
+    }
+
+    //--- Role ------------------------------------------------------//
+
+    function createDefaultRole(RoleId roleId, string memory name) external restricted() {
+        _createRole(roleId, name, false, true);
+    }
+
+    function createRole(RoleId roleId, string memory name) external restricted() {
+        _createRole(roleId, name, true, true);
+    }
+
+    function setRoleLocked(RoleId roleId, bool locked) external restricted() {
+        if (!roleExists(roleId)) {
+            revert ErrorSetLockedForNonexstentRole(roleId);
+        }
+
+        _role[roleId].isLocked = locked;
+        _role[roleId].updatedAt = TimestampLib.blockTimestamp();
+    }
+
+    function roleExists(RoleId roleId) public view returns (bool exists) {
+        return _role[roleId].createdAt.gtz();
+    }
+
+    function grantRole(RoleId roleId, address member) external restricted() returns (bool granted) {
+        if (!roleExists(roleId)) {
+            revert ErrorGrantNonexstentRole(roleId);
+        }
+
+        if (_role[roleId].isLocked) {
+            revert ErrorRoleIdNotActive(roleId);
+        }
+
+        if (!EnumerableSet.contains(_roleMembers[roleId], member)) {
+            _accessManager.grantRole(roleId.toInt(), member, EXECUTION_DELAY);
+            EnumerableSet.add(_roleMembers[roleId], member);
+            return true;
+        }
+
+        return false;
+    }
+
+    function revokeRole(RoleId roleId, address member) external restricted() returns (bool revoked) {
+        if (!roleExists(roleId)) {
+            revert ErrorRevokeNonexstentRole(roleId);
+        }
+
+        if (EnumerableSet.contains(_roleMembers[roleId], member)) {
+            _accessManager.revokeRole(roleId.toInt(), member);
+            EnumerableSet.remove(_roleMembers[roleId], member);
+            return true;
+        }
+
+        return false;
+    }
+
+    /// @dev not restricted function by intention
+    /// the restriction to role members is already enforced by the call to the access manger
+    function renounceRole(RoleId roleId) external returns (bool revoked) {
+        address member = msg.sender;
+
+        if (!roleExists(roleId)) {
+            revert ErrorRenounceNonexstentRole(roleId);
+        }
+
+        if (EnumerableSet.contains(_roleMembers[roleId], member)) {
+            // cannot use accessManger.renounce as it directly checks against msg.sender
+            _accessManager.revokeRole(roleId.toInt(), member);
+            EnumerableSet.remove(_roleMembers[roleId], member);
+            return true;
+        }
+
+        return false;
+    }
+
+    function roles() external view returns (uint256 numberOfRoles) {
+        return _roles.length;
+    }
+
+    function getRoleId(uint256 idx) external view returns (RoleId roleId) {
+        return _roles[idx];
+    }
+
+    function getRoleIdForName(string memory name) external view returns (RoleId roleId) {
+        return _roleForName[ShortStrings.toShortString(name)];
+    }
+
+    function getRole(RoleId roleId) external view returns (RoleInfo memory role) {
+        return _role[roleId];
+    }
+
+    function hasRole(RoleId roleId, address account) external view returns (bool accountHasRole) {
+        (accountHasRole, ) = _accessManager.hasRole(roleId.toInt(), account);
+    }
+
+    function roleMembers(RoleId roleId) external view returns (uint256 numberOfMembers) {
+        return EnumerableSet.length(_roleMembers[roleId]);
+    }
+
+    function getRoleMember(RoleId roleId, uint256 idx) external view returns (address roleMember) {
+        return EnumerableSet.at(_roleMembers[roleId], idx);
+    }
+
+    //--- Target ------------------------------------------------------//
+    function createTarget(address target, string memory name) external restricted() {
+        _createTarget(target, name, true, true);
+    }
+
+    function setTargetLocked(address target, bool locked) external restricted() {
+        if (!targetExists(target)) {
+            revert ErrorSetLockedForNonexstentTarget(target);
+        }
+
+        _target[target].isLocked = locked;
+        _accessManager.setTargetClosed(target, locked);
+    }
+
+    function targetExists(address target) public view returns (bool exists) {
+        return _target[target].createdAt.gtz();
+    }
+
+    //--- internal view/pure functions --------------------------------------//
+
+    function _createRole(RoleId roleId, string memory name, bool isCustom, bool validateParameters) internal {
+        if (validateParameters) {
+            _validateRoleParameters(roleId, name, isCustom);
+        }
+
+        RoleInfo memory role = RoleInfo(
+            ShortStrings.toShortString(name), 
+            isCustom,
+            false, // role un-locked,
+            TimestampLib.blockTimestamp(),
+            TimestampLib.blockTimestamp());
+
+        _role[roleId] = role;
+        _roleForName[role.name] = roleId;
+        _roles.push(roleId);
+    }
+
+    function _validateRoleParameters(
+        RoleId roleId, 
+        string memory name, 
+        bool isCustom
+    )
+        internal
+        view 
+        returns (RoleInfo memory existingRole)
+    {
+        // check role id
+        uint64 roleIdInt = RoleId.unwrap(roleId);
+        if(roleIdInt == _accessManager.ADMIN_ROLE() || roleIdInt == _accessManager.PUBLIC_ROLE()) {
+            revert ErrorRoleIdInvalid(roleId); 
+        }
+
+        // prevent changing isCustom for existing roles
+        existingRole = _role[roleId];
+
+        if (existingRole.createdAt.gtz() && isCustom != existingRole.isCustom) {
+            revert ErrorRoleIsCustomIsImmutable(roleId, isCustom, existingRole.isCustom); 
+        }
+
+        if (isCustom && roleIdInt < CUSTOM_ROLE_ID_MIN) {
+            revert ErrorRoleIdTooSmall(roleId); 
+        } else if (!isCustom && roleIdInt >= CUSTOM_ROLE_ID_MIN) {
+            revert ErrorRoleIdTooBig(roleId); 
+        }
+
+        // role name checks
+        ShortString nameShort = ShortStrings.toShortString(name);
+        if (ShortStrings.byteLength(nameShort) == 0) {
+            revert ErrorRoleNameEmpty(roleId);
+        }
+
+        if (_roleForName[nameShort] != RoleIdLib.zero() && _roleForName[nameShort] != roleId) {
+            revert ErrorRoleNameNotUnique(_roleForName[nameShort], nameShort);
+        }
+    }
+
+    function _createTarget(address target, string memory name, bool isCustom, bool validateParameters) internal {
+        if (validateParameters) {
+            _validateTargetParameters(target, name, isCustom);
+        }
+
+        TargetInfo memory info = TargetInfo(
+            ShortStrings.toShortString(name), 
+            isCustom,
+            _accessManager.isTargetClosed(target), // sync with state in access manager
+            TimestampLib.blockTimestamp(),
+            TimestampLib.blockTimestamp());
+
+        _target[target] = info;
+        _targetForName[info.name] = target;
+        _targets.push(target);
+    }
+
+    function _validateTargetParameters(address target, string memory name, bool isCustom) internal view {
+
+    }
+}

package/contracts/instance/InstanceReader.sol

@@ -0,0 +1,235 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin5/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {DistributorType} from "../types/DistributorType.sol";
+import {Fee, FeeLib} from "../types/Fee.sol";
+import {Key32} from "../types/Key32.sol";
+import {NftId} from "../types/NftId.sol";
+import {ObjectType, DISTRIBUTOR, INSTANCE, PRODUCT, POLICY, TREASURY} from "../types/ObjectType.sol";
+import {ReferralId, ReferralStatus, ReferralLib, REFERRAL_OK, REFERRAL_ERROR_UNKNOWN, REFERRAL_ERROR_EXPIRED, REFERRAL_ERROR_EXHAUSTED} from "../types/Referral.sol";
+import {Registerable} from "../shared/Registerable.sol";
+import {RiskId} from "../types/RiskId.sol";
+import {UFixed, UFixedMathLib} from "../types/UFixed.sol";
+import {Version} from "../types/Version.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IDistribution} from "../instance/module/IDistribution.sol";
+import {IInstance} from "./IInstance.sol";
+import {IKeyValueStore} from "../instance/base/IKeyValueStore.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IRisk} from "../instance/module/IRisk.sol";
+import {ITreasury} from "../instance/module/ITreasury.sol";
+import {TimestampLib} from "../types/Timestamp.sol";
+
+
+contract InstanceReader {
+
+    IRegistry internal _registry;
+    NftId internal _instanceNftId;
+    IInstance internal _instance;
+    IKeyValueStore internal _store;
+
+    constructor(
+        address registry, 
+        NftId instanceNftId
+    )
+    {
+        require(
+            address(registry) != address(0),
+            "ERROR:CRD-001:REGISTRY_ZERO");
+
+        require(
+            instanceNftId.gtz(),
+            "ERROR:CRD-002:NFT_ID_ZERO");
+
+        _registry = IRegistry(registry);
+        _instanceNftId = instanceNftId;
+        IRegistry.ObjectInfo memory instanceInfo = _registry.getObjectInfo(_instanceNftId);
+
+        require(
+            instanceInfo.objectType == INSTANCE(), 
+            "ERROR:CRD-003:PARENT_NOT_INSTANCE");
+
+        _instance = IInstance(instanceInfo.objectAddress);
+        _store = IKeyValueStore(instanceInfo.objectAddress);
+    }
+
+    // module specific functions
+
+    function getPolicyInfo(NftId policyNftId)
+        public
+        view
+        returns (IPolicy.PolicyInfo memory info)
+    {
+        bytes memory data = _store.getData(toPolicyKey(policyNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (IPolicy.PolicyInfo));
+        }
+    }
+
+    function getRiskInfo(RiskId riskId)
+        public 
+        view 
+        returns (IRisk.RiskInfo memory info)
+    {
+        bytes memory data = _store.getData(riskId.toKey32());
+        if (data.length > 0) {
+            return abi.decode(data, (IRisk.RiskInfo));
+        }
+    }
+
+    function getTokenHandler(NftId productNftId)
+        public
+        view
+        returns (address tokenHandler)
+    {
+        bytes memory data = _store.getData(toTreasuryKey(productNftId));
+
+        if (data.length > 0) {
+            ITreasury.TreasuryInfo memory info = abi.decode(data, (ITreasury.TreasuryInfo));
+            return address(info.tokenHandler);
+        }
+    }
+
+    function getTreasuryInfo(NftId productNftId)
+        public 
+        view 
+        returns (ITreasury.TreasuryInfo memory info)
+    {
+        bytes memory data = _store.getData(toTreasuryKey(productNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (ITreasury.TreasuryInfo));
+        }
+    }
+
+    function getDistributorTypeInfo(DistributorType distributorType)
+        public 
+        view 
+        returns (IDistribution.DistributorTypeInfo memory info)
+    {
+        bytes memory data = _store.getData(distributorType.toKey32());
+        if (data.length > 0) {
+            return abi.decode(data, (IDistribution.DistributorTypeInfo));
+        }
+    }
+
+    function getDistributorInfo(NftId distributorNftId)
+        public
+        view
+        returns (IDistribution.DistributorInfo memory info)
+    {
+        bytes memory data = _store.getData(toDistributorKey(distributorNftId));
+        if (data.length > 0) {
+            return abi.decode(data, (IDistribution.DistributorInfo));
+        }
+    }
+
+
+    function getReferralInfo(ReferralId referralId)
+        public 
+        view 
+        returns (IDistribution.ReferralInfo memory info)
+    {
+        bytes memory data = _store.getData(referralId.toKey32());
+        if (data.length > 0) {
+            return abi.decode(data, (IDistribution.ReferralInfo));
+        }
+    }
+
+
+    function getMetadata(Key32 key)
+        public 
+        view 
+        returns (IKeyValueStore.Metadata memory metadata)
+    {
+        return _store.getMetadata(key);
+    }
+
+
+    function toReferralId(
+        NftId distributionNftId,
+        string memory referralCode
+    )
+        public
+        pure 
+        returns (ReferralId referralId)
+    {
+        return ReferralLib.toReferralId(
+            distributionNftId, 
+            referralCode);      
+    }
+
+
+    function getDiscountPercentage(ReferralId referralId)
+        public
+        view
+        returns (
+            UFixed discountPercentage, 
+            ReferralStatus status
+        )
+    {
+        IDistribution.ReferralInfo memory info = getReferralInfo(
+            referralId);        
+
+        if (info.expiryAt.eqz()) {
+            return (
+                UFixedMathLib.zero(),
+                REFERRAL_ERROR_UNKNOWN());
+        }
+
+        if (info.expiryAt < TimestampLib.blockTimestamp()) {
+            return (
+                UFixedMathLib.zero(),
+                REFERRAL_ERROR_EXPIRED());
+        }
+
+        if (info.usedReferrals >= info.maxReferrals) {
+            return (
+                UFixedMathLib.zero(),
+                REFERRAL_ERROR_EXHAUSTED());
+        }
+
+        return (
+            info.discountPercentage,
+            REFERRAL_OK()
+        );
+    }
+
+
+    function toTreasuryKey(NftId productNftId) public pure returns (Key32) { 
+        return productNftId.toKey32(TREASURY());
+    }
+
+
+    function toPolicyKey(NftId policyNftId) public pure returns (Key32) { 
+        return policyNftId.toKey32(POLICY());
+    }
+
+
+    function toDistributorKey(NftId distributorNftId) public pure returns (Key32) { 
+        return distributorNftId.toKey32(DISTRIBUTOR());
+    }
+
+    // low level function
+    function getInstance() external view returns (IInstance instance) {
+        return _instance;
+    }
+
+    function getInstanceStore() external view returns (IKeyValueStore store) {
+        return _store;
+    }
+
+    function getInstanceNftId() external view returns (NftId nftId) {
+        return _instanceNftId;
+    }
+
+    function toUFixed(uint256 value, int8 exp) public pure returns (UFixed) {
+        return UFixedMathLib.toUFixed(value, exp);
+    }
+
+    function toInt(UFixed value) public pure returns (uint256) {
+        return UFixedMathLib.toInt(value);
+    }
+}

package/contracts/instance/InstanceService.sol

@@ -0,0 +1,45 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Clones} from "@openzeppelin5/contracts/proxy/Clones.sol";
+
+import {AccessManagerSimple} from "./AccessManagerSimple.sol";
+import {InstanceAccessManager} from "./InstanceAccessManager.sol";
+import {Instance} from "./Instance.sol";
+
+contract InstanceService {
+
+    address internal _accessManagerMaster;
+    address internal _instanceAccessManagerMaster;
+    address internal _instanceMaster;
+
+    function createInstanceClone()
+        external 
+        returns (
+            AccessManagerSimple am, 
+            InstanceAccessManager im, 
+            Instance i
+        )
+    {
+        am = AccessManagerSimple(Clones.clone(_accessManagerMaster));
+        im = InstanceAccessManager(Clones.clone(_instanceAccessManagerMaster));
+        i = Instance(Clones.clone(_instanceMaster));
+    }
+
+    function setAccessManagerMaster(address accessManager) external {
+        _accessManagerMaster = accessManager;
+    }
+
+    function setInstanceAccessManagerMaster(address instanceAccessManager) external {
+        _instanceAccessManagerMaster = instanceAccessManager;
+    }
+
+    function setInstanceMaster(address instance) external {
+        _instanceMaster = instance;
+    }
+
+    function getAccessManagerMaster() external view returns (address) { return address(_accessManagerMaster); }
+    function getInstanceAccessManagerMaster() external view returns (address) { return address(_instanceAccessManagerMaster); }
+    function getInstanceMaster() external view returns (address) { return address(_instanceMaster); }
+}
+

package/contracts/instance/base/IKeyValueStore.sol

@@ -1,5 +1,5 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
 
 import {Blocknumber, blockBlocknumber, zeroBlocknumber} from "../../types/Blocknumber.sol";
 import {Key32, KeyId} from "../../types/Key32.sol";
@@ -11,11 +11,6 @@ import {ILifecycle} from "./ILifecycle.sol";
 
 interface IKeyValueStore is ILifecycle {
 
-    struct Key {
-        ObjectType objectType;
-        KeyId id;
-    }
-
     struct Value {
         Metadata metadata;
         bytes data;
@@ -24,18 +19,22 @@ interface IKeyValueStore is ILifecycle {
     struct Metadata {
         ObjectType objectType;
         StateId state;
+        // TODO updatedBy needs concept that says what value should go here
+        // eg account outside gif objects that initiated the tx
+        // implies the caller needs to be propagated through all calls up to key values store itself
+        // to always have the instance address there doesn't seem to make sense
         address updatedBy;
         Blocknumber updatedIn;
         Blocknumber createdIn;
     }
 
-    event LogInfoCreated(Key key, StateId state, address createdBy);
-    event LogInfoUpdated(Key key, StateId state, address updatedBy, Blocknumber lastUpdatedIn);
-    event LogStateUpdated(Key key, StateId stateOld, StateId stateNew, address updatedBy, Blocknumber lastUpdatedIn);
+    event LogInfoCreated(ObjectType objectType, KeyId keyId, StateId state, address createdBy, address txOrigin);
+    event LogInfoUpdated(ObjectType objectType, KeyId keyId, StateId state, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
+    event LogStateUpdated(ObjectType objectType, KeyId keyId, StateId stateOld, StateId stateNew, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
 
     // generic state changing functions
-    function create(Key32 key, ObjectType objectType, bytes memory data) external;
-    function update(Key32 key, StateId state, bytes memory data) external;
+    function create(Key32 key, bytes memory data) external;
+    function update(Key32 key, bytes memory data, StateId state) external;
     function updateData(Key32 key, bytes memory data) external;
     function updateState(Key32 key, StateId state) external;
 

package/contracts/instance/base/ILifecycle.sol

@@ -1,9 +1,9 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
 
-import {ObjectType} from "../../types/ObjectType.sol";
-import {StateId, toStateId, zeroStateId} from "../../types/StateId.sol";
 import {NftId} from "../../types/NftId.sol";
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId} from "../../types/StateId.sol";
 
 interface ILifecycle {