@etherisc/gif-next 0.0.2-cddad6b-504 → 0.0.2-ce3fd5e-324

package/contracts/instance/InstanceService.sol

@@ -0,0 +1,308 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Clones} from "@openzeppelin/contracts/proxy/Clones.sol";
+import {ShortString, ShortStrings} from "@openzeppelin/contracts/utils/ShortStrings.sol";
+
+import {NftId} from "../type/NftId.sol";
+import {RoleId} from "../type/RoleId.sol";
+import {ADMIN_ROLE, INSTANCE_OWNER_ROLE, DISTRIBUTION_OWNER_ROLE, POOL_OWNER_ROLE, PRODUCT_OWNER_ROLE, INSTANCE_SERVICE_ROLE, DISTRIBUTION_SERVICE_ROLE, POOL_SERVICE_ROLE, PRODUCT_SERVICE_ROLE, APPLICATION_SERVICE_ROLE, POLICY_SERVICE_ROLE, CLAIM_SERVICE_ROLE, BUNDLE_SERVICE_ROLE, INSTANCE_ROLE} from "../type/RoleId.sol";
+import {ObjectType, INSTANCE, BUNDLE, APPLICATION, POLICY, CLAIM, PRODUCT, DISTRIBUTION, REGISTRY, POOL} from "../type/ObjectType.sol";
+
+import {Service} from "../shared/Service.sol";
+import {IService} from "../shared/IService.sol";
+import {AccessManagerUpgradeableInitializeable} from "../shared/AccessManagerUpgradeableInitializeable.sol";
+
+import {IDistributionComponent} from "../distribution/IDistributionComponent.sol";
+import {IPoolComponent} from "../pool/IPoolComponent.sol";
+import {IProductComponent} from "../product/IProductComponent.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegistryService} from "../registry/IRegistryService.sol";
+import {ChainNft} from "../registry/ChainNft.sol";
+
+import {Instance} from "./Instance.sol";
+import {IInstance} from "./IInstance.sol";
+import {InstanceAccessManager} from "./InstanceAccessManager.sol";
+import {IInstanceService} from "./IInstanceService.sol";
+import {InstanceReader} from "./InstanceReader.sol";
+import {BundleManager} from "./BundleManager.sol";
+import {InstanceStore} from "./InstanceStore.sol";
+import {InstanceAuthorizationsLib} from "./InstanceAuthorizationsLib.sol";
+
+contract InstanceService is
+    Service,
+    IInstanceService
+{
+
+    // TODO update to real hash when instance is stable
+    bytes32 public constant INSTANCE_CREATION_CODE_HASH = bytes32(0);
+
+    IRegistryService internal _registryService;
+    address internal _masterOzAccessManager;
+    address internal _masterInstanceAccessManager;
+    address internal _masterInstance;
+    address internal _masterInstanceReader;
+    address internal _masterInstanceBundleManager;
+    address internal _masterInstanceStore;
+
+    modifier onlyInstanceOwner(NftId instanceNftId) {        
+        if(msg.sender != getRegistry().ownerOf(instanceNftId)) {
+            revert ErrorInstanceServiceRequestUnauhorized(msg.sender);
+        }
+        _;
+    }
+    // TODO check service domain?
+    // TODO check release version?
+    modifier onlyRegisteredService() {
+        if (! getRegistry().isRegisteredService(msg.sender)) {
+            revert ErrorInstanceServiceRequestUnauhorized(msg.sender);
+        }
+        _;
+    }
+    // TODO check release version?
+    modifier onlyComponent() {
+        if (! getRegistry().isRegisteredComponent(msg.sender)) {
+            revert ErrorInstanceServiceRequestUnauhorized(msg.sender);
+        }
+        _;
+    }
+
+    function createInstanceClone()
+        external 
+        returns (
+            Instance clonedInstance,
+            NftId clonedInstanceNftId
+        )
+    {
+        address instanceOwner = msg.sender;
+        AccessManagerUpgradeableInitializeable clonedOzAccessManager = AccessManagerUpgradeableInitializeable(
+            Clones.clone(_masterOzAccessManager));
+
+        // initially grants ADMIN_ROLE to this (being the instance service). 
+        // This will allow the instance service to bootstrap the authorizations of the instance.
+        // Instance service will not use oz access manager directlly but through instance access manager instead
+        // Instance service will renounce ADMIN_ROLE when bootstraping is finished
+        clonedOzAccessManager.initialize(address(this));
+
+        clonedInstance = Instance(Clones.clone(_masterInstance));
+        clonedInstance.initialize(
+            address(clonedOzAccessManager),
+            address(getRegistry()), 
+            instanceOwner);
+        // initialize and set before instance reader
+        InstanceStore clonedInstanceStore = InstanceStore(Clones.clone(address(_masterInstanceStore)));
+        clonedInstanceStore.initialize(address(clonedInstance));
+        clonedInstance.setInstanceStore(clonedInstanceStore);
+        
+        InstanceReader clonedInstanceReader = InstanceReader(Clones.clone(address(_masterInstanceReader)));
+        clonedInstanceReader.initialize(address(clonedInstance));
+        clonedInstance.setInstanceReader(clonedInstanceReader);
+
+        BundleManager clonedBundleManager = BundleManager(Clones.clone(_masterInstanceBundleManager));
+        clonedBundleManager.initialize(address(clonedInstance));
+        clonedInstance.setBundleManager(clonedBundleManager);
+
+        InstanceAccessManager clonedInstanceAccessManager = InstanceAccessManager(Clones.clone(_masterInstanceAccessManager));
+        clonedOzAccessManager.grantRole(ADMIN_ROLE().toInt(), address(clonedInstanceAccessManager), 0);
+        clonedInstanceAccessManager.initialize(address(clonedInstance));
+        clonedInstance.setInstanceAccessManager(clonedInstanceAccessManager);
+
+        // TODO amend setters with instance specific , policy manager ...
+
+        // TODO library does external calls -> but it is registry and access manager -> find out is it best practice
+        InstanceAuthorizationsLib.grantInitialAuthorizations(
+            clonedInstanceAccessManager, 
+            clonedInstance, 
+            clonedBundleManager, 
+            clonedInstanceStore, 
+            instanceOwner,
+            getRegistry(),
+            getVersion().toMajorPart());
+
+        clonedOzAccessManager.renounceRole(ADMIN_ROLE().toInt(), address(this));
+
+        IRegistry.ObjectInfo memory info = _registryService.registerInstance(clonedInstance, instanceOwner);
+        clonedInstanceNftId = info.nftId;
+
+        emit LogInstanceCloned(
+            address(clonedOzAccessManager), 
+            address(clonedInstanceAccessManager), 
+            address(clonedInstance),
+            address(clonedInstanceStore),
+            address(clonedBundleManager), 
+            address(clonedInstanceReader), 
+            clonedInstanceNftId);
+    }
+
+    function setAndRegisterMasterInstance(address instanceAddress)
+            external 
+            onlyOwner 
+            returns(NftId masterInstanceNftId)
+    {
+        if(_masterInstance != address(0)) { revert ErrorInstanceServiceMasterInstanceAlreadySet(); }
+        if(_masterOzAccessManager != address(0)) { revert ErrorInstanceServiceMasterOzAccessManagerAlreadySet(); }
+        if(_masterInstanceAccessManager != address(0)) { revert ErrorInstanceServiceMasterInstanceAccessManagerAlreadySet(); }
+        if(_masterInstanceBundleManager != address(0)) { revert ErrorInstanceServiceMasterBundleManagerAlreadySet(); }
+
+        if(instanceAddress == address(0)) { revert ErrorInstanceServiceInstanceAddressZero(); }
+
+        IInstance instance = IInstance(instanceAddress);
+        InstanceAccessManager instanceAccessManager = instance.getInstanceAccessManager();
+        address instanceAccessManagerAddress = address(instanceAccessManager);
+        InstanceReader instanceReader = instance.getInstanceReader();
+        address instanceReaderAddress = address(instanceReader);
+        BundleManager bundleManager = instance.getBundleManager();
+        address bundleManagerAddress = address(bundleManager);
+        InstanceStore instanceStore = instance.getInstanceStore();
+        address instanceStoreAddress = address(instanceStore);
+
+        if(instanceAccessManagerAddress == address(0)) { revert ErrorInstanceServiceInstanceAccessManagerZero(); }
+        if(instanceReaderAddress == address(0)) { revert ErrorInstanceServiceInstanceReaderZero(); }
+        if(bundleManagerAddress == address(0)) { revert ErrorInstanceServiceBundleManagerZero(); }
+        if(instanceStoreAddress == address(0)) { revert ErrorInstanceServiceInstanceStoreZero(); }
+        
+        if(instance.authority() != instanceAccessManager.authority()) { revert ErrorInstanceServiceInstanceAuthorityMismatch(); }
+        if(bundleManager.authority() != instanceAccessManager.authority()) { revert ErrorInstanceServiceBundleManagerAuthorityMismatch(); }
+        if(instanceStore.authority() != instanceAccessManager.authority()) { revert ErrorInstanceServiceInstanceStoreAuthorityMismatch(); }
+        if(bundleManager.getInstance() != instance) { revert ErrorInstanceServiceBundleMangerInstanceMismatch(); }
+        if(instanceReader.getInstance() != instance) { revert ErrorInstanceServiceInstanceReaderInstanceMismatch2(); }
+
+        _masterOzAccessManager = instance.authority();
+        _masterInstanceAccessManager = instanceAccessManagerAddress;
+        _masterInstance = instanceAddress;
+        _masterInstanceReader = instanceReaderAddress;
+        _masterInstanceBundleManager = bundleManagerAddress;
+        _masterInstanceStore = instanceStoreAddress;
+        
+        IInstance masterInstance = IInstance(_masterInstance);
+        IRegistry.ObjectInfo memory info = _registryService.registerInstance(masterInstance, getOwner());
+        masterInstanceNftId = info.nftId;
+    }
+
+    function setMasterInstanceReader(address instanceReaderAddress) external onlyOwner {
+        if(_masterInstanceReader == address(0)) { revert ErrorInstanceServiceMasterInstanceReaderNotSet(); }
+        if(instanceReaderAddress == address(0)) { revert ErrorInstanceServiceInstanceReaderAddressZero(); }
+        if(instanceReaderAddress == _masterInstanceReader) { revert ErrorInstanceServiceInstanceReaderSameAsMasterInstanceReader(); }
+
+        InstanceReader instanceReader = InstanceReader(instanceReaderAddress);
+        if(instanceReader.getInstance() != IInstance(_masterInstance)) { revert ErrorInstanceServiceInstanceReaderInstanceMismatch(); }
+
+        _masterInstanceReader = instanceReaderAddress;
+    }
+
+    function upgradeInstanceReader(NftId instanceNftId) 
+        external 
+        onlyInstanceOwner(instanceNftId) 
+    {
+        IRegistry registry = getRegistry();
+        IRegistry.ObjectInfo memory instanceInfo = registry.getObjectInfo(instanceNftId);
+        Instance instance = Instance(instanceInfo.objectAddress);
+        
+        InstanceReader upgradedInstanceReaderClone = InstanceReader(Clones.clone(address(_masterInstanceReader)));
+        upgradedInstanceReaderClone.initialize(address(instance));
+        instance.setInstanceReader(upgradedInstanceReaderClone);
+    }
+
+
+    // all gif targets MUST be childs of instanceNftId
+    function createGifTarget(
+        NftId instanceNftId,
+        address targetAddress,
+        string memory targetName,
+        bytes4[][] memory selectors,
+        RoleId[] memory roles
+    )
+        external
+        onlyRegisteredService
+    {
+        (
+            IInstance instance, // or instanceInfo
+            // or targetInfo
+        ) = _validateInstanceAndComponent(instanceNftId, targetAddress);
+
+        InstanceAccessManager accessManager = instance.getInstanceAccessManager();
+        accessManager.createGifTarget(targetAddress, targetName);
+        // set proposed target config
+        // TODO restriction: gif targets are set only once and only here?
+        //      assume config is a mix of gif and custom roles and no further configuration by INSTANCE_OWNER_ROLE is ever needed?
+        for(uint roleIdx = 0; roleIdx < roles.length; roleIdx++)
+        {
+            accessManager.setCoreTargetFunctionRole(targetName, selectors[roleIdx], roles[roleIdx]);
+        }
+    }
+
+
+    // TODO called by component, but target can be component helper...so needs target name
+    // TODO check that targetName associated with component...how???
+    function setComponentLocked(bool locked) onlyComponent external {
+
+        address componentAddress = msg.sender;
+        IRegistry registry = getRegistry();
+        NftId instanceNftId = registry.getObjectInfo(componentAddress).parentNftId;
+
+        IInstance instance = IInstance(
+            registry.getObjectInfo(
+                instanceNftId).objectAddress);
+
+        instance.getInstanceAccessManager().setTargetLockedByService(
+            componentAddress, 
+            locked);
+    }
+
+
+    function getMasterInstanceReader() external view returns (address) {
+        return _masterInstanceReader;
+    }
+
+    // From IService
+    function getDomain() public pure override returns(ObjectType) {
+        return INSTANCE();
+    }
+    
+    /// @dev top level initializer
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        initializer
+        virtual override
+    {
+        (
+            address registryAddress,
+            address initialOwner
+        ) = abi.decode(data, (address, address));
+
+        _registryService = IRegistryService(
+            IRegistry(registryAddress).getServiceAddress(
+                REGISTRY(), 
+                getVersion().toMajorPart()));
+
+        // TODO while InstanceService is not deployed in InstanceServiceManager constructor
+        //      owner is InstanceServiceManager deployer
+        initializeService(registryAddress, address(0), owner);
+        registerInterface(type(IInstanceService).interfaceId);
+    }
+
+
+    function _validateInstanceAndComponent(NftId instanceNftId, address componentAddress) 
+        internal
+        view
+        returns (IInstance instance, NftId componentNftId)
+    {
+        IRegistry registry = getRegistry();
+        IRegistry.ObjectInfo memory instanceInfo = registry.getObjectInfo(instanceNftId);
+        if(instanceInfo.objectType != INSTANCE()) {
+            revert ErrorInstanceServiceNotInstance(instanceNftId);
+        }
+
+        IRegistry.ObjectInfo memory componentInfo = registry.getObjectInfo(componentAddress);
+        if(componentInfo.parentNftId != instanceNftId) {
+            revert ErrorInstanceServiceInstanceComponentMismatch(instanceNftId, componentInfo.nftId);
+        }
+
+        instance = Instance(instanceInfo.objectAddress);
+        componentNftId = componentInfo.nftId;
+    }
+}

package/contracts/instance/InstanceServiceManager.sol

@@ -0,0 +1,54 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Instance} from "./Instance.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
+import {InstanceService} from "./InstanceService.sol";
+import {Registry} from "../registry/Registry.sol";
+import {RegistryService} from "../registry/RegistryService.sol";
+import {REGISTRY} from "../type/ObjectType.sol";
+
+contract InstanceServiceManager is ProxyManager {
+
+    InstanceService private _instanceService;
+
+    /// @dev initializes proxy manager with instance service implementation and deploys instance
+    constructor(
+        address registryAddress
+    )
+        ProxyManager(registryAddress)
+    {
+        InstanceService instSrv = new InstanceService();
+        // bytes memory initCode = type(InstanceService).creationCode;
+        bytes memory data = abi.encode(registryAddress, address(this));
+        IVersionable versionable = deploy(
+            address(instSrv), 
+            data);
+
+        _instanceService = InstanceService(address(versionable));
+
+        // TODO `this` must have a role or own nft to register service
+        //Registry registry = Registry(registryAddress);
+        //address registryServiceAddress = registry.getServiceAddress(REGISTRY(), _instanceService.getMajorVersion());
+        //RegistryService registryService = RegistryService(registryServiceAddress);
+        //registryService.registerService(_instanceService);
+        // RegistryService registryService = _instanceService.getRegistryService();
+
+        // TODO no nft to link yet
+        // link ownership of instance service manager ot nft owner of instance service
+        //_linkToNftOwnable(
+        //    address(registryAddress),
+        //    address(_instanceService));
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getInstanceService()
+        external
+        view
+        returns (InstanceService instanceService)
+    {
+        return _instanceService;
+    }
+
+}

package/contracts/instance/InstanceStore.sol

@@ -0,0 +1,211 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+
+import {Key32, KeyId, Key32Lib} from "../type/Key32.sol";
+import {NftId} from "../type/NftId.sol";
+import {ClaimId} from "../type/ClaimId.sol";
+import {ObjectType, BUNDLE, DISTRIBUTION, INSTANCE, POLICY, POOL, ROLE, PRODUCT, TARGET, COMPONENT, DISTRIBUTOR, DISTRIBUTOR_TYPE} from "../type/ObjectType.sol";
+import {RiskId, RiskIdLib} from "../type/RiskId.sol";
+import {RoleId, RoleIdLib, INSTANCE_ROLE, INSTANCE_OWNER_ROLE} from "../type/RoleId.sol";
+import {StateId, ACTIVE} from "../type/StateId.sol";
+import {TimestampLib} from "../type/Timestamp.sol";
+import {VersionPart, VersionPartLib} from "../type/Version.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {DistributorType} from "../type/DistributorType.sol";
+import {PayoutId} from "../type/PayoutId.sol";
+
+import {IInstance} from "./IInstance.sol";
+import {KeyValueStore} from "./base/KeyValueStore.sol";
+import {IKeyValueStore} from "./base/KeyValueStore.sol";
+
+import {IBundle} from "./module/IBundle.sol";
+import {IComponents} from "./module/IComponents.sol";
+import {IDistribution} from "./module/IDistribution.sol";
+import {IPolicy} from "./module/IPolicy.sol";
+import {IRisk} from "./module/IRisk.sol";
+import {ISetup} from "./module/ISetup.sol";
+
+
+// TODO combine with instance reader?
+contract InstanceStore is AccessManagedUpgradeable, KeyValueStore
+{
+    function initialize(address instance)
+        public 
+        initializer()
+    {
+        address authority = IInstance(instance).authority();
+        __AccessManaged_init(authority);
+        initializeLifecycle();
+    }
+
+    //--- ProductSetup ------------------------------------------------------//
+    function createProductSetup(NftId productNftId, ISetup.ProductSetupInfo memory setup) external restricted() {
+        create(_toNftKey32(productNftId, PRODUCT()), abi.encode(setup));
+    }
+
+    function updateProductSetup(NftId productNftId, ISetup.ProductSetupInfo memory setup, StateId newState) external restricted() {
+        update(_toNftKey32(productNftId, PRODUCT()), abi.encode(setup), newState);
+    }
+
+    function updateProductSetupState(NftId productNftId, StateId newState) external restricted() {
+        updateState(_toNftKey32(productNftId, PRODUCT()), newState);
+    }
+
+    //--- DistributionSetup ------------------------------------------------------//
+    function createDistributionSetup(NftId distributionNftId, ISetup.DistributionSetupInfo memory setup) external restricted() {
+        create(_toNftKey32(distributionNftId, DISTRIBUTION()), abi.encode(setup));
+    }
+
+    function updateDistributionSetup(NftId distributionNftId, ISetup.DistributionSetupInfo memory setup, StateId newState) external restricted() {
+        update(_toNftKey32(distributionNftId, DISTRIBUTION()), abi.encode(setup), newState);
+    }
+
+    function updateDistributionSetupState(NftId distributionNftId, StateId newState) external restricted() {
+        updateState(_toNftKey32(distributionNftId, DISTRIBUTION()), newState);
+    }
+
+    //--- PoolSetup ------------------------------------------------------//
+    function createPoolSetup(NftId poolNftId, IComponents.ComponentInfo memory info) external restricted() {
+        create(_toNftKey32(poolNftId, POOL()), abi.encode(info));
+    }
+
+    function updatePoolSetup(NftId poolNftId, IComponents.ComponentInfo memory info, StateId newState) external restricted() {
+        update(_toNftKey32(poolNftId, POOL()), abi.encode(info), newState);
+    }
+
+    function updatePoolSetupState(NftId poolNftId, StateId newState) external restricted() {
+        updateState(_toNftKey32(poolNftId, POOL()), newState);
+    }
+
+    //--- DistributorType -------------------------------------------------------//
+    function createDistributorType(DistributorType distributorType, IDistribution.DistributorTypeInfo memory info) external restricted() {
+        create(distributorType.toKey32(), abi.encode(info));
+    }
+
+    function updateDistributorType(DistributorType distributorType, IDistribution.DistributorTypeInfo memory info, StateId newState) external restricted() {
+        update(distributorType.toKey32(), abi.encode(info), newState);
+    }
+
+    function updateDistributorTypeState(DistributorType distributorType, StateId newState) external restricted() {
+        updateState(distributorType.toKey32(), newState);
+    }
+
+    //--- Distributor -------------------------------------------------------//
+    function createDistributor(NftId distributorNftId, IDistribution.DistributorInfo memory info) external restricted() {
+        create(_toNftKey32(distributorNftId, DISTRIBUTOR()), abi.encode(info));
+    }
+
+    function updateDistributor(NftId distributorNftId, IDistribution.DistributorInfo memory info, StateId newState) external restricted() {
+        update(_toNftKey32(distributorNftId, DISTRIBUTOR()), abi.encode(info), newState);
+    }
+
+    function updateDistributorState(NftId distributorNftId, StateId newState) external restricted() {
+        updateState(_toNftKey32(distributorNftId, DISTRIBUTOR()), newState);
+    }
+
+    //--- Referral ----------------------------------------------------------//
+    function createReferral(ReferralId referralId, IDistribution.ReferralInfo memory referralInfo) external restricted() {
+        create(referralId.toKey32(), abi.encode(referralInfo));
+    }
+
+    function updateReferral(ReferralId referralId, IDistribution.ReferralInfo memory referralInfo, StateId newState) external restricted() {
+        update(referralId.toKey32(), abi.encode(referralInfo), newState);
+    }
+
+    function updateReferralState(ReferralId referralId, StateId newState) external restricted() {
+        updateState(referralId.toKey32(), newState);
+    }
+
+    //--- Bundle ------------------------------------------------------------//
+    function createBundle(NftId bundleNftId, IBundle.BundleInfo memory bundle) external restricted() {
+        create(_toNftKey32(bundleNftId, BUNDLE()), abi.encode(bundle));
+    }
+
+    function updateBundle(NftId bundleNftId, IBundle.BundleInfo memory bundle, StateId newState) external restricted() {
+        update(_toNftKey32(bundleNftId, BUNDLE()), abi.encode(bundle), newState);
+    }
+
+    function updateBundleState(NftId bundleNftId, StateId newState) external restricted() {
+        updateState(_toNftKey32(bundleNftId, BUNDLE()), newState);
+    }
+
+    //--- Risk --------------------------------------------------------------//
+    function createRisk(RiskId riskId, IRisk.RiskInfo memory risk) external restricted() {
+        create(riskId.toKey32(), abi.encode(risk));
+    }
+
+    function updateRisk(RiskId riskId, IRisk.RiskInfo memory risk, StateId newState) external restricted() {
+        update(riskId.toKey32(), abi.encode(risk), newState);
+    }
+
+    function updateRiskState(RiskId riskId, StateId newState) external restricted() {
+        updateState(riskId.toKey32(), newState);
+    }
+
+    //--- Application (Policy) ----------------------------------------------//
+    function createApplication(NftId applicationNftId, IPolicy.PolicyInfo memory policy) external restricted() {
+        create(_toNftKey32(applicationNftId, POLICY()), abi.encode(policy));
+    }
+
+    function updateApplication(NftId applicationNftId, IPolicy.PolicyInfo memory policy, StateId newState) external restricted() {
+        update(_toNftKey32(applicationNftId, POLICY()), abi.encode(policy), newState);
+    }
+
+    function updateApplicationState(NftId applicationNftId, StateId newState) external restricted() {
+        updateState(_toNftKey32(applicationNftId, POLICY()), newState);
+    }
+
+    //--- Policy ------------------------------------------------------------//
+    function updatePolicy(NftId policyNftId, IPolicy.PolicyInfo memory policy, StateId newState) external restricted() {
+        update(_toNftKey32(policyNftId, POLICY()), abi.encode(policy), newState);
+    }
+
+    function updatePolicyClaims(NftId policyNftId, IPolicy.PolicyInfo memory policy, StateId newState) external restricted() {
+        update(_toNftKey32(policyNftId, POLICY()), abi.encode(policy), newState);
+    }
+
+    function updatePolicyState(NftId policyNftId, StateId newState) external restricted() {
+        updateState(_toNftKey32(policyNftId, POLICY()), newState);
+    }
+
+    //--- Claim -------------------------------------------------------------//
+    function createClaim(NftId policyNftId, ClaimId claimId, IPolicy.ClaimInfo memory claim) external restricted() {
+        create(_toClaimKey32(policyNftId, claimId), abi.encode(claim));
+    }
+
+    function updateClaim(NftId policyNftId, ClaimId claimId, IPolicy.ClaimInfo memory claim, StateId newState) external restricted() {
+        update(_toClaimKey32(policyNftId, claimId), abi.encode(claim), newState);
+    }
+
+    function updateClaimState(NftId policyNftId, ClaimId claimId, StateId newState) external restricted() {
+        updateState(_toClaimKey32(policyNftId, claimId), newState);
+    }
+
+    //--- Payout ------------------------------------------------------------//
+    function createPayout(NftId policyNftId, PayoutId payoutId, IPolicy.PayoutInfo memory payout) external restricted() {
+        create(_toPayoutKey32(policyNftId, payoutId), abi.encode(payout));
+    }
+
+    function updatePayout(NftId policyNftId, PayoutId payoutId, IPolicy.PayoutInfo memory payout, StateId newState) external restricted() {
+        update(_toPayoutKey32(policyNftId, payoutId), abi.encode(payout), newState);
+    }
+
+    function updatePayoutState(NftId policyNftId, PayoutId payoutId, StateId newState) external restricted() {
+        updateState(_toPayoutKey32(policyNftId, payoutId), newState);
+    }
+
+    //--- internal view/pure functions --------------------------------------//
+    function _toNftKey32(NftId nftId, ObjectType objectType) private pure returns (Key32) {
+        return nftId.toKey32(objectType);
+    }
+
+    function _toClaimKey32(NftId policyNftId, ClaimId claimId) private pure returns (Key32) {
+        return claimId.toKey32(policyNftId);
+    }
+
+    function _toPayoutKey32(NftId policyNftId, PayoutId payoutId) private pure returns (Key32) {
+        return payoutId.toKey32(policyNftId);
+    }
+}

package/contracts/instance/base/Cloneable.sol

@@ -0,0 +1,51 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+
+abstract contract Cloneable is 
+    AccessManagedUpgradeable
+{
+    event CloneableInitialized(address authority, address registry);
+    
+    error CloneableAuthorityZero();
+    error CloneableRegistryInvalid(address registry);
+
+    IRegistry internal _registry;
+
+    constructor() {
+        _registry = IRegistry(address(0));
+    }
+
+    /// @dev call to initialize MUST be made in the same transaction as cloning of the contract
+    function initialize(
+        address authority,
+        address registry
+    )
+        public 
+        onlyInitializing
+    {
+        // check/handle access managed
+        if(authority == address(0)) {
+            revert CloneableAuthorityZero();
+        }
+        
+        __AccessManaged_init(authority);
+
+        // check/handle registry
+        if (registry.code.length == 0) {
+            revert CloneableRegistryInvalid(registry);
+        }
+
+        _registry = IRegistry(registry);
+
+        emit CloneableInitialized(authority, registry);
+    }
+
+    function getRegistry() external view returns (IRegistry) {
+        return _registry;
+    }
+}