@etherisc/gif-next 0.0.2-cc253b3 → 0.0.2-ce2fc91-485

package/contracts/instance/module/access/IAccess.sol

@@ -0,0 +1,53 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {RoleId} from "../../../types/RoleId.sol";
+
+interface IAccess {
+    struct RoleInfo {
+        RoleId id;
+        string name;
+        bool isActive;
+    }
+}
+
+interface IAccessModule is
+    IAccess
+{
+    event LogAccessRoleCreated(RoleId role, string roleName);
+    event LogAccessRoleStateSet(RoleId role, bool active);
+    event LogAccessRoleGranted(RoleId role, address member, bool isMember);
+
+    function createRole(string memory roleName) external returns (RoleId role);
+
+    function setRoleState(RoleId role, bool active) external;
+
+    function grantRole(RoleId role, address member) external;
+
+    function revokeRole(RoleId role, address member) external;
+
+    function roleExists(RoleId role) external view returns (bool);
+
+    function hasRole(RoleId role, address member) external view returns (bool);
+
+    function getRoleCount() external view returns (uint256 roles);
+
+    function getRole(uint256 idx) external view returns (RoleId role);
+
+    function getRoleId(string memory roleName) external pure returns (RoleId role);
+
+    function getRoleInfo(
+        RoleId role
+    ) external view returns (RoleInfo memory info);
+
+    function getRoleMemberCount(
+        RoleId role
+    ) external view returns (uint256 roleMembers);
+
+    function getRoleMember(
+        RoleId role,
+        uint256 idx
+    ) external view returns (address roleMember);
+
+    function getOwner() external view returns (address owner);
+}

package/contracts/instance/module/bundle/BundleModule.sol

@@ -0,0 +1,136 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+
+import {IProductService} from "../../service/IProductService.sol";
+import {IPoolService} from "../../service/IPoolService.sol";
+
+import {NftId} from "../../../types/NftId.sol";
+import {Key32, KeyId} from "../../../types/Key32.sol";
+import {LibNftIdSet} from "../../../types/NftIdSet.sol";
+import {ObjectType, PRODUCT, ORACLE, POOL, BUNDLE, POLICY} from "../../../types/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED, ARCHIVED, CLOSED, APPLIED, REVOKED, DECLINED} from "../../../types/StateId.sol";
+import {Timestamp, blockTimestamp, zeroTimestamp} from "../../../types/Timestamp.sol";
+import {Blocknumber, blockNumber} from "../../../types/Blocknumber.sol";
+
+import {IKeyValueStore} from "../../base/IKeyValueStore.sol";
+import {ModuleBase} from "../../base/ModuleBase.sol";
+
+import {IBundleModule} from "./IBundle.sol";
+
+abstract contract BundleModule is 
+    ModuleBase,
+    IBundleModule
+{
+
+    using LibNftIdSet for LibNftIdSet.Set;
+
+    mapping(NftId bundleNftId => LibNftIdSet.Set policies) private _collateralizedPolicies;
+    mapping(NftId bundleNftId => mapping(NftId policyNftId => uint256 amount)) private _collateralizationAmount;
+
+    modifier onlyBundlePoolService() {
+        require(
+            msg.sender == address(this.getPoolService()),
+            "ERROR:BDL-001:NOT_POOL_SERVICE"
+        );
+        _;
+    }
+
+    modifier onlyBundleProductService() {
+        require(
+            msg.sender == address(this.getProductService()),
+            "ERROR:BDL-002:NOT_PRODUCT_SERVICE"
+        );
+        _;
+    }
+
+    modifier onlyPoolOrProductService() {
+        require(
+            msg.sender == address(this.getPoolService())
+                || msg.sender == address(this.getProductService()),
+            "ERROR:BDL-003:NOT_POOL_OR_PRODUCT_SERVICE"
+        );
+        _;
+    }
+
+    function initializeBundleModule(IKeyValueStore keyValueStore) internal {
+        _initialize(keyValueStore, BUNDLE());
+    }
+
+    function createBundleInfo(
+        NftId bundleNftId,
+        NftId poolNftId,
+        uint256 amount, 
+        uint256 lifetime, 
+        bytes calldata filter
+    )
+        external
+        onlyBundlePoolService
+        override
+    {
+        BundleInfo memory bundleInfo = BundleInfo(
+            bundleNftId,
+            poolNftId,
+            filter,
+            amount, // capital
+            0, // locked capital
+            amount, // balance
+            blockTimestamp().addSeconds(lifetime), // expiredAt
+            zeroTimestamp() // closedAt
+        );
+
+        _create(bundleNftId, abi.encode(bundleInfo));
+    }
+
+    function setBundleInfo(BundleInfo memory bundleInfo)
+        external
+        override
+        onlyPoolOrProductService
+    {
+        _updateData(bundleInfo.nftId, abi.encode(bundleInfo));
+    }
+
+    function updateBundleState(NftId bundleNftId, StateId state)
+        external
+        override
+        onlyBundlePoolService
+    {
+        _updateState(bundleNftId, state);
+    }
+
+    function collateralizePolicy(
+        NftId bundleNftId, 
+        NftId policyNftId, 
+        uint256 collateralAmount
+    )
+        external
+        onlyBundleProductService
+        override
+    {
+        _collateralizationAmount[bundleNftId][policyNftId] = collateralAmount;
+        _collateralizedPolicies[bundleNftId].add(policyNftId);
+    }
+
+    function releasePolicy(
+        NftId bundleNftId,
+        NftId policyNftId
+    )
+        external
+        onlyBundleProductService
+        override 
+        returns(uint256 collateralAmount)
+    {
+        collateralAmount = _collateralizationAmount[bundleNftId][policyNftId];
+        delete _collateralizationAmount[bundleNftId][policyNftId];
+        _collateralizedPolicies[bundleNftId].remove(policyNftId);
+    }
+
+    function getBundleInfo(NftId bundleNftId) external view override returns(BundleInfo memory bundleInfo) {
+        return abi.decode(_getData(bundleNftId), (BundleInfo));
+    }
+
+    function toBundleKey32(NftId bundleNftId) external view override returns (Key32 key32) {
+        return _toKey32(bundleNftId);
+    } 
+}

package/contracts/instance/module/bundle/IBundle.sol

@@ -0,0 +1,58 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+import {IInstance} from "../../IInstance.sol";
+import {Key32} from "../../../types/Key32.sol";
+import {NftId} from "../../../types/NftId.sol";
+import {StateId} from "../../../types/StateId.sol";
+import {Timestamp} from "../../../types/Timestamp.sol";
+import {Blocknumber} from "../../../types/Blocknumber.sol";
+
+import {IKeyValueStore} from "../../base/IKeyValueStore.sol";
+import {IProductService} from "../../service/IProductService.sol";
+import {IPoolService} from "../../service/IPoolService.sol";
+
+interface IBundle {
+
+    struct BundleInfo {
+        NftId nftId;
+        NftId poolNftId;
+        bytes filter; // required conditions for applications to be considered for collateralization by this bundle
+        uint256 capitalAmount; // net investment capital amount (<= balance)
+        uint256 lockedAmount; // capital amount linked to collateralizaion of non-closed policies (<= balance)
+        uint256 balanceAmount; // total amount of funds: net investment capital + net premiums - payouts
+        Timestamp expiredAt; // no new policies
+        Timestamp closedAt;
+    }
+}
+
+interface IBundleModule is IBundle {
+
+    function createBundleInfo(
+        NftId bundleNftId,
+        NftId poolNftId,
+        uint256 amount, 
+        uint256 lifetime, 
+        bytes calldata filter
+    ) external;
+
+    function setBundleInfo(BundleInfo memory bundleInfo) external;
+    function updateBundleState(NftId bundleNftId, StateId state) external;
+
+    function collateralizePolicy(NftId bundleNftId, NftId policyNftId, uint256 amount) external;
+    function releasePolicy(NftId bundleNftId, NftId policyNftId) external returns(uint256 collateralAmount);
+
+    function getBundleInfo(NftId bundleNftId) external view returns(BundleInfo memory bundleInfo);
+    function toBundleKey32(NftId bundleNftId) external view returns (Key32 key32);
+
+    // repeat registry linked signature
+    function getRegistry() external view returns (IRegistry registry);
+
+    // repeat instance base signature
+    function getKeyValueStore() external view returns (IKeyValueStore keyValueStore);
+
+    // repeat service linked signatures to avoid linearization issues
+    function getProductService() external returns(IProductService);
+    function getPoolService() external returns(IPoolService);
+}

package/contracts/instance/module/compensation/CompensationModule.sol

@@ -0,0 +1,8 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {ICompensationModule} from "./ICompensation.sol";
+
+contract CompensationModule is ICompensationModule {
+    
+}

package/contracts/instance/module/compensation/ICompensation.sol

@@ -0,0 +1,10 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+interface ICompensation {
+
+}
+
+interface ICompensationModule is ICompensation {
+    
+}

package/contracts/instance/module/component/ComponentModule.sol

@@ -0,0 +1,104 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+
+import {IProductService} from "../../service/IProductService.sol";
+import {IPoolService} from "../../service/IPoolService.sol";
+
+import {NftId} from "../../../types/NftId.sol";
+import {Key32, KeyId} from "../../../types/Key32.sol";
+import {LibNftIdSet} from "../../../types/NftIdSet.sol";
+import {ObjectType, COMPONENT, PRODUCT, ORACLE, POOL, BUNDLE, POLICY} from "../../../types/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED, ARCHIVED, CLOSED, APPLIED, REVOKED, DECLINED} from "../../../types/StateId.sol";
+import {Timestamp, blockTimestamp, zeroTimestamp} from "../../../types/Timestamp.sol";
+import {Blocknumber, blockNumber} from "../../../types/Blocknumber.sol";
+
+import {IKeyValueStore} from "../../base/IKeyValueStore.sol";
+import {ModuleBase} from "../../base/ModuleBase.sol";
+
+import {IComponentModule} from "./IComponent.sol";
+
+abstract contract ComponentModule is 
+    ModuleBase,
+    IComponentModule
+{
+
+    NftId[] private _nftIds;
+
+    modifier onlyComponentOwnerService() {
+        require(
+            msg.sender == address(this.getComponentOwnerService()),
+            "ERROR:CMP-001:NOT_OWNER_SERVICE"
+        );
+        _;
+    }
+
+    function initializeComponentModule(IKeyValueStore keyValueStore) internal {
+        _initialize(keyValueStore, COMPONENT());
+    }
+
+    function registerComponent(
+        NftId nftId,
+        ObjectType, // objectType,
+        IERC20Metadata token
+    )
+        external
+        onlyComponentOwnerService
+        override
+    {
+        ComponentInfo memory info = ComponentInfo(
+            nftId,
+            token
+        );
+
+        _nftIds.push(nftId);
+
+        _create(nftId, abi.encode(info));
+    }
+
+    function setComponentInfo(ComponentInfo memory info)
+        external
+        override
+        onlyComponentOwnerService
+    {
+        _updateData(info.nftId, abi.encode(info));
+    }
+
+    function updateComponentState(NftId nftId, StateId state)
+        external
+        override
+        onlyComponentOwnerService
+    {
+        _updateState(nftId, state);
+    }
+
+    function getComponentCount()
+        external
+        view
+        override
+        returns (uint256 numberOfCompnents)
+    {
+        return _nftIds.length;
+    }
+
+    function getComponentId(
+        uint256 idx
+    ) external view override returns (NftId componentNftId) {
+        return _nftIds[idx];
+    }
+
+    function getComponentInfo(NftId nftId) external view override returns(ComponentInfo memory info) {
+        return abi.decode(_getData(nftId), (ComponentInfo));
+    }
+
+    function getComponentState(NftId nftId) external view returns (StateId state) {
+        return _getState(nftId);
+    }
+
+    function toComponentKey32(NftId nftId) external view override returns (Key32 key32) {
+        return _toKey32(nftId);
+    } 
+}

package/contracts/instance/module/component/IComponent.sol

@@ -0,0 +1,63 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+import {IInstance} from "../../IInstance.sol";
+import {StateId} from "../../../types/StateId.sol";
+import {Key32} from "../../../types/Key32.sol";
+import {NftId} from "../../../types/NftId.sol";
+import {ObjectType} from "../../../types/ObjectType.sol";
+import {RoleId} from "../../../types/RoleId.sol";
+import {Fee} from "../../../types/Fee.sol";
+import {UFixed} from "../../../types/UFixed.sol";
+
+import {IKeyValueStore} from "../../base/IKeyValueStore.sol";
+import {IComponentOwnerService} from "../../service/IComponentOwnerService.sol";
+
+interface IComponent {
+    struct ComponentInfo {
+        NftId nftId;
+        IERC20Metadata token;
+    }
+}
+
+interface IComponentModule is IComponent {
+
+    function registerComponent(
+        NftId nftId,
+        ObjectType objectType,
+        IERC20Metadata token
+    ) external;
+
+    function setComponentInfo(
+        ComponentInfo memory info
+    ) external;
+
+    function updateComponentState(NftId nftId, StateId state) external;
+
+    function getComponentInfo(
+        NftId nftId
+    ) external view returns (ComponentInfo memory info);
+
+    function getComponentState(NftId nftId) external view returns (StateId state);
+
+    function getComponentCount() external view returns (uint256 numberOfCompnents);
+
+    function getComponentId(uint256 idx) external view returns (NftId nftId);
+
+    function hasRole(RoleId role, address member) external view returns (bool);
+
+    function toComponentKey32(NftId nftId) external view returns (Key32 key32);
+
+    // repeat registry linked signature
+    function getRegistry() external view returns (IRegistry registry);
+
+    // repeat instance base signature
+    function getKeyValueStore() external view returns (IKeyValueStore keyValueStore);
+
+    // repeat service linked signaturea to avoid linearization issues
+    function getComponentOwnerService() external view returns(IComponentOwnerService);
+}

package/contracts/instance/module/policy/IPolicy.sol

@@ -0,0 +1,61 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+import {IInstance} from "../../IInstance.sol";
+import {IProductService} from "../../service/IProductService.sol";
+import {NftId} from "../../../types/NftId.sol";
+import {StateId} from "../../../types/StateId.sol";
+import {Timestamp} from "../../../types/Timestamp.sol";
+import {Blocknumber} from "../../../types/Blocknumber.sol";
+
+// TODO check if there is value to introuce IContract and let IPolicy derive from IContract
+interface IPolicy {
+    struct PolicyInfo {
+        NftId nftId;
+        NftId productNftId;
+        NftId bundleNftId;
+        address beneficiary;
+        StateId state; // applied, withdrawn, rejected, active, closed
+        uint256 sumInsuredAmount;
+        uint256 premiumAmount;
+        uint256 premiumPaidAmount;
+        uint256 lifetime;
+        bytes applicationData;
+        bytes policyData;
+        Timestamp createdAt;
+        Timestamp activatedAt; // time of underwriting
+        Timestamp expiredAt; // no new claims (activatedAt + lifetime)
+        Timestamp closedAt; // no locked capital
+        Blocknumber updatedIn; // write log entries in a way to support backtracking of all state changes
+    }
+}
+
+interface IPolicyModule is IPolicy {
+    function createApplication(
+        NftId productNftId,
+        NftId policyNftId,
+        uint256 sumInsuredAmount,
+        uint256 premiumAmount,
+        uint256 lifetime,
+        NftId bundleNftId
+    ) external;
+
+    function setPolicyInfo(PolicyInfo memory policyInfo) external;
+
+    // function underwrite(NftId nftId) external;
+
+    // function processPremium(NftId nftId, uint256 amount) external;
+
+    // function activate(NftId nftId, Timestamp activateAt) external;
+
+    function getPolicyInfo(
+        NftId nftId
+    ) external view returns (PolicyInfo memory info);
+
+    // repeat registry linked signature
+    function getRegistry() external view returns (IRegistry registry);
+
+    // repeat service linked signature to avoid linearization issues
+    function getProductService() external  returns(IProductService);
+}

package/contracts/instance/module/policy/PolicyModule.sol

@@ -0,0 +1,77 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+
+import {IProductService} from "../../service/IProductService.sol";
+import {IPolicy, IPolicyModule} from "./IPolicy.sol";
+import {ObjectType, POLICY} from "../../../types/ObjectType.sol";
+import {APPLIED, ACTIVE, UNDERWRITTEN} from "../../../types/StateId.sol";
+import {NftId, NftIdLib} from "../../../types/NftId.sol";
+import {Timestamp, blockTimestamp, zeroTimestamp} from "../../../types/Timestamp.sol";
+import {Blocknumber, blockNumber} from "../../../types/Blocknumber.sol";
+
+abstract contract PolicyModule is IPolicyModule {
+    using NftIdLib for NftId;
+
+    mapping(NftId nftId => PolicyInfo info) private _policyInfo;
+
+    // TODO find a better place to avoid dupliation
+    modifier onlyProductService2() {
+        require(
+            msg.sender == address(this.getProductService()),
+            "ERROR:POL-001:NOT_PRODUCT_SERVICE"
+        );
+        _;
+    }
+
+    function createApplication(
+        NftId productNftId,
+        NftId policyNftId,
+        uint256 sumInsuredAmount,
+        uint256 premiumAmount,
+        uint256 lifetime,
+        NftId bundleNftId
+    )
+        external
+        onlyProductService2
+        override
+    {
+        _policyInfo[policyNftId] = PolicyInfo(
+            policyNftId,
+            productNftId,
+            bundleNftId,
+            address(0), // beneficiary = policy nft holder
+            // _lifecycleModule.getInitialState(POLICY()),
+            APPLIED(),
+            sumInsuredAmount,
+            premiumAmount,
+            0, // premium paid amount
+            lifetime, 
+            "", // applicationData
+            "", // policyData
+            blockTimestamp(), // createdAt
+            zeroTimestamp(), // activatedAt
+            zeroTimestamp(), // expiredAt
+            zeroTimestamp(), // closedAt
+            blockNumber() // updatedIn
+        );
+
+        // TODO add logging
+    }
+
+    function setPolicyInfo(PolicyInfo memory policyInfo)
+        external
+        override
+        onlyProductService2
+    {
+        _policyInfo[policyInfo.nftId] = policyInfo;
+    }
+
+    function getPolicyInfo(
+        NftId nftId
+    ) external view returns (PolicyInfo memory info) {
+        return _policyInfo[nftId];
+    }
+
+}

package/contracts/instance/module/pool/IPoolModule.sol

@@ -0,0 +1,41 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+import {NftId} from "../../../types/NftId.sol";
+import {UFixed} from "../../../types/UFixed.sol";
+import {IProductService} from "../../service/IProductService.sol";
+import {IPoolService} from "../../service/IPoolService.sol";
+
+interface IPool {
+    struct PoolInfo {
+        NftId nftId;
+        bool isVerifying;
+        UFixed collateralizationLevel;
+    }
+}
+
+interface IPoolModule is IPool {
+
+    function registerPool(
+        NftId poolNftId, 
+        bool isVerifying, 
+        UFixed collateralizationLevel
+    ) external;
+
+    function addBundleToPool(
+        NftId bundleNftId,
+        NftId poolNftId,
+        uint256 amount
+    ) external;
+
+    function getPoolInfo(
+        NftId nftId
+    ) external view returns (PoolInfo memory info);
+
+    function getBundleCount(NftId poolNftId) external view returns (uint256 bundleCount);
+    function getBundleNftId(NftId poolNftId, uint256 index) external view returns (NftId bundleNftId);
+
+    // repeat service linked signatures to avoid linearization issues
+    function getPoolService() external returns(IPoolService);
+}