@etherisc/gif-next 0.0.2-cc253b3 → 0.0.2-cddad6b-504

package/contracts/instance/module/bundle/IBundle.sol

@@ -0,0 +1,53 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+import {IInstance} from "../../IInstance.sol";
+import {Fee} from "../../../types/Fee.sol";
+import {Key32} from "../../../types/Key32.sol";
+import {NftId} from "../../../types/NftId.sol";
+import {StateId} from "../../../types/StateId.sol";
+import {Timestamp} from "../../../types/Timestamp.sol";
+import {Blocknumber} from "../../../types/Blocknumber.sol";
+
+import {IKeyValueStore} from "../../base/IKeyValueStore.sol";
+import {IProductService} from "../../service/IProductService.sol";
+import {IPoolService} from "../../service/IPoolService.sol";
+
+interface IBundle {
+
+    struct BundleInfo {
+        NftId poolNftId;
+        Fee fee; // bundle fee on net premium amounts
+        bytes filter; // required conditions for applications to be considered for collateralization by this bundle
+        uint256 capitalAmount; // net investment capital amount (<= balance)
+        uint256 lockedAmount; // capital amount linked to collateralizaion of non-closed policies (<= balance)
+        uint256 balanceAmount; // total amount of funds: net investment capital + net premiums - payouts
+        Timestamp expiredAt; // no new policies
+        Timestamp closedAt;
+    }
+}
+
+interface IBundleModule is IBundle {
+
+    function createBundleInfo(
+        NftId bundleNftId,
+        NftId poolNftId,
+        Fee memory fee,
+        uint256 amount, 
+        uint256 lifetime, 
+        bytes calldata filter
+    ) external;
+
+    function setBundleInfo(NftId nftId, BundleInfo memory bundleInfo) external;
+    function updateBundleState(NftId nftId, StateId state) external;
+
+    function collateralizePolicy(NftId bundleNftId, NftId policyNftId, uint256 amount) external;
+    function releasePolicy(NftId bundleNftId, NftId policyNftId) external returns(uint256 collateralAmount);
+
+    function getBundleInfo(NftId nftId) external view returns(BundleInfo memory bundleInfo);
+
+    // repeat service linked signatures to avoid linearization issues
+    function getProductService() external returns(IProductService);
+    function getPoolService() external returns(IPoolService);
+}

package/contracts/instance/module/component/ComponentModule.sol

@@ -0,0 +1,70 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {IKeyValueStore} from "../../base/IKeyValueStore.sol";
+import {IComponentModule} from "./IComponent.sol";
+
+import {NftId} from "../../../types/NftId.sol";
+import {ObjectType, COMPONENT} from "../../../types/ObjectType.sol";
+import {StateId} from "../../../types/StateId.sol";
+import {ModuleBase} from "../../base/ModuleBase.sol";
+
+abstract contract ComponentModule is 
+    ModuleBase,
+    IComponentModule
+{
+
+    NftId[] private _nftIds;
+
+    modifier onlyComponentOwnerService() {
+        require(
+            msg.sender == address(this.getComponentOwnerService()),
+            "ERROR:CMP-001:NOT_OWNER_SERVICE"
+        );
+        _;
+    }
+
+    function initializeComponentModule(IKeyValueStore keyValueStore) internal {
+        _initialize(keyValueStore);
+    }
+
+    function registerComponent(
+        NftId nftId,
+        IERC20Metadata token,
+        address wallet
+    )
+        external
+        onlyComponentOwnerService
+        override
+    {
+        ComponentInfo memory info = ComponentInfo(token, wallet);
+        _nftIds.push(nftId);
+        _create(COMPONENT(), nftId, abi.encode(info));
+    }
+
+    function getComponentToken(NftId nftId) external view override returns(IERC20Metadata token) {
+        ComponentInfo memory info = abi.decode(_getData(COMPONENT(), nftId), (ComponentInfo));
+        return info.token;
+    }
+
+    function getComponentWallet(NftId nftId) external view override returns (address wallet) {
+        ComponentInfo memory info = abi.decode(_getData(COMPONENT(), nftId), (ComponentInfo));
+        return info.wallet;
+    }
+
+    function getComponentCount()
+        external
+        view
+        override
+        returns (uint256 numberOfCompnents)
+    {
+        return _nftIds.length;
+    }
+
+    function getComponentId(
+        uint256 idx
+    ) external view override returns (NftId componentNftId) {
+        return _nftIds[idx];
+    }
+}

package/contracts/instance/module/component/IComponent.sol

@@ -0,0 +1,28 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {IComponentOwnerService} from "../../service/IComponentOwnerService.sol";
+
+import {StateId} from "../../../types/StateId.sol";
+import {NftId} from "../../../types/NftId.sol";
+
+interface IComponent {
+    struct ComponentInfo {
+        IERC20Metadata token;
+        address wallet;
+    }
+}
+
+interface IComponentModule is IComponent {
+
+    function registerComponent(NftId nftId, IERC20Metadata token, address wallet) external;
+    function getComponentToken(NftId nftId) external view returns (IERC20Metadata token);
+    function getComponentWallet(NftId nftId) external view returns (address wallet);
+
+    function getComponentCount() external view returns (uint256 numberOfCompnents);
+    function getComponentId(uint256 idx) external view returns (NftId nftId);
+
+    // repeat service linked signaturea to avoid linearization issues
+    function getComponentOwnerService() external view returns(IComponentOwnerService);
+}

package/contracts/instance/module/distribution/DistributionModule.sol

@@ -0,0 +1,17 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IDistributionModule} from "./IDistribution.sol";
+import {IKeyValueStore} from "../../base/IKeyValueStore.sol";
+import {ModuleBase} from "../../base/ModuleBase.sol";
+
+contract DistributionModule is
+    ModuleBase,
+    IDistributionModule
+{
+
+    function initializeDistributionModule(IKeyValueStore keyValueStore) internal {
+        _initialize(keyValueStore);
+    }
+
+}

package/contracts/instance/module/distribution/IDistribution.sol

@@ -0,0 +1,10 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+interface IDistribution {
+
+}
+
+interface IDistributionModule is IDistribution {
+    
+}

package/contracts/instance/module/policy/IPolicy.sol

@@ -0,0 +1,63 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+import {IInstance} from "../../IInstance.sol";
+import {IProductService} from "../../service/IProductService.sol";
+import {NftId} from "../../../types/NftId.sol";
+import {ReferralId} from "../../../types/ReferralId.sol";
+import {RiskId} from "../../../types/RiskId.sol";
+import {StateId} from "../../../types/StateId.sol";
+import {Timestamp} from "../../../types/Timestamp.sol";
+
+// TODO check if there is value to introuce IContract and let IPolicy derive from IContract
+interface IPolicy {
+    struct PolicyInfo {
+        NftId productNftId;
+        NftId bundleNftId;
+        ReferralId referralId;
+        address beneficiary;
+        RiskId riskId;
+        uint256 sumInsuredAmount;
+        uint256 premiumAmount;
+        uint256 premiumPaidAmount;
+        uint256 lifetime;
+        bytes applicationData;
+        bytes policyData;
+        Timestamp activatedAt; // time of underwriting
+        Timestamp expiredAt; // no new claims (activatedAt + lifetime)
+        Timestamp closedAt; // no locked capital
+    }
+}
+
+interface IPolicyModule is IPolicy {
+    function createPolicyInfo(
+        NftId policyNftId,
+        NftId productNftId,
+        ReferralId referralId,
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        uint256 premiumAmount,
+        uint256 lifetime,
+        NftId bundleNftId
+    ) external;
+
+    function setPolicyInfo(NftId policyNftId, PolicyInfo memory info) external;
+    function updatePolicyState(NftId nftId, StateId state) external;
+
+    // function underwrite(NftId nftId) external;
+
+    // function processPremium(NftId nftId, uint256 amount) external;
+
+    // function activate(NftId nftId, Timestamp activateAt) external;
+
+    function getPolicyInfo(
+        NftId nftId
+    ) external view returns (PolicyInfo memory info);
+
+    // repeat registry linked signature
+    function getRegistry() external view returns (IRegistry registry);
+
+    // repeat service linked signature to avoid linearization issues
+    function getProductService() external  returns(IProductService);
+}

package/contracts/instance/module/policy/PolicyModule.sol

@@ -0,0 +1,91 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+
+import {IProductService} from "../../service/IProductService.sol";
+import {IPolicy, IPolicyModule} from "./IPolicy.sol";
+import {ObjectType, POLICY} from "../../../types/ObjectType.sol";
+import {NftId, NftIdLib} from "../../../types/NftId.sol";
+import {ReferralId} from "../../../types/ReferralId.sol";
+import {RiskId} from "../../../types/RiskId.sol";
+import {StateId} from "../../../types/StateId.sol";
+import {Timestamp, blockTimestamp, zeroTimestamp} from "../../../types/Timestamp.sol";
+
+import {IKeyValueStore} from "../../base/IKeyValueStore.sol";
+import {ModuleBase} from "../../base/ModuleBase.sol";
+
+abstract contract PolicyModule is
+    ModuleBase,
+    IPolicyModule
+{
+
+    // TODO find a better place to avoid dupliation
+    modifier onlyProductService2() {
+        require(
+            msg.sender == address(this.getProductService()),
+            "ERROR:POL-001:NOT_PRODUCT_SERVICE"
+        );
+        _;
+    }
+
+    function initializePolicyModule(IKeyValueStore keyValueStore) internal {
+        _initialize(keyValueStore);
+    }
+
+    function createPolicyInfo(
+        NftId policyNftId,
+        NftId productNftId,
+        ReferralId referralId,
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        uint256 premiumAmount,
+        uint256 lifetime,
+        NftId bundleNftId
+    )
+        external
+        onlyProductService2
+        override
+    {
+        PolicyInfo memory info = PolicyInfo(
+            productNftId,
+            bundleNftId,
+            referralId,
+            address(0), // beneficiary = policy nft holder
+            riskId,
+            sumInsuredAmount,
+            premiumAmount,
+            0, // premium paid amount
+            lifetime, 
+            "", // applicationData
+            "", // policyData
+            zeroTimestamp(), // activatedAt
+            zeroTimestamp(), // expiredAt
+            zeroTimestamp() // closedAt
+        );
+
+        _create(POLICY(), policyNftId, abi.encode(info));
+    }
+
+    function setPolicyInfo(NftId policyNftId, PolicyInfo memory info)
+        external
+        override
+        onlyProductService2
+    {
+        _updateData(POLICY(), policyNftId, abi.encode(info));
+    }
+
+    function updatePolicyState(NftId bundleNftId, StateId state)
+        external
+        override
+        onlyProductService2
+    {
+        _updateState(POLICY(), bundleNftId, state);
+    }
+
+    function getPolicyInfo(
+        NftId nftId
+    ) external view returns (PolicyInfo memory info) {
+        return abi.decode(_getData(POLICY(), nftId), (PolicyInfo));
+    }
+}

package/contracts/instance/module/pool/IPoolModule.sol

@@ -0,0 +1,40 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+import {NftId} from "../../../types/NftId.sol";
+import {UFixed} from "../../../types/UFixed.sol";
+import {IProductService} from "../../service/IProductService.sol";
+import {IPoolService} from "../../service/IPoolService.sol";
+
+interface IPool {
+    struct PoolInfo {
+        bool isVerifying;
+        UFixed collateralizationLevel;
+    }
+}
+
+interface IPoolModule is IPool {
+
+    function registerPool(
+        NftId poolNftId, 
+        bool isVerifying, 
+        UFixed collateralizationLevel
+    ) external;
+
+    function addBundleToPool(
+        NftId bundleNftId,
+        NftId poolNftId,
+        uint256 amount
+    ) external;
+
+    function getPoolInfo(
+        NftId nftId
+    ) external view returns (PoolInfo memory info);
+
+    function getBundleCount(NftId poolNftId) external view returns (uint256 bundleCount);
+    function getBundleNftId(NftId poolNftId, uint256 index) external view returns (NftId bundleNftId);
+
+    // repeat service linked signatures to avoid linearization issues
+    function getPoolService() external returns(IPoolService);
+}

package/contracts/instance/module/pool/PoolModule.sol

@@ -0,0 +1,90 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+import {IProductService} from "../../service/IProductService.sol";
+import {IPoolService} from "../../service/IPoolService.sol";
+import {IPolicy, IPolicyModule} from "../../module/policy/IPolicy.sol";
+import {ITreasuryModule} from "../../module/treasury/ITreasury.sol";
+
+import {NftId} from "../../../types/NftId.sol";
+import {POOL} from "../../../types/ObjectType.sol";
+import {LibNftIdSet} from "../../../types/NftIdSet.sol";
+import {StateId, APPLIED} from "../../../types/StateId.sol";
+import {UFixed} from "../../../types/UFixed.sol";
+
+import {IKeyValueStore} from "../../base/IKeyValueStore.sol";
+import {IPoolModule} from "./IPoolModule.sol";
+import {ModuleBase} from "../../base/ModuleBase.sol";
+
+abstract contract PoolModule is
+    ModuleBase,
+    IPoolModule
+{
+    using LibNftIdSet for LibNftIdSet.Set;
+
+    // mapping(NftId poolNftId => PoolInfo info) private _poolInfo;
+    mapping(NftId poolNftId => LibNftIdSet.Set bundles) private _bundlesForPool;
+
+    modifier poolServiceCallingPool() {
+        require(
+            msg.sender == address(this.getPoolService()),
+            "ERROR:PL-001:NOT_POOL_SERVICE"
+        );
+        _;
+    }
+
+    function initializePoolModule(IKeyValueStore keyValueStore) internal {
+        _initialize(keyValueStore);
+    }
+
+    function registerPool(
+        NftId nftId, 
+        bool isVerifying,
+        UFixed collateralizationRate
+    )
+        public
+        override
+    {
+        PoolInfo memory info  = PoolInfo(
+            isVerifying,
+            collateralizationRate
+        );
+
+        _create(POOL(), nftId, abi.encode(info));
+    }
+
+    function addBundleToPool(
+        NftId bundleNftId,
+        NftId poolNftId,
+        uint256 // amount
+    )
+        external
+        override
+    {
+        LibNftIdSet.Set storage bundleSet = _bundlesForPool[poolNftId];
+        require(
+            !bundleSet.contains(bundleNftId),
+            "ERROR:PL-020:BUNDLE_ALREADY_ADDED");
+
+        bundleSet.add(bundleNftId);
+    }
+
+
+    function getPoolInfo(
+        NftId nftId
+    ) external view override returns (PoolInfo memory info) {
+        return abi.decode(_getData(POOL(), nftId), (PoolInfo));
+    }
+
+
+    function getBundleCount(NftId poolNftId) external view override returns (uint256 bundleCount) {
+        return _bundlesForPool[poolNftId].getLength();
+    }
+
+
+    function getBundleNftId(NftId poolNftId, uint256 index) external view override returns (NftId bundleNftId) {
+        return _bundlesForPool[poolNftId].getElementAt(index);
+    }
+
+}

package/contracts/instance/module/risk/IRisk.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../../../types/NftId.sol";
+import {RiskId} from "../../../types/RiskId.sol";
+import {StateId} from "../../../types/StateId.sol";
+
+interface IRisk {
+    struct RiskInfo {
+        NftId productNftId;
+        bytes data;
+    }
+}
+
+interface IRiskModule is IRisk {
+    function createRisk(
+        RiskId riskId,
+        NftId productNftId,
+        bytes memory data
+    ) external;
+
+    function setRiskInfo(RiskId riskId, RiskInfo memory info) external;
+    function updateRiskState(RiskId riskId, StateId state) external;
+
+    function getRiskInfo(RiskId riskId) external view returns (RiskInfo memory info);
+}

package/contracts/instance/module/risk/RiskModule.sol

@@ -0,0 +1,62 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../../../types/NftId.sol";
+import {RISK} from "../../../types/ObjectType.sol";
+import {RiskId} from "../../../types/RiskId.sol";
+import {StateId} from "../../../types/StateId.sol";
+
+import {IKeyValueStore} from "../../base/IKeyValueStore.sol";
+import {IRiskModule} from "./IRisk.sol";
+import {ModuleBase} from "../../base/ModuleBase.sol";
+
+contract RiskModule is
+    ModuleBase,
+    IRiskModule
+{
+    function initializeRiskModule(IKeyValueStore keyValueStore) internal {
+        _initialize(keyValueStore);
+    }
+
+    function createRisk(
+        RiskId riskId,
+        NftId productNftId,
+        bytes memory data
+    ) external override {
+        RiskInfo memory info = RiskInfo(
+            productNftId,
+            data
+        );
+
+        _create(RISK(), riskId.toKey32(), abi.encode(info));
+    }
+
+    function setRiskInfo(
+        RiskId riskId, 
+        RiskInfo memory info
+    )
+        external
+        override
+    {
+
+    }
+
+    function updateRiskState(
+        RiskId riskId, 
+        StateId state
+    )
+        external
+        override
+    {
+
+    }
+
+    function getRiskInfo(RiskId riskId)
+        external
+        view
+        override
+        returns (RiskInfo memory info)
+    {
+
+    }
+}

package/contracts/instance/module/treasury/ITreasury.sol

@@ -0,0 +1,82 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {IDistributionComponent} from "../../../components/IDistributionComponent.sol";
+import {IPoolComponent} from "../../../components/IPoolComponent.sol";
+import {IProductComponent} from "../../../components/IProductComponent.sol";
+
+import {NftId} from "../../../types/NftId.sol";
+import {UFixed} from "../../../types/UFixed.sol";
+import {Fee} from "../../../types/Fee.sol";
+
+import {TokenHandler} from "./TokenHandler.sol";
+
+interface ITreasury {
+    // TODO add events
+    // TODO add errors
+
+    // treasury info is linked to product nft id
+    struct TreasuryInfo {
+        NftId poolNftId;
+        NftId distributionNftId;
+        IERC20Metadata token;
+        Fee productFee; // product fee on net premium
+        Fee processingFee; // product fee on payout amounts
+        Fee poolFee; // pool fee on net premium
+        Fee stakingFee; // pool fee on staked capital from investor
+        Fee performanceFee; // pool fee on profits from capital investors
+        Fee distributionFee; // default distribution fee (no referral id)
+    }
+}
+
+interface ITreasuryModule is ITreasury {
+
+    function registerProductSetup(
+        IProductComponent product,
+        IPoolComponent pool,
+        IDistributionComponent distribution
+    ) external;
+
+    function setTreasuryInfo(
+        NftId productNftId,
+        TreasuryInfo memory info
+    ) external;
+
+    function hasTreasuryInfo(
+        NftId productNftId
+    ) external view returns (bool hasInfo);
+
+    function getTreasuryInfo(
+        NftId productNftId
+    ) external view returns (TreasuryInfo memory info);
+
+    function getProductNftId(
+        NftId componentNftId
+    ) external view returns (NftId productNftId);
+
+    function getTokenHandler(
+        NftId componentNftId
+    ) external view returns (TokenHandler tokenHandler);
+
+    function calculateFeeAmount(
+        uint256 amount,
+        Fee memory fee
+    ) external pure returns (uint256 feeAmount, uint256 netAmount);
+
+    function getFee(
+        UFixed fractionalFee, 
+        uint256 fixedFee
+    ) external pure returns (Fee memory fee);
+
+    function getZeroFee() external view returns (Fee memory fee);
+
+    function getUFixed(
+        uint256 a
+    ) external pure returns (UFixed);
+
+    function getUFixed(
+        uint256 a, 
+        int8 exp
+    ) external pure returns (UFixed);
+}

package/contracts/instance/module/treasury/TokenHandler.sol

@@ -0,0 +1,48 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {NftId} from "../../../types/NftId.sol";
+
+contract TokenHandler {
+    NftId private _productNftId;
+    IERC20Metadata private _token;
+
+    constructor(
+        NftId productNftId,
+        address token
+    )
+    {
+        _productNftId = productNftId;
+        _token = IERC20Metadata(token);
+    }
+
+    // TODO add logging
+    function transfer(
+        address from,
+        address to,
+        uint256 amount
+    )
+        external // TODO add authz (only treasury/instance/product/pool/ service)
+    {
+        // TODO switch to oz safeTransferFrom
+        _token.transferFrom(from, to, amount);
+    }
+
+    function getProductNftId()
+        external
+        view
+        returns(NftId)
+    {
+        return _productNftId;
+    }
+
+    function getToken()
+        external
+        view
+        returns(IERC20Metadata)
+    {
+        return _token;
+    }
+}