@etherisc/gif-next 0.0.2-c6d46bb-892 → 0.0.2-c75d1c9-837

package/contracts/registry/RegistryAdmin.sol

@@ -0,0 +1,258 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity ^0.8.20;
+
+import {IAuthorization} from "../authorization/IAuthorization.sol";
+import {IComponent} from "../shared/IComponent.sol";
+import {IRegistry} from "./IRegistry.sol";
+import {IService} from "../shared/IService.sol";
+import {IStaking} from "../staking/IStaking.sol";
+
+import {AccessAdmin} from "../authorization/AccessAdmin.sol";
+import {AccessAdminLib} from "../authorization/AccessAdminLib.sol";
+import {AccessManagerCloneable} from "../authorization/AccessManagerCloneable.sol";
+import {ContractLib} from "../shared/ContractLib.sol";
+import {ObjectType, REGISTRY, STAKING, POOL, RELEASE} from "../type/ObjectType.sol";
+import {ReleaseRegistry} from "./ReleaseRegistry.sol";
+import {RoleId, RoleIdLib, ADMIN_ROLE, GIF_MANAGER_ROLE, GIF_ADMIN_ROLE, PUBLIC_ROLE} from "../type/RoleId.sol";
+import {Staking} from "../staking/Staking.sol";
+import {Str, StrLib} from "../type/String.sol";
+import {StakingStore} from "../staking/StakingStore.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {TokenRegistry} from "./TokenRegistry.sol";
+import {VersionPart, VersionPartLib} from "../type/Version.sol";
+
+/*
+    1) GIF_MANAGER_ROLE
+        - can have arbitrary number of members
+        - responsible for release preparation
+        - responsible for services registrations
+        - responsible for token registration and activation
+
+    2) GIF_ADMIN_ROLE
+        - admin of GIF_MANAGER_ROLE
+        - MUST have 1 member at any time
+        - granted/revoked ONLY in transferAdminRole() -> consider lock out situations!!!
+        - responsible for creation, activation and locking/unlocking of releases
+*/
+
+/// @dev The RegistryAdmin contract implements the central authorization for the GIF core contracts.
+/// These are the release independent registry and staking contracts and their respective helper contracts.
+/// The RegistryAdmin also manages the access from service contracts to the GIF core contracts
+contract RegistryAdmin is
+    AccessAdmin
+{
+    /// @dev gif core roles
+    string public constant GIF_ADMIN_ROLE_NAME = "GifAdminRole";
+    string public constant GIF_MANAGER_ROLE_NAME = "GifManagerRole";
+    string public constant RELEASE_REGISTRY_ROLE_NAME = "ReleaseRegistryRole";
+    string public constant STAKING_ROLE_NAME = "StakingRole";
+
+    /// @dev gif roles for external contracts
+    string public constant REGISTRY_SERVICE_ROLE_NAME = "RegistryServiceRole";
+    string public constant COMPONENT_SERVICE_ROLE_NAME = "ComponentServiceRole";
+    string public constant POOL_SERVICE_ROLE_NAME = "PoolServiceRole";
+    string public constant STAKING_SERVICE_ROLE_NAME = "StakingServiceRole";
+
+    /// @dev gif core targets
+    string public constant REGISTRY_ADMIN_TARGET_NAME = "RegistryAdmin";
+    string public constant REGISTRY_TARGET_NAME = "Registry";
+    string public constant RELEASE_REGISTRY_TARGET_NAME = "ReleaseRegistry";
+    string public constant STAKING_TARGET_NAME = "Staking";
+    string public constant STAKING_TH_TARGET_NAME = "StakingTH";
+    string public constant STAKING_STORE_TARGET_NAME = "StakingStore";
+    string public constant TOKEN_REGISTRY_TARGET_NAME = "TokenRegistry";
+    string public constant TOKEN_HANDLER_TARGET_NAME = "TokenHandler";
+
+    // completeSetup
+    error ErrorRegistryAdminNotRegistry(address registry);
+
+    address internal _registry;
+    address private _releaseRegistry;
+    address private _tokenRegistry;
+    address private _staking;
+    address private _stakingStore;
+
+    constructor() {
+        initialize(
+            address(new AccessManagerCloneable()),
+            "RegistryAdmin");
+    }
+
+
+    function completeSetup(
+        address registry,
+        address authorization,
+        address gifAdmin, 
+        address gifManager
+    )
+        public
+        virtual
+        reinitializer(type(uint8).max)
+        onlyDeployer()
+    {
+        // checks
+        _checkRegistry(registry);
+
+        VersionPart release = VersionPartLib.toVersionPart(3);
+        AccessManagerCloneable(
+            authority()).completeSetup(
+                registry, 
+                release); 
+
+        _checkAuthorization(authorization, REGISTRY(), release, true);
+
+        _registry = registry;
+        _authorization = IAuthorization(authorization);
+
+        IRegistry registryContract = IRegistry(registry);
+        _releaseRegistry = registryContract.getReleaseRegistryAddress();
+        _tokenRegistry = registryContract.getTokenRegistryAddress();
+        _staking = registryContract.getStakingAddress();
+        _stakingStore = address(
+            IStaking(_staking).getStakingStore());
+
+        // link nft ownability to registry
+        _linkToNftOwnable(_registry);
+
+        _setupRegistry(_registry);
+
+        // setup authorization for registry and supporting contracts
+        _createRoles(_authorization);
+        _grantRoleToAccount(GIF_ADMIN_ROLE(), gifAdmin);
+        _grantRoleToAccount(GIF_MANAGER_ROLE(), gifManager);
+
+        _createTargets(_authorization);
+        _createTargetAuthorizations(_authorization);
+    }
+
+
+
+    function grantServiceRoleForAllVersions(
+        IService service, 
+        ObjectType domain
+    )
+        external
+        restricted()
+    {
+        _grantRoleToAccount( 
+            RoleIdLib.roleForTypeAndAllVersions(domain),
+            address(service)); 
+    }
+
+    //--- view functions ----------------------------------------------------//
+
+    function getGifAdminRole() external view returns (RoleId) {
+        return GIF_ADMIN_ROLE();
+    }
+
+    function getGifManagerRole() external view returns (RoleId) {
+        return GIF_MANAGER_ROLE();
+    }
+
+    //--- private initialization functions -------------------------------------------//
+
+    // create registry role and target
+    function _setupRegistry(address registry) internal {
+
+        // create registry role
+        RoleId roleId = _authorization.getTargetRole(
+            _authorization.getMainTarget());
+
+        _createRole(
+            roleId,
+            _authorization.getRoleInfo(roleId));
+
+        // create registry target
+        _createTarget(
+            registry, 
+            _authorization.getMainTargetName(), 
+            true, // checkAuthority
+            false); // custom
+
+        // assign registry role to registry
+        _grantRoleToAccount(
+            roleId, 
+            registry);
+    }
+
+
+    function _createRoles(IAuthorization authorization)
+        internal
+    {
+        RoleId[] memory roles = authorization.getRoles();
+        RoleId mainTargetRoleId = authorization.getTargetRole(
+            authorization.getMainTarget());
+
+        RoleId roleId;
+        RoleInfo memory roleInfo;
+
+        for(uint256 i = 0; i < roles.length; i++) {
+
+            roleId = roles[i];
+
+            // skip main target role, create role if not exists
+            if (roleId != mainTargetRoleId && !roleExists(roleId)) {
+                _createRole(
+                    roleId,
+                    authorization.getRoleInfo(roleId));
+            }
+        }
+    }
+
+
+    function _createTargets(IAuthorization authorization)
+        internal
+    {
+        // registry
+        _createTargetWithRole(address(this), REGISTRY_ADMIN_TARGET_NAME, authorization.getTargetRole(StrLib.toStr(REGISTRY_ADMIN_TARGET_NAME)));
+        _createTargetWithRole(_releaseRegistry, RELEASE_REGISTRY_TARGET_NAME, authorization.getTargetRole(StrLib.toStr(RELEASE_REGISTRY_TARGET_NAME)));
+        _createTargetWithRole(_tokenRegistry, TOKEN_REGISTRY_TARGET_NAME, authorization.getTargetRole(StrLib.toStr(TOKEN_REGISTRY_TARGET_NAME)));
+
+        // staking
+        _createTargetWithRole(_staking, STAKING_TARGET_NAME, authorization.getTargetRole(StrLib.toStr(STAKING_TARGET_NAME)));
+        _createTarget(_stakingStore, STAKING_STORE_TARGET_NAME, true, false);
+        _createTarget(address(IComponent(_staking).getTokenHandler()), STAKING_TH_TARGET_NAME, true, false);
+    }
+
+
+    function _createTargetAuthorizations(IAuthorization authorization)
+        internal
+    {
+        Str[] memory targets = authorization.getTargets();
+        Str target;
+
+        for(uint256 i = 0; i < targets.length; i++) {
+            target = targets[i];
+            RoleId[] memory authorizedRoles = authorization.getAuthorizedRoles(target);
+            RoleId authorizedRole;
+
+            for(uint256 j = 0; j < authorizedRoles.length; j++) {
+                authorizedRole = authorizedRoles[j];
+
+                _authorizeTargetFunctions(
+                    getTargetForName(target),
+                    authorizedRole,
+                    authorization.getAuthorizedFunctions(
+                        target, 
+                        authorizedRole));
+            }
+        }
+    }
+
+
+    function _createTargets(address authorization)
+        private 
+        onlyInitializing()
+    {
+        IStaking staking = IStaking(_staking);
+        address tokenHandler = address(staking.getTokenHandler());
+
+        _createTarget(address(this), REGISTRY_ADMIN_TARGET_NAME, false, false);
+        _createTarget(_registry, REGISTRY_TARGET_NAME, true, false);
+        _createTarget(_releaseRegistry, RELEASE_REGISTRY_TARGET_NAME, true, false);
+        _createTarget(_staking, STAKING_TARGET_NAME, true, false);
+        _createTarget(_stakingStore, STAKING_STORE_TARGET_NAME, true, false);
+        _createTarget(_tokenRegistry, TOKEN_REGISTRY_TARGET_NAME, true, false);
+        _createTarget(tokenHandler, TOKEN_HANDLER_TARGET_NAME, true, false);
+    }
+}

package/contracts/registry/RegistryAuthorization.sol

@@ -0,0 +1,267 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAccess} from "../authorization/IAccess.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IStaking} from "../staking/IStaking.sol";
+
+import {Authorization} from "../authorization/Authorization.sol";
+import {POOL, REGISTRY, STAKING} from "../../contracts/type/ObjectType.sol";
+import {PUBLIC_ROLE} from "../type/RoleId.sol";
+import {ReleaseRegistry} from "./ReleaseRegistry.sol";
+import {RegistryAdmin} from "./RegistryAdmin.sol";
+import {RoleIdLib, ADMIN_ROLE, GIF_ADMIN_ROLE, GIF_MANAGER_ROLE} from "../type/RoleId.sol";
+import {StakingStore} from "../staking/StakingStore.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {TokenRegistry} from "../registry/TokenRegistry.sol";
+
+
+contract RegistryAuthorization
+     is Authorization
+{
+
+     /// @dev gif core roles
+     string public constant GIF_ADMIN_ROLE_NAME = "GifAdminRole";
+     string public constant GIF_MANAGER_ROLE_NAME = "GifManagerRole";
+     string public constant RELEASE_REGISTRY_ROLE_NAME = "ReleaseRegistryRole";
+     string public constant STAKING_ROLE_NAME = "StakingRole";
+
+     /// @dev gif roles for external contracts
+     string public constant REGISTRY_SERVICE_ROLE_NAME = "RegistryServiceRole";
+     string public constant COMPONENT_SERVICE_ROLE_NAME = "ComponentServiceRole";
+     string public constant POOL_SERVICE_ROLE_NAME = "PoolServiceRole";
+     string public constant STAKING_SERVICE_ROLE_NAME = "StakingServiceRole";
+
+     /// @dev gif core targets
+     string public constant REGISTRY_ADMIN_TARGET_NAME = "RegistryAdmin";
+     string public constant REGISTRY_TARGET_NAME = "Registry";
+     string public constant RELEASE_REGISTRY_TARGET_NAME = "ReleaseRegistry";
+     string public constant TOKEN_REGISTRY_TARGET_NAME = "TokenRegistry";
+
+     string public constant STAKING_TARGET_NAME = "Staking";
+     string public constant STAKING_TH_TARGET_NAME = "StakingTH";
+     string public constant STAKING_STORE_TARGET_NAME = "StakingStore";
+
+     constructor()
+          Authorization(REGISTRY_TARGET_NAME, REGISTRY(), false, false)
+     { }
+
+     /// @dev Sets up the GIF admin and manager roles.
+     function _setupRoles() internal override {
+
+          // service roles (for all versions)
+          _addRole(
+               RoleIdLib.roleForTypeAndAllVersions(REGISTRY()), 
+               _toRoleInfo({
+                    adminRoleId: ADMIN_ROLE(),
+                    roleType: RoleType.Gif,
+                    maxMemberCount: 999, // max member count = max 
+                    name: REGISTRY_SERVICE_ROLE_NAME}));
+
+          _addRole(
+               RoleIdLib.roleForTypeAndAllVersions(STAKING()), 
+               _toRoleInfo({
+                    adminRoleId: ADMIN_ROLE(),
+                    roleType: RoleType.Gif,
+                    maxMemberCount: 999, // max member count = max 
+                    name: STAKING_SERVICE_ROLE_NAME}));
+
+          _addRole(
+               RoleIdLib.roleForTypeAndAllVersions(POOL()), 
+               _toRoleInfo({
+                    adminRoleId: ADMIN_ROLE(),
+                    roleType: RoleType.Gif,
+                    maxMemberCount: 999, // max member count = max 
+                    name: POOL_SERVICE_ROLE_NAME}));
+
+          // gif admin role
+          _addRole(
+               GIF_ADMIN_ROLE(),
+               _toRoleInfo({
+                    adminRoleId: ADMIN_ROLE(),
+                    roleType: RoleType.Gif,
+                    maxMemberCount: 2, // TODO decide on max member count
+                    name: GIF_ADMIN_ROLE_NAME}));
+
+          // gif manager role
+          _addRole(
+               GIF_MANAGER_ROLE(), 
+               _toRoleInfo({
+                    adminRoleId: ADMIN_ROLE(),
+                    roleType: RoleType.Gif,
+                    maxMemberCount: 1, // TODO decide on max member count
+                    name: GIF_MANAGER_ROLE_NAME}));
+
+     }
+
+     /// @dev Sets up the relevant (non-service) targets for the registry.
+     function _setupTargets() internal override {
+          _addGifContractTarget(REGISTRY_ADMIN_TARGET_NAME);
+          _addGifContractTarget(RELEASE_REGISTRY_TARGET_NAME);
+          _addGifContractTarget(TOKEN_REGISTRY_TARGET_NAME);
+
+          _addGifContractTarget(STAKING_TARGET_NAME);
+          _addGifContractTarget(STAKING_TH_TARGET_NAME);
+          _addTarget(STAKING_STORE_TARGET_NAME);
+     }
+
+
+     function _setupTargetAuthorizations()
+          internal
+          override
+     {
+          // registry
+          _setupRegistryAuthorization();
+          _setupRegistryAdminAuthorization();
+          _setupReleaseRegistryAuthorization();
+          _setupTokenRegistryAuthorization();
+
+          // staking
+          _setupStakingAuthorization();
+          _setupStakingThAuthorization();
+          _setupStakingStoreAuthorization();
+     }
+
+     event LogAccessAdminDebug(string message, string custom, uint256 value);
+
+     function _setupRegistryAuthorization() internal {
+          IAccess.FunctionInfo[] storage functions;
+
+          // gif admin role
+          functions = _authorizeForTarget(REGISTRY_TARGET_NAME, GIF_ADMIN_ROLE());
+          _authorize(functions, IRegistry.registerRegistry.selector, "registerRegistry");
+
+          // registry service role
+          functions = _authorizeForTarget(
+               REGISTRY_TARGET_NAME, 
+               RoleIdLib.roleForTypeAndAllVersions(REGISTRY()));
+
+          _authorize(functions, IRegistry.register.selector, "register");
+          _authorize(functions, IRegistry.registerWithCustomType.selector, "registerWithCustomType");
+          
+          // release registry role
+          functions = _authorizeForTarget(
+               REGISTRY_TARGET_NAME, 
+               getTargetRole(getTarget(RELEASE_REGISTRY_TARGET_NAME)));
+
+          _authorize(functions, IRegistry.registerService.selector, "registerService");
+     }
+
+
+     function _setupRegistryAdminAuthorization() internal {
+          IAccess.FunctionInfo[] storage functions;
+
+          // release registry role
+          functions = _authorizeForTarget(
+               REGISTRY_ADMIN_TARGET_NAME, 
+               getTargetRole(getTarget(RELEASE_REGISTRY_TARGET_NAME)));
+
+          _authorize(functions, RegistryAdmin.grantServiceRoleForAllVersions.selector, "grantServiceRoleForAllVersions");
+     }
+
+
+     function _setupReleaseRegistryAuthorization() internal {
+          IAccess.FunctionInfo[] storage functions;
+
+          functions = _authorizeForTarget(RELEASE_REGISTRY_TARGET_NAME, GIF_ADMIN_ROLE());
+          _authorize(functions, ReleaseRegistry.createNextRelease.selector, "createNextRelease");
+          _authorize(functions, ReleaseRegistry.activateNextRelease.selector, "activateNextRelease");
+          _authorize(functions, ReleaseRegistry.setActive.selector, "setActive");
+
+          functions = _authorizeForTarget(RELEASE_REGISTRY_TARGET_NAME, GIF_MANAGER_ROLE());
+          _authorize(functions, ReleaseRegistry.prepareNextRelease.selector, "prepareNextRelease");
+          _authorize(functions, ReleaseRegistry.registerService.selector, "registerService");
+     }
+
+
+     function _setupTokenRegistryAuthorization() internal {
+          IAccess.FunctionInfo[] storage functions;
+
+          // gif manager role
+          functions = _authorizeForTarget(TOKEN_REGISTRY_TARGET_NAME, GIF_MANAGER_ROLE());
+          _authorize(functions, TokenRegistry.registerToken.selector, "registerToken");
+          _authorize(functions, TokenRegistry.registerRemoteToken.selector, "registerRemoteToken");
+          _authorize(functions, TokenRegistry.setActive.selector, "setActive");
+          _authorize(functions, TokenRegistry.setActiveForVersion.selector, "setActiveForVersion");
+          // TODO find a better way (only needed for testing)
+          _authorize(functions, TokenRegistry.setActiveWithVersionCheck.selector, "setActiveWithVersionCheck");
+     }
+
+
+     function _setupStakingAuthorization() internal {
+          IAccess.FunctionInfo[] storage functions;
+
+          // staking public role
+          functions = _authorizeForTarget(
+               STAKING_TARGET_NAME,
+               PUBLIC_ROLE());
+
+          _authorize(functions, IStaking.approveTokenHandler.selector, "approveTokenHandler");
+
+          // staking service role
+          functions = _authorizeForTarget(
+               STAKING_TARGET_NAME, 
+               RoleIdLib.roleForTypeAndAllVersions(STAKING()));
+
+          _authorize(functions, IStaking.registerTarget.selector, "registerTarget");
+          _authorize(functions, IStaking.setLockingPeriod.selector, "setLockingPeriod");
+          _authorize(functions, IStaking.setRewardRate.selector, "setRewardRate");
+          _authorize(functions, IStaking.setMaxStakedAmount.selector, "setMaxStakedAmount");
+          _authorize(functions, IStaking.refillRewardReserves.selector, "refillRewardReserves");
+          _authorize(functions, IStaking.withdrawRewardReserves.selector, "withdrawRewardReserves");
+          _authorize(functions, IStaking.createStake.selector, "createStake");
+          _authorize(functions, IStaking.stake.selector, "stake");
+          _authorize(functions, IStaking.unstake.selector, "unstake");
+          _authorize(functions, IStaking.restake.selector, "restake");
+          _authorize(functions, IStaking.updateRewards.selector, "updateRewards");
+          _authorize(functions, IStaking.claimRewards.selector, "claimRewards");
+
+          // pool service role
+          functions = _authorizeForTarget(
+               STAKING_TARGET_NAME, 
+               RoleIdLib.roleForTypeAndAllVersions(POOL()));
+
+          _authorize(functions, IStaking.increaseTotalValueLocked.selector, "increaseTotalValueLocked");
+          _authorize(functions, IStaking.decreaseTotalValueLocked.selector, "decreaseTotalValueLocked");
+     }
+
+
+     function _setupStakingThAuthorization() internal {
+          IAccess.FunctionInfo[] storage functions;
+
+          // staking service role
+          functions = _authorizeForTarget(
+               STAKING_TH_TARGET_NAME,
+               RoleIdLib.roleForTypeAndAllVersions(STAKING()));
+
+          _authorize(functions, TokenHandler.approve.selector, "approve");
+          _authorize(functions, TokenHandler.pullToken.selector, "pullToken");
+          _authorize(functions, TokenHandler.pushToken.selector, "pushToken");
+     }
+
+
+     function _setupStakingStoreAuthorization() internal {
+          IAccess.FunctionInfo[] storage functions;
+
+          // release registry role
+          functions = _authorizeForTarget(
+               STAKING_STORE_TARGET_NAME, 
+               getTargetRole(getTarget(STAKING_TARGET_NAME)));
+
+          _authorize(functions, StakingStore.setStakingRate.selector, "setStakingRate");
+          _authorize(functions, StakingStore.createTarget.selector, "createTarget");
+          _authorize(functions, StakingStore.updateTarget.selector, "updateTarget");
+          _authorize(functions, StakingStore.increaseReserves.selector, "increaseReserves");
+          _authorize(functions, StakingStore.decreaseReserves.selector, "decreaseReserves");
+          _authorize(functions, StakingStore.increaseTotalValueLocked.selector, "increaseTotalValueLocked");
+          _authorize(functions, StakingStore.decreaseTotalValueLocked.selector, "decreaseTotalValueLocked");
+          _authorize(functions, StakingStore.create.selector, "create");
+          _authorize(functions, StakingStore.update.selector, "update");
+          _authorize(functions, StakingStore.increaseStake.selector, "increaseStake");
+          _authorize(functions, StakingStore.restakeRewards.selector, "restakeRewards");
+          _authorize(functions, StakingStore.updateRewards.selector, "updateRewards");
+          _authorize(functions, StakingStore.claimUpTo.selector, "claimUpTo");
+          _authorize(functions, StakingStore.unstakeUpTo.selector, "unstakeUpTo");
+     }
+}
+