@etherisc/gif-next 0.0.2-c5c9395-682 → 0.0.2-c5f9a75-197

package/contracts/registry/ReleaseRegistry.sol

@@ -0,0 +1,491 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Create2} from "@openzeppelin/contracts/utils/Create2.sol";
+import {Clones} from "@openzeppelin/contracts/proxy/Clones.sol";
+import {IAccessManager} from "@openzeppelin/contracts/access/manager/IAccessManager.sol";
+import {Initializable} from "@openzeppelin/contracts/proxy/utils/Initializable.sol";
+import {AccessManaged} from "@openzeppelin/contracts/access/manager/AccessManaged.sol";
+import {Math} from "@openzeppelin/contracts/utils/math/Math.sol";
+
+import {NftId} from "../type/NftId.sol";
+import {RoleId, ADMIN_ROLE, PUBLIC_ROLE} from "../type/RoleId.sol";
+import {ObjectType, ObjectTypeLib, POOL, RELEASE, REGISTRY, SERVICE, STAKING} from "../type/ObjectType.sol";
+import {Version, VersionLib, VersionPart, VersionPartLib} from "../type/Version.sol";
+import {Timestamp, TimestampLib, zeroTimestamp, ltTimestamp} from "../type/Timestamp.sol";
+import {Seconds, SecondsLib} from "../type/Seconds.sol";
+import {StateId, INITIAL, SCHEDULED, DEPLOYING, ACTIVE, PAUSED, CLOSED} from "../type/StateId.sol";
+import {Version, VersionLib, VersionPart, VersionPartLib} from "../type/Version.sol";
+
+import {IService} from "../shared/IService.sol";
+import {ILifecycle} from "../shared/ILifecycle.sol";
+import {INftOwnable} from "../shared/INftOwnable.sol";
+import {IRegisterable} from "../shared/IRegisterable.sol";
+
+import {IRegistry} from "./IRegistry.sol";
+import {IRegistryLinked} from "../shared/IRegistryLinked.sol";
+import {IRegistryService} from "./IRegistryService.sol";
+import {IServiceAuthorization} from "../authorization/IServiceAuthorization.sol";
+import {IAccessAdmin} from "../authorization/IAccessAdmin.sol";
+import {RegistryAdmin} from "./RegistryAdmin.sol";
+import {Registry} from "./Registry.sol";
+import {TokenRegistry} from "./TokenRegistry.sol";
+import {ReleaseLifecycle} from "./ReleaseLifecycle.sol";
+
+contract ReleaseRegistry is 
+    AccessManaged,
+    ReleaseLifecycle, 
+    IRegistryLinked
+{
+    using ObjectTypeLib for ObjectType;
+
+    uint256 public constant INITIAL_GIF_VERSION = 3;
+
+    event LogReleaseCreation(VersionPart version, bytes32 salt); 
+    event LogReleaseActivation(VersionPart version);
+    event LogReleaseDisabled(VersionPart version);
+    event LogReleaseEnabled(VersionPart version);
+
+    // constructor
+    error ErrorReleaseRegistryNotRegistry(Registry registry);
+
+    // createNextRelease
+    error ErrorReleaseRegistryReleaseCreationDisallowed(VersionPart version, StateId currentStateId);
+
+    // prepareRelease
+    error ErrorReleaseRegistryReleasePreparationDisallowed(VersionPart version, StateId currentStateId);
+    error ErrorReleaseRegistryReleaseAlreadyPrepared(VersionPart version, StateId currentStateId);
+    error ErrorReleaseRegistryVersionMismatch(VersionPart expected, VersionPart actual);
+    error ErrorReleaseRegistryNoDomains(VersionPart version);
+
+    // registerService
+    error ErrorReleaseRegistryNoServiceRegistrationExpected();
+    error ErrorReleaseRegistryServiceRegistrationDisallowed(StateId currentStateId);
+    error ErrorReleaseRegistryServiceDomainMismatch(ObjectType expectedDomain, ObjectType actualDomain);
+    error ErrorReleaseRegistryNotService(address notService);
+    error ErrorReleaseRegistryServiceAddressMismatch(address expected, address actual);
+
+    // activateNextRelease
+    error ErrorReleaseRegistryReleaseActivationDisallowed(VersionPart releaseVersion, StateId currentStateId);
+    error ErrorReleaseRegistryReleaseNotCreated(VersionPart releaseVersion);
+    error ErrorReleaseRegistryReleaseRegistrationNotFinished(VersionPart releaseVersion, uint awaitingRegistration);
+    error ErrorReleaseRegistryReleaseAlreadyActivated(VersionPart releaseVersion);
+
+    // disableRelease
+    error ErrorReleaseRegistryReleaseNotActivated(VersionPart releaseVersion);
+    error ErrorReleaseRegistryReleaseAlreadyDisabled(VersionPart releaseVersion);
+
+    // _verifyService
+    error ErrorReleaseRegistryServiceReleaseAuthorityMismatch(IService service, address serviceAuthority, address releaseAuthority);
+    error ErrorReleaseRegistryServiceReleaseVersionMismatch(IService service, VersionPart serviceVersion, VersionPart releaseVersion);
+
+    // _verifyServiceInfo
+    error ErrorReleaseRegistryServiceInfoAddressInvalid(IService service, address expected);
+    error ErrorReleaseRegistryServiceInfoInterceptorInvalid(IService service, bool isInterceptor);
+    error ErrorReleaseRegistryServiceInfoTypeInvalid(IService service, ObjectType expected, ObjectType found);
+    error ErrorReleaseRegistryServiceInfoOwnerInvalid(IService service, address expected, address found);
+    error ErrorReleaseRegistryServiceSelfRegistration(IService service);
+    error ErrorReleaseRegistryServiceOwnerRegistered(IService service, address owner);
+
+    Seconds public constant MIN_DISABLE_DELAY = Seconds.wrap(60 * 24 * 365); // 1 year
+
+    RegistryAdmin public immutable _admin;
+    Registry public immutable _registry;
+    IRegisterable private _staking;
+    address private _stakingOwner;
+
+    mapping(VersionPart version => IRegistry.ReleaseInfo info) internal _releaseInfo;
+    mapping(VersionPart version => IServiceAuthorization authz) internal _serviceAuthorization;
+
+    // TODO check where/why this is used
+    mapping(address registryService => VersionPart version) _releaseVersionByAddress;
+
+    VersionPart private _initial;// first active version    
+    VersionPart internal _latest; // latest active version
+    VersionPart internal _next; // version to create and activate 
+    mapping(VersionPart verson => StateId releaseState) private _state;
+
+    uint256 internal _registeredServices;
+    uint256 internal _servicesToRegister;
+
+    constructor(Registry registry)
+        AccessManaged(msg.sender)
+    {
+        // TODO move this part to RegistryLinked constructor
+        if(!_isRegistry(address(registry))) {
+            revert ErrorReleaseRegistryNotRegistry(registry);
+        }
+
+        setAuthority(registry.getAuthority());
+
+        _registry = registry;
+        _admin = RegistryAdmin(_registry.getRegistryAdminAddress());
+
+        _initial = VersionPartLib.toVersionPart(INITIAL_GIF_VERSION);
+        _next = VersionPartLib.toVersionPart(INITIAL_GIF_VERSION - 1);
+    }
+
+    /// @dev skips previous release if was not activated
+    /// sets next release into state SCHEDULED
+    function createNextRelease()
+        external
+        restricted() // GIF_ADMIN_ROLE
+        returns(VersionPart)
+    {
+        _next = VersionPartLib.toVersionPart(_next.toInt() + 1);
+        _servicesToRegister = 0;
+        _registeredServices = 0;
+        _state[_next] = getInitialState(RELEASE());
+
+        return _next;
+    }
+
+    function prepareNextRelease(
+        IServiceAuthorization serviceAuthorization,
+        bytes32 salt
+    )
+        external
+        restricted() // GIF_MANAGER_ROLE
+        returns(
+            address authority, 
+            VersionPart version, 
+            bytes32 releaseSalt
+        )
+    {
+        authority = _admin.authority();
+        version = _next;
+
+        // ensures unique salt
+        // TODO CreateX have clones capability also
+        // what would releaseSalt look like if used with CreateX in pemissioned mode?
+        releaseSalt = keccak256(
+            bytes.concat(
+                bytes32(version.toInt()),
+                salt));
+
+        // verify release in state SCHEDULED
+        if (!isValidTransition(RELEASE(), _state[version], DEPLOYING())) {
+            revert ErrorReleaseRegistryReleasePreparationDisallowed(version, _state[version]);
+        }
+
+        _state[version] = DEPLOYING();
+
+        // verify authorizaion contract release matches with expected version
+        VersionPart releaseVersion = serviceAuthorization.getRelease();
+        if (releaseVersion != version) {
+            revert ErrorReleaseRegistryVersionMismatch(version, releaseVersion);
+        }
+
+
+        // sanity check to ensure service domain list is not empty
+        uint256 serviceDomainsCount = serviceAuthorization.getServiceDomains().length;
+        if (serviceDomainsCount == 0) {
+            revert ErrorReleaseRegistryNoDomains(version);
+        }
+
+        // verify prepareNextRelease is only called once per release
+        if(_servicesToRegister > 0) {
+            revert ErrorReleaseRegistryReleaseAlreadyPrepared(version, _state[version]);
+        }
+
+        _servicesToRegister = serviceDomainsCount;
+        _serviceAuthorization[version] = serviceAuthorization;
+
+        emit LogReleaseCreation(version, releaseSalt);
+    }
+
+    function registerService(IService service) 
+        external
+        restricted // GIF_MANAGER_ROLE
+        returns(NftId nftId)
+    {
+        VersionPart releaseVersion = _next;
+        StateId state = _state[releaseVersion];
+
+        // verify release in state DEPLOYING
+        if (!isValidTransition(RELEASE(), state, DEPLOYING())) {
+            // TOOD name must represent failed state transition
+            revert ErrorReleaseRegistryServiceRegistrationDisallowed(state);
+        }
+
+        _state[releaseVersion] = DEPLOYING();
+
+        // not all services are registered
+        if (_servicesToRegister == _registeredServices) {
+            revert ErrorReleaseRegistryNoServiceRegistrationExpected();
+        }
+
+        // service can work with release manager
+        (
+            IRegistry.ObjectInfo memory info,
+            ObjectType serviceDomain,
+            VersionPart serviceVersion
+        ) = _verifyService(service);
+
+        // service domain matches defined in release config
+        ObjectType expectedDomain = _serviceAuthorization[releaseVersion].getServiceDomain(_registeredServices);
+        if (serviceDomain != expectedDomain) {
+            revert ErrorReleaseRegistryServiceDomainMismatch(expectedDomain, serviceDomain);
+        }
+
+        // register service with registry
+        // !!! TODO MUST call registry at the end of this function
+        nftId = _registry.registerService(info, serviceVersion, serviceDomain);
+        service.linkToRegisteredNftId();
+        _registeredServices++;
+
+        // setup service authorization
+        // !!! TODO service A can call service B while release is not active
+        _admin.authorizeService(
+            _serviceAuthorization[releaseVersion], 
+            service,
+            serviceDomain,
+            serviceVersion);
+
+        // special roles for registry/staking/pool service
+        // !!! TODO registry service allowed to call registry while release is not activated (same for staking/pool service and staking)
+        if (
+            serviceDomain == REGISTRY() ||
+            serviceDomain == STAKING() ||
+            serviceDomain == POOL()) 
+        {
+            _admin.grantServiceRoleForAllVersions(service, serviceDomain);
+        }
+    }
+
+
+    function activateNextRelease() 
+        external 
+        restricted // GIF_ADMIN_ROLE
+    {
+        VersionPart version = _next;
+        StateId state = _state[version];
+        StateId newState = ACTIVE();
+
+        // verify release in state DEPLOYING
+        if (!isValidTransition(RELEASE(), state, newState)) {
+            revert ErrorReleaseRegistryReleaseActivationDisallowed(version, state);
+        }
+
+        // release fully deployed
+        if(_registeredServices < _servicesToRegister) {
+            revert ErrorReleaseRegistryReleaseRegistrationNotFinished(version, _servicesToRegister - _registeredServices);
+        }
+
+        // release exists, registry service MUST exist
+        address service = _registry.getServiceAddress(REGISTRY(), version);
+        if(service == address(0)) {
+            revert ErrorReleaseRegistryReleaseNotCreated(version);
+        }
+
+        _latest = version;
+        _state[version] = newState;
+
+        _releaseVersionByAddress[service] = version;
+        _releaseInfo[version].activatedAt = TimestampLib.blockTimestamp();
+
+        emit LogReleaseActivation(version);
+    }
+
+    /// @dev stop all operations with release services
+    function pauseRelease(VersionPart version)
+        external
+        restricted // GIF_ADMIN_ROLE
+    {
+        StateId state = _state[version];
+        StateId newState = PAUSED();
+
+        // verify release in state ACTIVE
+        if (!isValidTransition(RELEASE(), state, newState)) {
+            revert ErrorReleaseRegistryReleaseActivationDisallowed(version, state);
+        }
+
+        // TODO come up with a substitute
+        //_releaseAccessManager[version].disable();
+
+        _state[version] = newState;
+        _releaseInfo[version].disabledAt = TimestampLib.blockTimestamp();
+
+        emit LogReleaseDisabled(version);
+    }
+
+    // TODO consider revert if some delay is expired -> becomes disabled automatically
+    /// @dev resume operations with release services
+    function unpauseRelease(VersionPart version)
+        external
+        restricted // GIF_ADMIN_ROLE
+    {
+        StateId state = _state[version];
+        StateId newState = ACTIVE();
+
+        // verify release in state PAUSED
+        if (!isValidTransition(RELEASE(), state, newState)) {
+            revert ErrorReleaseRegistryReleaseActivationDisallowed(version, state);
+        }
+
+        // TODO come up with a substitute
+        // _releaseAccessManager[version].enable();
+        
+        _state[version] = newState;
+        _releaseInfo[version].disabledAt = zeroTimestamp();
+
+        emit LogReleaseEnabled(version);
+    }
+
+    //--- view functions ----------------------------------------------------//
+
+    function predictDeterministicAddress(
+        address implementation,
+        bytes32 salt,
+        address deployer
+    ) external pure returns (address predicted) {
+        return Clones.predictDeterministicAddress(implementation, salt, deployer);
+    }
+
+    function isActiveRegistryService(address service) external view returns(bool) {
+        VersionPart version = _releaseVersionByAddress[service];
+        return isActiveRelease(version);
+    }
+
+    function isActiveRelease(VersionPart version) public view returns(bool) {
+        return _state[version] == ACTIVE();
+    }
+
+    function getReleaseInfo(VersionPart version) external view returns(IRegistry.ReleaseInfo memory) {
+        return _releaseInfo[version];
+    }
+
+    function getNextVersion() public view returns(VersionPart) {
+        return _next;
+    }
+
+    function getLatestVersion() external view returns(VersionPart) {
+        return _latest;
+    }
+
+    function getInitialVersion() external view returns(VersionPart) {
+        return _initial;
+    }
+
+    function getState(VersionPart version) external view returns (StateId stateId) {
+        return _state[version];
+    }
+
+    function getRemainingServicesToRegister() external view returns (uint256 services) {
+        return _servicesToRegister - _registeredServices;
+    }
+
+    function getServiceAuthorization(VersionPart version)
+        external
+        view
+        returns (IServiceAuthorization serviceAuthorization)
+    {
+        return _serviceAuthorization[version];
+    }
+
+    function getRegistryAdmin() external view returns (address) {
+        return address(_admin);
+    }
+
+    //--- IRegistryLinked ------------------------------------------------------//
+
+    function getRegistry() external view returns (IRegistry) {
+        return _registry;
+    }
+
+    //--- private functions ----------------------------------------------------//
+
+    function _verifyService(IService service)
+        internal
+        view
+        returns(
+            IRegistry.ObjectInfo memory serviceInfo,
+            ObjectType serviceDomain, 
+            VersionPart serviceVersion
+        )
+    {
+        if(!service.supportsInterface(type(IService).interfaceId)) {
+            revert ErrorReleaseRegistryNotService(address(service));
+        }
+
+        address owner = msg.sender;
+        address serviceAuthority = service.authority();
+        serviceVersion = service.getVersion().toMajorPart();
+        serviceDomain = service.getDomain();// checked in registry
+        serviceInfo = service.getInitialInfo();
+
+        _verifyServiceInfo(service, serviceInfo, owner);
+
+        VersionPart releaseVersion = _next; // never 0
+        address expectedAuthority = _admin.authority(); // can be zero if registering service when release is not created
+
+        // IMPORTANT: can not guarantee service access is actually controlled by authority
+        if(serviceAuthority != expectedAuthority) {
+            revert ErrorReleaseRegistryServiceReleaseAuthorityMismatch(
+                service,
+                serviceAuthority,
+                expectedAuthority);
+        }
+
+        if(serviceVersion != releaseVersion) {
+            revert ErrorReleaseRegistryServiceReleaseVersionMismatch(
+                service,
+                serviceVersion,
+                releaseVersion);            
+        }
+    }
+
+
+    function _verifyServiceInfo(
+        IService service,
+        IRegistry.ObjectInfo memory info,
+        address expectedOwner // assume always valid, can not be 0
+    )
+        internal
+        view
+    {
+        if(info.objectAddress != address(service)) {
+            revert ErrorReleaseRegistryServiceInfoAddressInvalid(service, address(service));
+        }
+
+        if(info.isInterceptor != false) { // service is never interceptor
+            revert ErrorReleaseRegistryServiceInfoInterceptorInvalid(service, info.isInterceptor);
+        }
+
+        if(info.objectType != SERVICE()) {
+            revert ErrorReleaseRegistryServiceInfoTypeInvalid(service, SERVICE(), info.objectType);
+        }
+
+        address owner = info.initialOwner;
+
+        if(owner != expectedOwner) { // registerable owner protection
+            revert ErrorReleaseRegistryServiceInfoOwnerInvalid(service, expectedOwner, owner); 
+        }
+
+        if(owner == address(service)) {
+            revert ErrorReleaseRegistryServiceSelfRegistration(service);
+        }
+        
+        if(_registry.isRegistered(owner)) { 
+            revert ErrorReleaseRegistryServiceOwnerRegistered(service, owner);
+        }
+    }
+
+    /// @dev returns true iff a the address passes some simple proxy tests.
+    function _isRegistry(address registryAddress) internal view returns (bool) {
+
+        // zero address is certainly not registry
+        if (registryAddress == address(0)) {
+            return false;
+        }
+        // TODO try catch and return false in case of revert
+        // or just panic
+        // check if contract returns a zero nft id for its own address
+        if (IRegistry(registryAddress).getNftIdForAddress(registryAddress).eqz()) {
+            return false;
+        }
+
+        return true;
+    }
+}
+

package/contracts/registry/ServiceAuthorizationV3.sol

@@ -0,0 +1,199 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {
+     ALL, REGISTRY, PRODUCT, ORACLE, POOL, INSTANCE, COMPONENT, DISTRIBUTION, DISTRIBUTOR, APPLICATION, POLICY, CLAIM, BUNDLE, STAKING, PRICE
+} from "../../contracts/type/ObjectType.sol";
+
+import {IAccess} from "../authorization/IAccess.sol";
+import {IBundleService} from "../pool/IBundleService.sol";
+import {IDistributionService} from "../distribution/IDistributionService.sol";
+import {IInstanceService} from "../instance/IInstanceService.sol";
+import {IPoolService} from "../pool/IPoolService.sol";
+import {IStakingService} from "../staking/IStakingService.sol";
+import {IRegistryService} from "./IRegistryService.sol";
+import {ServiceAuthorization} from "../authorization/ServiceAuthorization.sol";
+
+
+contract ServiceAuthorizationV3
+     is ServiceAuthorization
+{
+
+     constructor(string memory commitHash)
+          ServiceAuthorization(commitHash)
+     {}
+
+     function _setupDomains()
+          internal
+          override
+     {
+          _authorizeDomain(REGISTRY(), address(1));
+          _authorizeDomain(STAKING(), address(2));
+          _authorizeDomain(INSTANCE(), address(3));
+          _authorizeDomain(COMPONENT(), address(4));
+          _authorizeDomain(DISTRIBUTION(), address(5));
+          _authorizeDomain(PRICE(), address(6));
+          _authorizeDomain(BUNDLE(), address(7));
+          _authorizeDomain(POOL(), address(8));
+          _authorizeDomain(ORACLE(), address(9));
+          _authorizeDomain(PRODUCT(), address(10));
+          _authorizeDomain(CLAIM(), address(11));
+          _authorizeDomain(APPLICATION(), address(12));
+          _authorizeDomain(POLICY(), address(13));
+     }
+
+
+     function _setupDomainAuthorizations()
+          internal
+          override
+     {
+          _setupIRegistryServiceAuthorization();
+          _setupStakingServiceAuthorization();
+          _setupInstanceServiceAuthorization();
+          _setupComponentServiceAuthorization();
+          _setupDistributionServiceAuthorization();
+          _setupPoolServiceAuthorization();
+          _setupBundleServiceAuthorization();
+     }
+
+
+     /// @dev registry service authorization.
+     /// authorized functions MUST be implemented with a restricted modifier
+     function _setupIRegistryServiceAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          functions = _authorizeForService(REGISTRY(), APPLICATION());
+          _authorize(functions, IRegistryService.registerPolicy.selector, "registerPolicy");
+
+          // functions = _authorizeForService(REGISTRY(), POOL());
+          // _authorize(functions, IRegistryService.registerPool.selector, "registerPool");
+
+          functions = _authorizeForService(REGISTRY(), BUNDLE());
+          _authorize(functions, IRegistryService.registerBundle.selector, "registerBundle");
+
+          functions = _authorizeForService(REGISTRY(), DISTRIBUTION());
+          // _authorize(functions, IRegistryService.registerDistribution.selector, "registerDistribution");
+          _authorize(functions, IRegistryService.registerDistributor.selector, "registerDistributor");
+
+          functions = _authorizeForService(REGISTRY(), COMPONENT());
+          _authorize(functions, IRegistryService.registerComponent.selector, "registerComponent");
+
+          functions = _authorizeForService(REGISTRY(), INSTANCE());
+          _authorize(functions, IRegistryService.registerInstance.selector, "registerInstance");
+
+          functions = _authorizeForService(REGISTRY(), STAKING());
+          _authorize(functions, IRegistryService.registerStake.selector, "registerStake");
+
+          // functions = _authorizeForService(REGISTRY(), PRODUCT());
+          // _authorize(functions, IRegistryService.registerProduct.selector, "registerProduct");
+     }
+
+
+     /// @dev staking service authorization.
+     /// authorized functions MUST be implemented with a restricted modifier
+     function _setupStakingServiceAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          functions = _authorizeForService(STAKING(), INSTANCE());
+          _authorize(functions, IStakingService.createInstanceTarget.selector, "createInstanceTarget");
+          _authorize(functions, IStakingService.setInstanceLockingPeriod.selector, "setInstanceLockingPeriod");
+          _authorize(functions, IStakingService.setInstanceRewardRate.selector, "setInstanceRewardRate");
+          _authorize(functions, IStakingService.refillInstanceRewardReserves.selector, "refillInstanceRewardReserves");
+          _authorize(functions, IStakingService.withdrawInstanceRewardReserves.selector, "withdrawInstanceRewardReserves");
+
+          functions = _authorizeForService(STAKING(), ALL());
+          _authorize(functions, IStakingService.create.selector, "create");
+          _authorize(functions, IStakingService.stake.selector, "stake");
+          _authorize(functions, IStakingService.restakeToNewTarget.selector, "restakeToNewTarget");
+          _authorize(functions, IStakingService.updateRewards.selector, "updateRewards");
+          _authorize(functions, IStakingService.claimRewards.selector, "claimRewards");
+          _authorize(functions, IStakingService.unstake.selector, "unstake");
+     }
+
+
+     /// @dev Instance service function authorization.
+     function _setupInstanceServiceAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          functions = _authorizeForService(INSTANCE(), COMPONENT());
+          _authorize(functions, IInstanceService.initializeAuthorization.selector, "initializeAuthorization");
+     }
+
+
+     /// @dev Component service function authorization.
+     function _setupComponentServiceAuthorization()
+          internal
+     {
+          // authz.authorizations = new DomainAuthorization[](4);
+
+          // authz.authorizations[0].domain = POLICY();
+          // _functions = new IAccessAdmin.Function[](1);
+          // __authorize(ComponentService.increaseProductFees.selector, "increaseProductFees"));
+          // authz.authorizations[0].functions = _functions;
+
+          // authz.authorizations[1].domain = DISTRIBUTION();
+          // _functions = new IAccessAdmin.Function[](1);
+          // __authorize(ComponentService.increaseDistributionBalance.selector, "increaseDistributionBalance"));
+          // authz.authorizations[1].functions = _functions;
+
+          // authz.authorizations[2].domain = POOL();
+          // _functions = new IAccessAdmin.Function[](1);
+          // __authorize(ComponentService.increasePoolBalance.selector, "increasePoolBalance"));
+          // authz.authorizations[2].functions = _functions;
+
+          // authz.authorizations[3].domain = BUNDLE();
+          // _functions = new IAccessAdmin.Function[](1);
+          // __authorize(ComponentService.increaseBundleBalance.selector, "increaseBundleBalance"));
+          // authz.authorizations[3].functions = _functions;
+     }
+
+     /// @dev Distribution service function authorization.
+     function _setupDistributionServiceAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          functions = _authorizeForService(DISTRIBUTION(), POLICY());
+          _authorize(functions, IDistributionService.processSale.selector, "processSale");
+          _authorize(functions, IDistributionService.processReferral.selector, "processReferral");
+     }
+
+
+     /// @dev Pool service function authorization.
+     function _setupPoolServiceAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          functions = _authorizeForService(POOL(), POLICY());
+          _authorize(functions, IPoolService.lockCollateral.selector, "lockCollateral");
+          _authorize(functions, IPoolService.releaseCollateral.selector, "releaseCollateral");
+          _authorize(functions, IPoolService.reduceCollateral.selector, "reduceCollateral");
+          _authorize(functions, IPoolService.processSale.selector, "processSale");
+
+          functions = _authorizeForService(POOL(), CLAIM());
+          _authorize(functions, IPoolService.reduceCollateral.selector, "reduceCollateral");
+     }
+
+
+     /// @dev Instance service function authorization.
+     function _setupBundleServiceAuthorization()
+          internal
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          functions = _authorizeForService(BUNDLE(), POOL());
+          _authorize(functions, IBundleService.create.selector, "create");
+          _authorize(functions, IBundleService.close.selector, "close");
+          _authorize(functions, IBundleService.lockCollateral.selector, "lockCollateral");
+          _authorize(functions, IBundleService.releaseCollateral.selector, "releaseCollateral");
+          _authorize(functions, IBundleService.unlinkPolicy.selector, "unlinkPolicy");
+     }
+}
+