@etherisc/gif-next 0.0.2-bdd64e2-180 → 0.0.2-be78639-672

package/contracts/type/RoleId.sol

@@ -0,0 +1,180 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {ObjectType, ROLE} from "./ObjectType.sol";
+import {VersionPart, VersionPartLib} from "./Version.sol";
+
+type RoleId is uint64;
+
+// type bindings
+using {
+    eqRoleId as ==, 
+    neRoleId as !=,
+    RoleIdLib.toInt,
+    RoleIdLib.isServiceRole,
+    RoleIdLib.eqz,
+    RoleIdLib.gtz
+} for RoleId global;
+
+// general pure free functions
+
+// @dev Returns true iff role ids a and b are identical
+function eqRoleId(RoleId a, RoleId b) pure returns (bool isSame) {
+    return RoleId.unwrap(a) == RoleId.unwrap(b);
+}
+
+// @dev Returns true iff role ids a and b are different
+function neRoleId(RoleId a, RoleId b) pure returns (bool isDifferent) {
+    return RoleId.unwrap(a) != RoleId.unwrap(b);
+}
+
+//--- OpenZeppelin provided roles -------------------------------------------//
+
+/// @dev Role ID needs to match with oz AccessManager.ADMIN_ROLE
+function ADMIN_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(type(uint64).min); }
+
+/// @dev Role ID needs to match with oz AccessManager.PUBLIC_ROLE
+function PUBLIC_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(type(uint64).max); }
+
+//--- GIF roles (range: 1-99) ----------------------------------------------//
+
+/// @dev cental role for gif release management.
+/// this role is necessary to call ReleaseManager.createNextRelease/activateNextRelease
+/// the actual deployment of a release requires the GIF_MANAGER_ROLE.
+/// GIF_ADMIN_ROLE is the admin of the GIF_MANAGER_ROLE.
+/// only a single holder may hold this role at any time
+function GIF_ADMIN_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(1); } 
+
+/// @dev role for token whith/blacklisting, deploying and registering the services for a new major release
+/// registering services for a new major release is only possible after a new initial release has been created by the GIF_ADMIN_ROLE
+/// token white/blacklisting is possible for any active release
+function GIF_MANAGER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(2); } 
+
+/// @dev role for registering remote staking targets and reporting remote total value locked amounts.
+function GIF_REMOTE_MANAGER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(3); } 
+
+// TODO check if/where this is really needed
+/// @dev role assigned to release registry, release specfic to lock/unlock a release
+function RELEASE_REGISTRY_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(4); }
+
+/// @dev role assigned to every instance owner
+function INSTANCE_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId(5); }  
+
+// TODO upate role id ranges
+//--- GIF core contract roles (range: 200 - 9'900) --------------------------//
+// created and assigned during initial deployment for registry and staking
+// granting for instances and components in instance service
+// object type * 100 + 0, examples:
+// - registry contract role: 200 
+// - staking contract role: 300 
+// - instance contract role: 1000
+
+//--- GIF service roles (range 201 - 9'9xx) ---------------------------------//
+// created and assigned by release manager contract
+// object type * 100 + 1/major version, examples:
+// - registry service role (any version): 299
+// - registry service role (version 3): 203
+// - registry service role (any version): 399
+// - staking service role: (version 3): 303
+// - application service role (version 3): 2003
+
+//--- GIF component contract roles (range 12'001 - 19'099) ------------------//
+// the min value of 12'001 is based on the following calculation:
+// object type * 1000 + 1 where the lowest object type is 12 (product) 
+// assigned at component registration time
+// object type * 1000 + instane specific component counter
+// on any instance a maximum number of 999 components may be deployed
+// examples:
+// - 1st pool on instance: 15001
+// - 1st distribution on instance: 14002
+// - 1st product on instance: 12003
+// - 2nd pool on instance: 15004
+// - 2nd distribution on instance: 14005
+// - 2nd product on instance: 12006
+
+
+//--- Custom roles (range >= 1'000'000) -------------------------------------//
+
+function CUSTOM_ROLE_MIN() pure returns (RoleId) { return RoleIdLib.toRoleId(1000000); }
+
+library RoleIdLib {
+
+    error ErrorRoleIdTooBig(uint256 roleId);
+
+    // constant values need to match with AccessAdminLib.SERVICE_ROLE_*
+    uint64 public constant SERVICE_ROLE_MIN =  1000;
+    uint64 public constant SERVICE_ROLE_MAX = 99099; // 99 (max object type) * 1000 + 99
+
+    uint64 public constant SERVICE_ROLE_FACTOR = 1000;
+
+    /// @dev Converts the RoleId to a uint.
+    function zero() public pure returns (RoleId) {
+        return RoleId.wrap(0);
+    }
+
+
+    /// @dev Converts an uint into a role id.
+    function toRoleId(uint256 a) public pure returns (RoleId) {
+        if (a > type(uint64).max) {
+            revert ErrorRoleIdTooBig(a);
+        }
+
+        return RoleId.wrap(uint64(a));
+    }
+
+
+    function isServiceRole(RoleId roleId)
+        public
+        pure
+        returns (bool)
+    {
+        uint256 roleIdInt = RoleId.unwrap(roleId);
+        return roleIdInt >= SERVICE_ROLE_MIN && roleIdInt <= SERVICE_ROLE_MAX;
+    }
+
+
+    function toGenericServiceRoleId(
+        ObjectType objectType
+    )
+        public 
+        pure 
+        returns (RoleId)
+    {
+        return toServiceRoleId(
+            objectType, 
+            VersionPartLib.releaseMax());
+    }
+
+
+    function toServiceRoleId(
+        ObjectType serviceDomain, 
+        VersionPart release
+    )
+        public 
+        pure 
+        returns (RoleId serviceRoleId)
+    {
+        uint256 serviceRoleIdInt = 
+            SERVICE_ROLE_MIN 
+            + SERVICE_ROLE_FACTOR * (serviceDomain.toInt() - 1)
+            + release.toInt();
+
+        return toRoleId(serviceRoleIdInt);
+    }
+
+    /// @dev Converts the role id to a uint.
+    function toInt(RoleId a) public pure returns (uint64) {
+        return uint64(RoleId.unwrap(a));
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(RoleId a) public pure returns (bool) {
+        return RoleId.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(RoleId a) public pure returns (bool) {
+        return RoleId.unwrap(a) == 0;
+    }
+}

package/contracts/type/Seconds.sol

@@ -0,0 +1,120 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+/// @dev Target: Cover durations of 1000 years.
+type Seconds is uint40;
+
+using {
+    SecondsEq as ==,
+    SecondsLt as <,
+    SecondsGt as >,
+    SecondsAdd as +,
+    SecondsLib.eqz,
+    SecondsLib.gtz,
+    SecondsLib.eq,
+    SecondsLib.gt,
+    SecondsLib.lt,
+    SecondsLib.toInt,
+    SecondsLib.add
+} for Seconds global;
+
+function SecondsEq(Seconds duration1, Seconds duration2) pure returns (bool) {
+    return SecondsLib.eq(duration1, duration2);
+}
+
+function SecondsLt(Seconds duration1, Seconds duration2) pure returns (bool) {
+    return SecondsLib.lt(duration1, duration2);
+}
+
+function SecondsGt(Seconds duration1, Seconds duration2) pure returns (bool) {
+    return SecondsLib.gt(duration1, duration2);
+}
+
+function SecondsAdd(Seconds duration1, Seconds duration2) pure returns (Seconds) {
+    return SecondsLib.add(duration1, duration2);
+}
+
+
+library SecondsLib {
+
+    error ErrorSecondsLibDurationTooBig(uint256 duration);
+
+    function zero() public pure returns (Seconds) {
+        return Seconds.wrap(0);
+    }
+
+    function max() public pure returns (Seconds) {
+        return Seconds.wrap(_max());
+    }
+
+    function oneDay() public pure returns (Seconds duration) {
+        return Seconds.wrap(24 * 3600);
+    }
+
+    function fromDays(uint32 numberOfDays) public pure returns (Seconds duration) {
+        return Seconds.wrap(numberOfDays * 24 * 3600);
+    }
+
+    function oneYear() public pure returns (Seconds duration) {
+        return Seconds.wrap(365 * 24 * 3600);
+    }
+
+    /// @dev converts the uint duration into Seconds
+    /// function reverts if duration is exceeding max Seconds value
+    function toSeconds(uint256 duration) public pure returns (Seconds) {
+        // if(duration > type(uint40).max) {
+        if(duration > _max()) {
+            revert ErrorSecondsLibDurationTooBig(duration);
+        }
+
+        return Seconds.wrap(uint40(duration));
+    }
+
+    /// @dev return true if duration equals 0
+    function eqz(Seconds duration) public pure returns (bool) {
+        return Seconds.unwrap(duration) == 0;
+    }
+
+    /// @dev return true if duration is larger than 0
+    function gtz(Seconds duration) public pure returns (bool) {
+        return Seconds.unwrap(duration) > 0;
+    }
+
+    /// @dev return true iff duration1 and duration2 are the same
+    function eq(Seconds duration1, Seconds duration2) public pure returns (bool) {
+        return Seconds.unwrap(duration1) == Seconds.unwrap(duration2);
+    }
+
+    /// @dev return true if duration1 is larger than duration2
+    function gt(Seconds duration1, Seconds duration2) public pure returns (bool) {
+        return Seconds.unwrap(duration1) > Seconds.unwrap(duration2);
+    }
+
+    /// @dev return true if duration1 is smaller than duration2
+    function lt(Seconds duration1, Seconds duration2) public pure returns (bool) {
+        return Seconds.unwrap(duration1) < Seconds.unwrap(duration2);
+    }
+
+    /// @dev returns the smaller of the duration
+    function min(Seconds duration1, Seconds duration2) public pure returns (Seconds) {
+        if (Seconds.unwrap(duration1) < Seconds.unwrap(duration2)) {
+            return duration1;
+        } 
+        
+        return duration2;
+    }   
+
+    /// @dev return add duration1 and duration2
+    function add(Seconds duration1, Seconds duration2) public pure returns (Seconds) {
+        return Seconds.wrap(Seconds.unwrap(duration1) + Seconds.unwrap(duration2));
+    }
+
+    function toInt(Seconds duration) public pure returns (uint256) {
+        return uint256(uint40(Seconds.unwrap(duration)));
+    }
+
+    function _max() internal pure returns (uint40) {
+        // IMPORTANT: type nees to match with actual definition for Seconds
+        return type(uint40).max;
+    }
+}

package/contracts/type/Selector.sol

@@ -0,0 +1,107 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+type Selector is bytes4;
+
+// type bindings
+using {
+    eqSelector as ==, 
+    neSelector as !=, 
+    SelectorLib.toBytes4,
+    SelectorLib.toString,
+    SelectorLib.eqz
+} for Selector global;
+
+// pure free functions for operators
+function eqSelector(Selector s1, Selector s2) pure returns (bool isSame) {
+    return SelectorLib.eq(s1, s2);
+}
+
+function neSelector(Selector s1, Selector s2) pure returns (bool isDifferent) {
+    return SelectorLib.ne(s1, s2);
+}
+
+// library functions that operate on user defined type
+library SelectorLib {
+
+    function zero() public pure returns (Selector) {
+        return Selector.wrap("");
+    }
+
+    function eqz(Selector s) public pure returns (bool) {
+        return Selector.unwrap(s) == "";
+    }
+
+    function eq(Selector s1, Selector s2) public pure returns (bool isSame) {
+        return Selector.unwrap(s1) == Selector.unwrap(s2);
+    }
+
+    function ne(Selector s1, Selector s2) public pure returns (bool isDifferent) {
+        return Selector.unwrap(s1) != Selector.unwrap(s2);
+    }
+
+    function toSelector(bytes4 selector) public pure returns (Selector) {
+        return Selector.wrap(selector);
+    }
+
+    function toBytes4(Selector s) public pure returns (bytes4) {
+        return Selector.unwrap(s);
+    }
+
+    function toString(Selector s) public pure returns (string memory) {
+        return string(abi.encode(Selector.unwrap(s)));
+    }
+}
+
+// selector specific set library
+// based on https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/utils/structs/EnumerableSet.sol
+library SelectorSetLib {
+
+    struct Set {
+        Selector[] selectors;
+        mapping(Selector selector => uint256 index) at;
+    }
+
+    function add(Set storage set, Selector selector) external {
+        // selector already in set
+        if (set.at[selector] > 0) { return; }
+
+        set.selectors.push(selector);
+        set.at[selector] = set.selectors.length;
+    }
+
+    function remove(Set storage set, Selector selector) external {
+        uint256 selectorIndex = set.at[selector];
+
+        // selector not in set
+        if (selectorIndex == 0) {return; }
+
+        uint256 toDeleteIndex = selectorIndex - 1;
+        uint256 lastIndex = set.selectors.length - 1;
+
+        if (lastIndex != toDeleteIndex) {
+            Selector lastSelector = set.selectors[lastIndex];
+            set.selectors[toDeleteIndex] = lastSelector;
+            set.at[lastSelector] = selectorIndex; // Replace lastValue's index to valueIndex
+        }
+
+        set.selectors.pop();
+        delete set.at[selector];
+    }
+
+    function isEmpty(Set storage set) external view returns(bool empty) {
+        return set.selectors.length == 0;
+    }
+
+    function contains(Set storage set, Selector selector) external view returns(bool inSet) {
+        return set.at[selector] > 0;
+    }
+
+    function size(Set storage set) external view returns(uint256 length) {
+        return set.selectors.length;
+    }
+
+    function at(Set storage set, uint256 index) external view returns(Selector selector) {
+        return set.selectors[index];
+    }
+}

package/contracts/{types → type}/StateId.sol

@@ -9,11 +9,37 @@ using {
     eqStateId as ==, 
     neStateId as !=, 
     StateIdLib.eqz,
+    StateIdLib.eq,
     StateIdLib.gtz,
     StateIdLib.toInt
 } for StateId global;
 
 // general pure free functions
+
+function INITIAL() pure returns (StateId) {
+    return toStateId(1);
+}
+
+function SCHEDULED() pure returns (StateId) {
+    return toStateId(2);
+}
+
+function DEPLOYING() pure returns (StateId) {
+    return toStateId(3);
+}
+
+function DEPLOYED() pure returns (StateId) {
+    return toStateId(4);
+}
+
+function ACTIVE() pure returns (StateId) {
+    return toStateId(5);
+}
+
+function SKIPPED() pure returns (StateId) {
+    return toStateId(6);
+}
+
 function APPLIED() pure returns (StateId) {
     return toStateId(10);
 }
@@ -26,20 +52,32 @@ function DECLINED() pure returns (StateId) {
     return toStateId(30);
 }
 
-function UNDERWRITTEN() pure returns (StateId) {
+function COLLATERALIZED() pure returns (StateId) {
     return toStateId(40);
 }
 
-function CONFIRMED() pure returns (StateId) {
+function SUBMITTED() pure returns (StateId) {
     return toStateId(50);
 }
 
+function CONFIRMED() pure returns (StateId) {
+    return toStateId(51);
+}
+
 function EXPECTED() pure returns (StateId) {
     return toStateId(60);
 }
 
-function ACTIVE() pure returns (StateId) {
-    return toStateId(100);
+function FULFILLED() pure returns (StateId) {
+    return toStateId(70);
+}
+
+function FAILED() pure returns (StateId) {
+    return toStateId(7);
+}
+
+function CANCELLED() pure returns (StateId) {
+    return toStateId(72);
 }
 
 function PAUSED() pure returns (StateId) {
@@ -67,6 +105,7 @@ function toStateId(uint256 id) pure returns (StateId) {
     return StateId.wrap(uint8(id));
 }
 
+// TODO move to StateIdLib and rename to zero()
 /// @dev Return the StateId zero (0)
 function zeroStateId() pure returns (StateId) {
     return StateId.wrap(0);
@@ -83,6 +122,11 @@ function neStateId(StateId a, StateId b) pure returns (bool isDifferent) {
 
 // library functions that operate on user defined type
 library StateIdLib {
+
+    function zero() public pure returns (StateId) {
+        return StateId.wrap(0);
+    }
+
     /// @dev Converts the NftId to a uint256.
     function toInt(StateId stateId) public pure returns (uint96) {
         return uint96(StateId.unwrap(stateId));

package/contracts/type/String.sol

@@ -0,0 +1,65 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ShortString, ShortStrings} from "@openzeppelin/contracts/utils/ShortStrings.sol";
+
+type Str is bytes32;
+
+using {
+    StrEq as ==,
+    StrNe as !=,
+    StrLib.toString,
+    StrLib.length
+} for Str global;
+
+// pure free function needed for the operator overloading
+function StrEq(Str s1, Str s2) pure returns (bool) {
+    return StrLib.eq(s1, s2);
+}
+
+// pure free function needed for the operator overloading
+function StrNe(Str s1, Str s2) pure returns (bool) {
+    return StrLib.ne(s1, s2);
+}
+
+library StrLib {
+
+
+    /// @dev converts the provided string into a short string.
+    /// uses ShortStrings.toShortString
+    function toStr(string memory str) public pure returns (Str) {
+        return Str.wrap(ShortString.unwrap(ShortStrings.toShortString(str)));
+    }
+
+    /// @dev return true iff s1 equals s2
+    function eq(Str s1, Str s2) public pure returns (bool) {
+        return Str.unwrap(s1) == Str.unwrap(s2);
+    }
+
+    /// @dev return true iff s1 differs from s2
+    function ne(Str s1, Str s2) public pure returns (bool) {
+        return Str.unwrap(s1) != Str.unwrap(s2);
+    }
+
+    /// @dev return true iff s1 equals from s2
+    function eq(string memory s1, string memory s2) public pure returns (bool) {
+        return keccak256(bytes(s1)) == keccak256(bytes(s2));
+    }
+
+    /// @dev return true iff s1 differs s2
+    function ne(string memory s1, string memory s2) public pure returns (bool) {
+        return !eq(s1, s2);
+    }
+
+    /// @dev converts the provided short string into a string.
+    /// uses ShortStrings.toString
+    function toString(Str str) public pure returns (string memory) {
+        return ShortStrings.toString(ShortString.wrap(Str.unwrap(str)));
+    }
+
+    /// @dev converts the provided short string into a string.
+    /// uses ShortStrings.byteLength
+    function length(Str str) public pure returns (uint256 byteLength) {
+        return ShortStrings.byteLength(ShortString.wrap(Str.unwrap(str)));
+    }
+}

package/contracts/{types → type}/Timestamp.sol

@@ -1,6 +1,10 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
 
+import {Seconds} from "./Seconds.sol";
+
+/// @dev Target: Cover 10 years with 1 ms block time resolution.
+/// Typical block time resolution is 1s.
 type Timestamp is uint40;
 
 using {
@@ -10,9 +14,16 @@ using {
     lteTimestamp as <=,
     eqTimestamp as ==,
     neTimestamp as !=,
+    TimestampLib.eq,
+    TimestampLib.ne,
+    TimestampLib.gt,
+    TimestampLib.gte,
+    TimestampLib.lt,
+    TimestampLib.lte,
     TimestampLib.gtz,
     TimestampLib.eqz,
-    TimestampLib.addSeconds
+    TimestampLib.addSeconds,
+    TimestampLib.toInt
 } for Timestamp global;
 
 /// @dev return true if Timestamp a is after Timestamp b
@@ -45,24 +56,29 @@ function neTimestamp(Timestamp a, Timestamp b) pure returns (bool) {
     return Timestamp.unwrap(a) != Timestamp.unwrap(b);
 }
 
-/// @dev Converts the uint256 to a Timestamp.
-function toTimestamp(uint256 timestamp) pure returns (Timestamp) {
-    return Timestamp.wrap(uint40(timestamp));
-}
-
-// function blockTimestamp() view returns (Timestamp) {
-//     return toTimestamp(block.timestamp);
-// }
-
+// TODO move to TimestampLib and rename to zero()
 /// @dev Return the Timestamp zero (0)
 function zeroTimestamp() pure returns (Timestamp) {
-    return toTimestamp(0);
+    return Timestamp.wrap(0);
 }
 
 library TimestampLib {
-    function blockTimestamp() public view returns (Timestamp) {
+
+    function zero() public pure returns (Timestamp) {
+        return Timestamp.wrap(0);
+    }
+
+    function max() public pure returns (Timestamp) {
+        return Timestamp.wrap(type(uint40).max);
+    }
+
+    function current() public view returns (Timestamp) {
         return Timestamp.wrap(uint40(block.timestamp));
     }
+
+    function toTimestamp(uint256 timestamp) public pure returns (Timestamp) {
+        return Timestamp.wrap(uint40(timestamp));
+    }
     
     /// @dev return true if Timestamp a is after Timestamp b
     function gt(Timestamp a, Timestamp b) public pure returns (bool isAfter) {
@@ -103,22 +119,22 @@ library TimestampLib {
         return neTimestamp(a, b);
     }
 
-    /// @dev return true if Timestamp is larger than 0
-    function gtz(Timestamp timestamp) public pure returns (bool) {
-        return Timestamp.unwrap(timestamp) > 0;
-    }
-
     /// @dev return true if Timestamp equals 0
     function eqz(Timestamp timestamp) public pure returns (bool) {
         return Timestamp.unwrap(timestamp) == 0;
     }
 
+    /// @dev return true if Timestamp is larger than 0
+    function gtz(Timestamp timestamp) public pure returns (bool) {
+        return Timestamp.unwrap(timestamp) > 0;
+    }
+
     /// @dev return true if Timestamp a is not equal to Timestamp b
     function addSeconds(
         Timestamp timestamp,
-        uint256 timeDelta
+        Seconds duration
     ) public pure returns (Timestamp) {
-        return toTimestamp(Timestamp.unwrap(timestamp) + uint40(timeDelta));
+        return toTimestamp(Timestamp.unwrap(timestamp) + duration.toInt());
     }
 
     function toInt(Timestamp timestamp) public pure returns (uint256) {