@etherisc/gif-next 0.0.2-bdb6804-509 → 0.0.2-bdbfee9-660

package/contracts/instance/service/DistributionService.sol

@@ -1,346 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {IRegistry} from "../../registry/IRegistry.sol";
-import {IInstance} from "../../instance/IInstance.sol";
-import {InstanceAccessManager} from "../InstanceAccessManager.sol";
-import {InstanceReader} from "../../instance/InstanceReader.sol";
-import {ISetup} from "../../instance/module/ISetup.sol";
-import {IPolicy} from "../module/IPolicy.sol";
-
-import {NftId, NftIdLib, zeroNftId} from "../../types/NftId.sol";
-import {Fee, FeeLib} from "../../types/Fee.sol";
-import {PRODUCT_SERVICE_ROLE, DISTRIBUTION_OWNER_ROLE} from "../../types/RoleId.sol";
-import {KEEP_STATE} from "../../types/StateId.sol";
-import {ObjectType, DISTRIBUTION, INSTANCE, DISTRIBUTION, DISTRIBUTOR, PRICE} from "../../types/ObjectType.sol";
-import {Version, VersionLib} from "../../types/Version.sol";
-import {RoleId} from "../../types/RoleId.sol";
-
-import {IVersionable} from "../../shared/IVersionable.sol";
-import {Versionable} from "../../shared/Versionable.sol";
-
-import {IService} from "../../shared/IService.sol";
-import {Service} from "../../shared/Service.sol";
-import {ComponentService} from "../base/ComponentService.sol";
-import {InstanceService} from "../InstanceService.sol";
-import {IComponent} from "../../components/IComponent.sol";
-import {IDistributionComponent} from "../../components/IDistributionComponent.sol";
-import {IDistributionService} from "./IDistributionService.sol";
-import {IPricingService} from "./IPricingService.sol";
-
-import {UFixed, UFixedLib} from "../../types/UFixed.sol";
-import {DistributorType, DistributorTypeLib} from "../../types/DistributorType.sol";
-import {ReferralId, ReferralStatus, ReferralLib} from "../../types/Referral.sol";
-import {Timestamp, TimestampLib, zeroTimestamp} from "../../types/Timestamp.sol";
-import {Key32} from "../../types/Key32.sol";
-import {IDistribution} from "../module/IDistribution.sol";
-import {InstanceStore} from "../InstanceStore.sol";
-
-
-contract DistributionService is
-    ComponentService,
-    IDistributionService
-{
-    using NftIdLib for NftId;
-    using TimestampLib for Timestamp;
-    using UFixedLib for UFixed;
-    using FeeLib for Fee;
-    using ReferralLib for ReferralId;
-
-    address internal _registryAddress;
-    
-    function _initialize(
-        address owner, 
-        bytes memory data
-    )
-        internal
-        initializer
-        virtual override
-    {
-        address initialOwner;
-        address registryAddress;
-        (registryAddress, initialOwner) = abi.decode(data, (address, address));
-        // TODO while DistributionService is not deployed in DistributionServiceManager constructor
-        //      owner is DistributionServiceManager deployer
-        initializeService(registryAddress, address(0), owner);
-        registerInterface(type(IDistributionService).interfaceId);
-    }
-
-    function getDomain() public pure override returns(ObjectType) {
-        return DISTRIBUTION();
-    }
-
-    function register(address distributionAddress) 
-        external
-        returns(NftId distributionNftId)
-    {
-        (
-            IComponent component,
-            address owner,
-            IInstance instance,
-            NftId instanceNftId
-        ) = _checkComponentForRegistration(
-            distributionAddress,
-            DISTRIBUTION(),
-            DISTRIBUTION_OWNER_ROLE());
-
-        IRegistry.ObjectInfo memory distributionInfo = getRegistryService().registerDistribution(component, owner);
-        IDistributionComponent distribution = IDistributionComponent(distributionAddress);
-        distribution.linkToRegisteredNftId();
-        distributionNftId = distributionInfo.nftId;
-
-        instance.getInstanceStore().createDistributionSetup(distributionNftId, distribution.getSetupInfo());
-        // TODO move to distribution?
-        bytes4[][] memory selectors = new bytes4[][](2);
-        selectors[0] = new bytes4[](1);
-        selectors[1] = new bytes4[](2);
-
-        selectors[0][0] = IDistributionComponent.setFees.selector;
-        selectors[1][0] = IDistributionComponent.processRenewal.selector;
-
-        RoleId[] memory roles = new RoleId[](2);
-        roles[0] = DISTRIBUTION_OWNER_ROLE();
-        roles[1] = PRODUCT_SERVICE_ROLE();
-
-        getInstanceService().createGifTarget(
-            instanceNftId, 
-            distributionAddress, 
-            distribution.getName(), 
-            selectors, 
-            roles);
-    }
-
-    function setFees(
-        Fee memory minDistributionOwnerFee,
-        Fee memory distributionFee
-    )
-        external
-        override
-    {
-        if (minDistributionOwnerFee.fractionalFee > distributionFee.fractionalFee) {
-            revert ErrorIDistributionServiceMinFeeTooHigh(minDistributionOwnerFee.fractionalFee.toInt(), distributionFee.fractionalFee.toInt());
-        }
-
-        (NftId distributionNftId,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(DISTRIBUTION());
-        InstanceReader instanceReader = instance.getInstanceReader();
-
-        ISetup.DistributionSetupInfo memory distSetupInfo = instanceReader.getDistributionSetupInfo(distributionNftId);
-        distSetupInfo.minDistributionOwnerFee = minDistributionOwnerFee;
-        distSetupInfo.distributionFee = distributionFee;
-        
-        instance.getInstanceStore().updateDistributionSetup(distributionNftId, distSetupInfo, KEEP_STATE());
-    }
-
-    function createDistributorType(
-        string memory name,
-        UFixed minDiscountPercentage,
-        UFixed maxDiscountPercentage,
-        UFixed commissionPercentage,
-        uint32 maxReferralCount,
-        uint32 maxReferralLifetime,
-        bool allowSelfReferrals,
-        bool allowRenewals,
-        bytes memory data
-    )
-        external
-        returns (DistributorType distributorType)
-    {
-        (NftId distributionNftId,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(DISTRIBUTION());
-
-        {
-            ISetup.DistributionSetupInfo memory setupInfo = instance.getInstanceReader().getDistributionSetupInfo(distributionNftId);
-            UFixed variableFeesPartsTotal = setupInfo.minDistributionOwnerFee.fractionalFee.add(commissionPercentage);
-            UFixed maxDiscountPercentageLimit = setupInfo.distributionFee.fractionalFee.sub(variableFeesPartsTotal);
-            if (maxDiscountPercentage.gt(maxDiscountPercentageLimit)) {
-                revert ErrorIDistributionServiceMaxDiscountTooHigh(maxDiscountPercentage.toInt(), maxDiscountPercentageLimit.toInt());
-            }
-        }
-
-        distributorType = DistributorTypeLib.toDistributorType(distributionNftId, name);
-        Key32 key32 = distributorType.toKey32();
-
-        if(!instance.getInstanceStore().exists(key32)) {
-            IDistribution.DistributorTypeInfo memory info = IDistribution.DistributorTypeInfo(
-                name,
-                minDiscountPercentage,
-                maxDiscountPercentage,
-                commissionPercentage,
-                maxReferralCount,
-                maxReferralLifetime,
-                allowSelfReferrals,
-                allowRenewals,
-                data);
-
-            instance.getInstanceStore().createDistributorType(key32, info);
-        }
-    }
-
-    function createDistributor(
-        address distributor,
-        DistributorType distributorType,
-        bytes memory data
-    ) external returns (NftId distributorNftId)
-    {
-        (NftId distributionNftId,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(DISTRIBUTION());
-
-        distributorNftId = getRegistryService().registerDistributor(
-            IRegistry.ObjectInfo(
-                zeroNftId(), 
-                distributionNftId,
-                DISTRIBUTOR(),
-                true, // intercepting property for bundles is defined on pool
-                address(0),
-                distributor,
-                ""
-            ));
-
-        IDistribution.DistributorInfo memory info = IDistribution.DistributorInfo(
-            distributorType,
-            true, // active
-            data,
-            0,
-            0);
-
-        instance.getInstanceStore().createDistributor(distributorNftId, info);
-    }
-
-    function updateDistributorType(
-        NftId distributorNftId,
-        DistributorType distributorType,
-        bytes memory data
-    ) external virtual
-    {
-        (,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(DISTRIBUTION());
-        InstanceReader instanceReader = instance.getInstanceReader();
-        IDistribution.DistributorInfo memory distributorInfo = instanceReader.getDistributorInfo(distributorNftId);
-        distributorInfo.distributorType = distributorType;
-        distributorInfo.data = data;
-        instance.getInstanceStore().updateDistributor(distributorNftId, distributorInfo, KEEP_STATE());
-    }
-
-
-    function createReferral(
-        NftId distributorNftId,
-        string memory code,
-        UFixed discountPercentage,
-        uint32 maxReferrals,
-        Timestamp expiryAt,
-        bytes memory data
-    )
-        external
-        virtual
-        returns (ReferralId referralId)
-    {
-        (NftId distributionNftId,, IInstance instance) = _getAndVerifyCallingComponentAndInstance(DISTRIBUTION());
-
-        if (bytes(code).length == 0) {
-            revert ErrorIDistributionServiceInvalidReferral(code);
-        }
-        if (expiryAt.eqz()) {
-            revert ErrorIDistributionServiceExpirationInvalid(expiryAt);
-        }
-
-        InstanceReader instanceReader = instance.getInstanceReader();
-        IDistribution.DistributorInfo memory distributorInfo = instanceReader.getDistributorInfo(distributorNftId);
-        DistributorType distributorType = distributorInfo.distributorType;
-        IDistribution.DistributorTypeInfo memory distributorTypeData = instanceReader.getDistributorTypeInfo(distributorType);
-
-        if (distributorTypeData.maxReferralCount < maxReferrals) {
-            revert ErrorIDistributionServiceMaxReferralsExceeded(distributorTypeData.maxReferralCount);
-        }
-        if (distributorTypeData.minDiscountPercentage > discountPercentage) {
-            revert ErrorIDistributionServiceDiscountTooLow(distributorTypeData.minDiscountPercentage.toInt(), discountPercentage.toInt());
-        }
-        if (distributorTypeData.maxDiscountPercentage < discountPercentage) {
-            revert ErrorIDistributionServiceDiscountTooHigh(distributorTypeData.maxDiscountPercentage.toInt(), discountPercentage.toInt());
-        }
-        if (expiryAt.toInt() - TimestampLib.blockTimestamp().toInt() > distributorTypeData.maxReferralLifetime) {
-            revert ErrorIDistributionServiceExpiryTooLong(distributorTypeData.maxReferralLifetime, expiryAt.toInt());
-        }
-
-        referralId = ReferralLib.toReferralId(distributionNftId, code);
-        IDistribution.ReferralInfo memory info = IDistribution.ReferralInfo(
-            distributorNftId,
-            code,
-            discountPercentage,
-            maxReferrals,
-            0, // used referrals
-            expiryAt,
-            data
-        );
-
-        instance.getInstanceStore().createReferral(referralId.toKey32(), info);
-        return referralId;
-    }
-
-    function processSale(
-        NftId distributionNftId, // assume always of distribution type
-        ReferralId referralId,
-        IPolicy.Premium memory premium,
-        uint256 transferredDistributionFeeAmount
-    )
-        external
-        virtual
-    {
-        bool isReferral = ! referralId.eqz();
-        bool referralValid = referralIsValid(distributionNftId, referralId);
-
-        if (isReferral && ! referralValid) {
-            revert ErrorIDistributionServiceReferralInvalid(distributionNftId, referralId);
-        }
-
-        IInstance instance = _getInstanceForDistribution(distributionNftId);
-        InstanceReader reader = instance.getInstanceReader();
-        InstanceStore store = instance.getInstanceStore();
-        IDistribution.ReferralInfo memory referralInfo = reader.getReferralInfo(referralId);
-        IDistribution.DistributorInfo memory distributorInfo = reader.getDistributorInfo(referralInfo.distributorNftId);
-        ISetup.DistributionSetupInfo memory setupInfo = reader.getDistributionSetupInfo(distributionNftId);
-        
-        uint256 distributionOwnerFee = premium.distributionOwnerFeeFixAmount + premium.distributionOwnerFeeVarAmount;
-        uint256 commissionAmount = premium.commissionAmount;
-
-        if (transferredDistributionFeeAmount != distributionOwnerFee + commissionAmount) {
-            revert ErrorIDistributionServiceInvalidFeeTransferred(transferredDistributionFeeAmount, distributionOwnerFee + commissionAmount);
-        }
-
-
-        if (distributionOwnerFee > 0) {
-            setupInfo.sumDistributionOwnerFees += distributionOwnerFee;
-            store.updateDistributionSetup(distributionNftId, setupInfo, KEEP_STATE());
-        }
-
-        if (isReferral) {
-            referralInfo.usedReferrals += 1;
-            store.updateReferral(referralId.toKey32(), referralInfo, KEEP_STATE());
-
-            if (commissionAmount > 0) {
-                distributorInfo.sumCommisions += commissionAmount;
-                distributorInfo.numPoliciesSold += 1;
-                store.updateDistributor(referralInfo.distributorNftId, distributorInfo, KEEP_STATE());
-            }
-        }
-    }
-
-    // TODO: zero should return false
-    function referralIsValid(NftId distributionNftId, ReferralId referralId) public view returns (bool isValid) {
-        IInstance instance = _getInstanceForDistribution(distributionNftId);
-        IDistribution.ReferralInfo memory info = instance.getInstanceReader().getReferralInfo(referralId);
-
-        if (info.distributorNftId.eqz()) {
-            return false;
-        }
-
-        isValid = info.expiryAt.eqz() || (info.expiryAt.gtz() && TimestampLib.blockTimestamp() <= info.expiryAt);
-        isValid = isValid && info.usedReferrals < info.maxReferrals;
-    }
-
-    function _getInstanceForDistribution(NftId distributionNftId)
-        internal
-        view
-        returns(IInstance instance)
-    {
-        NftId instanceNftId = getRegistry().getObjectInfo(distributionNftId).parentNftId;
-        address instanceAddress = getRegistry().getObjectInfo(instanceNftId).objectAddress;
-        return IInstance(instanceAddress);
-    }
-}

package/contracts/instance/service/DistributionServiceManager.sol

@@ -1,51 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {IVersionable} from "../../shared/IVersionable.sol";
-import {ProxyManager} from "../../shared/ProxyManager.sol";
-import {DistributionService} from "./DistributionService.sol";
-import {Registry} from "../../registry/Registry.sol";
-import {RegistryService} from "../../registry/RegistryService.sol";
-import {REGISTRY} from "../../types/ObjectType.sol";
-
-contract DistributionServiceManager is ProxyManager {
-
-    DistributionService private _distributionService;
-
-    /// @dev initializes proxy manager with distribution service implementation and deploys instance
-    constructor(
-        address registryAddress
-    )
-        ProxyManager(registryAddress)
-    {
-        DistributionService distSrv = new DistributionService();
-        bytes memory data = abi.encode(registryAddress, address(this));
-        IVersionable versionable = deploy(
-            address(distSrv), 
-            data);
-
-        _distributionService = DistributionService(address(versionable));
-        
-        // TODO `thi` must have a role or own nft to register service
-        //Registry registry = Registry(registryAddress);
-        //address registryServiceAddress = registry.getServiceAddress(REGISTRY(), _distributionService.getMajorVersion());
-        //RegistryService registryService = RegistryService(registryServiceAddress);
-        //registryService.registerService(_distributionService);
-        
-        // TODO no nft to link yet
-        // link ownership of instance service manager ot nft owner of instance service
-        //_linkToNftOwnable(
-        //    address(registryAddress),
-        //    address(_distributionService));
-    }
-
-    //--- view functions ----------------------------------------------------//
-    function getDistributionService()
-        external
-        view
-        returns (DistributionService distributionService)
-    {
-        return _distributionService;
-    }
-
-}

package/contracts/instance/service/IClaimService.sol

@@ -1,61 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {IRisk} from "../module/IRisk.sol";
-import {IService} from "../../shared/IService.sol";
-
-import {ClaimId} from "../../types/ClaimId.sol";
-import {PayoutId} from "../../types/PayoutId.sol";
-import {NftId} from "../../types/NftId.sol";
-import {ReferralId} from "../../types/Referral.sol";
-import {RiskId} from "../../types/RiskId.sol";
-import {StateId} from "../../types/StateId.sol";
-import {Timestamp} from "../../types/Timestamp.sol";
-import {UFixed} from "../../types/UFixed.sol";
-import {Fee} from "../../types/Fee.sol";
-
-/// @dev gif service responsible for creating claims and payouts
-/// only product components may call transaction functions
-interface IClaimService is
-    IService
-{
-
-    /// @dev create a new claim for the specified policy
-    /// function can only be called by product, policy needs to match with calling product
-    function createClaim(
-        NftId policyNftId, 
-        uint256 claimAmount,
-        bytes memory claimData
-    ) external returns (ClaimId);
-
-    /// @dev confirms the specified claim and fixes the final claim amount
-    /// function can only be called by product, policy needs to match with calling product
-    function confirmClaim(NftId policyNftId, ClaimId claimId, uint256 claimAmount) external;
-
-    /// @dev declares the claim as invalid, no payout(s) will be made
-    /// function can only be called by product, policy needs to match with calling product
-    function declineClaim(NftId policyNftId, ClaimId claimId) external;
-
-    /// @dev closes the claim
-    /// a claim may only be closed once all existing payouts have been executed and the sum of the paid out amounts has reached the claim amount
-    /// function can only be called by product, policy needs to match with calling product
-    function closeClaim(NftId policyNftId, ClaimId claimId) external; 
-
-    /// @dev create a new payout for the specified policy and claim
-    /// function can only be called by product, policy needs to match with calling product
-    function createPayout(
-        NftId policyNftId, 
-        ClaimId claimId,
-        uint256 payoutAmount,
-        bytes calldata payoutData
-    ) external returns (PayoutId payoutId);
-
-    /// @dev callback function to confirm transfer of payout token to beneficiary
-    /// allows claim service to update claims/payout book keeping
-    /// only pool service can confirm executed payout
-    function payoutExecuted(
-        NftId policyNftId, 
-        PayoutId payoutId
-    ) external;
-
-}

package/contracts/instance/service/IDistributionService.sol

@@ -1,85 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {NftId} from "../../types/NftId.sol";
-import {Fee} from "../../types/Fee.sol";
-import {IPolicy} from "../module/IPolicy.sol";
-import {IService} from "../../shared/IService.sol";
-import {UFixed} from "../../types/UFixed.sol";
-import {DistributorType} from "../../types/DistributorType.sol";
-import {ReferralId} from "../../types/Referral.sol";
-import {Timestamp} from "../../types/Timestamp.sol";
-
-
-interface IDistributionService is IService {
-    error ErrorDistributionServiceCallerNotRegistered(address caller);
-    error ErrorIDistributionServiceParentNftIdNotInstance(NftId nftId, NftId parentNftId);
-    error ErrorIDistributionServiceCallerNotDistributor(address caller);
-    error ErrorIDistributionServiceInvalidReferralId(ReferralId referralId);
-    error ErrorIDistributionServiceMaxReferralsExceeded(uint256 maxReferrals);
-    error ErrorIDistributionServiceDiscountTooLow(uint256 minDiscountPercentage, uint256 discountPercentage);
-    error ErrorIDistributionServiceDiscountTooHigh(uint256 maxDiscountPercentage, uint256 discountPercentage);
-    error ErrorIDistributionServiceExpiryTooLong(uint256 maxReferralLifetime, uint256 expiryAt);
-    error ErrorIDistributionServiceInvalidReferral(string code);
-    error ErrorIDistributionServiceExpirationInvalid(Timestamp expiryAt);
-    error ErrorIDistributionServiceCommissionTooHigh(uint256 commissionPercentage, uint256 maxCommissionPercentage);
-    error ErrorIDistributionServiceMinFeeTooHigh(uint256 minFee, uint256 limit);
-    error ErrorIDistributionServiceMaxDiscountTooHigh(uint256 maxDiscountPercentage, uint256 limit);
-    error ErrorIDistributionServiceReferralInvalid(NftId distributionNftId, ReferralId referralId);
-    error ErrorIDistributionServiceInvalidFeeTransferred(uint256 transferredDistributionFeeAmount, uint256 expectedDistributionFeeAmount);
-
-    function setFees(
-        Fee memory minDistributionOwnerFee,
-        Fee memory distributionFee
-    ) external;
-    
-    function createDistributorType(
-        string memory name,
-        UFixed minDiscountPercentage,
-        UFixed maxDiscountPercentage,
-        UFixed commissionPercentage,
-        uint32 maxReferralCount,
-        uint32 maxReferralLifetime,
-        bool allowSelfReferrals,
-        bool allowRenewals,
-        bytes memory data
-    )
-        external
-        returns (DistributorType distributorType);
-
-    function createDistributor(
-        address distributor,
-        DistributorType distributorType,
-        bytes memory data
-    ) external returns (NftId distributorNftId);
-
-    function updateDistributorType(
-        NftId distributorNftId,
-        DistributorType distributorType,
-        bytes memory data
-    ) external;
-
-    function createReferral(
-        NftId distributorNftId,
-        string memory code,
-        UFixed discountPercentage,
-        uint32 maxReferrals,
-        Timestamp expiryAt,
-        bytes memory data
-    )
-        external
-        returns (ReferralId referralId);
-
-    /// @dev callback from product service when selling a policy for a specific referralId
-    function processSale(
-        NftId distributionNftId,
-        ReferralId referralId,
-        IPolicy.Premium memory premium,
-        uint256 transferredDistributionFeeAmount
-    ) external;
-
-    function referralIsValid(
-        NftId distributorNftId,
-        ReferralId referralId
-    ) external view returns (bool isValid);
-}

package/contracts/instance/service/IPolicyService.sol

@@ -1,72 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {IRisk} from "../module/IRisk.sol";
-import {IService} from "../../shared/IService.sol";
-
-import {NftId} from "../../types/NftId.sol";
-import {ReferralId} from "../../types/Referral.sol";
-import {RiskId} from "../../types/RiskId.sol";
-import {Seconds} from "../../types/Seconds.sol";
-import {StateId} from "../../types/StateId.sol";
-import {Timestamp} from "../../types/Timestamp.sol";
-import {UFixed} from "../../types/UFixed.sol";
-import {Fee} from "../../types/Fee.sol";
-
-interface IPolicyService is IService {
-    
-    error ErrorIPolicyServiceInsufficientAllowance(address customer, address tokenHandlerAddress, uint256 amount);
-    error ErrorIPolicyServicePremiumAlreadyPaid(NftId policyNftId, uint256 premiumPaidAmount);
-    error ErrorIPolicyServicePolicyNotActivated(NftId policyNftId);
-    error ErrorIPolicyServicePolicyAlreadyClosed(NftId policyNftId);
-    error ErrorIPolicyServicePolicyNotActive(NftId policyNftId, StateId state);
-    error ErrorIPolicyServicePremiumNotFullyPaid(NftId policyNftId, uint256 premiumAmount, uint256 premiumPaidAmount);
-    error ErrorIPolicyServiceOpenClaims(NftId policyNftId, uint16 openClaimsCount);
-    error ErrorIPolicyServicePolicyHasNotExpired(NftId policyNftId, Timestamp expiredAt);
-
-    error ErrorIPolicyServicePremiumMismatch(NftId policyNftId, uint256 premiumAmount, uint256 recalculatedPremiumAmount);
-
-    /// @dev declines an application represented by {policyNftId}
-    /// an application can only be declined in applied state
-    /// only the related product may decline an application
-    function decline(NftId policyNftId) external;
-
-    /// @dev underwrites the policy represented by {policyNftId}
-    /// sets the policy state to underwritten
-    /// may set the policy state to activated and set the activation date
-    /// optionally collects premiums and activates the policy.
-    /// - premium payment is only attempted if requirePremiumPayment is set to true
-    /// - activation is only done if activateAt is a non-zero timestamp
-    /// an application can only be underwritten in applied state
-    /// only the related product may underwrite an application
-    function underwrite(
-        NftId policyNftId,
-        bool requirePremiumPayment,
-        Timestamp activateAt
-    ) external;
-
-    /// @dev collects the premium token for the specified policy
-    function collectPremium(NftId policyNftId, Timestamp activateAt) external;
-
-    /// @dev activates the specified policy and sets the activation date in the policy metadata
-    /// to activate a policy it needs to be in underwritten state
-    function activate(NftId policyNftId, Timestamp activateAt) external;
-
-    /// @dev expires the specified policy and sets the expiry date in the policy metadata
-    /// to expire a policy it must be in active state, policies may be expired even when the predefined expiry date is still in the future
-    /// a policy can only be closed when it has been expired. in addition, it must not have any open claims
-    /// this function can only be called by a product. the policy needs to match with the calling product
-    function expire(NftId policyNftId) external;
-
-    /// @dev closes the specified policy and sets the closed data in the policy metadata
-    /// a policy can only be closed when it has been expired. in addition, it must not have any open claims
-    /// this function can only be called by a product. the policy needs to match with the calling product
-    function close(NftId policyNftId) external;
-
-    // TODO move function to pool service
-    function calculateRequiredCollateral(
-        UFixed collateralizationLevel, 
-        uint256 sumInsuredAmount
-    ) external pure returns(uint256 collateralAmount);
-
-}