@etherisc/gif-next 0.0.2-bd7444a → 0.0.2-c336201-668

package/contracts/instance/Instance.sol

@@ -1,64 +1,68 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.19;
 
-import {Registerable} from "../registry/Registry.sol";
+import {NftId} from "../types/NftId.sol";
+import {RoleId} from "../types/RoleId.sol";
+
+import {InstanceBase} from "./base/InstanceBase.sol";
+import {AccessModule} from "./module/access/Access.sol";
+import {CompensationModule} from "./module/compensation/CompensationModule.sol";
+import {ComponentModule} from "./module/component/ComponentModule.sol";
+import {PolicyModule} from "./module/policy/PolicyModule.sol";
+import {PoolModule} from "./module/pool/PoolModule.sol";
+import {RiskModule} from "./module/risk/RiskModule.sol";
+import {BundleModule} from "./module/bundle/BundleModule.sol";
+import {TreasuryModule} from "./module/treasury/TreasuryModule.sol";
+
 import {IRegistry} from "../registry/IRegistry.sol";
+import {Registerable} from "../shared/Registerable.sol";
+import {IAccessModule} from "./module/access/IAccess.sol";
+import {IBundleModule} from "./module/bundle/IBundle.sol";
+import {IComponentModule} from "./module/component/IComponent.sol";
+import {IPoolModule} from "./module/pool/IPoolModule.sol";
+import {IPolicyModule} from "./module/policy/IPolicy.sol";
+import {IInstanceBase} from "./base/IInstanceBase.sol";
 
-import {IAccessModule, AccessModule} from "./access/Access.sol";
-import {ComponentModule} from "./component/ComponentModule.sol";
-import {ProductModule} from "./product/ProductService.sol";
-import {PolicyModule} from "./policy/PolicyModule.sol";
-import {PoolModule} from "./pool/PoolModule.sol";
+import {IComponentOwnerService} from "./service/IComponentOwnerService.sol";
+import {IProductService} from "./service/IProductService.sol";
+import {IPoolService} from "./service/IPoolService.sol";
 
-import {IInstance} from "./IInstance.sol";
-import {NftId, toNftId} from "../types/NftId.sol";
+import {IKeyValueStore} from "./base/IKeyValueStore.sol";
 
 contract Instance is
-    Registerable,
+    InstanceBase,
     AccessModule,
-    ComponentModule, 
-    PolicyModule, 
+    BundleModule,
+    ComponentModule,
+    CompensationModule,
+    PolicyModule,
     PoolModule,
-    ProductModule, 
-    IInstance
+    RiskModule,
+    TreasuryModule
 {
-
     constructor(
         address registry,
-        address componentOwnerService,
-        address productService
+        NftId registryNftId
     )
-        Registerable(registry)
+        InstanceBase(registry, registryNftId)
         AccessModule()
-        ComponentModule(componentOwnerService)
-        PolicyModule(productService)
-        ProductModule(productService)
-        PoolModule(productService)
-    { }
-
-    // from registerable
-    function register() external override returns(NftId nftId) {
-        require(address(_registry) != address(0), "ERROR:PRD-001:REGISTRY_ZERO");
-        return _registry.register(address(this));
+        BundleModule()
+        ComponentModule()
+        PolicyModule()
+        PoolModule()
+        TreasuryModule()
+    {
+        initializeBundleModule(_keyValueStore);
     }
 
-    // from registerable
-    function getParentNftId() public view override returns(NftId) {
-        // TODO  add self registry and exchange 0 for_registry.getNftId();
-        // define parent tree for all registerables
-        // eg 0 <- chain(mainnet) <- global registry <- chain registry <- instance <- component <- policy/bundle 
-        return toNftId(0);
-    }
-
-    // from registerable
-    function getType() external view override returns(uint256 objectType) {
-        return _registry.INSTANCE();
-    }
+    function getRegistry() public view override (Registerable, IBundleModule, IComponentModule, IPolicyModule) returns (IRegistry registry) { return super.getRegistry(); }
+    function getKeyValueStore() public view override (InstanceBase, IBundleModule) returns (IKeyValueStore keyValueStore) { return super.getKeyValueStore(); }
 
-    // from registerable
-    function getData() external view override returns(bytes memory data) {
-        return bytes(abi.encode(0));
-    }
+    function hasRole(RoleId role, address member) public view override (AccessModule, IComponentModule) returns (bool) { return super.hasRole(role, member); }
 
+    function getComponentOwnerService() external view override (IComponentModule, IInstanceBase) returns(IComponentOwnerService service) { return _componentOwnerService; }
+    function getProductService() external view override (IBundleModule, IPolicyModule, IInstanceBase) returns(IProductService service) { return _productService; }
+    function getPoolService() external view override (IBundleModule, IPoolModule, IInstanceBase) returns(IPoolService service) { return _poolService; }
 
+    function getOwner() public view override (IAccessModule, Registerable) returns(address owner) { return super.getOwner(); }
 }

package/contracts/instance/base/ComponentServiceBase.sol

@@ -0,0 +1,42 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IInstance} from "../../instance/IInstance.sol";
+import {ObjectType, INSTANCE, PRODUCT, POOL} from "../../types/ObjectType.sol";
+import {NftId, NftIdLib} from "../../types/NftId.sol";
+
+import {ServiceBase} from "./ServiceBase.sol";
+
+abstract contract ComponentServiceBase is ServiceBase {
+
+    constructor(
+        address registry,
+        NftId registryNftId
+    )
+        ServiceBase(registry, registryNftId)
+    // solhint-disable-next-line no-empty-blocks
+    {
+    }
+
+
+    function _getAndVerifyComponentInfoAndInstance(
+        ObjectType objectType
+    )
+        internal
+        view
+        returns(
+            IRegistry.ObjectInfo memory info, 
+            IInstance instance
+        )
+    {
+        NftId componentNftId = _registry.getNftId(msg.sender);
+        require(componentNftId.gtz(), "ERROR_COMPONENT_UNKNOWN");
+
+        info = _registry.getObjectInfo(componentNftId);
+        require(info.objectType == objectType, "OBJECT_TYPE_INVALID");
+
+        address instanceAddress = _registry.getObjectInfo(info.parentNftId).objectAddress;
+        instance = IInstance(instanceAddress);
+    }
+}

package/contracts/instance/base/IInstanceBase.sol

@@ -0,0 +1,14 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IKeyValueStore} from "./IKeyValueStore.sol";
+import {IComponentOwnerService} from "../service/IComponentOwnerService.sol";
+import {IProductService} from "../service/IProductService.sol";
+import {IPoolService} from "../service/IPoolService.sol";
+
+interface IInstanceBase {
+    function getKeyValueStore() external view returns (IKeyValueStore keyValueStore);
+    function getComponentOwnerService() external view returns(IComponentOwnerService service);
+    function getProductService() external view returns(IProductService service);
+    function getPoolService() external view returns(IPoolService service);
+}

package/contracts/instance/base/IKeyValueStore.sol

@@ -0,0 +1,49 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Blocknumber, blockBlocknumber, zeroBlocknumber} from "../../types/Blocknumber.sol";
+import {Key32, KeyId} from "../../types/Key32.sol";
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId} from "../../types/StateId.sol";
+
+import {ILifecycle} from "./ILifecycle.sol";
+
+interface IKeyValueStore is ILifecycle {
+
+    struct Key {
+        ObjectType objectType;
+        KeyId id;
+    }
+
+    struct Value {
+        Metadata metadata;
+        bytes data;
+    }
+
+    struct Metadata {
+        ObjectType objectType;
+        StateId state;
+        address updatedBy;
+        Blocknumber updatedIn;
+        Blocknumber createdIn;
+    }
+
+    event LogInfoCreated(Key key, StateId state, address createdBy);
+    event LogInfoUpdated(Key key, StateId state, address updatedBy, Blocknumber lastUpdatedIn);
+    event LogStateUpdated(Key key, StateId stateOld, StateId stateNew, address updatedBy, Blocknumber lastUpdatedIn);
+
+    // generic state changing functions
+    function create(Key32 key, ObjectType objectType, bytes memory data) external;
+    function update(Key32 key, StateId state, bytes memory data) external;
+    function updateData(Key32 key, bytes memory data) external;
+    function updateState(Key32 key, StateId state) external;
+
+    function exists(Key32 key) external view returns (bool);
+    function get(Key32 key) external view returns (Value memory value);
+    function getData(Key32 key) external view returns (bytes memory data);
+    function getMetadata(Key32 key) external view returns (Metadata memory metadata);
+    function getState(Key32 key) external view returns (StateId state);
+
+    function toKey32(ObjectType objectType, KeyId id) external pure returns(Key32);
+}

package/contracts/instance/base/ILifecycle.sol

@@ -0,0 +1,30 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId, toStateId, zeroStateId} from "../../types/StateId.sol";
+import {NftId} from "../../types/NftId.sol";
+
+interface ILifecycle {
+
+    error ErrorNoLifecycle(NftId nftId, ObjectType objectType);
+    error ErrorInvalidStateTransition(
+        ObjectType objectType,
+        StateId fromStateId,
+        StateId toStateId
+    );
+
+    function hasLifecycle(
+        ObjectType objectType
+    ) external view returns (bool);
+
+    function getInitialState(
+        ObjectType objectType
+    ) external view returns (StateId);
+
+    function isValidTransition(
+        ObjectType objectType,
+        StateId fromId,
+        StateId toId
+    ) external view returns (bool);
+}

package/contracts/instance/base/IService.sol

@@ -0,0 +1,15 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {VersionPart} from "../../types/Version.sol";
+
+import {IRegisterable} from "../../shared/IRegisterable.sol";
+import {IVersionable} from "../../shared/IVersionable.sol";
+
+interface IService is 
+    IRegisterable,
+    IVersionable
+{
+    function getName() external pure returns(string memory name);
+    function getMajorVersion() external view returns(VersionPart majorVersion);
+}

package/contracts/instance/base/InstanceBase.sol

@@ -0,0 +1,80 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Versionable} from "../../shared/Versionable.sol";
+import {Registerable} from "../../shared/Registerable.sol";
+// import {IRegistry} from "../registry/IRegistry.sol";
+
+// import {IInstance} from "./IInstance.sol";
+import {ObjectType, INSTANCE} from "../../types/ObjectType.sol";
+import {NftId} from "../../types/NftId.sol";
+import {Version, VersionPart, VersionLib} from "../../types/Version.sol";
+
+import {IComponentOwnerService} from "../service/IComponentOwnerService.sol";
+import {IProductService} from "../service/IProductService.sol";
+import {IPoolService} from "../service/IPoolService.sol";
+
+import {IKeyValueStore} from "./IKeyValueStore.sol";
+import {IInstance} from "../IInstance.sol";
+import {IInstanceBase} from "./IInstanceBase.sol";
+
+import {KeyValueStore} from "./KeyValueStore.sol";
+
+abstract contract InstanceBase is
+    Versionable,
+    Registerable,
+    IInstanceBase
+{
+    IKeyValueStore internal _keyValueStore;
+
+    IComponentOwnerService internal _componentOwnerService;
+    IProductService internal _productService;
+    IPoolService internal _poolService;
+
+    constructor(
+        address registry,
+        NftId registryNftId
+    )
+        Registerable(registry, registryNftId)
+        Versionable()
+    {
+        _keyValueStore = new KeyValueStore();
+
+        _registerInterface(type(IInstance).interfaceId);
+        _linkToServicesInRegistry();
+    }
+
+    function getKeyValueStore() public view virtual override returns (IKeyValueStore keyValueStore) { return _keyValueStore; }
+
+    // from versionable
+    function getVersion()
+        public 
+        pure 
+        virtual override
+        returns(Version)
+    {
+        return VersionLib.toVersion(3,0,0);
+    }
+
+    // from registerable
+    function getType() external pure override returns (ObjectType objectType) {
+        return INSTANCE();
+    }
+
+
+    // internal / private functions
+    function _linkToServicesInRegistry() internal {
+        VersionPart majorVersion = getVersion().toMajorPart();
+        _componentOwnerService = IComponentOwnerService(_getAndCheck("ComponentOwnerService", majorVersion));
+        _productService = IProductService(_getAndCheck("ProductService", majorVersion));
+        _poolService = IPoolService(_getAndCheck("PoolService", majorVersion));
+    }
+
+    function _getAndCheck(string memory serviceName, VersionPart majorVersion) internal view returns (address serviceAddress) {
+        serviceAddress = _registry.getServiceAddress(serviceName, majorVersion);
+        require(
+            serviceAddress != address(0),
+            "ERROR:INS-001:NOT_REGISTERED"
+        );
+    }
+}

package/contracts/instance/base/KeyValueStore.sol

@@ -0,0 +1,156 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Blocknumber, blockBlocknumber, zeroBlocknumber} from "../../types/Blocknumber.sol";
+import {Key32, KeyId, Key32Lib} from "../../types/Key32.sol";
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId, ACTIVE} from "../../types/StateId.sol";
+import {Timestamp, blockTimestamp, zeroTimestamp} from "../../types/Timestamp.sol";
+
+import {Lifecycle} from "./Lifecycle.sol";
+import {IKeyValueStore} from "./IKeyValueStore.sol";
+
+contract KeyValueStore is Lifecycle, IKeyValueStore {
+
+    mapping(Key32 key32 => Value value) private _value;
+    address private _owner;
+
+    modifier onlyOwner() {
+        require(
+            msg.sender == _owner,
+            "ERROR:KVS-001:NOT_OWNER");
+        _;
+    }
+
+    constructor() {
+        _owner = msg.sender;
+    }
+
+    function create(
+        Key32 key32, 
+        ObjectType objectType, 
+        bytes memory data
+    )
+        public
+        onlyOwner
+    {
+        require(objectType.gtz(), "ERROR:KVS-010:TYPE_UNDEFINED");
+
+        Metadata storage metadata = _value[key32].metadata;
+        require(metadata.state.eqz(), "ERROR:KVS-012:ALREADY_CREATED");
+
+        address createdBy = msg.sender;
+        Blocknumber blocknumber = blockBlocknumber();
+        StateId initialState = hasLifecycle(objectType) ? getInitialState(objectType) : ACTIVE();
+
+        // set metadata
+        metadata.objectType = objectType;
+        metadata.state = initialState;
+        metadata.updatedBy = createdBy;
+        metadata.updatedIn = blocknumber;
+        metadata.createdIn = blocknumber;
+
+        // set data
+        _value[key32].data = data;
+
+        emit LogInfoCreated(toKey(key32), initialState, createdBy);
+    }
+
+    function update(Key32 key32, StateId state, bytes memory data) 
+        public
+        onlyOwner
+    {
+        require(state.gtz(), "ERROR:KVS-020:STATE_UNDEFINED");
+        Metadata storage metadata = _value[key32].metadata;
+        StateId stateOld = metadata.state;
+        require(stateOld.gtz(), "ERROR:KVS-021:NOT_EXISTING");
+
+        // update data
+        _value[key32].data = data;
+
+        // update metadata (and state)
+        address updatedBy = msg.sender;
+        Blocknumber lastUpdatedIn = metadata.updatedIn;
+        metadata.state = state;
+        metadata.updatedBy = updatedBy;
+        metadata.updatedIn = blockBlocknumber();
+
+        // create log entries
+        Key memory key = toKey(key32);
+        emit LogStateUpdated(key, state, stateOld, updatedBy, lastUpdatedIn);
+        emit LogInfoUpdated(key, state, updatedBy, lastUpdatedIn);
+    }
+
+    function updateData(Key32 key32, bytes memory data) 
+        public
+        onlyOwner
+    {
+        Metadata storage metadata = _value[key32].metadata;
+        StateId state = metadata.state;
+        require(state.gtz(), "ERROR:KVS-030:NOT_EXISTING");
+
+        // update data
+        _value[key32].data = data;
+
+        // update metadata
+        address updatedBy = msg.sender;
+        Blocknumber lastUpdatedIn = metadata.updatedIn;
+        metadata.updatedBy = updatedBy;
+        metadata.updatedIn = blockBlocknumber();
+
+        // create log entry
+        Key memory key = toKey(key32);
+        emit LogInfoUpdated(key, state, updatedBy, lastUpdatedIn);
+    }
+
+    function updateState(Key32 key32, StateId state)
+        public
+        onlyOwner
+    {
+        require(state.gtz(), "ERROR:KVS-040:STATE_UNDEFINED");
+        Metadata storage metadata = _value[key32].metadata;
+        StateId stateOld = metadata.state;
+        require(stateOld.gtz(), "ERROR:KVS-041:NOT_EXISTING");
+
+        // update metadata (and state)
+        address updatedBy = msg.sender;
+        Blocknumber lastUpdatedIn = metadata.updatedIn;
+        metadata.state = state;
+        metadata.updatedBy = updatedBy;
+        metadata.updatedIn = blockBlocknumber();
+
+        // create log entry
+        Key memory key = toKey(key32);
+        emit LogStateUpdated(key, state, stateOld, updatedBy, lastUpdatedIn);
+    }
+
+    function exists(Key32 key32) public view returns (bool) {
+        return _value[key32].metadata.state.gtz();
+    }
+
+    function get(Key32 key32) public view returns (Value memory value) {
+        return _value[key32];
+    }
+
+    function getMetadata(Key32 key32) public view returns (Metadata memory metadata) {
+        return _value[key32].metadata;
+    }
+
+    function getData(Key32 key32) public view returns (bytes memory data) {
+        return _value[key32].data;
+    }
+
+    function getState(Key32 key32) public view returns (StateId state) {
+        return _value[key32].metadata.state;
+    }
+
+    function toKey32(ObjectType objectType, KeyId id) external pure returns(Key32) {
+        return Key32Lib.toKey32(objectType, id);
+    }
+
+    function toKey(Key32 key32) public pure returns (Key memory key) {
+        (ObjectType objectType, KeyId id) = key32.toKey();
+        return Key(objectType, id);
+    }
+}

package/contracts/instance/base/Lifecycle.sol

@@ -0,0 +1,95 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType, PRODUCT, ORACLE, POOL, BUNDLE, POLICY} from "../../types/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED, ARCHIVED, CLOSED, APPLIED, UNDERWRITTEN, REVOKED, DECLINED} from "../../types/StateId.sol";
+import {ILifecycle} from "./ILifecycle.sol";
+
+contract Lifecycle is ILifecycle {
+    mapping(ObjectType objectType => StateId initialState)
+        private _initialState;
+
+    mapping(ObjectType objectType => mapping(StateId stateFrom => mapping(StateId stateTo => bool isValid)))
+        private _isValidTransition;
+
+    constructor() {
+        _setupComponentLifecycle(PRODUCT());
+        _setupComponentLifecycle(ORACLE());
+        _setupComponentLifecycle(POOL());
+
+        _setupBundleLifecycle();
+        _setupPolicyLifecycle();
+    }
+
+    function hasLifecycle(
+        ObjectType objectType
+    )
+        public
+        view
+        override
+        returns (bool)
+    {
+        return _initialState[objectType].gtz();
+    }
+
+    function getInitialState(
+        ObjectType objectType
+    )
+        public
+        view
+        returns (StateId)
+    {
+        return _initialState[objectType];
+    }
+
+    function checkTransition(
+        ObjectType objectType,
+        StateId fromId,
+        StateId toId
+    )
+        public
+        view
+    {
+        // return if no life cycle support
+        if (_initialState[objectType].eqz()) {
+            return;
+        }
+
+        // enforce valid state transition
+        if (!_isValidTransition[objectType][fromId][toId]) {
+            revert ErrorInvalidStateTransition(objectType, fromId, toId);
+        }
+    }
+
+    function isValidTransition(
+        ObjectType objectType,
+        StateId fromId,
+        StateId toId
+    ) public view returns (bool) {
+        return _isValidTransition[objectType][fromId][toId];
+    }
+
+    function _setupComponentLifecycle(ObjectType objectType) internal {
+        _initialState[objectType] = ACTIVE();
+        _isValidTransition[objectType][ACTIVE()][PAUSED()] = true;
+        _isValidTransition[objectType][PAUSED()][ACTIVE()] = true;
+        _isValidTransition[objectType][PAUSED()][ARCHIVED()] = true;
+    }
+
+    function _setupBundleLifecycle() internal {
+        _initialState[BUNDLE()] = ACTIVE();
+        _isValidTransition[BUNDLE()][ACTIVE()][PAUSED()] = true;
+        _isValidTransition[BUNDLE()][PAUSED()][ACTIVE()] = true;
+        _isValidTransition[BUNDLE()][PAUSED()][CLOSED()] = true;
+    }
+
+    function _setupPolicyLifecycle() internal {
+        _initialState[POLICY()] = APPLIED();
+        _isValidTransition[POLICY()][APPLIED()][REVOKED()] = true;
+        _isValidTransition[POLICY()][APPLIED()][DECLINED()] = true;
+        _isValidTransition[POLICY()][APPLIED()][UNDERWRITTEN()] = true;
+        _isValidTransition[POLICY()][UNDERWRITTEN()][ACTIVE()] = true;
+        _isValidTransition[POLICY()][ACTIVE()][CLOSED()] = true;
+    }
+}

package/contracts/instance/base/ModuleBase.sol

@@ -0,0 +1,52 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+
+import {Blocknumber, blockNumber} from "../../types/Blocknumber.sol";
+import {Key32, KeyId} from "../../types/Key32.sol";
+import {LibNftIdSet} from "../../types/NftIdSet.sol";
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType, PRODUCT, ORACLE, POOL, BUNDLE, POLICY} from "../../types/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED, ARCHIVED, CLOSED, APPLIED, REVOKED, DECLINED} from "../../types/StateId.sol";
+import {Timestamp, blockTimestamp, zeroTimestamp} from "../../types/Timestamp.sol";
+
+import {IKeyValueStore} from "./IKeyValueStore.sol";
+
+abstract contract ModuleBase {
+
+    IKeyValueStore private _store;
+    ObjectType private _type;
+
+    function _initialize(IKeyValueStore keyValueStore, ObjectType objectType) internal {
+        _store = keyValueStore;
+        _type = objectType;
+    }
+
+    function _create(NftId nftId, bytes memory data) internal {
+        _store.create(
+            _toKey32(nftId), 
+            _type,
+            data);
+    }
+
+    function _updateData(NftId nftId, bytes memory data) internal {
+        _store.updateData(_toKey32(nftId), data);
+    }
+
+    function _updateState(NftId nftId, StateId state) internal {
+        _store.updateState(_toKey32(nftId), state);
+    }
+
+    function _getData(NftId nftId) internal view returns(bytes memory data) {
+        return _store.getData(_toKey32(nftId));
+    }
+
+    function _getState(NftId nftId) internal view returns(StateId) {
+        return _store.getState(_toKey32(nftId));
+    }
+
+    function _toKey32(NftId nftId) internal view returns (Key32 key32) {
+        return nftId.toKey32(_type);
+    } 
+}