@etherisc/gif-next 0.0.2-bca28f1-161 → 0.0.2-bcecc4c-647

package/contracts/product/IPolicyService.sol

@@ -0,0 +1,78 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IRisk} from "../instance/module/IRisk.sol";
+import {IService} from "../shared/IService.sol";
+
+import {Amount} from "../type/Amount.sol";
+import {ClaimId} from "../type/ClaimId.sol";
+import {NftId} from "../type/NftId.sol";
+import {PayoutId} from "../type/PayoutId.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {RiskId} from "../type/RiskId.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {StateId} from "../type/StateId.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+import {UFixed} from "../type/UFixed.sol";
+import {Fee} from "../type/Fee.sol";
+
+interface IPolicyService is IService {
+
+    error ErrorPolicyServicePolicyProductMismatch(NftId applicationNftId, NftId expectedProductNftId, NftId actualProductNftId);
+    error ErrorPolicyServicePolicyStateNotApplied(NftId applicationNftId);
+    error ErrorPolicyServicePolicyStateNotCollateralizedOrApplied(NftId applicationNftId);
+
+    error ErrorPolicyServicePremiumHigherThanExpected(Amount premiumExpectedAmount, Amount premiumToBePaidAmount);
+    error ErrorPolicyServiceBalanceInsufficient(address policyOwner, uint256 premiumAmount, uint256 balance);
+    error ErrorPolicyServiceAllowanceInsufficient(address policyOwner, address tokenHandler, uint256 premiumAmount, uint256 allowance);
+
+    error ErrorIPolicyServiceInsufficientAllowance(address customer, address tokenHandlerAddress, uint256 amount);
+    error ErrorPolicyServicePremiumAlreadyPaid(NftId policyNftId, Amount premiumPaidAmount);
+    error ErrorIPolicyServicePolicyNotActivated(NftId policyNftId);
+    error ErrorIPolicyServicePolicyAlreadyClosed(NftId policyNftId);
+    error ErrorIPolicyServicePolicyNotActive(NftId policyNftId, StateId state);
+    error ErrorPolicyServicePremiumNotFullyPaid(NftId policyNftId, Amount premiumAmount, Amount premiumPaidAmount);
+    error ErrorIPolicyServiceOpenClaims(NftId policyNftId, uint16 openClaimsCount);
+    error ErrorIPolicyServicePolicyHasNotExpired(NftId policyNftId, Timestamp expiredAt);
+
+    error ErrorPolicyServicePremiumMismatch(NftId policyNftId, Amount expectedPremiumAmount, Amount recalculatedPremiumAmount);
+    error ErrorPolicyServiceTransferredPremiumMismatch(NftId policyNftId, Amount expectedPremiumAmount, Amount transferredPremiumAmount);
+
+    /// @dev collateralizes the policy represented by {policyNftId}
+    /// sets the policy state to collateralized
+    /// may set the policy state to activated and set the activation date
+    /// optionally collects premiums and activates the policy.
+    /// - premium payment is only attempted if requirePremiumPayment is set to true
+    /// - activation is only done if activateAt is a non-zero timestamp
+    /// an application can only be collateralized in applied state
+    /// only the related product may collateralize an application
+    function collateralize(
+        NftId policyNftId,
+        bool requirePremiumPayment,
+        Timestamp activateAt
+    ) external;
+
+    /// @dev declines an application represented by {policyNftId}
+    /// an application can only be declined in applied state
+    /// only the related product may decline an application
+    function decline(NftId policyNftId) external;
+
+    /// @dev collects the premium token for the specified policy
+    function collectPremium(NftId policyNftId, Timestamp activateAt) external;
+
+    /// @dev activates the specified policy and sets the activation date in the policy metadata
+    /// to activate a policy it needs to be in underwritten state
+    function activate(NftId policyNftId, Timestamp activateAt) external;
+
+    /// @dev expires the specified policy and sets the expiry date in the policy metadata
+    /// to expire a policy it must be in active state, policies may be expired even when the predefined expiry date is still in the future
+    /// a policy can only be closed when it has been expired. in addition, it must not have any open claims
+    /// this function can only be called by a product. the policy needs to match with the calling product
+    function expire(NftId policyNftId) external;
+
+    /// @dev closes the specified policy and sets the closed data in the policy metadata
+    /// a policy can only be closed when it has been expired. in addition, it must not have any open claims
+    /// this function can only be called by a product. the policy needs to match with the calling product
+    function close(NftId policyNftId) external;
+
+}

package/contracts/product/IPricingService.sol

@@ -0,0 +1,39 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Seconds} from "../type/Seconds.sol";
+import {NftId} from "../type/NftId.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {RiskId} from "../type/RiskId.sol";
+import {Amount} from "../type/Amount.sol";
+
+import {IService} from "./IApplicationService.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+
+interface IPricingService is IService
+{
+
+    error ErrorPricingServiceTargetWalletAmountsMismatch();
+    error ErrorIPricingServiceBundlePoolMismatch(NftId bundleNftId, NftId bundlePoolNftId, NftId poolNftId);
+    error ErrorIPricingServiceFeeCalculationMismatch(
+                uint256 distributionFeeFixAmount,
+                uint256 distributionFeeVarAmount,
+                uint256 distributionOwnerFeeFixAmount,
+                uint256 distributionOwnerFeeVarAmount,
+                uint256 commissionAmount,
+                uint256 discountAmount
+            );
+
+    function calculatePremium(
+        NftId productNftId,
+        RiskId riskId,
+        Amount sumInsuredAmount,
+        Seconds lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        external
+        view
+        returns (IPolicy.Premium memory premium);
+}

package/contracts/product/IProductComponent.sol

@@ -0,0 +1,40 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount} from "../type/Amount.sol";
+import {Fee} from "../type/Fee.sol";
+import {IInstanceLinkedComponent} from "../shared/IInstanceLinkedComponent.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {NftId} from "../type/NftId.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {RiskId} from "../type/RiskId.sol";
+import {Seconds} from "../type/Seconds.sol";
+
+interface IProductComponent is
+    IInstanceLinkedComponent
+{
+
+    function calculatePremium(
+        Amount sumInsuredAmount,
+        RiskId riskId,
+        Seconds lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    ) external view returns (Amount premiumAmount);
+
+    function calculateNetPremium(
+        Amount sumInsuredAmount,
+        RiskId riskId,
+        Seconds lifetime,
+        bytes memory applicationData
+    ) external view returns (Amount netPremiumAmount);    
+
+    function getPoolNftId() external view returns (NftId poolNftId);
+    function getDistributionNftId() external view returns (NftId distributionNftId);
+
+
+    /// @dev returns initial pool specific infos for this pool
+    function getInitialProductInfo() external view returns (IComponents.ProductInfo memory info);
+    
+}

package/contracts/product/IProductService.sol

@@ -0,0 +1,33 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IRisk} from "../instance/module/IRisk.sol";
+import {IService} from "../shared/IService.sol";
+
+import {NftId} from "../type/NftId.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {RiskId} from "../type/RiskId.sol";
+import {StateId} from "../type/StateId.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+import {UFixed} from "../type/UFixed.sol";
+import {Fee} from "../type/Fee.sol";
+
+interface IProductService is IService {
+
+    function createRisk(
+        RiskId riskId,
+        bytes memory data
+    ) external;
+
+
+    function updateRisk(
+        RiskId riskId,
+        bytes memory data
+    ) external;
+
+
+    function updateRiskState(
+        RiskId riskId,
+        StateId newState
+    ) external;
+}

package/contracts/product/PolicyService.sol

@@ -0,0 +1,476 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {Product} from "./Product.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IDistributionComponent} from "../distribution/IDistributionComponent.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IPoolComponent} from "../pool/IPoolComponent.sol";
+import {IRisk} from "../instance/module/IRisk.sol";
+import {IBundle} from "../instance/module/IBundle.sol";
+
+import {TokenHandler} from "../shared/TokenHandler.sol";
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {ClaimId, ClaimIdLib} from "../type/ClaimId.sol";
+import {Timestamp, TimestampLib, zeroTimestamp} from "../type/Timestamp.sol";
+import {UFixed, UFixedLib} from "../type/UFixed.sol";
+import {ObjectType, APPLICATION, COMPONENT, DISTRIBUTION, PRODUCT, POOL, POLICY, BUNDLE, CLAIM, PRICE} from "../type/ObjectType.sol";
+import {APPLIED, COLLATERALIZED, ACTIVE, KEEP_STATE, CLOSED, DECLINED, CONFIRMED} from "../type/StateId.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {PayoutId, PayoutIdLib} from "../type/PayoutId.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {StateId} from "../type/StateId.sol";
+import {VersionPart} from "../type/Version.sol";
+
+import {ComponentVerifyingService} from "../shared/ComponentVerifyingService.sol";
+import {IApplicationService} from "./IApplicationService.sol";
+import {IBundleService} from "../pool/IBundleService.sol";
+import {IClaimService} from "./IClaimService.sol";
+import {IComponentService} from "../shared/IComponentService.sol";
+import {IDistributionService} from "../distribution/IDistributionService.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {InstanceStore} from "../instance/InstanceStore.sol";
+import {IPolicyService} from "./IPolicyService.sol";
+import {IPoolService} from "../pool/IPoolService.sol";
+import {IPricingService} from "./IPricingService.sol";
+import {IService} from "../shared/IService.sol";
+import {Service} from "../shared/Service.sol";
+
+contract PolicyService is
+    ComponentVerifyingService, 
+    IPolicyService
+{
+    using NftIdLib for NftId;
+    using TimestampLib for Timestamp;
+
+    IApplicationService internal _applicationService;
+    IComponentService internal _componentService;
+    IBundleService internal _bundleService;
+    IClaimService internal _claimService;
+    IDistributionService internal _distributionService;
+    IPoolService internal _poolService;
+    IPricingService internal _pricingService;
+
+    event LogProductServiceSender(address sender);
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer
+    {
+        (
+            address registryAddress,, 
+            //address managerAddress
+            address authority
+        ) = abi.decode(data, (address, address, address));
+
+        initializeService(registryAddress, authority, owner);
+
+        VersionPart majorVersion = getVersion().toMajorPart();
+        _applicationService = IApplicationService(getRegistry().getServiceAddress(APPLICATION(), majorVersion));
+        _bundleService = IBundleService(getRegistry().getServiceAddress(BUNDLE(), majorVersion));
+        _componentService = IComponentService(getRegistry().getServiceAddress(COMPONENT(), majorVersion));
+        _claimService = IClaimService(getRegistry().getServiceAddress(CLAIM(), majorVersion));
+        _poolService = IPoolService(getRegistry().getServiceAddress(POOL(), majorVersion));
+        _distributionService = IDistributionService(getRegistry().getServiceAddress(DISTRIBUTION(), majorVersion));
+        _pricingService = IPricingService(getRegistry().getServiceAddress(PRICE(), majorVersion));
+
+        registerInterface(type(IPolicyService).interfaceId);
+    }
+
+
+    function _getAndVerifyInstanceAndProduct() internal view returns (Product product) {
+        IRegistry.ObjectInfo memory productInfo;
+        (, productInfo,) = _getAndVerifyActiveComponent(PRODUCT());
+        product = Product(productInfo.objectAddress);
+    }
+
+
+    function decline(
+        NftId policyNftId
+    )
+        external
+        override
+    {
+        revert();
+    }
+
+    event LogDebug(uint idx, string message);
+
+    /// @dev underwites application which includes the locking of the required collateral from the pool.
+    function collateralize(
+        NftId applicationNftId, // = policyNftId
+        bool requirePremiumPayment,
+        Timestamp activateAt
+    )
+        external 
+        virtual override
+    {
+        // check caller is registered product
+        (NftId productNftId,, IInstance instance) = _getAndVerifyActiveComponent(PRODUCT());
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        // check policy is in state applied
+        if (instanceReader.getPolicyState(applicationNftId) != APPLIED()) {
+            revert ErrorPolicyServicePolicyStateNotApplied(applicationNftId);
+        }
+
+        // check policy matches with calling product
+        IPolicy.PolicyInfo memory applicationInfo = instanceReader.getPolicyInfo(applicationNftId);
+        if(applicationInfo.productNftId != productNftId) {
+            revert ErrorPolicyServicePolicyProductMismatch(
+                applicationNftId, 
+                applicationInfo.productNftId, 
+                productNftId);
+        }
+        
+        StateId newPolicyState = COLLATERALIZED();
+
+        // actual collateralizaion
+        (
+            Amount localCollateralAmount,
+            Amount totalCollateralAmount
+        ) = _poolService.lockCollateral(
+            instance,
+            address(instanceReader.getComponentInfo(productNftId).token),
+            productNftId,
+            applicationNftId,
+            applicationInfo.bundleNftId,
+            applicationInfo.sumInsuredAmount);
+
+        // optional activation of policy
+        if(activateAt > zeroTimestamp()) {
+            newPolicyState = ACTIVE();
+            applicationInfo.activatedAt = activateAt;
+            applicationInfo.expiredAt = activateAt.addSeconds(applicationInfo.lifetime);
+        }
+
+        // optional collection of premium
+        if(requirePremiumPayment) {
+            Amount premiumPaidAmount = _calculateAndCollectPremium(
+                instance,
+                applicationNftId,
+                applicationInfo);
+
+            applicationInfo.premiumPaidAmount = premiumPaidAmount;
+        }
+
+        // store updated policy info
+        instance.getInstanceStore().updatePolicy(
+            applicationNftId, 
+            applicationInfo, 
+            newPolicyState);
+
+        // TODO add calling pool contract if it needs to validate application
+
+        // TODO: add logging
+    }
+
+
+    function collectPremium(
+        NftId policyNftId, 
+        Timestamp activateAt
+    )
+        external 
+        virtual
+    {
+        // check caller is registered product
+        (,, IInstance instance) = _getAndVerifyActiveComponent(PRODUCT());
+        InstanceReader instanceReader = instance.getInstanceReader();
+        StateId stateId = instanceReader.getPolicyState(policyNftId);
+
+        // check policy is in state collateralized or active
+        if (!(stateId == COLLATERALIZED() || stateId == ACTIVE())) {
+            revert ErrorPolicyServicePolicyStateNotCollateralizedOrApplied(policyNftId);
+        }
+
+        IPolicy.PolicyInfo memory policyInfo = instanceReader.getPolicyInfo(policyNftId);
+
+        // check if premium is already collected
+        if (policyInfo.premiumPaidAmount.gtz()) {
+            revert ErrorPolicyServicePremiumAlreadyPaid(policyNftId, policyInfo.premiumPaidAmount);
+        }
+
+        policyInfo.premiumPaidAmount = _calculateAndCollectPremium(
+                instance,
+                policyNftId,
+                policyInfo);
+
+        instance.getInstanceStore().updatePolicy(policyNftId, policyInfo, KEEP_STATE());
+
+        if(activateAt.gtz() && policyInfo.activatedAt.eqz()) {
+            activate(policyNftId, activateAt);
+        }
+
+        // TODO: add logging
+    }
+
+    function activate(NftId policyNftId, Timestamp activateAt) public override {
+        // check caller is registered product
+        (,, IInstance instance) = _getAndVerifyActiveComponent(PRODUCT());
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        IPolicy.PolicyInfo memory policyInfo = instanceReader.getPolicyInfo(policyNftId);
+
+        require(
+            policyInfo.activatedAt.eqz(),
+            "ERROR:PRS-020:ALREADY_ACTIVATED");
+
+        policyInfo.activatedAt = activateAt;
+        policyInfo.expiredAt = activateAt.addSeconds(policyInfo.lifetime);
+
+        instance.getInstanceStore().updatePolicy(policyNftId, policyInfo, ACTIVE());
+
+        // TODO: add logging
+    }
+
+
+    function expire(
+        NftId policyNftId
+    )
+        external
+        override
+        // solhint-disable-next-line no-empty-blocks
+    {
+        
+    }
+
+    function close(
+        NftId policyNftId
+    )
+        external 
+        override
+    {
+        (,, IInstance instance) = _getAndVerifyActiveComponent(PRODUCT());
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        IPolicy.PolicyInfo memory policyInfo = instanceReader.getPolicyInfo(policyNftId);
+
+        if (policyInfo.activatedAt.eqz()) {
+            revert ErrorIPolicyServicePolicyNotActivated(policyNftId);
+        }
+
+        StateId state = instanceReader.getPolicyState(policyNftId);
+        if (state != ACTIVE()) {
+            revert ErrorIPolicyServicePolicyNotActive(policyNftId, state);
+        }
+
+        if (policyInfo.closedAt.gtz()) {
+            revert ErrorIPolicyServicePolicyAlreadyClosed(policyNftId);
+        }
+
+        // TODO consider to allow for underpaid premiums (with the effects of reducing max payouts accordingly)
+        if (!(policyInfo.premiumAmount == policyInfo.premiumPaidAmount)) {
+            revert ErrorPolicyServicePremiumNotFullyPaid(policyNftId, policyInfo.premiumAmount, policyInfo.premiumPaidAmount);
+        }
+
+        if (policyInfo.openClaimsCount > 0) {
+            revert ErrorIPolicyServiceOpenClaims(policyNftId, policyInfo.openClaimsCount);
+        }
+
+        policyInfo.closedAt = TimestampLib.blockTimestamp();
+
+        _poolService.releaseCollateral(
+            instance, 
+            address(instanceReader.getComponentInfo(policyInfo.productNftId).token),
+            policyNftId, 
+            policyInfo);
+
+        instance.getInstanceStore().updatePolicy(policyNftId, policyInfo, CLOSED());
+    }
+
+
+    function _calculateAndCollectPremium(
+        IInstance instance,
+        NftId applicationNftId,
+        IPolicy.PolicyInfo memory applicationInfo
+    )
+        internal
+        virtual
+        returns (
+            Amount premiumPaidAmount
+        )
+    {
+        NftId productNftId = applicationInfo.productNftId;
+
+        // calculate premium details
+        IPolicy.Premium memory premium = _pricingService.calculatePremium(
+            productNftId,
+            applicationInfo.riskId,
+            applicationInfo.sumInsuredAmount,
+            applicationInfo.lifetime,
+            applicationInfo.applicationData,
+            applicationInfo.bundleNftId,
+            applicationInfo.referralId);
+
+
+        // update financials and transfer premium tokens
+        premiumPaidAmount = _processAndCollect(
+            instance, 
+            productNftId,
+            applicationNftId, 
+            applicationInfo.premiumAmount,
+            applicationInfo.bundleNftId,
+            applicationInfo.referralId,
+            premium);
+    }
+
+
+    function _processAndCollect(
+        IInstance instance,
+        NftId productNftId,
+        NftId policyNftId,
+        Amount premiumExpectedAmount,
+        NftId bundleNftId,
+        ReferralId referralId,
+        IPolicy.Premium memory premium
+    )
+        internal
+        virtual
+        returns (Amount premiumPaidAmount)
+    {
+        InstanceReader instanceReader = instance.getInstanceReader();
+        TokenHandler tokenHandler = instanceReader.getComponentInfo(productNftId).tokenHandler;
+        address policyHolder = getRegistry().ownerOf(policyNftId);
+        premiumPaidAmount = AmountLib.toAmount(premium.premiumAmount);
+
+        _checkPremiumBalanceAndAllowance(
+            tokenHandler, 
+            policyHolder, 
+            premiumExpectedAmount,
+            premiumPaidAmount);
+
+        _processSaleAndTransferFunds(
+            instanceReader, 
+            instance.getInstanceStore(), 
+            tokenHandler, 
+            policyHolder, 
+            productNftId, 
+            bundleNftId, 
+            referralId, 
+            premium);
+    }
+
+
+    function _checkPremiumBalanceAndAllowance(
+        TokenHandler tokenHandler, 
+        address policyHolder, 
+        Amount premiumExpectedAmount,
+        Amount premiumPaidAmount
+    )
+        internal
+        virtual
+        view
+    {
+        // TODO decide how to handle this properly
+        // not clear if this is the best way to handle this
+        if (premiumExpectedAmount < premiumPaidAmount) {
+            revert ErrorPolicyServicePremiumHigherThanExpected(premiumExpectedAmount, premiumPaidAmount);
+        }
+
+        uint256 premiumAmount = premiumPaidAmount.toInt();
+        uint256 balance = tokenHandler.getToken().balanceOf(policyHolder);
+        uint256 allowance = tokenHandler.getToken().allowance(policyHolder, address(tokenHandler));
+    
+        if (balance < premiumAmount) {
+            revert ErrorPolicyServiceBalanceInsufficient(policyHolder, premiumAmount, balance);
+        }
+
+        if (allowance < premiumAmount) {
+            revert ErrorPolicyServiceAllowanceInsufficient(policyHolder, address(tokenHandler), premiumAmount, allowance);
+        }
+    }
+
+
+    function _processSaleAndTransferFunds(
+        InstanceReader instanceReader,
+        InstanceStore instanceStore,
+        TokenHandler tokenHandler,
+        address policyHolder,
+        NftId productNftId,
+        NftId bundleNftId,
+        ReferralId referralId,
+        IPolicy.Premium memory premium
+    )
+        internal
+        virtual
+    {
+        (
+            NftId distributionNftId,
+            address distributionWallet,
+            address poolWallet,
+            address productWallet
+        ) = _getDistributionNftAndWallets(
+            instanceReader, 
+            productNftId);
+
+        // update product fees, distribution and pool fees 
+        _componentService.increaseProductFees(
+            instanceStore, 
+            productNftId, 
+            AmountLib.toAmount(premium.productFeeVarAmount + premium.productFeeFixAmount));
+
+        // update distribution fees and distributor commission and pool fees 
+        _distributionService.processSale(
+            distributionNftId, 
+            referralId, 
+            premium);
+
+        // update pool and bundle fees 
+        _poolService.processSale(
+            bundleNftId, 
+            premium);
+
+        // TODO: centralize token handling (issue #471)
+        // transfer premium amounts to target wallets
+        tokenHandler.transfer(policyHolder, productWallet, premium.productFeeAmount);
+        tokenHandler.transfer(policyHolder, distributionWallet, premium.distributionFeeAndCommissionAmount);
+        tokenHandler.transfer(policyHolder, poolWallet, premium.poolPremiumAndFeeAmount);
+    }
+
+
+    function _getTokenHandlerAndProductWallet(
+        InstanceReader instanceReader,
+        NftId productNftId
+    )
+        internal 
+        virtual
+        view 
+        returns (
+            TokenHandler tokenHandler
+        )
+    {
+        tokenHandler = instanceReader.getComponentInfo(productNftId).tokenHandler;
+    }
+
+    function _getDistributionNftAndWallets(
+        InstanceReader instanceReader,
+        NftId productNftId
+    )
+        internal 
+        virtual
+        view returns (
+            NftId distributionNftId,
+            address distributionWallet,
+            address poolWallet,
+            address productWallet
+        )
+    {
+        IComponents.ProductInfo memory productInfo = instanceReader.getProductInfo(productNftId);
+        distributionNftId = productInfo.distributionNftId;
+        distributionWallet = instanceReader.getComponentInfo(distributionNftId).wallet;
+        poolWallet = instanceReader.getComponentInfo(productInfo.poolNftId).wallet;
+        productWallet = instanceReader.getComponentInfo(productNftId).wallet;
+    }
+
+
+    function _getDomain() internal pure override returns(ObjectType) {
+        return POLICY();
+    }
+}