@etherisc/gif-next 0.0.2-bc4f70f-636 → 0.0.2-bc7a257-709

package/contracts/instance/InstanceStore.sol

@@ -4,16 +4,13 @@ pragma solidity ^0.8.20;
 import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
 
 import {Amount} from "../type/Amount.sol";
-import {Key32, KeyId, Key32Lib} from "../type/Key32.sol";
+import {Key32} from "../type/Key32.sol";
 import {NftId} from "../type/NftId.sol";
 import {ClaimId} from "../type/ClaimId.sol";
-import {ObjectType, BUNDLE, DISTRIBUTION, INSTANCE, POLICY, POOL, ROLE, PRODUCT, TARGET, COMPONENT, DISTRIBUTOR, DISTRIBUTOR_TYPE} from "../type/ObjectType.sol";
+import {ObjectType, BUNDLE, POLICY, POOL, PREMIUM, PRODUCT, COMPONENT, DISTRIBUTOR, FEE} from "../type/ObjectType.sol";
 import {RequestId} from "../type/RequestId.sol";
-import {RiskId, RiskIdLib} from "../type/RiskId.sol";
-import {RoleId, RoleIdLib, INSTANCE_ROLE, INSTANCE_OWNER_ROLE} from "../type/RoleId.sol";
-import {StateId, ACTIVE} from "../type/StateId.sol";
-import {TimestampLib} from "../type/Timestamp.sol";
-import {VersionPart, VersionPartLib} from "../type/Version.sol";
+import {RiskId} from "../type/RiskId.sol";
+import {StateId, KEEP_STATE} from "../type/StateId.sol";
 import {ReferralId} from "../type/Referral.sol";
 import {DistributorType} from "../type/DistributorType.sol";
 import {PayoutId} from "../type/PayoutId.sol";
@@ -21,7 +18,6 @@ import {PayoutId} from "../type/PayoutId.sol";
 import {BalanceStore} from "./base/BalanceStore.sol";
 import {IInstance} from "./IInstance.sol";
 import {KeyValueStore} from "../shared/KeyValueStore.sol";
-import {IKeyValueStore} from "../shared/KeyValueStore.sol";
 import {ObjectCounter} from "./base/ObjectCounter.sol";
 
 import {IBundle} from "./module/IBundle.sol";
@@ -31,21 +27,28 @@ import {IPolicy} from "./module/IPolicy.sol";
 import {IOracle} from "../oracle/IOracle.sol";
 import {IRisk} from "./module/IRisk.sol";
 
+import {ObjectLifecycle} from "./base/ObjectLifecycle.sol";
+
 
 contract InstanceStore is
     AccessManagedUpgradeable, 
     BalanceStore,
     KeyValueStore,
-    ObjectCounter
+    ObjectCounter,
+    ObjectLifecycle
 {
-    function initialize(address instance)
+
+    /// @dev This initializer needs to be called from the instance itself.
+    function initialize()
         public 
         initializer()
     {
+        address instance = msg.sender;
         address authority = IInstance(instance).authority();
-        __AccessManaged_init(authority);
 
-        initializeLifecycle();
+        __AccessManaged_init(authority);
+        // double initialization, safe
+        _initializeLifecycle();
     }
 
     //--- Component ---------------------------------------------------------//
@@ -82,8 +85,15 @@ contract InstanceStore is
         _update(_toNftKey32(productNftId, PRODUCT()), abi.encode(info), newState);
     }
 
-    function updateProductSetupState(NftId productNftId, StateId newState) external restricted() {
-        _updateState(_toNftKey32(productNftId, PRODUCT()), newState);
+
+    //--- Fee -----------------------------------------------------------//
+    function createFee(NftId productNftId, IComponents.FeeInfo memory info) external restricted() {
+        _create(_toNftKey32(productNftId, FEE()), abi.encode(info));
+    }
+
+    // Fee only has one state, so no change change possible
+    function updateFee(NftId productNftId, IComponents.FeeInfo memory info) external restricted() {
+        _update(_toNftKey32(productNftId, FEE()), abi.encode(info), KEEP_STATE());
     }
 
     //--- Pool --------------------------------------------------------------//
@@ -102,10 +112,6 @@ contract InstanceStore is
         _update(_toNftKey32(poolNftId, POOL()), abi.encode(info), newState);
     }
 
-    function updatePoolState(NftId poolNftId, StateId newState) external restricted() {
-        _updateState(_toNftKey32(poolNftId, POOL()), newState);
-    }
-
     //--- DistributorType ---------------------------------------------------//
     function createDistributorType(DistributorType distributorType, IDistribution.DistributorTypeInfo memory info) external restricted() {
         _create(distributorType.toKey32(), abi.encode(info));
@@ -121,6 +127,7 @@ contract InstanceStore is
 
     //--- Distributor -------------------------------------------------------//
     function createDistributor(NftId distributorNftId, IDistribution.DistributorInfo memory info) external restricted() {
+        _registerBalanceTarget(distributorNftId);
         _create(_toNftKey32(distributorNftId, DISTRIBUTOR()), abi.encode(info));
     }
 
@@ -199,6 +206,16 @@ contract InstanceStore is
         _updateState(_toNftKey32(policyNftId, POLICY()), newState);
     }
 
+    
+    //--- Premium (Policy) ----------------------------------------------//
+    function createPremium(NftId policyNftId, IPolicy.PremiumInfo memory premium) external restricted() {
+        _create(_toNftKey32(policyNftId, PREMIUM()), abi.encode(premium));
+    }
+
+    function updatePremiumState(NftId policyNftId, StateId newState) external restricted() {
+        _updateState(_toNftKey32(policyNftId, PREMIUM()), newState);
+    }
+
     //--- Claim -------------------------------------------------------------//
     function createClaim(NftId policyNftId, ClaimId claimId, IPolicy.ClaimInfo memory claim) external restricted() {
         _create(_toClaimKey32(policyNftId, claimId), abi.encode(claim));

package/contracts/instance/RiskSet.sol

@@ -0,0 +1,118 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Key32} from "../type/Key32.sol";
+import {LibNftIdSet} from "../type/NftIdSet.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectSet} from "./base/ObjectSet.sol";
+import {ObjectSetHelperLib} from "./base/ObjectSetHelperLib.sol";
+import {RiskIdLib, RiskId} from "../type/RiskId.sol";
+
+/// @dev RiskSet manages the risks and its active policies per product.
+contract RiskSet is
+    ObjectSet
+{
+
+    event LogRiskSetPolicyLinked(RiskId riskId, NftId policyNftId);
+    event LogRiskSetPolicyUnlinked(RiskId riskId, NftId policyNftId);
+
+    event LogRiskSetRiskAdded(NftId productNftId, RiskId riskId);
+    event LogRiskSetRiskActive(NftId poolNftId,  RiskId riskId);
+    event LogRiskSetRiskPaused(NftId poolNftId,  RiskId riskId);
+    event LogRiskSetRiskArchived(NftId poolNftId,  RiskId riskId);
+
+    error ErrorRiskSetRiskLocked(RiskId riskId, NftId policyNftId); 
+    error ErrorRiskSetRiskUnknown(RiskId riskId);
+    error ErrorRiskSetRiskNotRegistered(RiskId riskId);
+
+    mapping(RiskId riskId => LibNftIdSet.Set policies) internal _activePolicies;
+
+    /// @dev links a policy to its bundle
+    function linkPolicy(NftId productNftId, RiskId riskId, NftId policyNftId) external restricted() {
+
+        // ensure risk is active (in active set) and registered with this instance
+        if (!_isActive(productNftId, riskId.toKey32())) {
+            revert ErrorRiskSetRiskLocked(riskId, policyNftId);
+        }
+
+        LibNftIdSet.add(_activePolicies[riskId], policyNftId);
+        emit LogRiskSetPolicyLinked(riskId, policyNftId);
+    }
+
+    /// @dev Unlinks a policy from its risk.
+    function unlinkPolicy(NftId productNftId, RiskId riskId, NftId policyNftId) external restricted() {
+
+        // ensure risk is registered with this instance
+        if (!_contains(productNftId, riskId.toKey32())) {
+            revert ErrorRiskSetRiskUnknown(riskId);
+        }
+
+        LibNftIdSet.remove(_activePolicies[riskId], policyNftId);
+        emit LogRiskSetPolicyUnlinked(riskId, policyNftId);
+    }
+
+    /// @dev add a new risk to a product registered with this instance
+    // the corresponding product is fetched via instance reader
+    function add(RiskId riskId) external restricted() {
+        NftId productNftId = ObjectSetHelperLib.getProductNftId(_instanceAddress, riskId);
+
+        // ensure product is registered with instance
+        if(productNftId.eqz()) {
+            revert ErrorRiskSetRiskNotRegistered(riskId);
+        }
+
+        _add(productNftId, riskId.toKey32());
+        emit LogRiskSetRiskAdded(productNftId, riskId);
+    }
+
+    /// @dev Applications linked to active risks may be underwritten
+    function activate(RiskId riskId) external restricted() {
+        NftId productNftId = ObjectSetHelperLib.getProductNftId(_instanceAddress, riskId);
+        _activate(productNftId, riskId.toKey32());
+        emit LogRiskSetRiskActive(productNftId, riskId);
+    }
+
+    /// @dev Applications linked to paused/archived risks may not be underwritten
+    function pause(RiskId riskId) external restricted() {
+        NftId productNftId = ObjectSetHelperLib.getProductNftId(_instanceAddress, riskId);
+        _deactivate(productNftId, riskId.toKey32());
+        emit LogRiskSetRiskPaused(productNftId, riskId);
+    }
+
+    function checkRisk(NftId productNftId, RiskId riskId)
+        public
+        view 
+        returns (bool exists, bool active)
+    {
+        Key32 riskKey32 = riskId.toKey32();
+        exists = _contains(productNftId, riskKey32);
+
+        if (exists) {
+            active = _isActive(productNftId, riskKey32);
+        }
+    }
+
+    function risks(NftId productNftId) external view returns(uint256) {
+        return _objects(productNftId);
+    }
+
+    function getRiskId(NftId productNftId, uint256 idx) external view returns(RiskId riskId) {
+        return RiskIdLib.toRiskId(_getObject(productNftId, idx).toKeyId());
+    }
+    
+    function activeRisks(NftId productNftId) external view returns(uint256) {
+        return _activeObjs(productNftId);
+    }
+
+    function getActiveRiskId(NftId productNftId, uint256 idx) external view returns(RiskId riskId) {
+        return RiskIdLib.toRiskId(_getActiveObject(productNftId, idx).toKeyId());
+    }
+
+    function linkedPolicies(RiskId riskId) external view returns(uint256) {
+        return LibNftIdSet.size(_activePolicies[riskId]);
+    }
+
+    function getLinkedPolicyNftId(RiskId riskId, uint256 idx) external view returns(NftId policyNftId) {
+        return LibNftIdSet.getElementAt(_activePolicies[riskId], idx);
+    }
+}

package/contracts/instance/base/BalanceStore.sol

@@ -24,13 +24,12 @@ contract BalanceStore {
     mapping(NftId nftId => Amount balance) private _balanceAmount;
     mapping(NftId nftId => Amount locked) private _lockedAmount;
     mapping(NftId nftId => Amount fees) private _feeAmount;
-    mapping(NftId nftId => bool isRegistered) private _isRegistered;
 
-    // TODO check if this is made redundant by *Info struct updates
+    // used to indicate if the target has been registered as well as when it was last updated (not used externally atm)    
     mapping(NftId nftId => Blocknumber lastUpdatedIn) private _lastUpdatedIn;
 
     modifier onlyRegisteredTarget(NftId targetNftId) {
-        if (!_isRegistered[targetNftId]) {
+        if (!_lastUpdatedIn[targetNftId].gtz()) {
             revert ErrorBalanceStoreTargetNotRegistered(targetNftId);
         }
         _;
@@ -55,12 +54,11 @@ contract BalanceStore {
     }
 
     function _registerBalanceTarget(NftId targetNftId) internal {
-        if (_isRegistered[targetNftId]) {
+        if (_lastUpdatedIn[targetNftId].gtz()) {
             revert ErrorBalanceStoreTargetAlreadyRegistered(targetNftId);
         }
 
-        _isRegistered[targetNftId] = true;
-        _lastUpdatedIn[targetNftId] = BlocknumberLib.currentBlocknumber();
+        _setLastUpdatedIn(targetNftId);
 
         emit LogBalanceStoreTargetRegistered(targetNftId);
     }
@@ -71,7 +69,7 @@ contract BalanceStore {
         _feeAmount[targetNftId] = newBalance;
 
         emit LogBalanceStoreFeesIncreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
-        _lastUpdatedIn[targetNftId] = BlocknumberLib.currentBlocknumber();
+        _setLastUpdatedIn(targetNftId);
     }
 
     function _decreaseFees(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
@@ -79,7 +77,7 @@ contract BalanceStore {
         _feeAmount[targetNftId] = newBalance;
 
         emit LogBalanceStoreFeesDecreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
-        _lastUpdatedIn[targetNftId] = BlocknumberLib.currentBlocknumber();
+        _setLastUpdatedIn(targetNftId);
     }
 
     //--- locked management -------------------------------------------------//
@@ -88,7 +86,7 @@ contract BalanceStore {
         _lockedAmount[targetNftId] = newBalance;
 
         emit LogBalanceStoreLockedIncreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
-        _lastUpdatedIn[targetNftId] = BlocknumberLib.currentBlocknumber();
+        _setLastUpdatedIn(targetNftId);
     }
 
     function _decreaseLocked(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
@@ -96,7 +94,7 @@ contract BalanceStore {
         _lockedAmount[targetNftId] = newBalance;
 
         emit LogBalanceStoreLockedDecreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
-        _lastUpdatedIn[targetNftId] = BlocknumberLib.currentBlocknumber();
+        _setLastUpdatedIn(targetNftId);
     }
 
     //--- balance management ------------------------------------------------//
@@ -105,7 +103,7 @@ contract BalanceStore {
         _balanceAmount[targetNftId] = newBalance;
 
         emit LogBalanceStoreBalanceIncreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
-        _lastUpdatedIn[targetNftId] = BlocknumberLib.currentBlocknumber();
+        _setLastUpdatedIn(targetNftId);
     }
 
     function _decreaseBalance(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
@@ -113,6 +111,11 @@ contract BalanceStore {
         _balanceAmount[targetNftId] = newBalance;
 
         emit LogBalanceStoreBalanceDecreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
+        _setLastUpdatedIn(targetNftId);
+    }
+
+    //--- internal/private functions ----------------------------------------//
+    function _setLastUpdatedIn(NftId targetNftId) internal {
         _lastUpdatedIn[targetNftId] = BlocknumberLib.currentBlocknumber();
     }
 }

package/contracts/instance/base/Cloneable.sol

@@ -2,47 +2,24 @@
 pragma solidity ^0.8.20;
 
 import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
-import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
 
 import {IRegistry} from "../../registry/IRegistry.sol";
 
 abstract contract Cloneable is 
     AccessManagedUpgradeable
 {
-    event CloneableInitialized(address authority, address registry);
-    
-    error CloneableAuthorityZero();
-    error CloneableRegistryInvalid(address registry);
-
     IRegistry internal _registry;
 
-    constructor() {
-        _registry = IRegistry(address(0));
-    }
-
     /// @dev call to initialize MUST be made in the same transaction as cloning of the contract
-    function initialize(
+    function __Cloneable_init(
         address authority,
         address registry
     )
-        public 
+        internal 
         onlyInitializing
     {
-        // check/handle access managed
-        if(authority == address(0)) {
-            revert CloneableAuthorityZero();
-        }
-        
         __AccessManaged_init(authority);
-
-        // check/handle registry
-        if (registry.code.length == 0) {
-            revert CloneableRegistryInvalid(registry);
-        }
-
         _registry = IRegistry(registry);
-
-        emit CloneableInitialized(authority, registry);
     }
 
     function getRegistry() external view returns (IRegistry) {

package/contracts/instance/base/ObjectCounter.sol

@@ -11,9 +11,8 @@ contract ObjectCounter {
     // TODO refactor risk id
     // mapping(NftId productNftId => uint64 risks) private _riskCounter;
 
-    uint256 private _requestCounter;
+    uint256 private _requestCounter = 0;
 
-    // TODO introduce RequestId (uint64)
     function _createNextRequestId() internal returns (RequestId requestId) {
         _requestCounter++;
         requestId = RequestIdLib.toRequestId(_requestCounter);

package/contracts/instance/base/ObjectLifecycle.sol

@@ -0,0 +1,113 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol"; 
+
+import {COMPONENT, BUNDLE, POLICY, REQUEST, RISK, CLAIM, PAYOUT, POOL, PREMIUM, PRODUCT, DISTRIBUTION, DISTRIBUTOR, DISTRIBUTOR_TYPE, REFERRAL, FEE} from "../../type/ObjectType.sol";
+import {ACTIVE, PAUSED, ARCHIVED, CLOSED, APPLIED, COLLATERALIZED, REVOKED, SUBMITTED, CONFIRMED, DECLINED, EXPECTED, PAID, FULFILLED, FAILED, CANCELLED} from "../../type/StateId.sol";
+import {Lifecycle} from "../../shared/Lifecycle.sol";
+
+contract ObjectLifecycle is
+    Lifecycle,
+    Initializable
+{
+    function _initializeLifecycle() internal onlyInitializing
+    {
+        _setupLifecycle();
+    }
+
+    function _setupLifecycle()
+        internal
+        override
+    {
+        _setupBundleLifecycle();
+        _setupComponentLifecycle();
+        _setupPolicyLifecycle();
+        _setupPremiumLifecycle();
+        _setupClaimLifecycle();
+        _setupPayoutLifecycle();
+        _setupRiskLifecycle();
+        _setupRequestLifecycle();
+
+        // setup dummy lifecycles to manage with key value store 
+        _setUpPoolLifecycle();
+        _setUpProductLifecycle();
+        _setUpDistributionLifecycle();
+    }
+
+    function _setupComponentLifecycle() private {
+        setInitialState(COMPONENT(), ACTIVE());
+        setStateTransition(COMPONENT(), ACTIVE(), PAUSED());
+        setStateTransition(COMPONENT(), PAUSED(), ACTIVE());
+        setStateTransition(COMPONENT(), PAUSED(), ARCHIVED());
+    }
+
+    function _setupBundleLifecycle() private {
+        setInitialState(BUNDLE(), ACTIVE());
+        setStateTransition(BUNDLE(), ACTIVE(), PAUSED());
+        setStateTransition(BUNDLE(), ACTIVE(), CLOSED());
+        setStateTransition(BUNDLE(), PAUSED(), ACTIVE());
+        setStateTransition(BUNDLE(), PAUSED(), CLOSED());
+    }
+
+    function _setupPolicyLifecycle() private {
+        setInitialState(POLICY(), APPLIED());
+        setStateTransition(POLICY(), APPLIED(), REVOKED());
+        setStateTransition(POLICY(), APPLIED(), DECLINED());
+        setStateTransition(POLICY(), APPLIED(), COLLATERALIZED());
+        setStateTransition(POLICY(), COLLATERALIZED(), CLOSED());
+    }
+
+    function _setupPremiumLifecycle() private {
+        setInitialState(PREMIUM(), EXPECTED());
+        setStateTransition(PREMIUM(), EXPECTED(), PAID());
+    }
+
+    function _setupClaimLifecycle() private {
+        setInitialState(CLAIM(), SUBMITTED());
+        setStateTransition(CLAIM(), SUBMITTED(), REVOKED());
+        setStateTransition(CLAIM(), SUBMITTED(), CONFIRMED());
+        setStateTransition(CLAIM(), SUBMITTED(), DECLINED());
+        setStateTransition(CLAIM(), CONFIRMED(), CLOSED());
+    }
+
+    function _setupPayoutLifecycle() private {
+        setInitialState(PAYOUT(), EXPECTED());
+        setStateTransition(PAYOUT(), EXPECTED(), PAID());
+        setStateTransition(PAYOUT(), EXPECTED(), CANCELLED());
+    }
+
+    function _setupRiskLifecycle() private {
+        setInitialState(RISK(), ACTIVE());
+        setStateTransition(RISK(), ACTIVE(), PAUSED());
+        setStateTransition(RISK(), PAUSED(), ACTIVE());
+        setStateTransition(RISK(), PAUSED(), ARCHIVED());
+    }
+
+    function _setupRequestLifecycle() private {
+        setInitialState(REQUEST(), ACTIVE());
+        setStateTransition(REQUEST(), ACTIVE(), FULFILLED());
+        setStateTransition(REQUEST(), ACTIVE(), FAILED());
+        setStateTransition(REQUEST(), FAILED(), FULFILLED());
+        setStateTransition(REQUEST(), ACTIVE(), CANCELLED());
+    }
+
+    // dummy lifecycle only
+    function _setUpPoolLifecycle() private {
+        setInitialState(POOL(), ACTIVE());
+    }
+
+    // dummy lifecycle only
+    function _setUpProductLifecycle() private {
+        setInitialState(PRODUCT(), ACTIVE());
+        setInitialState(FEE(), ACTIVE());
+    }
+
+    // dummy lifecycles only
+    function _setUpDistributionLifecycle() private {
+        setInitialState(DISTRIBUTION(), ACTIVE());
+        setInitialState(DISTRIBUTOR(), ACTIVE());
+        setInitialState(DISTRIBUTOR_TYPE(), ACTIVE());
+        setInitialState(REFERRAL(), ACTIVE());
+    }
+}

package/contracts/instance/base/ObjectSet.sol

@@ -0,0 +1,77 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Cloneable} from "./Cloneable.sol";
+
+import {LibKey32Set} from "../../type/Key32Set.sol";
+import {NftId} from "../../type/NftId.sol";
+import {Key32} from "../../type/Key32.sol";
+
+contract ObjectSet is
+    Cloneable
+{
+    using LibKey32Set for LibKey32Set.Set;
+
+    event LogObjectSetInitialized(address instance);
+
+    error ErrorObjectSetNftIdInvalid(NftId instanceNftId);
+
+    mapping(NftId compnentNftId => LibKey32Set.Set objects) internal _activeObjects;
+    mapping(NftId compnentNftId => LibKey32Set.Set objects) internal _allObjects;
+    address internal _instanceAddress;
+
+    /// @dev This initializer needs to be called from the instance itself.
+    function initialize(address authority, address registry) 
+        external
+        initializer()
+    {
+        _instanceAddress = msg.sender;
+        __Cloneable_init(authority, registry);
+        
+        emit LogObjectSetInitialized(address(_instanceAddress));
+    }
+
+    function getInstanceAddress() external view returns (address) {
+        return _instanceAddress;
+    }
+
+    function _add(NftId componentNftId, Key32 key) internal {
+        LibKey32Set.Set storage allSet = _allObjects[componentNftId];
+        LibKey32Set.Set storage activeSet = _activeObjects[componentNftId];
+
+        allSet.add(key);
+        activeSet.add(key);
+    }
+
+    function _activate(NftId componentNftId, Key32 key) internal {
+        _activeObjects[componentNftId].add(key);
+    }
+
+    function _deactivate(NftId componentNftId, Key32 key) internal {
+        _activeObjects[componentNftId].remove(key);
+    }
+
+    function _objects(NftId componentNftId) internal view returns (uint256) {
+        return _allObjects[componentNftId].size();
+    }
+
+    function _contains(NftId componentNftId, Key32 key) internal view returns (bool) {
+        return _allObjects[componentNftId].contains(key);
+    }
+
+    function _getObject(NftId componentNftId, uint256 idx) internal view returns (Key32) {
+        return _allObjects[componentNftId].getElementAt(idx);
+    }
+
+    function _activeObjs(NftId componentNftId) internal view returns (uint256)  {
+        return _activeObjects[componentNftId].size();
+    }
+
+    function _isActive(NftId componentNftId, Key32 key) internal view returns (bool) {
+        return _activeObjects[componentNftId].contains(key);
+    }
+
+    function _getActiveObject(NftId componentNftId, uint256 idx) internal view returns (Key32) {
+        return _activeObjects[componentNftId].getElementAt(idx);
+    }
+}

package/contracts/instance/base/ObjectSetHelperLib.sol

@@ -0,0 +1,30 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IBundle} from "../module/IBundle.sol";
+import {IInstance} from "../IInstance.sol";
+import {IRisk} from "../module/IRisk.sol";
+import {NftId} from "../../type/NftId.sol";
+import {RiskId} from "../../type/RiskId.sol";
+
+
+library ObjectSetHelperLib {
+
+    function getRiskInfo(address instanceAddress, RiskId riskId) public view returns (IRisk.RiskInfo memory) {
+
+        return IInstance(instanceAddress).getInstanceReader().getRiskInfo(riskId);
+    }
+
+    function getProductNftId(address instanceAddress, RiskId riskId) public view returns (NftId) {
+        return getRiskInfo(instanceAddress, riskId).productNftId;
+    }
+
+    function getBundleInfo(address instanceAddress, NftId bundleNftId) public view returns (IBundle.BundleInfo memory) {
+        return IInstance(instanceAddress).getInstanceReader().getBundleInfo(bundleNftId);
+    }
+
+    function getPoolNftId(address instanceAddress, NftId bundleNftId) public view returns (NftId) {
+        return getBundleInfo(instanceAddress, bundleNftId).poolNftId;
+    }
+
+}

package/contracts/instance/module/IBundle.sol

@@ -1,20 +1,21 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.20;
 
-import {Amount} from "../../type/Amount.sol";
 import {NftId} from "../../type/NftId.sol";
 import {Fee} from "../../type/Fee.sol";
-import {Seconds} from "../../type/Seconds.sol";
 import {Timestamp} from "../../type/Timestamp.sol";
 
 interface IBundle {
 
     struct BundleInfo {
+        // slot 0
+        Timestamp activatedAt; 
+        Timestamp expiredAt; // no new policies starting with this timestamp
+        Timestamp closedAt; // no open policies, locked amount = 0
         NftId poolNftId;
+        // slot 1
         Fee fee; // bundle fee on net premium amounts
+        // slot 2
         bytes filter; // required conditions for applications to be considered for collateralization by this bundle
-        Seconds lifetime; // lifetime of bundle after creation
-        Timestamp expiredAt; // no new policies starting with this timestamp
-        Timestamp closedAt; // no open policies, locked amount = 0
     }
 }