@etherisc/gif-next 0.0.2-bc11089-132 → 0.0.2-bc7a257-709

package/contracts/type/UFixed.sol

@@ -0,0 +1,262 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Math} from "@openzeppelin/contracts/utils/math/Math.sol";
+
+/// @dev UFixed is a 160-bit fixed point number with 15 decimals precision.
+type UFixed is uint160; 
+
+using {
+    addUFixed as +,
+    subUFixed as -,
+    mulUFixed as *,
+    divUFixed as /,
+    gtUFixed as >,
+    gteUFixed as >=,
+    ltUFixed as <,
+    lteUFixed as <=,
+    eqUFixed as ==,
+    neUFixed as !=,
+    UFixedLib.gt,
+    UFixedLib.gtz,
+    UFixedLib.toInt,
+    UFixedLib.toInt1000
+} for UFixed global;
+
+// TODO move to UFixedLib and rename to zero()
+function zeroUFixed() pure returns (UFixed zero) {
+    return UFixed.wrap(0);
+}
+
+function addUFixed(UFixed a, UFixed b) pure returns (UFixed) {
+    return UFixed.wrap(UFixed.unwrap(a) + UFixed.unwrap(b));
+}
+
+function subUFixed(UFixed a, UFixed b) pure returns (UFixed) {
+    if (a < b) {
+        revert UFixedLib.UFixedLibNegativeResult();
+    }
+    return UFixed.wrap(UFixed.unwrap(a) - UFixed.unwrap(b));
+}
+
+function mulUFixed(UFixed a, UFixed b) pure returns (UFixed) {
+    return
+        UFixed.wrap(uint160(Math.mulDiv(UFixed.unwrap(a), UFixed.unwrap(b), 10 ** 15)));
+}
+
+function divUFixed(UFixed a, UFixed b) pure returns (UFixed) {
+    if (UFixed.unwrap(b) == 0) {
+        revert UFixedLib.UFixedLibDivisionByZero();
+    }
+    
+    return
+        UFixed.wrap(uint160(Math.mulDiv(UFixed.unwrap(a), 10 ** 15, UFixed.unwrap(b))));
+}
+
+function gtUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
+    return UFixed.unwrap(a) > UFixed.unwrap(b);
+}
+
+function gteUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
+    return UFixed.unwrap(a) >= UFixed.unwrap(b);
+}
+
+function ltUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
+    return UFixed.unwrap(a) < UFixed.unwrap(b);
+}
+
+function lteUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
+    return UFixed.unwrap(a) <= UFixed.unwrap(b);
+}
+
+function eqUFixed(UFixed a, UFixed b) pure returns (bool isEqual) {
+    return UFixed.unwrap(a) == UFixed.unwrap(b);
+}
+
+function neUFixed(UFixed a, UFixed b) pure returns (bool isEqual) {
+    return UFixed.unwrap(a) != UFixed.unwrap(b);
+}
+
+function gtzUFixed(UFixed a) pure returns (bool isZero) {
+    return UFixed.unwrap(a) > 0;
+}
+
+function eqzUFixed(UFixed a) pure returns (bool isZero) {
+    return UFixed.unwrap(a) == 0;
+}
+
+function deltaUFixed(UFixed a, UFixed b) pure returns (UFixed) {
+    if (a > b) {
+        return a - b;
+    }
+
+    return b - a;
+}
+
+library UFixedLib {
+    error UFixedLibNegativeResult();
+    error UFixedLibDivisionByZero();
+
+    error UFixedLibExponentTooSmall(int8 exp);
+    error UFixedLibExponentTooLarge(int8 exp);
+
+    error UFixedLibNumberTooLarge(uint256 number);
+
+    int8 public constant EXP = 15;
+    uint256 public constant MULTIPLIER = 10 ** uint256(int256(EXP));
+    uint256 public constant MULTIPLIER_HALF = MULTIPLIER / 2;
+
+    /// @dev returns the rounding mode DOWN - 0.4 becomes 0, 0.5 becomes 0, 0.6 becomes 0
+    function ROUNDING_DOWN() public pure returns (uint8) {
+        return uint8(0);
+    }
+
+    /// @dev returns the rounding mode UP - 0.4 becomes 1, 0.5 becomes 1, 0.6 becomes 1
+    function ROUNDING_UP() public pure returns (uint8) {
+        return uint8(1);
+    }
+
+    /// @dev returns the rounding mode HALF_UP - 0.4 becomes 0, 0.5 becomes 1, 0.6 becomes 1
+    function ROUNDING_HALF_UP() public pure returns (uint8) {
+        return uint8(2);
+    }
+
+    /// @dev Converts the uint256 to a uint160 based UFixed. 
+    /// This method reverts if the number is too large to fit in a uint160.
+    function toUFixed(uint256 a) public pure returns (UFixed) {
+        uint256 n = a * MULTIPLIER;
+        if (n > type(uint160).max) {
+            revert UFixedLibNumberTooLarge(a);
+        }
+        return UFixed.wrap(uint160(n));
+    }
+
+    /// @dev Converts the uint256 to a UFixed with given exponent.
+    function toUFixed(uint256 a, int8 exp) public pure returns (UFixed) {
+        if (EXP + exp < 0) {
+            revert UFixedLibExponentTooSmall(exp);
+        }
+        if (EXP + exp > 48) {
+            revert UFixedLibExponentTooLarge(exp);
+        }
+        
+        uint256 n = a * 10 ** uint8(EXP + exp);
+
+        if (n > type(uint160).max) {
+            revert UFixedLibNumberTooLarge(n);
+        }
+
+        return UFixed.wrap(uint160(n));
+    }
+
+    /// @dev returns the decimals precision of the UFixed type
+    function decimals() public pure returns (uint256) {
+        return uint8(EXP);
+    }
+
+    /// @dev Converts a UFixed to a uint256.
+    function toInt(UFixed a) public pure returns (uint256) {
+        return toIntWithRounding(a, ROUNDING_HALF_UP());
+    }
+
+    /// @dev Converts a UFixed to a uint256.
+    function toInt1000(UFixed a) public pure returns (uint256) {
+        return toIntWithRounding(toUFixed(1000) * a, ROUNDING_HALF_UP());
+    }
+
+    /// @dev Converts a UFixed to a uint256 with given rounding mode.
+    function toIntWithRounding(UFixed a, uint8 rounding) public pure returns (uint256) {
+        if (rounding == ROUNDING_HALF_UP()) {
+            return
+                Math.mulDiv(
+                    UFixed.unwrap(a) + MULTIPLIER_HALF,
+                    1,
+                    MULTIPLIER,
+                    Math.Rounding.Floor
+                );
+        } else if (rounding == ROUNDING_DOWN()) {
+            return
+                Math.mulDiv(
+                    UFixed.unwrap(a),
+                    1,
+                    MULTIPLIER,
+                    Math.Rounding.Floor
+                );
+        } else {
+            return
+                Math.mulDiv(UFixed.unwrap(a), 1, MULTIPLIER, Math.Rounding.Ceil);
+        }
+    }
+
+    /// @dev adds two UFixed numbers
+    function add(UFixed a, UFixed b) public pure returns (UFixed) {
+        return addUFixed(a, b);
+    }
+
+    /// @dev subtracts two UFixed numbers
+    function sub(UFixed a, UFixed b) public pure returns (UFixed) {
+        return subUFixed(a, b);
+    }
+
+    /// @dev multiplies two UFixed numbers
+    function mul(UFixed a, UFixed b) public pure returns (UFixed) {
+        return mulUFixed(a, b);
+    }
+
+    /// @dev divides two UFixed numbers
+    function div(UFixed a, UFixed b) public pure returns (UFixed) {
+        return divUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is greater than UFixed b
+    function gt(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
+        return gtUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is greater than or equal to UFixed b
+    function gte(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
+        return gteUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is less than UFixed b
+    function lt(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
+        return ltUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is less than or equal to UFixed b
+    function lte(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
+        return lteUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is equal to UFixed b
+    function eq(UFixed a, UFixed b) public pure returns (bool isEqual) {
+        return eqUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is not zero
+    function gtz(UFixed a) public pure returns (bool isZero) {
+        return gtzUFixed(a);
+    }
+
+    /// @dev return true if UFixed a is zero
+    function eqz(UFixed a) public pure returns (bool isZero) {
+        return eqzUFixed(a);
+    }
+
+    function zero() public pure returns (UFixed) {
+        return UFixed.wrap(0);
+    }
+
+    function one() public pure returns (UFixed) {
+        return UFixed.wrap(uint160(MULTIPLIER));
+    }
+
+    function max() public pure returns (UFixed) {
+        return UFixed.wrap(type(uint160).max);
+    }
+
+    /// @dev return the absolute delta between two UFixed numbers
+    function delta(UFixed a, UFixed b) public pure returns (UFixed) {
+        return deltaUFixed(a, b);
+    }
+}

package/contracts/{types → type}/Version.sol

@@ -1,5 +1,5 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
 
 type VersionPart is uint8;
 
@@ -7,7 +7,11 @@ using {
     versionPartGt as >,
     versionPartEq as ==,
     versionPartNe as !=,
-    VersionPartLib.toInt
+    VersionPartLib.eqz,
+    VersionPartLib.gtz,
+    VersionPartLib.toInt,
+    VersionPartLib.toString,
+    VersionPartLib.isValidRelease
 }
     for VersionPart global;
 
@@ -16,8 +20,54 @@ function versionPartEq(VersionPart a, VersionPart b) pure returns(bool isSame) {
 function versionPartNe(VersionPart a, VersionPart b) pure returns(bool isSame) { return VersionPart.unwrap(a) != VersionPart.unwrap(b); }
 
 library VersionPartLib {
-    function toInt(VersionPart a) external pure returns(uint) { return VersionPart.unwrap(a); }
-    function toVersionPart(uint256 a) external pure returns(VersionPart) { return VersionPart.wrap(uint8(a)); }
+
+    error ErrorReleaseTooBig(VersionPart releaseMax, VersionPart release);
+
+    function releaseMin() public pure returns (VersionPart) { return toVersionPart(3); }
+    function releaseMax() public pure returns (VersionPart) { return toVersionPart(99); }
+
+    function isValidRelease(VersionPart release) external pure returns(bool) { 
+        uint256 releaseInt = VersionPart.unwrap(release);
+        return 3 <= releaseInt && releaseInt <= 99; 
+    } 
+
+    function toString(VersionPart a) external pure returns (string memory) {
+        if (a > releaseMax()) {
+            revert ErrorReleaseTooBig(releaseMax(), a);
+        }
+
+        uint256 value = VersionPart.unwrap(a);
+        if (value == 0) {
+            return "0";
+        }
+
+        uint256 temp = value;
+        uint256 digits = 0;
+        while (temp != 0) {
+            digits++;
+            temp /= 10;
+        }
+
+        bytes memory buffer = new bytes(digits);
+        uint index = digits - 1;
+
+        temp = value;
+        while (temp != 0) {
+            buffer[index] = bytes1(uint8(48 + temp % 10));
+            temp /= 10;
+
+            if (index > 0) {
+                index--;
+            }
+        }
+
+        return string(buffer);
+    }
+
+    function eqz(VersionPart a) external pure returns(bool) { return VersionPart.unwrap(a) == 0; }
+    function gtz(VersionPart a) external pure returns(bool) { return VersionPart.unwrap(a) > 0; }
+    function toInt(VersionPart a) external pure returns(uint256) { return VersionPart.unwrap(a); }
+    function toVersionPart(uint256 a) public pure returns(VersionPart) { return VersionPart.wrap(uint8(a)); }
 }
 
 type Version is uint24; // contains major,minor,patch version parts
@@ -36,6 +86,7 @@ function versionGt(Version a, Version b) pure returns(bool isGreaterThan) { retu
 function versionEq(Version a, Version b) pure returns(bool isSame) { return Version.unwrap(a) == Version.unwrap(b); }
 
 library VersionLib {
+
     function toInt(Version version) external pure returns(uint) { return Version.unwrap(version); }
 
     function toUint64(Version version) external pure returns(uint64) { return Version.unwrap(version); }
@@ -73,9 +124,9 @@ library VersionLib {
         );
     }
 
-    function toVersionPart(uint256 versionPart) external pure returns(VersionPart) { 
-        return VersionPart.wrap(uint8(versionPart)); 
-    }
+    // function toVersionPart(uint256 versionPart) public pure returns(VersionPart) { 
+    //     return VersionPart.wrap(uint8(versionPart)); 
+    // }
 
     function toVersion(
         uint256 major,
@@ -101,6 +152,7 @@ library VersionLib {
         return Version.wrap(uint24(versionNumber));
     }
 
+    // TODO rename to zero()
     function zeroVersion() external pure returns(Version) {
         return Version.wrap(0);
     }

package/contracts/{shared → upgradeability}/IVersionable.sol

@@ -1,10 +1,7 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.20;
 
-import {Blocknumber} from "../types/Blocknumber.sol";
-import {Timestamp} from "../types/Timestamp.sol";
-import {Version} from "../types/Version.sol";
-
+import {Version} from "../type/Version.sol";
 
 /// IMPORTANT
 // Upgradeable contract MUST:
@@ -14,7 +11,7 @@ import {Version} from "../types/Version.sol";
 // 4) implement internal _upgrade() function with onlyInitializing modifier (1st version MUST revert)
 // 5) have onlyInitialising modifier for each function callable inside _initialize()/_upgrade() (MUST use different functions for initialization/upgrade and normal operations)
 // 6) use default empty constructor -> _disableInitializer() is called from Versionable contructor
-// 7) use namespace storage
+// 7) use namespace storage (should this be needed)
 // 8) since now inheritance is used for upgradability, contract MUST BE inherited ONLY by the next version 
 // Upgradeable contract SHOULD:
 // 9) define all non private methods as virtual (in order to be able to upgrade them latter)
@@ -22,48 +19,29 @@ import {Version} from "../types/Version.sol";
 //    in some cases this ok but not in the others...
 //
 // IMPORTANT
-// Each version MUST:
+// If introducting/amending storage related to Versionable version MUST:
 // 1) define namespace storage struct if accessing storage
 //      - DO NOT use structs inside, except
 //      - CAN use structs ONLY inside mappings
 // 2) ALWAYS define private getter if accessing storage
 //      - MUST use default implementation, CAN change ONLY return type
-//      - MUST use the same "LOCATION_V1"
 
 interface IVersionable {
 
-    struct VersionInfo {
-        Version version;
-        address implementation;
-        address activatedBy;
-        Timestamp activatedAt;
-        Blocknumber activatedIn;
-    }
-
-    event LogVersionableInitialized(Version version, address implementation, address activatedBy);
-
-    // TODO uncomment when all implementations are ready
     /**
      * @dev IMPORTANT
      * implementation MUST be guarded by initializer modifier
-     * implementation MUST call internal function Versionable._updateVersionHistory 
      * new version MUST inherit from previous version
      */
-    function initialize(address implementation, address activatedBy, bytes memory activationData) external;
+    function initializeVersionable(address activatedBy, bytes memory activationData) external;
 
     /**
      * @dev
      * implementation MUST be guarded by reinitializer(version().toUint64()) modifier
-     * implementation MUST call internal function Versionable._updateVersionHistory
      * new version MUST inherit from previous version
      * the first verion MUST revert 
      */
-    function upgrade(address implementation, address activatedBy, bytes memory upgradeData) external;
-
-    /**
-     * @dev returns true if the specified version has been activated for the current contract
-     */
-    function isInitialized(Version version) external view returns(bool);
+    function upgradeVersionable(bytes memory upgradeData) external;
 
     /**
      * @dev returns version of this contract
@@ -72,25 +50,4 @@ interface IVersionable {
      */
     function getVersion() external pure returns(Version);
 
-    /**
-     * @dev returns the number of all deployed versions of this contract
-     */
-    function getVersionCount() external view returns(uint256 numberOfVersions);
-
-    /**
-     * @dev returns the i-th (index) version of this contract
-     */
-    function getVersion(uint256 index) external view returns(Version version);
-
-    /**
-     * @dev returns the i-th (index) version info of this contract
-     */
-    function getVersionInfo(Version version) external view returns(VersionInfo memory versionInfo);
-
-    // TODO make sure it is needed here
-    /**
-     * @dev returns currently active version
-     */
-    function getInitializedVersion() external view returns(uint64);
-
 }

package/contracts/upgradeability/ProxyManager.sol

@@ -0,0 +1,234 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ProxyAdmin} from "@openzeppelin/contracts/proxy/transparent/ProxyAdmin.sol";
+import {ITransparentUpgradeableProxy} from "@openzeppelin/contracts/proxy/transparent/TransparentUpgradeableProxy.sol";
+
+import {Blocknumber, blockNumber} from "../type/Blocknumber.sol";
+import {IVersionable} from "./IVersionable.sol";
+import {NftId} from "../type/NftId.sol";
+import {NftOwnable} from "../shared/NftOwnable.sol";
+import {Timestamp, TimestampLib} from "../type/Timestamp.sol";
+import {UpgradableProxyWithAdmin} from "./UpgradableProxyWithAdmin.sol";
+import {Version, VersionLib} from "../type/Version.sol";
+
+/// @dev manages proxy deployments for upgradable contracs of type IVersionable
+contract ProxyManager is
+    NftOwnable
+{
+
+    struct VersionInfo {
+        // slot 0
+        address implementation;
+        Timestamp activatedAt;
+        Blocknumber activatedIn;
+        Version version;
+        // slot 1
+        address activatedBy;
+    }
+
+    event LogProxyManagerVersionableDeployed(address indexed proxy, address initialImplementation);
+    event LogProxyManagerVersionableUpgraded(address indexed proxy, address upgradedImplementation);
+
+    error ErrorProxyManagerAlreadyDeployed();
+    error ErrorProxyManagerNotYetDeployed();
+
+    error ErrorProxyManagerZeroVersion();
+    error ErrorProxyManagerNextVersionNotIncreasing(Version nextVersion);
+
+    UpgradableProxyWithAdmin internal _proxy;
+
+    // state to keep version history
+    mapping(Version version => VersionInfo info) _versionHistory;
+    Version [] _versions;
+
+    /// @dev convencience initializer
+    function initialize(
+        address registry,
+        address implementation,
+        bytes memory data,
+        bytes32 salt
+    )
+        public
+        initializer()
+        returns (IVersionable versionable)
+    {
+        versionable = deployDetermenistic(
+            registry,
+            implementation, 
+            data,
+            salt);
+    }
+
+    /// @dev deploy initial contract
+    function deploy(
+        address registry, 
+        address initialImplementation, 
+        bytes memory initializationData
+    )
+        public
+        virtual
+        onlyInitializing()
+        returns (IVersionable versionable)
+    {
+        (
+            address currentProxyOwner, 
+            address initialProxyAdminOwner
+        ) = _preDeployChecksAndSetup(registry);
+
+        _proxy = new UpgradableProxyWithAdmin(
+            initialImplementation,
+            initialProxyAdminOwner,
+            getDeployData(currentProxyOwner, initializationData)
+        );
+
+        versionable = _updateVersionHistory(
+            initialImplementation, 
+            currentProxyOwner);
+
+        emit LogProxyManagerVersionableDeployed(address(versionable), initialImplementation);
+    }
+
+    function deployDetermenistic(
+        address registry, 
+        address initialImplementation, 
+        bytes memory initializationData, 
+        bytes32 salt
+    )
+        public
+        virtual
+        onlyInitializing()
+        returns (IVersionable versionable)
+    {
+        (
+            address currentProxyOwner, 
+            address initialProxyAdminOwner
+        ) = _preDeployChecksAndSetup(registry);
+
+        _proxy = new UpgradableProxyWithAdmin{salt: salt}(
+            initialImplementation,
+            initialProxyAdminOwner,
+            getDeployData(currentProxyOwner, initializationData)
+        );
+
+        versionable = _updateVersionHistory(
+            initialImplementation, 
+            currentProxyOwner);
+
+        emit LogProxyManagerVersionableDeployed(address(versionable), initialImplementation);
+    }
+
+    /// @dev upgrade existing contract
+    function upgrade(address newImplementation, bytes memory upgradeData)
+        public
+        virtual
+        onlyOwner()
+        returns (IVersionable versionable)
+    {
+        if (_versions.length == 0) { 
+            revert ErrorProxyManagerNotYetDeployed();
+        }
+
+        address currentProxyOwner = getOwner();
+        ProxyAdmin proxyAdmin = getProxy().getProxyAdmin();
+        ITransparentUpgradeableProxy proxy = ITransparentUpgradeableProxy(address(_proxy));
+
+        proxyAdmin.upgradeAndCall(
+            proxy,
+            newImplementation, 
+            getUpgradeData(upgradeData));
+
+        versionable = _updateVersionHistory(
+            newImplementation, 
+            currentProxyOwner);
+
+        emit LogProxyManagerVersionableUpgraded(address(versionable), newImplementation);
+
+    }
+
+    function linkToProxy() public returns (NftId) {
+        return _linkToNftOwnable(address(_proxy));
+    }
+
+    function getDeployData(address proxyOwner, bytes memory deployData) public pure returns (bytes memory data) {
+        return abi.encodeWithSelector(
+            IVersionable.initializeVersionable.selector, 
+            proxyOwner, 
+            deployData);
+    }
+
+    function getUpgradeData(bytes memory upgradeData) public pure returns (bytes memory data) {
+        return abi.encodeWithSelector(
+            IVersionable.upgradeVersionable.selector, 
+            upgradeData);
+    }
+
+    function getProxy() public view returns (UpgradableProxyWithAdmin) {
+        return _proxy;
+    }
+
+    function getVersion() external view virtual returns(Version) {
+        return IVersionable(address(_proxy)).getVersion();
+    }
+
+    function getVersionCount() external view returns(uint256) {
+        return _versions.length;
+    }
+
+    function getVersion(uint256 idx) external view returns(Version) {
+        return _versions[idx];
+    }
+
+    function getVersionInfo(Version _version) external view returns(VersionInfo memory) {
+        return _versionHistory[_version];
+    }
+
+    function _preDeployChecksAndSetup(address registry)
+        private
+        returns (
+            address currentProxyOwner,
+            address initialProxyAdminOwner
+        )
+    {
+        if (_versions.length > 0) {
+            revert ErrorProxyManagerAlreadyDeployed();
+        }
+
+        address initialOwner = msg.sender;
+        __NftOwnable_init(registry, initialOwner);
+
+        currentProxyOwner = getOwner(); // used by implementation
+        initialProxyAdminOwner = address(this); // used by proxy
+    }
+
+    function _updateVersionHistory(
+        address implementation,
+        address activatedBy
+    )
+        private
+        returns (IVersionable versionable)
+    {
+        versionable = IVersionable(address(_proxy));
+        Version newVersion = versionable.getVersion();
+
+        if(newVersion == VersionLib.zeroVersion()) {
+            revert ErrorProxyManagerZeroVersion();
+        }
+
+        if(_versions.length > 0) {
+            if(newVersion.toInt() <= _versions[_versions.length-1].toInt()) {
+                revert ErrorProxyManagerNextVersionNotIncreasing(newVersion);
+            }
+        }
+
+        // update version history
+        _versions.push(newVersion);
+        _versionHistory[newVersion] = VersionInfo({
+            version: newVersion,
+            implementation: implementation,
+            activatedBy: activatedBy,
+            activatedAt: TimestampLib.blockTimestamp(),
+            activatedIn: blockNumber()
+        });
+    }
+}