@etherisc/gif-next 0.0.2-bb7b80e-316 → 0.0.2-bc0a9a8-101

package/contracts/instance/InstanceAdmin.sol

@@ -0,0 +1,331 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+import {EnumerableSet} from "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
+
+import {RoleId, RoleIdLib, ADMIN_ROLE, PUBLIC_ROLE, INSTANCE_SERVICE_ROLE, INSTANCE_OWNER_ROLE, INSTANCE_ROLE} from "../type/RoleId.sol";
+import {TimestampLib} from "../type/Timestamp.sol";
+import {NftId} from "../type/NftId.sol";
+
+import {AccessManagerExtendedInitializeable} from "../shared/AccessManagerExtendedInitializeable.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+
+import {IInstance} from "./IInstance.sol";
+import {IAccess} from "./module/IAccess.sol";
+
+contract InstanceAdmin is
+    AccessManagedUpgradeable
+{
+    using RoleIdLib for RoleId;
+
+    string public constant INSTANCE_ROLE_NAME = "InstanceRole";
+    string public constant INSTANCE_OWNER_ROLE_NAME = "InstanceOwnerRole";
+
+    string public constant INSTANCE_ADMIN_TARGET_NAME = "InstanceAdmin";
+
+    uint64 public constant CUSTOM_ROLE_ID_MIN = 10000; // MUST be even
+    uint32 public constant EXECUTION_DELAY = 0;
+
+    mapping(address target => IAccess.Type) _targetType;
+    mapping(RoleId roleId => IAccess.Type) _roleType;
+    uint64 _idNext;
+
+    AccessManagerExtendedInitializeable internal _accessManager;
+    address _instance;
+    IRegistry internal _registry;
+
+    // instance owner role is granted upon instance nft minting in callback function
+    // assume this contract is already a member of ADMIN_ROLE, the only member
+    function initialize(address instanceAddress) external initializer 
+    {
+        IInstance instance = IInstance(instanceAddress);
+        IRegistry registry = instance.getRegistry();
+        address authority = instance.authority();
+
+        __AccessManaged_init(authority);
+
+        _accessManager = AccessManagerExtendedInitializeable(authority);
+        _instance = instanceAddress;
+        _registry = registry;
+        _idNext = CUSTOM_ROLE_ID_MIN;
+
+        // minimum configuration required for nft interception
+        _createRole(INSTANCE_ROLE(), INSTANCE_ROLE_NAME, IAccess.Type.Core);
+        _createRole(INSTANCE_OWNER_ROLE(), INSTANCE_OWNER_ROLE_NAME, IAccess.Type.Core);
+        _grantRole(INSTANCE_ROLE(), address(instance));
+
+        _createTarget(address(this), INSTANCE_ADMIN_TARGET_NAME, IAccess.Type.Core);
+        bytes4[] memory instanceAdminInstanceSelectors = new bytes4[](1);
+        instanceAdminInstanceSelectors[0] = this.transferInstanceOwnerRole.selector;
+        _setTargetFunctionRole(address(this), instanceAdminInstanceSelectors, INSTANCE_ROLE());                
+    }
+
+    //--- Role ------------------------------------------------------//
+    // ADMIN_ROLE
+    // assume all core roles are known at deployment time
+    // assume core roles are set and granted only during instance cloning
+    // assume core roles are never revoked -> core roles admin is never active after intialization
+    function createCoreRole(RoleId roleId, string memory name) external restricted() {
+        _createRole(roleId, name, IAccess.Type.Core);
+    }
+
+    // ADMIN_ROLE
+    // assume gif roles can be revoked
+    // assume admin is INSTANCE_OWNER_ROLE or INSTANCE_ROLE
+    function createGifRole(RoleId roleId, string memory name, RoleId admin) external restricted() {
+        _createRole(roleId, name, IAccess.Type.Gif);
+        _setRoleAdmin(roleId, admin);
+    }
+
+    // INSTANCE_ROLE
+    // TODO specify how many owners role can have -> many roles MUST have exactly 1 member?
+    function createRole(string memory roleName, string memory adminName)
+        external
+        restricted()
+        returns(RoleId roleId, RoleId admin)
+    {
+        (roleId, admin) = _getNextCustomRoleId();
+
+        _createRole(roleId, roleName, IAccess.Type.Custom);
+        _createRole(admin, adminName, IAccess.Type.Custom);
+
+        _setRoleAdmin(roleId, admin);
+        _setRoleAdmin(admin, INSTANCE_OWNER_ROLE());
+    }
+
+    // ADMIN_ROLE
+    // assume used by instance service only during instance cloning
+    // assume used only by this.createRole(), this.createGifRole() afterwards
+    function setRoleAdmin(RoleId roleId, RoleId admin) public restricted() {
+        _setRoleAdmin(roleId, admin);
+    }
+
+    // INSTANCE_ROLE
+    function transferInstanceOwnerRole(address from, address to) external restricted() {
+        // temp pre transfer checks
+        assert(_getRoleMembers(INSTANCE_ROLE()) == 1);
+        assert(_hasRole(INSTANCE_ROLE(), _instance));
+        assert(_getRoleAdmin(INSTANCE_OWNER_ROLE()).toInt() == ADMIN_ROLE().toInt());
+        if(from != address(0)) { // nft transfer
+            assert(_getRoleMembers(INSTANCE_OWNER_ROLE()) == 1);
+        } else { // nft minting 
+            assert(_getRoleMembers(INSTANCE_OWNER_ROLE()) == 0);            
+        }
+
+        // transfer
+        assert(from != to);
+        _grantRole(INSTANCE_OWNER_ROLE(), to);
+        if(from != address(0)) { // nft transfer
+            _revokeRole(INSTANCE_OWNER_ROLE(), from);
+        }
+
+        // temp post transfer checks
+        assert(_getRoleMembers(INSTANCE_OWNER_ROLE()) == 1);// temp
+        assert(_hasRole(INSTANCE_OWNER_ROLE(), to));
+    }
+
+    //--- Target ------------------------------------------------------//
+    // ADMIN_ROLE
+    // assume some core targets are registred (instance) while others are not (instance accesss manager, instance reader, bundle manager)
+    function createCoreTarget(address target, string memory name) external restricted() {
+        _createTarget(target, name, IAccess.Type.Core);
+    }
+
+    // INSTANCE_SERVICE_ROLE
+    function createGifTarget(address target, string memory name) external restricted() 
+    {
+        if(!_registry.isRegistered(target)) {
+            revert IAccess.ErrorIAccessTargetNotRegistered(target);
+        }
+
+        NftId targetParentNftId = _registry.getObjectInfo(target).parentNftId;
+        NftId instanceNftId = _registry.getObjectInfo(_instance).nftId;
+        if(targetParentNftId != instanceNftId) {
+            revert IAccess.ErrorIAccessTargetInstanceMismatch(target, targetParentNftId, instanceNftId);
+        }
+
+        _createTarget(target, name, IAccess.Type.Gif);
+    }
+
+    // INSTANCE_ROLE
+    // assume custom target.authority() is constant -> target MUST not be used with different instance access manager
+    // assume custom target can not be registered as component -> each service which is doing component registration MUST register a gif target
+    // assume custom target can not be registered as instance or service -> why?
+    // TODO check target associated with instance owner or instance or instance components or components helpers
+    function createTarget(address target, string memory name) external restricted() {
+        _createTarget(target, name, IAccess.Type.Custom);
+    }
+
+    // TODO instance owner locks component instead of revoking it access to the instance...
+    // INSTANCE_SERVICE_ROLE
+    function setTargetLockedByService(address target, bool locked) external restricted {
+        _setTargetLocked(target, locked);
+    }
+
+    // INSTANCE_ROLE
+    function setTargetLockedByInstance(address target, bool locked) external restricted {
+        _setTargetLocked(target, locked);
+    }
+
+
+    // allowed combinations of roles and targets:
+    //1) set core role for core target 
+    //2) set gif role for gif target  
+    //3) set custom role for gif target
+    //4) set custom role for custom target
+
+    // ADMIN_ROLE if used only during initialization, works with:
+    //      any roles for any targets
+    // INSTANCE_SERVICE_ROLE if used not only during initilization, works with:
+    //      core roles for core targets
+    //      gif roles for gif targets
+    function setTargetFunctionRoleByService(
+        string memory targetName,
+        bytes4[] calldata selectors,
+        RoleId roleId
+    ) 
+        public 
+        virtual 
+        restricted
+    {
+        address target = _accessManager.getTargetAddress(targetName);
+        // not custom target
+        if(_targetType[target] == IAccess.Type.Custom) {
+            revert IAccess.ErrorIAccessTargetTypeInvalid(target, IAccess.Type.Custom);
+        }
+
+        // not custom role
+        if(_roleType[roleId] == IAccess.Type.Custom) {
+            revert IAccess.ErrorIAccessRoleTypeInvalid(roleId, IAccess.Type.Custom);
+        }
+
+        _setTargetFunctionRole(target, selectors, roleId);
+    }
+
+    // INSTANCE_ROLE
+    // gif role for gif target
+    // gif role for custom target
+    // custom role for gif target -> need to prohibit
+    // custom role for custom target
+    // TODO instance owner can mess with gif target (component) -> e.g. set custom role for function intendent to work with gif role
+    function setTargetFunctionRoleByInstance(
+        string memory targetName,
+        bytes4[] calldata selectors,
+        RoleId roleId// string memory roleName
+    ) 
+        public 
+        virtual 
+        restricted() 
+    {
+        address target = _accessManager.getTargetAddress(targetName);
+
+        // not core target
+        if(_targetType[target] == IAccess.Type.Core) {
+            revert IAccess.ErrorIAccessTargetTypeInvalid(target, IAccess.Type.Core);
+        }
+
+        // not core role
+        if(_roleType[roleId] == IAccess.Type.Core) {
+            revert IAccess.ErrorIAccessRoleTypeInvalid(roleId, IAccess.Type.Core);
+        }
+
+        _setTargetFunctionRole(target, selectors, roleId);
+    }
+
+    //--- Role internal view/pure functions --------------------------------------//
+    function _createRole(RoleId roleId, string memory name, IAccess.Type rtype) internal {
+        _validateRole(roleId, rtype);
+
+        _roleType[roleId] = rtype;
+        _accessManager.createRole(roleId.toInt(), name);
+    }
+
+    function _validateRole(RoleId roleId, IAccess.Type rtype) internal pure
+    {
+        uint roleIdInt = roleId.toInt();
+        if(rtype == IAccess.Type.Custom && roleIdInt < CUSTOM_ROLE_ID_MIN) {
+            revert IAccess.ErrorIAccessRoleIdTooSmall(roleId);
+        }
+
+        if(
+            rtype != IAccess.Type.Custom && 
+            roleIdInt >= CUSTOM_ROLE_ID_MIN && 
+            roleIdInt != PUBLIC_ROLE().toInt()) 
+        {
+            revert IAccess.ErrorIAccessRoleIdTooBig(roleId);
+        }
+    }
+
+    function _grantRole(RoleId roleId, address account) internal {
+        _accessManager.grantRole(roleId.toInt(), account, EXECUTION_DELAY);
+    }
+
+    function _revokeRole(RoleId roleId, address member) internal {
+        _accessManager.revokeRole(roleId.toInt(), member);
+    }
+
+    function _setRoleAdmin(RoleId roleId, RoleId admin) internal {
+        if(_roleType[roleId] == IAccess.Type.Core) {
+            revert IAccess.ErrorIAccessRoleTypeInvalid(roleId, IAccess.Type.Core);
+        }
+
+        _accessManager.setRoleAdmin(roleId.toInt(), admin.toInt());
+    }
+
+    function _getRoleAdmin(RoleId roleId) internal view returns (RoleId admin) {
+        return RoleIdLib.toRoleId(_accessManager.getRoleAdmin(roleId.toInt()));
+    }
+
+    function _hasRole(RoleId roleId, address account) internal view returns (bool accountHasRole) {
+        uint32 executionDelay;
+        (accountHasRole, executionDelay) = _accessManager.hasRole(roleId.toInt(), account);
+        assert(executionDelay == 0);
+    }
+
+    function _getRoleMembers(RoleId roleId) internal view returns (uint) {
+        return _accessManager.getRoleMembers(roleId.toInt());
+    }
+
+    function _getNextCustomRoleId() internal returns(RoleId roleId, RoleId admin) {
+        uint64 roleIdInt = _idNext;
+        uint64 adminInt = roleIdInt + 1;
+
+        _idNext = roleIdInt + 2;
+
+        roleId = RoleIdLib.toRoleId(roleIdInt);
+        admin = RoleIdLib.toRoleId(adminInt);
+    }
+
+    //--- Target internal view/pure functions --------------------------------------//
+    function _createTarget(address target, string memory name, IAccess.Type ttype) 
+        internal 
+    {
+        _validateTarget(target, ttype);
+        _targetType[target] = ttype;
+        _accessManager.createTarget(target, name);
+    }
+
+    function _validateTarget(address target, IAccess.Type ttype) 
+        internal 
+        view 
+    {}
+
+    // IMPORTANT: instance admin MUST be of Core type -> otherwise can be locked forever
+    // TODO: consider locking gif targets in a separate function?
+    function _setTargetLocked(address target, bool locked) internal
+    {
+        IAccess.Type targetType = _targetType[target];
+
+        if(targetType == IAccess.Type.Core) {
+            revert IAccess.ErrorIAccessTargetTypeInvalid(target, targetType);
+        }
+
+        _accessManager.setTargetClosed(target, locked);
+    }
+
+    function _setTargetFunctionRole(address target, bytes4[] memory selectors, RoleId roleId) internal {
+        _accessManager.setTargetFunctionRole(target, selectors, roleId.toInt());
+    }
+}

package/contracts/instance/InstanceAuthorizationsLib.sol

@@ -0,0 +1,349 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ADMIN_ROLE, INSTANCE_OWNER_ROLE, DISTRIBUTION_OWNER_ROLE, POOL_OWNER_ROLE, PRODUCT_OWNER_ROLE, INSTANCE_SERVICE_ROLE, COMPONENT_SERVICE_ROLE, DISTRIBUTION_SERVICE_ROLE, POOL_SERVICE_ROLE, PRODUCT_SERVICE_ROLE, APPLICATION_SERVICE_ROLE, POLICY_SERVICE_ROLE, CLAIM_SERVICE_ROLE, BUNDLE_SERVICE_ROLE, INSTANCE_ROLE} from "../type/RoleId.sol";
+import {APPLICATION, BUNDLE, CLAIM, COMPONENT, DISTRIBUTION, INSTANCE, POLICY, POOL, PRODUCT, REGISTRY} from "../type/ObjectType.sol";
+import {VersionPart} from "../type/Version.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+
+import {Instance} from "./Instance.sol";
+import {InstanceAdmin} from "./InstanceAdmin.sol";
+import {InstanceReader} from "./InstanceReader.sol";
+import {BundleManager} from "./BundleManager.sol";
+import {AccessManagerExtendedInitializeable} from "../shared/AccessManagerExtendedInitializeable.sol";
+import {InstanceStore} from "./InstanceStore.sol";
+
+
+library InstanceAuthorizationsLib
+{
+    function grantInitialAuthorizations(
+        AccessManagerExtendedInitializeable accessManager,
+        InstanceAdmin instanceAdmin,
+        Instance instance,
+        BundleManager bundleManager,
+        InstanceStore instanceStore,
+        address instanceOwner,
+        IRegistry registry,
+        VersionPart majorVersion)
+            external
+    {
+        _createRoles(instanceAdmin);
+        _createTargets(instanceAdmin, instance, bundleManager, instanceStore);
+        _grantComponentServiceAuthorizations(accessManager, instanceAdmin, instanceStore, registry, majorVersion);
+        _grantDistributionServiceAuthorizations(accessManager, instanceAdmin, instanceStore, registry, majorVersion);
+        _grantPoolServiceAuthorizations(accessManager, instanceAdmin, instanceStore, registry, majorVersion);
+        _grantProductServiceAuthorizations(accessManager, instanceAdmin, instanceStore, registry, majorVersion);
+        _grantApplicationServiceAuthorizations(accessManager, instanceAdmin, instanceStore, registry, majorVersion);
+        _grantPolicyServiceAuthorizations(accessManager, instanceAdmin, instanceStore, registry, majorVersion);
+        _grantClaimServiceAuthorizations(accessManager, instanceAdmin, instanceStore, registry, majorVersion);
+        _grantBundleServiceAuthorizations(accessManager, instanceAdmin, instanceStore, bundleManager, registry, majorVersion);
+        _grantInstanceServiceAuthorizations(accessManager, instanceAdmin, instance, registry, majorVersion);
+        _grantInstanceAuthorizations(accessManager, instanceAdmin, instance, registry, majorVersion);
+        _grantInstanceOwnerAuthorizations(instanceAdmin, instance, registry, majorVersion);
+    }
+
+    function _createRoles(InstanceAdmin instanceAdmin) private {
+        // default roles controlled by ADMIN_ROLE -> core roles
+        // all set/granted only once during cloning (the only exception is INSTANCE_OWNER_ROLE, hooked to instance nft)
+        instanceAdmin.createCoreRole(INSTANCE_SERVICE_ROLE(), "InstanceServiceRole");
+        instanceAdmin.createCoreRole(COMPONENT_SERVICE_ROLE(), "ComponentServiceRole");
+        instanceAdmin.createCoreRole(DISTRIBUTION_SERVICE_ROLE(), "DistributionServiceRole");
+        instanceAdmin.createCoreRole(POOL_SERVICE_ROLE(), "PoolServiceRole");
+        instanceAdmin.createCoreRole(APPLICATION_SERVICE_ROLE(), "ApplicationServiceRole");
+        instanceAdmin.createCoreRole(PRODUCT_SERVICE_ROLE(), "ProductServiceRole");
+        instanceAdmin.createCoreRole(CLAIM_SERVICE_ROLE(), "ClaimServiceRole");
+        instanceAdmin.createCoreRole(POLICY_SERVICE_ROLE(), "PolicyServiceRole");
+        instanceAdmin.createCoreRole(BUNDLE_SERVICE_ROLE(), "BundleServiceRole");
+
+        // default roles controlled by INSTANCE_OWNER_ROLE -> gif roles
+        instanceAdmin.createGifRole(DISTRIBUTION_OWNER_ROLE(), "DistributionOwnerRole", INSTANCE_OWNER_ROLE());
+        instanceAdmin.createGifRole(POOL_OWNER_ROLE(), "PoolOwnerRole", INSTANCE_OWNER_ROLE());
+        instanceAdmin.createGifRole(PRODUCT_OWNER_ROLE(), "ProductOwnerRole", INSTANCE_OWNER_ROLE());
+    }
+
+    function _createTargets(
+        InstanceAdmin instanceAdmin,
+        Instance instance,
+        BundleManager bundleManager,
+        InstanceStore instanceStore)
+        private
+    {
+        instanceAdmin.createCoreTarget(address(instance), "Instance");
+        //instanceAdmin.createCoreTarget(address(instanceAdmin), "InstanceAdmin");
+        instanceAdmin.createCoreTarget(address(bundleManager), "BundleManager");
+        instanceAdmin.createCoreTarget(address(instanceStore), "InstanceStore");
+    }
+
+    function _grantComponentServiceAuthorizations(
+        AccessManagerExtendedInitializeable accessManager,
+        InstanceAdmin instanceAdmin,
+        InstanceStore instanceStore,
+        IRegistry registry,
+        VersionPart majorVersion)
+        private
+    {
+        // configure authorization for component service on instance store
+        address componentServiceAddress = registry.getServiceAddress(COMPONENT(), majorVersion);
+        accessManager.grantRole(COMPONENT_SERVICE_ROLE().toInt(), componentServiceAddress, 0);
+
+        bytes4[] memory serviceSelectors = new bytes4[](8);
+        serviceSelectors[0] = instanceStore.createComponent.selector;
+        serviceSelectors[1] = instanceStore.updateComponent.selector;
+        serviceSelectors[2] = instanceStore.createPool.selector;
+        serviceSelectors[3] = instanceStore.createProduct.selector;
+        serviceSelectors[5] = instanceStore.updateProduct.selector;
+        serviceSelectors[6] = instanceStore.increaseBalance.selector;
+        serviceSelectors[7] = instanceStore.increaseFees.selector;
+
+        instanceAdmin.setTargetFunctionRoleByService(
+            "InstanceStore",
+            serviceSelectors,
+            COMPONENT_SERVICE_ROLE());
+    }
+
+    function _grantDistributionServiceAuthorizations(
+        AccessManagerExtendedInitializeable accessManager,
+        InstanceAdmin instanceAdmin,
+        InstanceStore instanceStore,
+        IRegistry registry,
+        VersionPart majorVersion)
+        private
+    {
+        // configure authorization for distribution service on instance
+        address distributionServiceAddress = registry.getServiceAddress(DISTRIBUTION(), majorVersion);
+        accessManager.grantRole(DISTRIBUTION_SERVICE_ROLE().toInt(), distributionServiceAddress, 0);
+        bytes4[] memory instanceDistributionServiceSelectors = new bytes4[](9);
+        //instanceDistributionServiceSelectors[0] = instanceStore.createDistributionSetup.selector;
+        //instanceDistributionServiceSelectors[1] = instanceStore.updateDistributionSetup.selector;
+        instanceDistributionServiceSelectors[0] = instanceStore.createDistributorType.selector;
+        instanceDistributionServiceSelectors[1] = instanceStore.updateDistributorType.selector;
+        instanceDistributionServiceSelectors[2] = instanceStore.updateDistributorTypeState.selector;
+        instanceDistributionServiceSelectors[3] = instanceStore.createDistributor.selector;
+        instanceDistributionServiceSelectors[4] = instanceStore.updateDistributor.selector;
+        instanceDistributionServiceSelectors[5] = instanceStore.updateDistributorState.selector;
+        instanceDistributionServiceSelectors[6] = instanceStore.createReferral.selector;
+        instanceDistributionServiceSelectors[7] = instanceStore.updateReferral.selector;
+        instanceDistributionServiceSelectors[8] = instanceStore.updateReferralState.selector;
+        instanceAdmin.setTargetFunctionRoleByService(
+            "InstanceStore",
+            instanceDistributionServiceSelectors,
+            DISTRIBUTION_SERVICE_ROLE());
+    }
+
+    function _grantPoolServiceAuthorizations(
+        AccessManagerExtendedInitializeable accessManager,
+        InstanceAdmin instanceAdmin,
+        InstanceStore instanceStore,
+        IRegistry registry,
+        VersionPart majorVersion)
+        private
+    {
+        // configure authorization for pool service on instance
+        address poolServiceAddress = registry.getServiceAddress(POOL(), majorVersion);
+        accessManager.grantRole(POOL_SERVICE_ROLE().toInt(), address(poolServiceAddress), 0);
+        bytes4[] memory instancePoolServiceSelectors = new bytes4[](1); // TODO works with (4)
+        instancePoolServiceSelectors[0] = instanceStore.updatePool.selector;
+        instanceAdmin.setTargetFunctionRoleByService(
+            "InstanceStore",
+            instancePoolServiceSelectors,
+            POOL_SERVICE_ROLE());
+    }
+
+    function _grantProductServiceAuthorizations(
+        AccessManagerExtendedInitializeable accessManager,
+        InstanceAdmin instanceAdmin,
+        InstanceStore instanceStore,
+        IRegistry registry,
+        VersionPart majorVersion)
+        private
+    {
+        // configure authorization for product service on instance
+        address productServiceAddress = registry.getServiceAddress(PRODUCT(), majorVersion);
+        accessManager.grantRole(PRODUCT_SERVICE_ROLE().toInt(), productServiceAddress, 0);
+        bytes4[] memory instanceProductServiceSelectors = new bytes4[](3);
+        instanceProductServiceSelectors[0] = instanceStore.createRisk.selector;
+        instanceProductServiceSelectors[1] = instanceStore.updateRisk.selector;
+        instanceProductServiceSelectors[2] = instanceStore.updateRiskState.selector;
+        instanceAdmin.setTargetFunctionRoleByService(
+            "InstanceStore",
+            instanceProductServiceSelectors,
+            PRODUCT_SERVICE_ROLE());
+    }
+
+    function _grantApplicationServiceAuthorizations(
+        AccessManagerExtendedInitializeable accessManager,
+        InstanceAdmin instanceAdmin,
+        InstanceStore instanceStore,
+        IRegistry registry,
+        VersionPart majorVersion)
+        private
+    {
+        // configure authorization for application services on instance
+        address applicationServiceAddress = registry.getServiceAddress(APPLICATION(), majorVersion);
+        accessManager.grantRole(APPLICATION_SERVICE_ROLE().toInt(), applicationServiceAddress, 0);
+        bytes4[] memory instanceApplicationServiceSelectors = new bytes4[](3);
+        instanceApplicationServiceSelectors[0] = instanceStore.createApplication.selector;
+        instanceApplicationServiceSelectors[1] = instanceStore.updateApplication.selector;
+        instanceApplicationServiceSelectors[2] = instanceStore.updateApplicationState.selector;
+        instanceAdmin.setTargetFunctionRoleByService(
+            "InstanceStore",
+            instanceApplicationServiceSelectors,
+            APPLICATION_SERVICE_ROLE());
+    }
+
+    function _grantPolicyServiceAuthorizations(
+        AccessManagerExtendedInitializeable accessManager,
+        InstanceAdmin instanceAdmin,
+        InstanceStore instanceStore,
+        IRegistry registry,
+        VersionPart majorVersion)
+        private
+    {
+        // configure authorization for policy services on instance
+        address policyServiceAddress = registry.getServiceAddress(POLICY(), majorVersion);
+        accessManager.grantRole(POLICY_SERVICE_ROLE().toInt(), policyServiceAddress, 0);
+        bytes4[] memory instancePolicyServiceSelectors = new bytes4[](2);
+        instancePolicyServiceSelectors[0] = instanceStore.updatePolicy.selector;
+        instancePolicyServiceSelectors[1] = instanceStore.updatePolicyState.selector;
+        instanceAdmin.setTargetFunctionRoleByService(
+            "InstanceStore",
+            instancePolicyServiceSelectors,
+            POLICY_SERVICE_ROLE());
+    }
+
+    function _grantClaimServiceAuthorizations(
+        AccessManagerExtendedInitializeable accessManager,
+        InstanceAdmin instanceAdmin,
+        InstanceStore instanceStore,
+        IRegistry registry,
+        VersionPart majorVersion)
+        private
+    {
+        // configure authorization for claim/payout services on instance
+        address claimServiceAddress = registry.getServiceAddress(CLAIM(), majorVersion);
+        accessManager.grantRole(CLAIM_SERVICE_ROLE().toInt(), claimServiceAddress, 0);
+
+        bytes4[] memory instancePolicyServiceSelectors = new bytes4[](1);
+        instancePolicyServiceSelectors[0] = instanceStore.updatePolicyClaims.selector;
+        instanceAdmin.setTargetFunctionRoleByService(
+            "InstanceStore",
+            instancePolicyServiceSelectors, 
+            CLAIM_SERVICE_ROLE());
+
+        bytes4[] memory instanceClaimServiceSelectors = new bytes4[](4);
+        instanceClaimServiceSelectors[0] = instanceStore.createClaim.selector;
+        instanceClaimServiceSelectors[1] = instanceStore.updateClaim.selector;
+        instanceClaimServiceSelectors[2] = instanceStore.createPayout.selector;
+        instanceClaimServiceSelectors[3] = instanceStore.updatePayout.selector;
+        instanceAdmin.setTargetFunctionRoleByService(
+            "InstanceStore",
+            instanceClaimServiceSelectors, 
+            CLAIM_SERVICE_ROLE());
+    }
+
+    function _grantBundleServiceAuthorizations(
+        AccessManagerExtendedInitializeable accessManager,
+        InstanceAdmin instanceAdmin,
+        InstanceStore instanceStore,
+        BundleManager bundleManager,
+        IRegistry registry,
+        VersionPart majorVersion)
+        private
+    {
+        // configure authorization for bundle service on instance
+        address bundleServiceAddress = registry.getServiceAddress(BUNDLE(), majorVersion);
+        accessManager.grantRole(BUNDLE_SERVICE_ROLE().toInt(), bundleServiceAddress, 0);
+        bytes4[] memory instanceBundleServiceSelectors = new bytes4[](5);
+        instanceBundleServiceSelectors[0] = instanceStore.createBundle.selector;
+        instanceBundleServiceSelectors[1] = instanceStore.updateBundle.selector;
+        instanceBundleServiceSelectors[2] = instanceStore.updateBundleState.selector;
+        instanceBundleServiceSelectors[3] = instanceStore.increaseLocked.selector;
+        instanceBundleServiceSelectors[4] = instanceStore.decreaseLocked.selector;
+        instanceAdmin.setTargetFunctionRoleByService(
+            "InstanceStore",
+            instanceBundleServiceSelectors,
+            BUNDLE_SERVICE_ROLE());
+
+        // configure authorization for bundle service on bundle manager
+        bytes4[] memory bundleManagerBundleServiceSelectors = new bytes4[](5);
+        bundleManagerBundleServiceSelectors[0] = bundleManager.linkPolicy.selector;
+        bundleManagerBundleServiceSelectors[1] = bundleManager.unlinkPolicy.selector;
+        bundleManagerBundleServiceSelectors[2] = bundleManager.add.selector;
+        bundleManagerBundleServiceSelectors[3] = bundleManager.lock.selector;
+        bundleManagerBundleServiceSelectors[4] = bundleManager.unlock.selector;
+        instanceAdmin.setTargetFunctionRoleByService(
+            "BundleManager",
+            bundleManagerBundleServiceSelectors,
+            BUNDLE_SERVICE_ROLE());
+    }
+
+    function _grantInstanceServiceAuthorizations(
+        AccessManagerExtendedInitializeable accessManager,
+        InstanceAdmin instanceAdmin,
+        Instance instance,
+        IRegistry registry,
+        VersionPart majorVersion)
+        private
+    {
+        // configure authorization for instance service on instance
+        address instanceServiceAddress = registry.getServiceAddress(INSTANCE(), majorVersion);
+        accessManager.grantRole(INSTANCE_SERVICE_ROLE().toInt(), instanceServiceAddress, 0);
+        bytes4[] memory instanceInstanceServiceSelectors = new bytes4[](1);
+        instanceInstanceServiceSelectors[0] = instance.setInstanceReader.selector;
+        instanceAdmin.setTargetFunctionRoleByService(
+            "Instance",
+            instanceInstanceServiceSelectors,
+            INSTANCE_SERVICE_ROLE());
+
+        // configure authorizations for instance service on instance access manager
+        bytes4[] memory instanceAdminInstanceServiceSelectors = new bytes4[](3);
+        instanceAdminInstanceServiceSelectors[0] = instanceAdmin.createGifTarget.selector;
+        instanceAdminInstanceServiceSelectors[1] = instanceAdmin.setTargetLockedByService.selector;
+        instanceAdminInstanceServiceSelectors[2] = instanceAdmin.setTargetFunctionRoleByService.selector;
+        instanceAdmin.setTargetFunctionRoleByService(
+            "InstanceAdmin",
+            instanceAdminInstanceServiceSelectors,
+            INSTANCE_SERVICE_ROLE());
+    }
+
+    function _grantInstanceAuthorizations(
+        AccessManagerExtendedInitializeable accessManager,
+        InstanceAdmin instanceAdmin,
+        Instance instance,
+        IRegistry registry,
+        VersionPart majorVersion)
+        private
+    {
+        // configure authorizations for instance on instance admin
+        bytes4[] memory instanceAdminInstanceSelectors = new bytes4[](4);
+        instanceAdminInstanceSelectors[0] = instanceAdmin.createRole.selector;
+        instanceAdminInstanceSelectors[1] = instanceAdmin.createTarget.selector;
+        instanceAdminInstanceSelectors[2] = instanceAdmin.setTargetFunctionRoleByInstance.selector;
+        instanceAdminInstanceSelectors[3] = instanceAdmin.setTargetLockedByInstance.selector;
+        instanceAdmin.setTargetFunctionRoleByService(
+            "InstanceAdmin",
+            instanceAdminInstanceSelectors,
+            INSTANCE_ROLE());
+    }
+
+    function _grantInstanceOwnerAuthorizations(
+        InstanceAdmin instanceAdmin,
+        Instance instance,
+        IRegistry registry,
+        VersionPart majorVersion) 
+        private 
+    {
+        // configure authorization for instance owner on instance access manager
+        // instance owner role is granted/revoked ONLY by INSTANCE_ROLE
+        bytes4[] memory instanceInstanceOwnerSelectors = new bytes4[](4);
+        instanceInstanceOwnerSelectors[0] = instance.createRole.selector;
+        instanceInstanceOwnerSelectors[1] = instance.createTarget.selector;
+        instanceInstanceOwnerSelectors[2] = instance.setTargetFunctionRole.selector;
+        instanceInstanceOwnerSelectors[3] = instance.setTargetLocked.selector;
+        instanceAdmin.setTargetFunctionRoleByService(
+            "Instance",
+            instanceInstanceOwnerSelectors,
+            INSTANCE_OWNER_ROLE());
+    }
+}