@etherisc/gif-next 0.0.2-bad4d33-850 → 0.0.2-baec8d5-329

package/contracts/distribution/DistributionService.sol

@@ -0,0 +1,345 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {IComponentService} from "../shared/IComponentService.sol";
+import {IInstanceService} from "../instance/IInstanceService.sol";
+import {IRegistryService} from "../registry/IRegistryService.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {Fee, FeeLib} from "../type/Fee.sol";
+import {KEEP_STATE} from "../type/StateId.sol";
+import {ObjectType, COMPONENT, DISTRIBUTION, INSTANCE, DISTRIBUTION, DISTRIBUTOR, REGISTRY} from "../type/ObjectType.sol";
+import {ComponentVerifyingService} from "../shared/ComponentVerifyingService.sol";
+import {IDistributionService} from "./IDistributionService.sol";
+import {UFixed, UFixedLib} from "../type/UFixed.sol";
+import {DistributorType, DistributorTypeLib} from "../type/DistributorType.sol";
+import {ReferralId, ReferralLib} from "../type/Referral.sol";
+import {Timestamp, TimestampLib} from "../type/Timestamp.sol";
+import {IDistribution} from "../instance/module/IDistribution.sol";
+import {InstanceStore} from "../instance/InstanceStore.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+
+
+contract DistributionService is
+    ComponentVerifyingService,
+    IDistributionService
+{
+    using AmountLib for Amount;
+    using NftIdLib for NftId;
+    using TimestampLib for Timestamp;
+    using UFixedLib for UFixed;
+    using FeeLib for Fee;
+    using ReferralLib for ReferralId;
+
+    IComponentService private _componentService;
+    IInstanceService private _instanceService;
+    IRegistryService private _registryService;
+    
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        initializer
+        virtual override
+    {
+        address initialOwner;
+        address registryAddress;
+        (registryAddress, initialOwner) = abi.decode(data, (address, address));
+        // TODO while DistributionService is not deployed in DistributionServiceManager constructor
+        //      owner is DistributionServiceManager deployer
+        initializeService(registryAddress, address(0), owner);
+
+        _componentService = IComponentService(_getServiceAddress(COMPONENT()));
+        _instanceService = IInstanceService(_getServiceAddress(INSTANCE()));
+        _registryService = IRegistryService(_getServiceAddress(REGISTRY()));
+
+        registerInterface(type(IDistributionService).interfaceId);
+    }
+
+
+    function createDistributorType(
+        string memory name,
+        UFixed minDiscountPercentage,
+        UFixed maxDiscountPercentage,
+        UFixed commissionPercentage,
+        uint32 maxReferralCount,
+        uint32 maxReferralLifetime,
+        bool allowSelfReferrals,
+        bool allowRenewals,
+        bytes memory data
+    )
+        external
+        returns (DistributorType distributorType)
+    {
+        (NftId distributionNftId,, IInstance instance) = _getAndVerifyActiveComponent(DISTRIBUTION());
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        {
+            NftId productNftId = _getProductNftId(instanceReader, distributionNftId);
+            IComponents.ProductInfo memory productInfo = instance.getInstanceReader().getProductInfo(productNftId);
+
+            UFixed variableDistributionFees = productInfo.distributionFee.fractionalFee;
+            UFixed variableFeesPartsTotal = productInfo.minDistributionOwnerFee.fractionalFee + commissionPercentage;
+
+            if (variableFeesPartsTotal > variableDistributionFees) {
+                revert ErrorDistributionServiceVariableFeesTooHight(variableDistributionFees.toInt1000(), variableFeesPartsTotal.toInt1000());
+            }
+            UFixed maxDiscountPercentageLimit = variableDistributionFees - variableFeesPartsTotal;
+
+            if (maxDiscountPercentage.gt(maxDiscountPercentageLimit)) {
+                revert ErrorDistributionServiceMaxDiscountTooHigh(maxDiscountPercentage.toInt1000(), maxDiscountPercentageLimit.toInt1000());
+            }
+        }
+
+        distributorType = DistributorTypeLib.toDistributorType(distributionNftId, name);
+        IDistribution.DistributorTypeInfo memory info = IDistribution.DistributorTypeInfo(
+            name,
+            minDiscountPercentage,
+            maxDiscountPercentage,
+            commissionPercentage,
+            maxReferralCount,
+            maxReferralLifetime,
+            allowSelfReferrals,
+            allowRenewals,
+            data);
+
+        instance.getInstanceStore().createDistributorType(distributorType, info);
+    }
+
+
+    function createDistributor(
+        address distributor,
+        DistributorType distributorType,
+        bytes memory data
+    )
+        external 
+        virtual
+        returns (NftId distributorNftId)
+    {
+        (NftId distributionNftId,, IInstance instance) = _getAndVerifyActiveComponent(DISTRIBUTION());
+
+        distributorNftId = _registryService.registerDistributor(
+            IRegistry.ObjectInfo(
+                NftIdLib.zero(), 
+                distributionNftId,
+                DISTRIBUTOR(),
+                true, // intercepting property for bundles is defined on pool
+                address(0),
+                distributor,
+                ""
+            ));
+
+        IDistribution.DistributorInfo memory info = IDistribution.DistributorInfo(
+            distributorType,
+            true, // active
+            data,
+            AmountLib.zero(),
+            0);
+
+        instance.getInstanceStore().createDistributor(distributorNftId, info);
+    }
+
+    // function updateDistributorType(
+    //     NftId distributorNftId,
+    //     DistributorType distributorType,
+    //     bytes memory data
+    // )
+    //     external
+    //     virtual
+    // {
+    //     (, IInstance instance) = _getAndVerifyCallingDistribution();
+    //     InstanceReader instanceReader = instance.getInstanceReader();
+    //     IDistribution.DistributorInfo memory distributorInfo = instanceReader.getDistributorInfo(distributorNftId);
+    //     distributorInfo.distributorType = distributorType;
+    //     distributorInfo.data = data;
+    //     instance.updateDistributor(distributorNftId, distributorInfo, KEEP_STATE());
+    // }
+
+
+    function createReferral(
+        NftId distributorNftId,
+        string memory code,
+        UFixed discountPercentage,
+        uint32 maxReferrals,
+        Timestamp expiryAt,
+        bytes memory data
+    )
+        external
+        virtual
+        returns (ReferralId referralId)
+    {
+        (NftId distributionNftId,, IInstance instance) = _getAndVerifyActiveComponent(DISTRIBUTION());
+
+        if (bytes(code).length == 0) {
+            revert ErrorIDistributionServiceInvalidReferral(code);
+        }
+        if (expiryAt.eqz()) {
+            revert ErrorIDistributionServiceExpirationInvalid(expiryAt);
+        }
+
+        InstanceReader instanceReader = instance.getInstanceReader();
+        DistributorType distributorType = instanceReader.getDistributorInfo(distributorNftId).distributorType;
+        IDistribution.DistributorTypeInfo memory distributorTypeData = instanceReader.getDistributorTypeInfo(distributorType);
+
+        if (distributorTypeData.maxReferralCount < maxReferrals) {
+            revert ErrorIDistributionServiceMaxReferralsExceeded(distributorTypeData.maxReferralCount);
+        }
+        if (distributorTypeData.minDiscountPercentage > discountPercentage) {
+            revert ErrorIDistributionServiceDiscountTooLow(distributorTypeData.minDiscountPercentage.toInt(), discountPercentage.toInt());
+        }
+        if (distributorTypeData.maxDiscountPercentage < discountPercentage) {
+            revert ErrorIDistributionServiceDiscountTooHigh(distributorTypeData.maxDiscountPercentage.toInt(), discountPercentage.toInt());
+        }
+        if (expiryAt.toInt() - TimestampLib.blockTimestamp().toInt() > distributorTypeData.maxReferralLifetime) {
+            revert ErrorIDistributionServiceExpiryTooLong(distributorTypeData.maxReferralLifetime, expiryAt.toInt());
+        }
+
+        referralId = ReferralLib.toReferralId(distributionNftId, code);
+        IDistribution.ReferralInfo memory info = IDistribution.ReferralInfo(
+            distributorNftId,
+            code,
+            discountPercentage,
+            maxReferrals,
+            0, // used referrals
+            expiryAt,
+            data
+        );
+
+        instance.getInstanceStore().createReferral(referralId, info);
+        return referralId;
+    }
+
+
+    function processSale(
+        NftId distributionNftId, // assume always of distribution type
+        ReferralId referralId,
+        IPolicy.Premium memory premium
+    )
+        external
+        virtual
+        restricted
+    {
+        IInstance instance = _getInstanceForDistribution(distributionNftId);
+        InstanceReader reader = instance.getInstanceReader();
+        InstanceStore store = instance.getInstanceStore();
+
+        // get distribution owner fee amount
+        Amount distributionOwnerFee = AmountLib.toAmount(premium.distributionOwnerFeeFixAmount + premium.distributionOwnerFeeVarAmount);
+
+        // update referral/distributor info if applicable
+        if (referralIsValid(distributionNftId, referralId)) {
+
+            // increase distribution balance by commission amount and distribution owner fee
+            Amount commissionAmount = AmountLib.toAmount(premium.commissionAmount);
+            _componentService.increaseDistributionBalance(store, distributionNftId, commissionAmount, distributionOwnerFee);
+
+            // update book keeping for referral info
+            IDistribution.ReferralInfo memory referralInfo = reader.getReferralInfo(referralId);
+            referralInfo.usedReferrals += 1;
+            store.updateReferral(referralId, referralInfo, KEEP_STATE());
+
+            // update book keeping for distributor info
+            IDistribution.DistributorInfo memory distributorInfo = reader.getDistributorInfo(referralInfo.distributorNftId);
+            // TODO refactor sum of commission amount into a fee balance for distributors
+            distributorInfo.commissionAmount = distributorInfo.commissionAmount + commissionAmount;
+            distributorInfo.numPoliciesSold += 1;
+            store.updateDistributor(referralInfo.distributorNftId, distributorInfo, KEEP_STATE());
+        } else {
+            // increase distribution balance by distribution owner fee
+            _componentService.increaseDistributionBalance(store, distributionNftId, AmountLib.zero(), distributionOwnerFee);
+        }
+    }
+
+    /// @inheritdoc IDistributionService
+    function withdrawCommission(NftId distributorNftId, Amount amount) 
+        public 
+        virtual
+        // TODO: restricted() (once #462 is done)
+        returns (Amount withdrawnAmount) 
+    {
+        (NftId distributionNftId,, IInstance instance) = _getAndVerifyActiveComponent(DISTRIBUTION());
+        InstanceReader reader = instance.getInstanceReader();
+        
+        IComponents.ComponentInfo memory distributionInfo = reader.getComponentInfo(distributionNftId);
+        address distributionWallet = distributionInfo.wallet;
+        
+        IDistribution.DistributorInfo memory distributorInfo = reader.getDistributorInfo(distributorNftId);
+        
+        // determine withdrawn amount
+        withdrawnAmount = amount;
+        if (withdrawnAmount.gte(AmountLib.max())) {
+            withdrawnAmount = distributorInfo.commissionAmount;
+        } else {
+            if (withdrawnAmount.gt(distributorInfo.commissionAmount)) {
+                revert ErrorDistributionServiceCommissionWithdrawAmountExceedsLimit(withdrawnAmount, distributorInfo.commissionAmount);
+            }
+        }
+
+        if (withdrawnAmount.eqz()) {
+            revert ErrorDistributionServiceCommissionWithdrawAmountIsZero();
+        }
+
+        // check allowance
+        IERC20Metadata token = IERC20Metadata(distributionInfo.token);
+        uint256 tokenAllowance = token.allowance(distributionWallet, address(distributionInfo.tokenHandler));
+        if (tokenAllowance < withdrawnAmount.toInt()) {
+            revert ErrorDistributionServiceWalletAllowanceTooSmall(distributionWallet, address(distributionInfo.tokenHandler), tokenAllowance, withdrawnAmount.toInt());
+        }
+
+        // decrease fee counters by withdrawnAmount and update distributor info
+        {
+            InstanceStore store = instance.getInstanceStore();
+            _componentService.decreaseDistributionBalance(store, distributionNftId, withdrawnAmount, AmountLib.zero());
+
+            distributorInfo.commissionAmount = distributorInfo.commissionAmount - withdrawnAmount;
+            store.updateDistributor(distributorNftId, distributorInfo, KEEP_STATE());
+        }
+
+        // transfer amount to distributor
+        {
+            address distributor = getRegistry().ownerOf(distributorNftId);
+            distributionInfo.tokenHandler.transfer(distributionWallet, distributor, withdrawnAmount);
+
+            emit LogDistributionServiceCommissionWithdrawn(distributorNftId, distributor, address(token), withdrawnAmount);
+        }
+    }
+
+    function referralIsValid(NftId distributionNftId, ReferralId referralId) public view returns (bool isValid) {
+        if (distributionNftId.eqz() || referralId.eqz()) {
+            return false;
+        }
+
+        IInstance instance = _getInstanceForDistribution(distributionNftId);
+        IDistribution.ReferralInfo memory info = instance.getInstanceReader().getReferralInfo(referralId);
+
+        if (info.distributorNftId.eqz()) {
+            return false;
+        }
+
+        isValid = info.expiryAt.eqz() || (info.expiryAt.gtz() && TimestampLib.blockTimestamp() <= info.expiryAt);
+        isValid = isValid && info.usedReferrals < info.maxReferrals;
+    }
+
+    function _getInstanceForDistribution(NftId distributionNftId)
+        internal
+        view
+        returns(IInstance instance)
+    {
+        NftId instanceNftId = getRegistry().getObjectInfo(distributionNftId).parentNftId;
+        address instanceAddress = getRegistry().getObjectInfo(instanceNftId).objectAddress;
+        return IInstance(instanceAddress);
+    }
+
+    function _getDomain() internal pure override returns(ObjectType) {
+        return DISTRIBUTION();
+    }
+}

package/contracts/distribution/DistributionServiceManager.sol

@@ -0,0 +1,39 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {ProxyManager} from "../upgradeability/ProxyManager.sol";
+import {DistributionService} from "./DistributionService.sol";
+
+contract DistributionServiceManager is ProxyManager {
+
+    DistributionService private _distributionService;
+
+    /// @dev initializes proxy manager with distribution service implementation and deploys instance
+    constructor(
+        address authority, 
+        address registryAddress,
+        bytes32 salt
+    ) 
+        ProxyManager(registryAddress)
+    {
+        DistributionService distSrv = new DistributionService{salt: salt}();
+        bytes memory data = abi.encode(registryAddress, address(this), authority);
+        IVersionable versionable = deployDetermenistic(
+            address(distSrv), 
+            data,
+            salt);
+
+        _distributionService = DistributionService(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getDistributionService()
+        external
+        view
+        returns (DistributionService distributionService)
+    {
+        return _distributionService;
+    }
+
+}

package/contracts/distribution/IDistributionComponent.sol

@@ -0,0 +1,52 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount} from "../type/Amount.sol";
+import {IInstanceLinkedComponent} from "../shared/IInstanceLinkedComponent.sol";
+import {NftId} from "../type/NftId.sol";
+import {ReferralId, ReferralStatus} from "../type/Referral.sol";
+import {UFixed} from "../type/UFixed.sol";
+
+interface IDistributionComponent is IInstanceLinkedComponent {
+
+    error ErrorDistributionNotDistributor(address distributor);
+    error ErrorDistributionAlreadyDistributor(address distributor, NftId distributorNftId);
+
+    event LogDistributorUpdated(address to, address caller);
+
+    /// @dev Returns true iff the provided address is registered as a distributor with this distribution component.
+    function isDistributor(address candidate) external view returns (bool);
+
+    /// @dev Returns the distributor Nft Id for the provided address
+    function getDistributorNftId(address distributor) external view returns (NftId distributorNftId);
+
+    function getDiscountPercentage(
+        string memory referralCode
+    ) external view returns (UFixed discountPercentage, ReferralStatus status);
+
+    function getReferralId(
+        string memory referralCode
+    ) external returns (ReferralId referralId);
+
+    function calculateRenewalFeeAmount(
+        ReferralId referralId,
+        uint256 netPremiumAmount
+    ) external view returns (uint256 feeAmount);
+
+    /// @dev Callback function to process a renewal of a policy.
+    /// The default implementation is empty.
+    /// Overwrite this function to implement a use case specific behaviour.
+    function processRenewal(
+        ReferralId referralId,
+        uint256 feeAmount
+    ) external;
+
+    /// @dev Returns true to ensure component is called when transferring distributor Nft Ids.
+    function isVerifying() external view returns (bool verifying);
+
+    /// @dev Withdraw commission for the distributor
+    /// @param distributorNftId the distributor Nft Id
+    /// @param amount the amount to withdraw. If set to AMOUNT_MAX, the full commission available is withdrawn
+    /// @return withdrawnAmount the effective withdrawn amount
+    function withdrawCommission(NftId distributorNftId, Amount amount) external returns (Amount withdrawnAmount);
+}

package/contracts/distribution/IDistributionService.sol

@@ -0,0 +1,97 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount} from "../type/Amount.sol";
+import {NftId} from "../type/NftId.sol";
+import {Fee} from "../type/Fee.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+import {IService} from "../shared/IService.sol";
+import {UFixed} from "../type/UFixed.sol";
+import {DistributorType} from "../type/DistributorType.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+
+interface IDistributionService is IService {
+
+    error ErrorDistributionServiceCallerNotRegistered(address caller);
+    error ErrorIDistributionServiceParentNftIdNotInstance(NftId nftId, NftId parentNftId);
+    error ErrorIDistributionServiceCallerNotDistributor(address caller);
+    error ErrorIDistributionServiceInvalidReferralId(ReferralId referralId);
+    error ErrorIDistributionServiceMaxReferralsExceeded(uint256 maxReferrals);
+    error ErrorIDistributionServiceDiscountTooLow(uint256 minDiscountPercentage, uint256 discountPercentage);
+    error ErrorIDistributionServiceDiscountTooHigh(uint256 maxDiscountPercentage, uint256 discountPercentage);
+    error ErrorIDistributionServiceExpiryTooLong(uint256 maxReferralLifetime, uint256 expiryAt);
+    error ErrorIDistributionServiceInvalidReferral(string code);
+    error ErrorIDistributionServiceExpirationInvalid(Timestamp expiryAt);
+    error ErrorIDistributionServiceCommissionTooHigh(uint256 commissionPercentage, uint256 maxCommissionPercentage);
+    error ErrorIDistributionServiceMinFeeTooHigh(uint256 minFee, uint256 limit);
+
+    error ErrorDistributionServiceCommissionWithdrawAmountExceedsLimit(Amount amount, Amount limit);
+    error ErrorDistributionServiceCommissionWithdrawAmountIsZero();
+    error ErrorDistributionServiceWalletAllowanceTooSmall(address wallet, address tokenHandler, uint256 allowance, uint256 amount);
+
+    error ErrorDistributionServiceVariableFeesTooHight(uint256 maxDiscountPercentage, uint256 limit);
+    error ErrorDistributionServiceMaxDiscountTooHigh(uint256 maxDiscountPercentage, uint256 limit);
+
+    error ErrorIDistributionServiceReferralInvalid(NftId distributionNftId, ReferralId referralId);
+    error ErrorDistributionServiceInvalidFeeTransferred(Amount transferredDistributionFeeAmount, Amount expectedDistributionFeeAmount);
+
+    event LogDistributionServiceCommissionWithdrawn(NftId distributorNftId, address recipient, address tokenAddress, Amount amount);
+
+    function createDistributorType(
+        string memory name,
+        UFixed minDiscountPercentage,
+        UFixed maxDiscountPercentage,
+        UFixed commissionPercentage,
+        uint32 maxReferralCount,
+        uint32 maxReferralLifetime,
+        bool allowSelfReferrals,
+        bool allowRenewals,
+        bytes memory data
+    )
+        external
+        returns (DistributorType distributorType);
+
+    function createDistributor(
+        address distributor,
+        DistributorType distributorType,
+        bytes memory data
+    ) external returns (NftId distributorNftId);
+
+    // TODO re-enable and reorganize (service contract too large)
+    // function updateDistributorType(
+    //     NftId distributorNftId,
+    //     DistributorType distributorType,
+    //     bytes memory data
+    // ) external;
+
+    function createReferral(
+        NftId distributorNftId,
+        string memory code,
+        UFixed discountPercentage,
+        uint32 maxReferrals,
+        Timestamp expiryAt,
+        bytes memory data
+    )
+        external
+        returns (ReferralId referralId);
+
+    /// @dev callback from product service when selling a policy for a specific referralId
+    function processSale(
+        NftId distributionNftId,
+        ReferralId referralId,
+        IPolicy.Premium memory premium
+    ) external;
+
+    function referralIsValid(
+        NftId distributorNftId,
+        ReferralId referralId
+    ) external view returns (bool isValid);
+
+    /// @dev Withdraw commission for the distributor
+    /// @param distributorNftId the distributor Nft Id
+    /// @param amount the amount to withdraw. If set to AMOUNT_MAX, the full commission available is withdrawn
+    /// @return withdrawnAmount the effective withdrawn amount
+    function withdrawCommission(NftId distributorNftId, Amount amount) external returns (Amount withdrawnAmount);
+}

package/contracts/instance/{BundleManager.sol → BundleSet.sol}

@@ -2,39 +2,39 @@
 pragma solidity ^0.8.20;
 
 import {IInstance} from "./IInstance.sol";
-import {INSTANCE} from "../types/ObjectType.sol";
+import {INSTANCE} from "../type/ObjectType.sol";
 import {InstanceReader} from "./InstanceReader.sol";
 import {IPolicy} from "../instance/module/IPolicy.sol";
 import {IRegistry} from "../registry/IRegistry.sol";
-import {LibNftIdSet} from "../types/NftIdSet.sol";
-import {NftId} from "../types/NftId.sol";
-import {TimestampLib} from "../types/Timestamp.sol";
+import {LibNftIdSet} from "../type/NftIdSet.sol";
+import {NftId} from "../type/NftId.sol";
+import {TimestampLib} from "../type/Timestamp.sol";
 
-import {ObjectManager} from "./ObjectManager.sol";
+import {ObjectSet} from "./base/ObjectSet.sol";
 
-contract BundleManager is 
-    ObjectManager
+contract BundleSet is 
+    ObjectSet
 {
 
-    event LogBundleManagerPolicyLinked(NftId bundleNftId, NftId policyNftId);
-    event LogBundleManagerPolicyUnlinked(NftId bundleNftId, NftId policyNftId);
+    event LogBundleSetPolicyLinked(NftId bundleNftId, NftId policyNftId);
+    event LogBundleSetPolicyUnlinked(NftId bundleNftId, NftId policyNftId);
 
-    event LogBundleManagerBundleAdded(NftId poolNftId, NftId bundleNftId);
-    event LogBundleManagerBundleUnlocked(NftId poolNftId, NftId bundleNftId);
-    event LogBundleManagerBundleLocked(NftId poolNftId, NftId bundleNftId);
+    event LogBundleSetBundleAdded(NftId poolNftId, NftId bundleNftId);
+    event LogBundleSetBundleUnlocked(NftId poolNftId, NftId bundleNftId);
+    event LogBundleSetBundleLocked(NftId poolNftId, NftId bundleNftId);
+    event LogBundleSetBundleClosed(NftId poolNftId, NftId bundleNftId);
 
-    error ErrorBundleManagerErrorPolicyAlreadyActivated(NftId policyNftId);
-    error ErrorBundleManagerErrorBundleLocked(NftId bundleNftId, NftId policyNftId);
-    error ErrorBundleManagerPolicyWithOpenClaims(NftId policyNftId, uint256 openClaimsCount);
-    error ErrorBundleManagerPolicyNotCloseable(NftId policyNftId);
-    error ErrorBundleManagerBundleUnknown(NftId bundleNftId);
-    error ErrorBundleManagerBundleNotRegistered(NftId bundleNftId);
+    error ErrorBundleSetPolicyAlreadyActivated(NftId policyNftId);
+    error ErrorBundleSetBundleLocked(NftId bundleNftId, NftId policyNftId);
+    error ErrorBundleSetPolicyWithOpenClaims(NftId policyNftId, uint256 openClaimsCount);
+    error ErrorBundleSetPolicyNotCloseable(NftId policyNftId);
+    error ErrorBundleSetBundleUnknown(NftId bundleNftId);
+    error ErrorBundleSetBundleNotRegistered(NftId bundleNftId);
 
     mapping(NftId bundleNftId => LibNftIdSet.Set policies) internal _activePolicies;
 
-    /// @dev links a policy with its bundle
-    // to link a policy it MUST NOT yet have been activated
-    // the bundle MUST be unlocked (active) for linking (underwriting) and registered with this instance
+    /// @dev links a policy to its bundle
+    // to link a policy it MUST NOT yet have been linked
     function linkPolicy(NftId policyNftId) external restricted() {
         NftId bundleNftId = _instance.getInstanceReader().getPolicyInfo(policyNftId).bundleNftId;
         // decision will likely depend on the decision what to check here and what in the service
@@ -42,11 +42,11 @@ contract BundleManager is
 
         // ensure bundle is unlocked (in active set) and registered with this instance
         if (!_isActive(poolNftId, bundleNftId)) {
-            revert ErrorBundleManagerErrorBundleLocked(bundleNftId, policyNftId);
+            revert ErrorBundleSetBundleLocked(bundleNftId, policyNftId);
         }
 
         LibNftIdSet.add(_activePolicies[bundleNftId], policyNftId);
-        emit LogBundleManagerPolicyLinked(bundleNftId, policyNftId);
+        emit LogBundleSetPolicyLinked(bundleNftId, policyNftId);
     }
 
 
@@ -63,40 +63,41 @@ contract BundleManager is
 
         // ensure bundle is registered with this instance
         if (!_contains(poolNftId, bundleNftId)) {
-            revert ErrorBundleManagerBundleUnknown(bundleNftId);
+            revert ErrorBundleSetBundleUnknown(bundleNftId);
         }
 
         LibNftIdSet.remove(_activePolicies[bundleNftId], policyNftId);
-        emit LogBundleManagerPolicyUnlinked(policyInfo.bundleNftId, policyNftId);
+        emit LogBundleSetPolicyUnlinked(policyInfo.bundleNftId, policyNftId);
     }
 
 
-    /// @dev add a new bundle to a riskpool registerd with this instance
+    /// @dev add a new bundle to a pool registerd with this instance
     // the corresponding pool is fetched via instance reader
     function add(NftId bundleNftId) external restricted() {
         NftId poolNftId = _instance.getInstanceReader().getBundleInfo(bundleNftId).poolNftId;
 
         // ensure pool is registered with instance
         if(poolNftId.eqz()) {
-            revert ErrorBundleManagerBundleNotRegistered(bundleNftId);
+            revert ErrorBundleSetBundleNotRegistered(bundleNftId);
         }
 
         _add(poolNftId, bundleNftId);
-        emit LogBundleManagerBundleAdded(poolNftId, bundleNftId);
+        emit LogBundleSetBundleAdded(poolNftId, bundleNftId);
     }
 
-    /// @dev unlocked (active) bundles are available to underwrite new policies
+
+    /// @dev unlocked (active) bundles are available to collateralize new policies
     function unlock(NftId bundleNftId) external restricted() {
         NftId poolNftId = _instance.getInstanceReader().getBundleInfo(bundleNftId).poolNftId;
         _activate(poolNftId, bundleNftId);
-        emit LogBundleManagerBundleUnlocked(poolNftId, bundleNftId);
+        emit LogBundleSetBundleUnlocked(poolNftId, bundleNftId);
     }
 
-    /// @dev locked (deactivated) bundles may not underwrite any new policies
+    /// @dev locked (deactivated) bundles may not collateralize any new policies
     function lock(NftId bundleNftId) external restricted() {
         NftId poolNftId = _instance.getInstanceReader().getBundleInfo(bundleNftId).poolNftId;
         _deactivate(poolNftId, bundleNftId);
-        emit LogBundleManagerBundleLocked(poolNftId, bundleNftId);
+        emit LogBundleSetBundleLocked(poolNftId, bundleNftId);
     }
 
     function bundles(NftId poolNftId) external view returns(uint256) {