@etherisc/gif-next 0.0.2-b9e9dc3-713 → 0.0.2-bb7b80e-316

package/contracts/registry/RegistryServiceManager.sol

@@ -9,6 +9,7 @@ import {Registry} from "./Registry.sol";
 import {IVersionable} from "../shared/IVersionable.sol";
 import {ProxyManager} from "../shared/ProxyManager.sol";
 import {RegistryService} from "./RegistryService.sol";
+import {TokenRegistry} from "./TokenRegistry.sol";
 
 
 contract RegistryServiceManager is
@@ -16,36 +17,41 @@ contract RegistryServiceManager is
 {
     bytes32 constant public ACCESS_MANAGER_CREATION_CODE_HASH = 0x0;
 
-    RegistryService private _registryService; 
-
-    AccessManager private _accessManager;
+    RegistryService private immutable _registryService;
 
     /// @dev initializes proxy manager with registry service implementation and deploys registry
     constructor(
-        address accessManager
-    )
+        address initialAuthority, // used by implementation 
+        address registry) // used by implementation 
         ProxyManager()
     {
-        _accessManager = AccessManager(accessManager);
-
-        bytes memory initializationData = abi.encode(accessManager, type(Registry).creationCode);
+        require(initialAuthority > address(0), "RegistryServiceManager: initial authority is 0");
+        require(registry > address(0), "RegistryServiceManager: registry is 0");
+        
+        // implementation's initializer func `data` argument
+        bytes memory initializationData = abi.encode(
+            initialAuthority,
+            registry); 
 
         IVersionable versionable = deploy(
             address(new RegistryService()), 
             initializationData);
 
         _registryService = RegistryService(address(versionable));
+    }
 
-        // link ownership of registry service manager ot nft owner of registry service
-        _linkToNftOwnable(
-            address(_registryService.getRegistry()),
-            address(_registryService));
+    // from IRegisterable
 
-        // implies that after this constructor call only upgrade functionality is available
-        _isDeployed = true;
+    // IMPORTANT: registry here and in constructor MUST be the same
+    function linkToNftOwnable(address registry)
+        public
+        onlyOwner
+    {
+        _linkToNftOwnable(registry, address(_registryService));
     }
 
     //--- view functions ----------------------------------------------------//
+
     function getRegistryService()
         external
         view
@@ -53,12 +59,4 @@ contract RegistryServiceManager is
     {
         return _registryService;
     }
-
-    function getAccessManager()
-        external
-        view
-        returns (AccessManager)
-    {
-        return _accessManager;
-    }
 }

package/contracts/registry/ReleaseManager.sol

@@ -0,0 +1,342 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManaged} from "@openzeppelin/contracts/access/manager/AccessManaged.sol";
+
+import {NftId} from "../types/NftId.sol";
+import {RoleId} from "../types/RoleId.sol";
+import {ObjectType, ObjectTypeLib, zeroObjectType, REGISTRY, SERVICE} from "../types/ObjectType.sol";
+import {VersionPart, VersionPartLib} from "../types/Version.sol";
+import {Timestamp, TimestampLib} from "../types/Timestamp.sol";
+
+import {IService} from "../shared/IService.sol";
+
+import {IRegistry} from "./IRegistry.sol";
+import {Registry} from "./Registry.sol";
+import {IRegistryService} from "./IRegistryService.sol";
+import {RegistryAccessManager} from "./RegistryAccessManager.sol";
+
+
+contract ReleaseManager is AccessManaged
+{
+    using ObjectTypeLib for ObjectType;
+
+    event LogReleaseCreation(VersionPart version, IService registryService); 
+    event LogReleaseActivation(VersionPart version);
+
+    // createNextRelease
+    error NotRegistryService();
+    error UnexpectedServiceAuthority(address expected, address found);
+
+    // registerService
+    error NotService();
+
+    // activateNextRelease
+    //error ReleaseNotCreated();
+    //error ReleaseRegistrationNotFinished();
+
+    // _getAndVerifyContractInfo
+    error UnexpectedRegisterableType(ObjectType expected, ObjectType found);
+    error NotRegisterableOwner(address notOwner);
+    error SelfRegistration();
+    error RegisterableOwnerIsRegistered();
+
+    // _verifyServiceInfo
+    error UnexpectedServiceVersion(VersionPart expected, VersionPart found);
+    error UnexpectedServiceDomain(ObjectType expected, ObjectType found);
+    
+    // _verifyAndStoreConfig
+    error ConfigMissing();
+    error ConfigServiceDomainInvalid(uint configArrayIndex, ObjectType domain);
+    error ConfigSelectorZero(uint configArrayIndex);
+    error SelectorAlreadyExists(VersionPart releaseVersion, ObjectType serviceDomain);
+
+
+    RegistryAccessManager private immutable _accessManager;
+    IRegistry private immutable _registry;
+
+    VersionPart _latest;// latest active version
+    VersionPart immutable _initial;// first active version
+
+    mapping(VersionPart version => IRegistry.ReleaseInfo info) _release;
+
+    mapping(VersionPart version => mapping(ObjectType serviceDomain => bytes4)) _selector; // registry service function selector assigned to domain 
+
+    uint _awaitingRegistration; // "services left to register" counter
+
+    mapping(address registryService => bool isActive) _active;
+
+    constructor(
+        RegistryAccessManager accessManager, 
+        VersionPart initialVersion)
+        AccessManaged(accessManager.authority())
+    {
+        require(initialVersion.toInt() > 0, "ReleaseManager: initial version is 0");
+
+        _accessManager = accessManager;
+
+        _initial = initialVersion;
+
+        _registry = new Registry();
+    }
+
+    // TODO deploy proxy and initialize with given implementation instead of using given proxy?
+    // IMPORTANT: MUST never be possible to create with access/release manager, token registry
+    function createNextRelease(IRegistryService service)
+        external
+        restricted // GIF_ADMIN_ROLE
+        returns(NftId nftId)
+    {
+        if(!service.supportsInterface(type(IRegistryService).interfaceId)) {
+            revert NotRegistryService();
+        }
+        // TODO unreliable! MUST guarantee the same authority -> how?
+        address serviceAuthority = service.authority();
+        if(serviceAuthority != authority()) {
+            revert UnexpectedServiceAuthority(
+                authority(), 
+                serviceAuthority); 
+        }
+
+        (
+            IRegistry.ObjectInfo memory info, 
+            bytes memory data
+        ) = _getAndVerifyContractInfo(service, SERVICE(), msg.sender);
+
+        VersionPart version = getNextVersion();
+        ObjectType domain = REGISTRY();
+        _verifyServiceInfo(info, version, domain);
+
+        _createRelease(data);
+
+        //setTargetClosed(service, true);
+        
+        nftId = _registry.registerService(info, version, domain);
+
+        // external call
+        service.linkToRegisteredNftId();
+
+        emit LogReleaseCreation(version, service); 
+    }
+
+    // TODO adding service to release -> synchronized with proxy upgrades or simple addServiceToRelease(service, version, selector)?
+    // TODO removing service from release? -> set _active to false forever, but keep all other records?
+    function registerService(IService service) 
+        external
+        restricted // GIF_MANAGER_ROLE
+        returns(NftId nftId)
+    {
+        if(!service.supportsInterface(type(IService).interfaceId)) {
+            revert NotService();
+        }
+
+        (
+            IRegistry.ObjectInfo memory info, 
+            //bytes memory data
+        ) = _getAndVerifyContractInfo(service, SERVICE(), msg.sender);
+
+        VersionPart version = getNextVersion();
+        ObjectType domain = _release[version].domains[_awaitingRegistration];// reversed registration order of services specified in RegistryService config
+        _verifyServiceInfo(info, version, domain);
+
+        // setup and grant unique role if service does registrations
+        address registryService = _registry.getServiceAddress(REGISTRY(), version);
+        bytes4[] memory selector = new bytes4[](1);
+        selector[0] = _selector[version][domain];
+        if(selector[0] != 0) {
+            _accessManager.setAndGrantUniqueRole(
+                address(service), 
+                registryService, 
+                selector);
+        }
+
+        _awaitingRegistration--;
+
+        // activate release
+        if(_awaitingRegistration == 0) {
+            _latest = version;
+            _active[registryService] = true;  
+
+            emit LogReleaseActivation(version);
+        }
+
+        nftId = _registry.registerService(info, version, domain);
+
+        // external call
+        service.linkToRegisteredNftId(); 
+    }
+
+    /*function activateNextRelease() 
+        external 
+        restricted // GIF_ADMIN_ROLE
+    {
+        VersionPart version = getNextVersion();
+        address service = _registry.getServiceAddress(REGISTRY(), version);
+
+        // release was created
+        if(service == address(0)) {
+            revert ReleaseNotCreated();
+        }
+
+        // release fully deployed
+        if(_awaitingRegistration > 0) {
+            revert ReleaseRegistrationNotFinished();
+        }
+
+        //setTargetClosed(service, false);
+
+        _latest = version;
+        _active[service] = true;
+
+        LogReleaseActivation(version);
+    }*/
+
+    //--- view functions ----------------------------------------------------//
+
+    function isActiveRegistryService(address service) external view returns(bool)
+    {
+        return _active[service];
+    }
+
+    function getRegistry() external view returns(address)
+    {
+        return (address(_registry));
+    }
+
+    function getReleaseInfo(VersionPart version) external view returns(IRegistry.ReleaseInfo memory)
+    {
+        return _release[version];
+    }
+
+    function getNextVersion() public view returns(VersionPart) 
+    {
+        uint256 latest = _latest.toInt();
+
+        return latest == 0 ?
+            _initial : // no active releases yet
+            VersionPartLib.toVersionPart(latest + 1);
+    }
+
+    function getLatestVersion() external view returns(VersionPart) {
+        return _latest;
+    }
+
+    function getInitialVersion() external view returns(VersionPart) {
+        return _initial;
+    }
+
+    //--- private functions ----------------------------------------------------//
+
+    function _getAndVerifyContractInfo(
+        IService service,
+        ObjectType expectedType,
+        address expectedOwner // assume always valid, can not be 0
+    )
+        internal
+        view
+        returns(
+            IRegistry.ObjectInfo memory info, 
+            bytes memory data
+        )
+    {
+        (info, data) = service.getInitialInfo();
+        info.objectAddress = address(service);
+        info.isInterceptor = false; // service is never interceptor, at least now
+
+        if(info.objectType != expectedType) {// type is checked in registry anyway...but service logic may depend on expected value
+            revert UnexpectedRegisterableType(expectedType, info.objectType);
+        }
+
+        address owner = info.initialOwner;
+
+        if(owner != expectedOwner) { // registerable owner protection
+            revert NotRegisterableOwner(expectedOwner); 
+        }
+
+        if(owner == address(service)) {
+            revert SelfRegistration();
+        }
+
+        /*if(owner == address(0)) { // never 0
+            revert();// RegisterableOwnerIsZero();
+        }*/
+        
+        if(_registry.isRegistered(owner)) { 
+            revert RegisterableOwnerIsRegistered(); 
+        }
+
+        /*NftId parentNftId = info.parentNftId;
+        IRegistry.ObjectInfo memory parentInfo = getRegistry().getObjectInfo(parentNftId);
+
+        if(parentInfo.objectType != parentType) { // parent registration + type
+            revert InvalidParent(parentNftId);
+        }*/
+
+        return(info, data);
+    }
+
+    function _verifyServiceInfo(
+        IRegistry.ObjectInfo memory info,
+        VersionPart expectedVersion,
+        ObjectType expectedDomain
+    )
+        internal
+        view
+        returns(ObjectType)
+    {
+        (
+            ObjectType domain,
+            VersionPart version
+        ) = abi.decode(info.data, (ObjectType, VersionPart));
+
+        if(version != expectedVersion) {
+            revert UnexpectedServiceVersion(expectedVersion, version);
+        }
+
+        if(expectedDomain.gtz()) { 
+            if(domain != expectedDomain) {
+                revert UnexpectedServiceDomain(expectedDomain, domain);
+            }
+        }
+
+        return domain;
+    }
+
+    // TODO check if registry supports types specified in the config array
+    function _createRelease(bytes memory configBytes)
+        internal
+    {
+        VersionPart version = getNextVersion();
+        IRegistryService.FunctionConfig[] memory config = abi.decode(configBytes, (IRegistryService.FunctionConfig[]));
+
+        if(config.length == 0) {
+            revert ConfigMissing();
+        }
+        // always in release
+        _release[version].domains.push(REGISTRY());
+        for(uint idx = 0; idx < config.length; idx++)
+        {
+            ObjectType domain = config[idx].serviceDomain;
+            bytes4 selector = config[idx].selector;
+
+            // not "registry service" / zero domain
+            if(
+                domain == REGISTRY() ||
+                domain.eqz()
+            ) { revert ConfigServiceDomainInvalid(idx, domain); } 
+
+            // no overwrite
+            if(_selector[version][domain] > 0) {
+                revert SelectorAlreadyExists(version, domain); 
+            }
+            
+            _selector[version][domain] = selector;
+            _release[version].domains.push(domain);
+        }
+        // TODO set when activated?
+        _release[version].createdAt = TimestampLib.blockTimestamp();
+        //_release[version].updatedAt = TimestampLib.blockTimestamp();
+
+        _awaitingRegistration = config.length;
+    }
+}

package/contracts/registry/TokenRegistry.sol

@@ -0,0 +1,110 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {ERC165Checker} from "@openzeppelin/contracts/utils/introspection/ERC165Checker.sol";
+
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {IRegistry} from "./IRegistry.sol";
+import {VersionPart} from "../types/Version.sol";
+import {REGISTRY} from "../types/ObjectType.sol";
+import {NftOwnable} from "../shared/NftOwnable.sol";
+
+/// @title contract to register token per GIF major release.
+contract TokenRegistry is
+    NftOwnable
+{
+    event LogRegistered(address token, string symbol, uint256 decimals);
+    event LogTokenStateSet(address token, VersionPart majorVersion, bool active);
+
+    error NotContract(address account);
+    error NotToken(address account);
+    error TokenDecimalsZero();
+    error TokenMajorVersionInvalid(VersionPart majorVersion);
+
+    address [] internal _token;
+    mapping(address token => bool registered) internal _registered;
+    mapping(address token => mapping(VersionPart majorVersion => bool isActive)) internal _active;
+
+    constructor()
+        NftOwnable()
+    { }
+
+
+    /// @dev link ownership of token registry to nft owner of registry service
+    function linkToNftOwnable(address registryAddress) 
+        external
+        onlyOwner
+    {
+        IRegistry registry = IRegistry(registryAddress);
+        // TODO use _latest instead of `next version` -> but _latest is 0 before first release activation
+        address registryServiceAddress = registry.getServiceAddress(REGISTRY(), registry.getMajorVersionMax());
+
+        _linkToNftOwnable(registryAddress, registryServiceAddress);
+    }
+
+    /// @dev token state is informative, registry have no clue about used tokens
+    // component owner is responsible for token selection and operations
+    // service MUST deny registration of component with inactive token 
+    function setActive(address token, VersionPart majorVersion, bool active)
+        external
+        onlyOwner
+    {
+        // verify that token is registered
+        if (!_registered[token]) {
+            _registerToken(token);
+        }
+
+        // verify valid major version
+        // ensure major version increments is one
+        uint256 version = majorVersion.toInt();
+        if (version < _registry.getMajorVersionMin().toInt() || version > _registry.getMajorVersionMax().toInt()) {
+            revert TokenMajorVersionInvalid(majorVersion);
+        }
+
+        _active[token][majorVersion] = active;
+
+        emit LogTokenStateSet(token, majorVersion, active);
+    }
+
+    function tokens() external view returns (uint256) {
+        return _token.length;
+    }
+
+    function getToken(uint256 idx) external view returns (IERC20Metadata token) {
+        return IERC20Metadata(_token[idx]);
+    }
+
+    function isRegistered(address token) external view returns (bool) {
+        return _registered[token];
+    }
+
+    function isActive(address token, VersionPart majorVersion) external view returns (bool) {
+        return _active[token][majorVersion];
+    }
+
+    /// @dev some sanity checks to prevent unintended registration
+    function _registerToken(address token) internal {
+
+        // MUST be contract
+        if(token.code.length == 0) {
+            revert NotContract(token);
+        }
+
+        // MUST not be GIF registerable
+        if(ERC165Checker.supportsInterface(token, type(IRegisterable).interfaceId)) {
+            revert NotToken(token);
+        }
+
+        // MUST have decimals > 0
+        IERC20Metadata erc20 = IERC20Metadata(token);
+        if(erc20.decimals() == 0) {
+            revert TokenDecimalsZero();
+        }
+
+        _registered[token] = true;
+        _token.push(token);
+
+        emit LogRegistered(token, erc20.symbol(), erc20.decimals());
+    }
+}

package/contracts/shared/ERC165.sol

@@ -7,14 +7,18 @@ contract ERC165 is IERC165 {
     mapping(bytes4 => bool) private _isSupported;
 
     constructor() {
-        // register support for ERC165
-        _registerInterface(type(IERC165).interfaceId);
+        _initializeERC165();
     }
 
     function supportsInterface(bytes4 interfaceId) external view override returns (bool) {
         return _isSupported[interfaceId];
     }
 
+    // @dev register support for ERC165 itself
+    function _initializeERC165() internal {
+        _isSupported[type(IERC165).interfaceId] = true;
+    }
+
     function _registerInterface(bytes4 interfaceId) internal {
         _isSupported[interfaceId] = true;
     }

package/contracts/shared/IService.sol

@@ -0,0 +1,16 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {VersionPart} from "../types/Version.sol";
+import {ObjectType} from "../types/ObjectType.sol";
+
+import {IRegisterable} from "./IRegisterable.sol";
+import {IVersionable} from "./IVersionable.sol";
+
+interface IService is 
+    IRegisterable,
+    IVersionable
+{
+    function getDomain() external pure returns(ObjectType serviceDomain);
+    function getMajorVersion() external view returns(VersionPart majorVersion);
+}

package/contracts/shared/NftOwnable.sol

@@ -13,10 +13,7 @@ contract NftOwnable is INftOwnable {
 
     /// @dev enforces msg.sender is owner of nft (or initial owner of nft ownable)
     modifier onlyOwner() {
-        address owner = getOwner();
-
-        // owner == address(0) is eg uninitialized upgradable contract
-        if (owner != address(0) && msg.sender != owner) {
+        if (msg.sender != getOwner()) {
             revert ErrorNotOwner(msg.sender);
         }
         _;
@@ -77,6 +74,7 @@ contract NftOwnable is INftOwnable {
         internal
         virtual
     {
+        require(initialOwner > address(0), "NftOwnable: initial owner is 0");
         _initialOwner = initialOwner;
         _setRegistry(registryAddress);
     }

package/contracts/shared/ProxyManager.sol

@@ -38,6 +38,7 @@ contract ProxyManager is
         returns (IVersionable versionable)
     {
         if (_isDeployed) { revert ErrorAlreadyDeployed(); }
+        _isDeployed = true;
 
         address currentProxyOwner = getOwner(); // used by implementation
         address initialProxyAdminOwner = address(this); // used by proxy
@@ -49,7 +50,6 @@ contract ProxyManager is
             data
         );
 
-        _isDeployed = true;
         versionable = IVersionable(address(_proxy));
 
         emit LogProxyDeployed(address(_proxy), initialImplementation);

package/contracts/shared/Registerable.sol

@@ -49,6 +49,7 @@ contract Registerable is
         //onlyInitializing//TODO uncomment when "fully" upgradeable
         virtual
     {
+        _initializeERC165();
         _initializeNftOwnable(
             initialOwner,
             registryAddress);

package/contracts/shared/RegisterableUpgradable.sol

@@ -0,0 +1,16 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Registerable} from "./Registerable.sol";
+import {Versionable} from "./Versionable.sol";
+
+/// @dev base contract for upgradable objects like services and upgradable components
+/// deriving contracs need to call _initializeRegisterable
+/// TODO internalizes versionable here, a non-registerable versionalbe might itself have some value but is outside the scope of the gif
+/// after this merge versionable will no longer exist on its own in gif
+/// only registerable and upgradable (which is a registerable too) will remain
+abstract contract RegisterableUpgradable is 
+    Registerable,
+    Versionable
+{
+}

package/contracts/shared/Service.sol

@@ -0,0 +1,58 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {ObjectType, SERVICE} from "../types/ObjectType.sol";
+import {NftId, zeroNftId} from "../types/NftId.sol";
+import {Version, VersionPart, VersionLib} from "../types/Version.sol";
+
+import {Versionable} from "./Versionable.sol";
+import {IService} from "./IService.sol";
+import {IVersionable} from "./IVersionable.sol";
+import {RegisterableUpgradable} from "./RegisterableUpgradable.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+
+
+/// @dev service base contract
+abstract contract Service is 
+    RegisterableUpgradable,
+    IService
+{
+    function getDomain() public pure virtual override returns(ObjectType);
+
+    function getMajorVersion() public view virtual override returns(VersionPart majorVersion) {
+        return getVersion().toMajorPart(); 
+    }
+
+    // from Versionable
+    function getVersion()
+        public 
+        pure 
+        virtual override (IVersionable, Versionable)
+        returns(Version)
+    {
+        return VersionLib.toVersion(3,0,0);
+    }
+
+    function _initializeService(
+        address registry, 
+        address initialOwner
+    )
+        internal
+        virtual
+        //onlyInitializing //TODO uncomment when "fully" upgradeable
+    {
+        // service must provide its name and version upon registration
+        bytes memory data = abi.encode(getDomain(), getMajorVersion());
+        NftId registryNftId = _getRegistryNftId(registry); 
+        bool isInterceptor = false;
+
+        _initializeRegisterable(registry, registryNftId, SERVICE(), isInterceptor, initialOwner, data);
+        _registerInterface(type(IService).interfaceId);
+    }
+
+    // this is just a conveniene function, actual validation will be done upon registration
+    function _getRegistryNftId(address registryAddress) internal view returns (NftId) {
+        return IRegistry(registryAddress).getNftId(registryAddress);
+    }
+}