@etherisc/gif-next 0.0.2-b9b3e89 → 0.0.2-ed4dd55

package/contracts/registry/ChainNft.sol

@@ -0,0 +1,173 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {ERC721, ERC721Enumerable} from "@openzeppelin/contracts/token/ERC721/extensions/ERC721Enumerable.sol";
+import {IChainNft} from "./IChainNft.sol";
+
+contract ChainNft is
+    ERC721Enumerable,
+    IChainNft
+{
+    string public constant NAME = "Dezentralized Insurance Protocol Registry";
+    string public constant SYMBOL = "DIPR";
+
+    // remember token uri
+    mapping(uint256 tokenId => string uri) private _uri;
+
+    // remember registry
+    address private _registry;
+
+    // only used for _getNextTokenId
+    uint256 internal _chainIdInt; 
+    uint256 internal _chainIdDigits;
+    uint256 internal _chainIdMultiplier;
+    uint256 internal _idNext;
+    uint256 internal _totalMinted;
+
+
+    modifier onlyRegistry() {
+        require(msg.sender == _registry, "ERROR:NFT-001:CALLER_NOT_REGISTRY");
+        _;
+    }
+
+
+    constructor(address registry)
+        ERC721(NAME, SYMBOL)
+    {
+        require(registry != address(0), "ERROR:NFT-010:REGISTRY_ZERO");
+
+        _registry = registry;
+
+        _chainIdInt = block.chainid;
+        _chainIdDigits = _countDigits(_chainIdInt);
+        _chainIdMultiplier = 10 ** _chainIdDigits;
+
+        // on mainnet/goerli start /1 (reserved for protocol nft) on other chains with 2
+        if(block.chainid == 1 || block.chainid == 5) {
+            _idNext = 1;
+        } else {
+            _idNext = 2;
+        }
+    }
+
+
+    function mint(
+        address to,
+        string memory uri
+    )
+        external
+        override
+        onlyRegistry
+        returns(uint256 tokenId)
+    {
+        tokenId = _getNextTokenId();
+        _totalMinted++;
+
+        _safeMint(to, tokenId);
+
+        if(bytes(uri).length > 0) {
+            _uri[tokenId] = uri;
+        }
+    }
+
+
+    function burn(uint256 tokenId)
+        external
+        override
+        onlyRegistry
+    {
+        _requireMinted(tokenId);
+        _burn(tokenId);
+        delete _uri[tokenId];
+    }
+
+
+    function setURI(uint256 tokenId, string memory uri)
+        external
+        override
+        onlyRegistry
+    {
+        require(bytes(uri).length > 0, "ERROR:CRG-011:URI_EMPTY");
+
+        _requireMinted(tokenId);
+        _uri[tokenId] = uri;
+    }
+
+
+    function exists(uint256 tokenId)
+        external
+        view
+        override
+        returns(bool)
+    {
+        return _exists(tokenId);
+    }
+
+
+    function tokenURI(uint256 tokenId)
+        public
+        view
+        override 
+        returns(string memory)
+    {
+        _requireMinted(tokenId);
+        return _uri[tokenId];
+    }
+
+
+    function getRegistryAddress()
+        external
+        view
+        override
+        returns(address)
+    {
+        return _registry;
+    }
+
+    function totalMinted() external override view returns(uint256) {
+        return _totalMinted;
+    }
+
+    // requirement: each chain registry produces token ids that
+    // are guaranteed to not collide with any token id genereated
+    // on a different chain
+    //
+    // format concat(counter,chainid,2 digits for len-of-chain-id)
+    // restriction chainid up to 99 digits
+    // decode: from right to left:
+    // - 2 right most digits encode length of chainid
+    // - move number of digits to left as determined above (-> chainid)
+    // - the reminder to the left is the counter
+    // examples
+    // 1101
+    // ^^ ^
+    // || +- 1-digit chain id
+    // |+-- chain id = 1 (mainnet)
+    // +-- 1st token id on mainnet
+    // (1 * 10 ** 1 + 1) * 100 + 1
+    // 42987654321010
+    // ^ ^          ^
+    // | |          +- 10-digit chain id
+    // | +-- chain id = 9876543210 (hypothetical chainid)
+    // +-- 42nd token id on this chain
+    // (42 * 10 ** 10 + 9876543210) * 100 + 10
+    // (index * 10 ** digits + chainid) * 100 + digits (1 < digits < 100)
+
+    function _getNextTokenId() private returns(uint256 id) {
+        id = (_idNext * _chainIdMultiplier + _chainIdInt) * 100 + _chainIdDigits;
+        _idNext++;
+    }
+
+
+    function _countDigits(uint256 num)
+        private 
+        pure 
+        returns (uint256 count)
+    {
+        count = 0;
+        while (num != 0) {
+            count++;
+            num /= 10;
+        }
+    }
+}

package/contracts/registry/IChainNft.sol

@@ -0,0 +1,18 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC721Enumerable} from "@openzeppelin/contracts/token/ERC721/extensions/IERC721Enumerable.sol";
+
+interface IChainNft is 
+    IERC721Enumerable 
+{
+
+    function mint(address to, string memory uri) external returns(uint256 tokenId);
+    function burn(uint256 tokenId) external;
+    function setURI(uint256 tokenId, string memory uri) external;
+
+    function exists(uint256 tokenId) external view returns(bool);
+    function totalMinted() external view returns(uint256);
+
+    function getRegistryAddress() external view returns(address registry);
+}

package/contracts/registry/IRegistry.sol

@@ -56,11 +56,13 @@ interface IRegistry {
     )
         external returns(uint256 nftId);
 
-    function transfer(uint256 nftId, address newOwner) external;
+    function getObjectCount() external view returns(uint256);
 
     function getNftId(address objectAddress) external view returns(uint256 nftId);
     function getInfo(uint256 nftId) external view returns(RegistryInfo memory info);
     function getOwner(uint256 nftId) external view returns(address ownerAddress);
 
     function isRegistered(address objectAddress) external view returns(bool);
+
+    function getNftAddress() external view returns(address nft);
 }

package/contracts/registry/Registry.sol

@@ -1,6 +1,7 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.19;
 
+import {IChainNft} from "./IChainNft.sol";
 import {IRegistry, IRegistryLinked, IRegisterable} from "./IRegistry.sol";
 
 contract RegistryLinked is IRegistryLinked {
@@ -11,11 +12,6 @@ contract RegistryLinked is IRegistryLinked {
         _registry = IRegistry(registry);
     }
 
-    // function setRegistry(address registry) public override {
-    //     require(address(_registry) == address(0), "ERROR:RGL-001:REGISTRY_ALREADY_SET");
-    //     _registry = IRegistry(registry);
-    // }
-
     function getRegistry() external view override returns(IRegistry registry) {
         return _registry;
     }
@@ -62,24 +58,19 @@ abstract contract Registerable is
 
 }
 
-    // struct RegistryInfo {
-    //     bytes32 id;
-    //     uint256 objectType;
-    //     address objectAddress;
-    //     address initialOwner;
-    // }
-
 contract Registry is IRegistry {
 
+    string public constant EMPTY_URI = "";
+
     mapping(uint256 id => RegistryInfo info) private _info;
     mapping(uint256 id => address owner) private _owner;
     mapping(address object => uint256 id) private _idByAddress;
-    uint256 [] private _ids;
-    uint256 private _idNext;
 
+    IChainNft private _chainNft;
 
-    constructor() {
-        _idNext = 0;
+    function initialize(address chainNft) external {
+        require(address(_chainNft) == address(0), "ERROR:REG-001:ALREADY_INITIALIZED");
+        _chainNft = IChainNft(chainNft);
     }
 
     function TOKEN() public pure override returns(uint256) { return 30; }
@@ -104,7 +95,9 @@ contract Registry is IRegistry {
             // policy -> product, bundle -> pool, product -> instance, pool -> instance
         }
 
-        nftId = _mint(registerable.getInitialOwner());
+        nftId = _chainNft.mint(
+            registerable.getInitialOwner(), 
+            EMPTY_URI);
     
         RegistryInfo memory info = RegistryInfo(
             nftId,
@@ -136,7 +129,9 @@ contract Registry is IRegistry {
             objectType == POLICY() || objectType == BUNDLE(),
             "ERROR:REG-005:TYPE_INVALID");
 
-        nftId = _mint(initialOwner);
+        nftId = _chainNft.mint(
+            initialOwner,
+            EMPTY_URI);
 
         RegistryInfo memory info = RegistryInfo(
             nftId,
@@ -152,16 +147,8 @@ contract Registry is IRegistry {
     }
 
 
-    function transfer(uint256 id, address newOwner) external {
-        require(msg.sender == _owner[id], "ERROR:REG-010:NOT_OWNER");
-        _owner[id] = newOwner;
-
-        // TODO logging
-    }
-
-
-    function getObjectCount() external view returns(uint256) {
-        return _ids.length;
+    function getObjectCount() external view override returns(uint256) {
+        return _chainNft.totalSupply();
     }
 
 
@@ -175,23 +162,15 @@ contract Registry is IRegistry {
     }
 
 
-    function getInfo(uint256 id) external view override returns(RegistryInfo memory info) {
-        return _info[id];
+    function getInfo(uint256 nftId) external view override returns(RegistryInfo memory info) {
+        return _info[nftId];
     }
 
-    function getOwner(uint256 id) external view override returns(address) {
-        return _owner[id];
+    function getOwner(uint256 nftId) external view override returns(address) {
+        return _chainNft.ownerOf(nftId);
     }
 
-
-    function _mint(address initialOwner)
-        internal
-        returns(uint256 id)
-    {
-        _idNext++;
-
-        id = _idNext;
-        _owner[id] = initialOwner;
-        _ids.push(id);
+    function getNftAddress() external view override returns(address nft) {
+        return address(_chainNft);
     }
 }

package/contracts/types/ChainId.sol

@@ -0,0 +1,24 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+// bytes5 (uint40) allows for chain ids up to 13 digits
+type ChainId is bytes5;
+
+// type bindings
+using {
+    eqChainId as ==,
+    neChainId as !=,
+    ChainIdLib.toInt
+} for ChainId global;
+
+// general pure free functions
+function toChainId(uint256 chainId) pure returns(ChainId) { return ChainId.wrap(bytes5(uint40(chainId))); }
+
+// pure free functions for operators
+function eqChainId(ChainId a, ChainId b) pure returns(bool isSame) { return ChainId.unwrap(a) == ChainId.unwrap(b); }
+function neChainId(ChainId a, ChainId b) pure returns(bool isDifferent) { return ChainId.unwrap(a) != ChainId.unwrap(b); }
+
+// library functions that operate on user defined type
+library ChainIdLib {
+    function toInt(ChainId chainId) internal pure returns(uint256) { return uint256(uint40(ChainId.unwrap(chainId))); }
+}

package/contracts/types/NftId.sol

@@ -0,0 +1,25 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+// uint96 allows for chain ids up to 13 digits
+type NftId is uint96;
+
+// type bindings
+using {
+    eqNftId as ==,
+    neNftId as !=,
+    NftIdLib.toInt
+} for NftId global;
+
+// general pure free functions
+function toNftId(uint256 id) pure returns(NftId) { return NftId.wrap(uint96(id)); }
+function gtz(NftId a) pure returns(bool) { return NftId.unwrap(a) > 0; }
+
+// pure free functions for operators
+function eqNftId(NftId a, NftId b) pure returns(bool isSame) { return NftId.unwrap(a) == NftId.unwrap(b); }
+function neNftId(NftId a, NftId b) pure returns(bool isDifferent) { return NftId.unwrap(a) != NftId.unwrap(b); }
+
+// library functions that operate on user defined type
+library NftIdLib {
+    function toInt(NftId nftId) internal pure returns(uint256) { return uint256(NftId.unwrap(nftId)); }
+}

package/package.json

@@ -1,6 +1,6 @@
 {
   "name": "@etherisc/gif-next",
-  "version": "0.0.2-b9b3e89",
+  "version": "0.0.2-ed4dd55",
   "description": "This is the repository for the next version of the Generic Insurance Framework (GIF) smart contracts. ",
   "main": "index.js",
   "scripts": {