@etherisc/gif-next 0.0.2-b89a442-717 → 0.0.2-b8da656-306

package/contracts/distribution/IDistributionService.sol

@@ -3,7 +3,6 @@ pragma solidity ^0.8.20;
 
 import {Amount} from "../type/Amount.sol";
 import {NftId} from "../type/NftId.sol";
-import {Fee} from "../type/Fee.sol";
 import {IPolicy} from "../instance/module/IPolicy.sol";
 import {IService} from "../shared/IService.sol";
 import {UFixed} from "../type/UFixed.sol";
@@ -27,12 +26,16 @@ interface IDistributionService is IService {
     error ErrorIDistributionServiceCommissionTooHigh(uint256 commissionPercentage, uint256 maxCommissionPercentage);
     error ErrorIDistributionServiceMinFeeTooHigh(uint256 minFee, uint256 limit);
 
+    error ErrorDistributionServiceCommissionWithdrawAmountExceedsLimit(Amount amount, Amount limit);
+    
     error ErrorDistributionServiceVariableFeesTooHight(uint256 maxDiscountPercentage, uint256 limit);
     error ErrorDistributionServiceMaxDiscountTooHigh(uint256 maxDiscountPercentage, uint256 limit);
 
     error ErrorIDistributionServiceReferralInvalid(NftId distributionNftId, ReferralId referralId);
     error ErrorDistributionServiceInvalidFeeTransferred(Amount transferredDistributionFeeAmount, Amount expectedDistributionFeeAmount);
 
+    event LogDistributionServiceCommissionWithdrawn(NftId distributorNftId, address recipient, address tokenAddress, Amount amount);
+
     function createDistributorType(
         string memory name,
         UFixed minDiscountPercentage,
@@ -71,15 +74,28 @@ interface IDistributionService is IService {
         external
         returns (ReferralId referralId);
 
+    /// @dev callback from product service when a referral is used. 
+    /// Calling this will increment the referral usage counter. 
+    function processReferral(
+        NftId distributionNftId, 
+        ReferralId referralId
+    ) external;
+
     /// @dev callback from product service when selling a policy for a specific referralId
     function processSale(
         NftId distributionNftId,
         ReferralId referralId,
-        IPolicy.Premium memory premium
+        IPolicy.PremiumInfo memory premium
     ) external;
 
     function referralIsValid(
         NftId distributorNftId,
         ReferralId referralId
     ) external view returns (bool isValid);
+
+    /// @dev Withdraw commission for the distributor
+    /// @param distributorNftId the distributor Nft Id
+    /// @param amount the amount to withdraw. If set to AMOUNT_MAX, the full commission available is withdrawn
+    /// @return withdrawnAmount the effective withdrawn amount
+    function withdrawCommission(NftId distributorNftId, Amount amount) external returns (Amount withdrawnAmount);
 }

package/contracts/examples/fire/DamageLevel.sol

@@ -0,0 +1,59 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+type DamageLevel is uint8;
+
+// type bindings
+using {
+    DamageLevelLib.eq,
+    DamageLevelLib.eqz,
+    DamageLevelLib.toInt
+} for DamageLevel global;
+
+// solhint-disable-next-line func-name-mixedcase
+function DAMAGE_SMALL() pure returns (DamageLevel) {
+    return DamageLevel.wrap(1);
+}
+
+// solhint-disable-next-line func-name-mixedcase
+function DAMAGE_MEDIUM() pure returns (DamageLevel) {
+    return DamageLevel.wrap(2);
+}
+
+// solhint-disable-next-line func-name-mixedcase
+function DAMAGE_LARGE() pure returns (DamageLevel) {
+    return DamageLevel.wrap(3);
+}
+
+library DamageLevelLib {
+
+    error ErrorDamageLeveLibInvalidDamageLevel(uint8 damageLevel);
+
+    function zero() internal pure returns (DamageLevel) {
+        return DamageLevel.wrap(0);
+    }
+
+    function toDamageLevel(uint8 damage) internal pure returns (DamageLevel) {
+        if (damage == 1) {
+            return DAMAGE_SMALL();
+        } else if (damage == 2) {
+            return DAMAGE_MEDIUM();
+        } else if (damage == 3) {
+            return DAMAGE_LARGE();
+        } else {
+            revert ErrorDamageLeveLibInvalidDamageLevel(damage);
+        }
+    }
+
+    function toInt(DamageLevel damageLevel) internal pure returns (uint8) {
+        return uint8(DamageLevel.unwrap(damageLevel));
+    }
+
+    function eq(DamageLevel a, DamageLevel b) internal pure returns (bool) {
+        return DamageLevel.unwrap(a) == DamageLevel.unwrap(b);
+    }
+
+    function eqz(DamageLevel a) internal pure returns (bool) {
+        return DamageLevel.unwrap(a) == 0;
+    }
+}

package/contracts/examples/fire/FirePool.sol

@@ -0,0 +1,75 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount, AmountLib} from "../../type/Amount.sol";
+import {BasicPool} from "../../pool/BasicPool.sol";
+import {BasicPoolAuthorization} from "../../pool/BasicPoolAuthorization.sol";
+import {Fee} from "../../type/Fee.sol";
+import {IAuthorization} from "../../authorization/IAuthorization.sol";
+import {NftId} from "../../type/NftId.sol";
+import {Seconds} from "../../type/Timestamp.sol";
+import {UFixed} from "../../type/UFixed.sol";
+
+contract FirePool is
+    BasicPool
+{
+    
+    constructor(
+        address registry,
+        NftId instanceNftId,
+        string memory componentName,
+        address token,
+        IAuthorization authorization
+    ) 
+    {
+        address initialOwner = msg.sender;
+        _intialize(
+            registry,
+            instanceNftId,
+            componentName,
+            token,
+            authorization,
+            initialOwner);
+    }
+
+    function _intialize(
+        address registry,
+        NftId instanceNftId,
+        string memory componentName,
+        address token,
+        IAuthorization authorization,
+        address initialOwner
+    )
+        internal
+        initializer
+    {
+        _initializeBasicPool(
+            registry,
+            instanceNftId,
+            authorization,
+            token,
+            componentName,
+            initialOwner);
+    }
+
+    function createBundle(
+        Fee memory fee,
+        Amount initialAmount,
+        Seconds lifetime
+    )
+        external
+        virtual 
+        restricted()
+        returns(NftId bundleNftId, Amount netStakedAmount)
+    {
+        address owner = msg.sender;
+        bundleNftId = _createBundle(
+            owner,
+            fee,
+            lifetime,
+            "" // filter
+        );
+        netStakedAmount = _stake(bundleNftId, initialAmount);
+    }
+
+}

package/contracts/examples/fire/FirePoolAuthorization.sol

@@ -0,0 +1,34 @@
+
+
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {BasicPoolAuthorization} from "../../pool/BasicPoolAuthorization.sol";
+import {FirePool} from "./FirePool.sol";
+import {IAccess} from "../../../contracts/authorization/IAccess.sol";
+import {PUBLIC_ROLE} from "../../../contracts/type/RoleId.sol";
+
+contract FirePoolAuthorization
+    is BasicPoolAuthorization
+{
+
+    constructor(string memory poolName)
+        BasicPoolAuthorization(poolName)
+    {}
+
+
+    function _setupTargetAuthorizations()
+        internal
+        virtual override
+    {
+        super._setupTargetAuthorizations();
+        IAccess.FunctionInfo[] storage functions;
+
+        // authorize public role (open access to any account, only allows to lock target)
+        functions = _authorizeForTarget(getTargetName(), PUBLIC_ROLE());
+        // TODO: FirePool.createBundle must require a custom role (e.g. INVESTOR) instead of PUBLIC_ROLE
+        _authorize(functions, FirePool.createBundle.selector, "createBundle");
+    }
+
+}
+

package/contracts/examples/fire/FireProduct.sol

@@ -0,0 +1,410 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ACTIVE, COLLATERALIZED, PAUSED} from "../../type/StateId.sol";
+import {Amount, AmountLib} from "../../type/Amount.sol";
+import {BasicProduct} from "../../product/BasicProduct.sol";
+import {ClaimId} from "../../type/ClaimId.sol";
+import {DamageLevel, DAMAGE_SMALL, DAMAGE_MEDIUM, DAMAGE_LARGE} from "./DamageLevel.sol";
+import {IAuthorization} from "../../authorization/IAuthorization.sol";
+import {IPolicy} from "../../instance/module/IPolicy.sol";
+import {NftId} from "../../type/NftId.sol";
+import {PayoutId} from "../../type/PayoutId.sol";
+import {ReferralLib} from "../../type/Referral.sol";
+import {RiskId, RiskIdLib} from "../../type/RiskId.sol";
+import {Seconds} from "../../type/Seconds.sol";
+import {StateId} from "../../type/StateId.sol";
+import {Timestamp, TimestampLib} from "../../type/Timestamp.sol";
+import {UFixed, UFixedLib} from "../../type/UFixed.sol";
+
+uint64 constant SPECIAL_ROLE_INT = 11111;
+
+// solhint-disable-next-line func-name-mixedcase
+function HALF_YEAR() pure returns (Seconds) {
+    return Seconds.wrap(180 * 86400);
+}
+
+// solhint-disable-next-line func-name-mixedcase
+function ONE_YEAR() pure returns (Seconds) {
+    return Seconds.wrap(360 * 86400);
+}
+
+/// @dev This is the product component for the fire insurance example. 
+/// It show how to insure a house for a given suminsured in a city. 
+/// The risk is based on the city. 
+/// If a fire is reported in the city, the policy holder is able to submit a claim and get a payout. 
+contract FireProduct is 
+    BasicProduct
+{
+    struct Fire {
+        string cityName;
+        DamageLevel damageLevel;
+        Timestamp reportedAt;
+    }
+
+    error ErrorFireProductCityUnknown(string cityName);
+    error ErrorFireProductTimestampTooEarly();
+    error ErrorFireProductFireAlreadyReported();
+    error ErrorFireProductAlreadyClaimed();
+    error ErrorFireProductPolicyNotActive();
+    error ErrorFireProductPolicyNotYetActive(Timestamp activateAt);
+    error ErrorFireProductPolicyExpired(Timestamp expiredAt);
+    error ErrorFireProductUnknownDamageLevel(DamageLevel damageLevel);
+    error ErrorFireProductFireUnknown(uint256 fireId);
+    error ErrorFireProductNotPolicyOwner(NftId nftId, address owner);
+
+    string[] private _cities;
+    // map from city name to the RiskId
+    mapping(string cityName => RiskId risk) private _riskMapping;
+
+    // map from city name to the damage level and the time of the report
+    mapping(uint256 fireId => Fire) private _fires;
+    mapping(uint256 fireId => mapping (NftId policyId => bool claimed)) private _claimed;
+
+    constructor(
+        address registry,
+        NftId instanceNftid,
+        string memory componentName,
+        address token,
+        address pool,
+        IAuthorization authorization
+    )
+    {
+        address initialOwner = msg.sender;
+        _initialize(
+            registry,
+            instanceNftid,
+            componentName,
+            token,
+            pool,
+            authorization,
+            initialOwner);
+    }
+
+    function _initialize(
+        address registry,
+        NftId instanceNftid,
+        string memory componentName,
+        address token,
+        address pool,
+        IAuthorization authorization,
+        address initialOwner
+    )
+        internal
+        initializer
+    {
+        _initializeBasicProduct(
+            registry,
+            instanceNftid,
+            authorization,
+            initialOwner,
+            componentName,
+            token,
+            false,
+            pool,
+            address(0));  // no distribution
+    }
+    
+    function cities() public view returns (uint256) {
+        return _cities.length;
+    }
+
+    function city(uint256 idx) public view returns (string memory) {
+        return _cities[idx];
+    }
+
+    function riskId(string memory cityName) public view returns (RiskId) {
+        return _riskMapping[cityName];
+    }
+
+    function pauseCity(
+        string memory cityName
+    ) 
+        public 
+        restricted()
+    {
+        if (_riskMapping[cityName].eqz()) {
+            revert ErrorFireProductCityUnknown(cityName);
+        }
+
+        _updateRiskState(
+            _riskMapping[cityName],
+            PAUSED()
+        );
+    }
+
+    function unpauseCity(
+        string memory cityName
+    ) 
+        public 
+        restricted()
+    {
+        if (_riskMapping[cityName].eqz()) {
+            revert ErrorFireProductCityUnknown(cityName);
+        }
+
+        _updateRiskState(
+            _riskMapping[cityName],
+            ACTIVE()
+        );
+    }
+
+    function calculatePremium(
+        string memory cityName,
+        Amount sumInsured,
+        Seconds lifetime,
+        NftId bundleNftId
+    ) 
+        public
+        view
+        returns (Amount premiumAmount)
+    {
+        RiskId riskId = _riskMapping[cityName];
+        if (riskId.eqz()) {
+            revert ErrorFireProductCityUnknown(cityName);
+        }
+        premiumAmount = calculatePremium( 
+            sumInsured,
+            riskId,
+            lifetime,
+            "",
+            bundleNftId,
+            ReferralLib.zero());
+    }
+
+    function calculateNetPremium(
+        Amount sumInsured,
+        RiskId,
+        Seconds lifetime,
+        bytes memory
+    )
+        external
+        view
+        virtual override
+        returns (Amount netPremiumAmount)
+    {
+        UFixed numDays = UFixedLib.toUFixed(lifetime.toInt() / 86400);
+        // to simplify time calculation we assume 360 days per year
+        UFixed pctOfYear = numDays / UFixedLib.toUFixed(360);
+        Amount premiumPerYear = AmountLib.toAmount(sumInsured.toInt() / 20);
+        return  premiumPerYear.multiplyWith(pctOfYear);
+    }
+
+    function createApplication(
+        string memory cityName,
+        Amount sumInsured,
+        Seconds lifetime,
+        NftId bundleNftId
+    )
+        public
+        restricted()
+        returns (NftId policyNftId)
+    {
+        address applicationOwner = msg.sender;
+        RiskId riskId = initializeCity(cityName);
+
+        Amount premiumAmount = calculatePremium(
+            sumInsured,
+            riskId,
+            lifetime,
+            "",
+            bundleNftId,
+            ReferralLib.zero());
+
+        return _createApplication(
+            applicationOwner,
+            riskId,
+            sumInsured,
+            premiumAmount,
+            lifetime,
+            bundleNftId,
+            ReferralLib.zero(),
+            ""
+        );
+    }
+
+    function initializeCity(
+        string memory cityName
+    ) 
+        public
+        returns (RiskId riskId) 
+    {
+        if (! _riskMapping[cityName].eqz()) {
+            return _riskMapping[cityName];
+        }
+        _cities.push(cityName);
+        riskId = RiskIdLib.toRiskId(cityName);
+        _createRisk(riskId, "");
+        _riskMapping[cityName] = riskId;
+    }
+
+    /// @dev Calling this method will lock the sum insured amount in the pool and activate the policy at the given time. 
+    /// It will also collect the tokens payment for the premium. An approval with the correct amount towards the TokenHandler of the product is therefor required. 
+    function createPolicy(
+        NftId policyNftId,
+        Timestamp activateAt
+    ) 
+        public 
+        restricted()
+        onlyOwner()
+    {
+        _createPolicy(policyNftId, activateAt);
+        _collectPremium(policyNftId, activateAt);
+    }
+
+    /// @dev Decline the policy application
+    function decline(
+        NftId policyNftId
+    ) 
+        public 
+        restricted()
+        onlyOwner()
+    {
+        _decline(policyNftId);
+    }
+
+    function expire(
+        NftId policyNftId,
+        Timestamp expireAt
+    ) 
+        public 
+        restricted()
+        onlyOwner()
+        returns (Timestamp)
+    {
+        return _expire(policyNftId, expireAt);
+    }
+
+    function close(
+        NftId policyNftId
+    ) 
+        public 
+        restricted()
+        onlyOwner()
+    {
+        _close(policyNftId);
+    }
+
+    function reportFire(
+        uint256 fireId,
+        string memory cityName,
+        DamageLevel damageLevel,
+        Timestamp reportedAt
+    ) 
+        public 
+        restricted()
+    {
+        if (_riskMapping[cityName].eqz()) {
+            revert ErrorFireProductCityUnknown(cityName);
+        }
+
+        if (reportedAt < TimestampLib.blockTimestamp()) {
+            revert ErrorFireProductTimestampTooEarly();
+        }
+
+        if (! _fires[fireId].reportedAt.eqz()) {
+            revert ErrorFireProductFireAlreadyReported();
+        }
+
+        _fires[fireId] = Fire({
+            cityName: cityName,
+            damageLevel: damageLevel,
+            reportedAt: reportedAt
+        });
+    }
+
+    function fire(uint256 fireId) public view returns (Fire memory) {
+        return _fires[fireId];
+    }
+
+    function submitClaim(
+        NftId policyNftId,
+        uint256 fireId
+    ) 
+        public 
+        restricted()
+        onlyNftOwner(policyNftId)
+        returns (ClaimId claimId, PayoutId payoutId) 
+    {
+        IPolicy.PolicyInfo memory policyInfo = _getInstanceReader().getPolicyInfo(policyNftId);
+        _checkClaimConditions(policyNftId, fireId, policyInfo);
+        
+        Fire memory fire = _fires[fireId];
+        _claimed[fireId][policyNftId] = true;
+
+        Amount claimAmount = _getClaimAmount(policyNftId, policyInfo.sumInsuredAmount, fire.damageLevel);
+        
+        claimId = _submitClaim(policyNftId, claimAmount, abi.encodePacked(fireId));
+        _confirmClaim(policyNftId, claimId, claimAmount, "");
+
+        payoutId = _createPayout(policyNftId, claimId, claimAmount, "");
+        _processPayout(policyNftId, payoutId);
+    }
+
+    function _checkClaimConditions(
+        NftId policyNftId,
+        uint256 fireId,
+        IPolicy.PolicyInfo memory policyInfo
+    ) 
+        internal
+    {
+        // check fire exists
+        if (_fires[fireId].reportedAt.eqz()) {
+            revert ErrorFireProductFireUnknown(fireId);
+        }
+
+        // check policy has not been claimed yet for this fire
+        if (_claimed[fireId][policyNftId]) {
+            revert ErrorFireProductAlreadyClaimed();
+        }
+
+        StateId policyState = _getInstanceReader().getPolicyState(policyNftId);
+        
+        if (! policyState.eq(COLLATERALIZED())) {
+            revert ErrorFireProductPolicyNotActive();
+        }
+
+        Fire memory fire = _fires[fireId];
+
+        if (fire.reportedAt < policyInfo.activatedAt) {
+            revert ErrorFireProductPolicyNotYetActive(policyInfo.activatedAt);
+        }
+
+        if (fire.reportedAt > policyInfo.expiredAt) {
+            revert ErrorFireProductPolicyExpired(policyInfo.expiredAt);
+        }
+    }
+
+    function _getClaimAmount(
+        NftId policyNftId,
+        Amount sumInsured,
+        DamageLevel damageLevel
+    ) 
+        internal
+        view
+        returns (Amount)
+    {
+        Amount claimAmount = sumInsured.multiplyWith(_damageLevelToPayoutPercentage(damageLevel));
+        Amount maxPayoutRemaining = _getInstanceReader().getRemainingClaimableAmount(policyNftId);
+
+        // if payout is higher than the remaining maximum payout, then claim what is remaining
+        if (maxPayoutRemaining < claimAmount) {
+            return maxPayoutRemaining;
+        }
+
+        return claimAmount;
+    }
+
+    function _damageLevelToPayoutPercentage(DamageLevel damageLevel) internal pure returns (UFixed) {
+        if (damageLevel.eq(DAMAGE_SMALL())) {
+            return UFixedLib.toUFixed(25, -2);
+        } else if (damageLevel.eq(DAMAGE_MEDIUM())) {
+            return UFixedLib.toUFixed(5, -1);
+        } else if (damageLevel.eq(DAMAGE_LARGE())) {
+            return UFixedLib.toUFixed(1);
+        } else {
+            revert ErrorFireProductUnknownDamageLevel(damageLevel);
+        }
+    }
+
+}

package/contracts/examples/fire/FireProductAuthorization.sol

@@ -0,0 +1,45 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {BasicProductAuthorization} from "../../product/BasicProductAuthorization.sol";
+import {FireProduct} from "./FireProduct.sol";
+import {IAccess} from "../../../contracts/authorization/IAccess.sol";
+import {PRODUCT_OWNER_ROLE, PUBLIC_ROLE} from "../../../contracts/type/RoleId.sol";
+
+
+contract FireProductAuthorization
+    is BasicProductAuthorization
+{
+
+    constructor(string memory poolName)
+        BasicProductAuthorization(poolName)
+    {}
+
+    function _setupTargetAuthorizations()
+        internal
+        virtual override
+    {
+        super._setupTargetAuthorizations();
+        IAccess.FunctionInfo[] storage functions;
+
+        // authorize public role (open access to any account, only allows to lock target)
+        functions = _authorizeForTarget(getTargetName(), PUBLIC_ROLE());
+        // fully public functions
+        _authorize(functions, FireProduct.createApplication.selector, "createApplication");
+        
+        // only owner
+        _authorize(functions, FireProduct.createPolicy.selector, "createPolicy"); 
+        _authorize(functions, FireProduct.decline.selector, "decline"); 
+        _authorize(functions, FireProduct.expire.selector, "expire"); 
+        _authorize(functions, FireProduct.close.selector, "close"); 
+
+        // only policy nft owner
+        _authorize(functions, FireProduct.submitClaim.selector, "submitClaim"); 
+
+        functions = _authorizeForTarget(getTargetName(), PRODUCT_OWNER_ROLE());
+        // TODO: add custom role for fire reporter
+        _authorize(functions, FireProduct.reportFire.selector, "reportFire");
+    }
+
+}
+

package/contracts/examples/fire/FireUSD.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
+
+/// @dev FireUSD is a stablecoin with 6 decimals and an initial supply of 1 Billion tokens. 
+contract FireUSD is ERC20 {
+
+    string public constant NAME = "FireUSD";
+    string public constant SYMBOL = "HOT";
+    uint8 public constant DECIMALS = 6;
+    uint256 public constant INITIAL_SUPPLY = 10**12 * 10**DECIMALS; // 1'000'000'000'000
+    
+    constructor()
+        ERC20(NAME, SYMBOL)
+    {
+        _mint(
+            _msgSender(),
+            INITIAL_SUPPLY
+        );   
+    }
+
+    function decimals() public pure override returns(uint8) {
+        return DECIMALS;
+    }
+}