@etherisc/gif-next 0.0.2-b38343e-249 → 0.0.2-b3a8633-027

package/contracts/instance/base/ComponentService.sol

@@ -1,134 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {IComponent} from "../../components/IComponent.sol";
-import {IRegistry} from "../../registry/IRegistry.sol";
-import {IRegistryService} from "../../registry/IRegistryService.sol";
-import {IInstance} from "../../instance/IInstance.sol";
-import {IAccess} from "../module/IAccess.sol";
-import {ObjectType, INSTANCE, REGISTRY} from "../../types/ObjectType.sol";
-import {NftId} from "../../types/NftId.sol";
-import {RoleId} from "../../types/RoleId.sol";
-
-import {Service} from "../../shared/Service.sol";
-import {InstanceService} from "../InstanceService.sol";
-import {InstanceAccessManager} from "../InstanceAccessManager.sol";
-
-abstract contract ComponentService is Service {
-
-    error ErrorComponentServiceAlreadyRegistered(address component, NftId nftId);
-    error ErrorComponentServiceNotComponent(address component);
-    error ErrorComponentServiceInvalidType(address component, ObjectType requiredType, ObjectType componentType);
-    error ErrorComponentServiceSenderNotOwner(address component, address initialOwner, address sender);
-    error ErrorComponentServiceExpectedRoleMissing(NftId instanceNftId, RoleId requiredRole, address sender);
-    error ErrorComponentServiceComponentLocked(address component);
-
-    /// @dev modifier to check if caller is a registered service
-    modifier onlyService() {
-        address caller = msg.sender;
-        require(getRegistry().isRegisteredService(caller), "ERROR_NOT_SERVICE");
-        _;
-    }
-
-    // view functions
-
-    function getRegistryService() public view virtual returns (IRegistryService) {
-        address service = getRegistry().getServiceAddress(REGISTRY(), getMajorVersion());
-        return IRegistryService(service);
-    }
-
-    function getInstanceService() public view returns (InstanceService) {
-        address service = getRegistry().getServiceAddress(INSTANCE(), getMajorVersion());
-        return InstanceService(service);
-    }
-
-    // internal functions
-    function _checkComponentForRegistration(
-        address componentAddress,
-        ObjectType requiredType,
-        RoleId requiredRole
-    )
-        internal
-        view
-        returns (
-            IComponent component,
-            address owner,
-            IInstance instance,
-            NftId instanceNftId
-        )
-    {
-        // component may only be registerd by initial owner of component
-        owner = msg.sender;
-
-        // check component has not already been registerd
-        NftId compoentNftId = getRegistry().getNftId(componentAddress);
-        if(compoentNftId.gtz()) {
-            revert ErrorComponentServiceAlreadyRegistered(componentAddress, compoentNftId);
-        }
-
-        // check this is a component
-        component = IComponent(componentAddress);
-        if(!component.supportsInterface(type(IComponent).interfaceId)) {
-            revert ErrorComponentServiceNotComponent(componentAddress);
-        }
-
-        // check component is of required type
-        IRegistry.ObjectInfo memory componentInfo = component.getInitialInfo();
-        if(componentInfo.objectType != requiredType) {
-            revert ErrorComponentServiceInvalidType(componentAddress, requiredType, componentInfo.objectType);
-        }
-
-        // check msg.sender is component owner
-        address initialOwner = componentInfo.initialOwner;
-        if(owner != initialOwner) {
-            revert ErrorComponentServiceSenderNotOwner(componentAddress, componentInfo.initialOwner, owner);
-        }
-
-        // check instance has assigned required role to owner
-        instanceNftId = componentInfo.parentNftId;
-        instance = _getInstance(instanceNftId);
-        bool hasRole = getInstanceService().hasRole(
-            owner, 
-            requiredRole, 
-            address(instance));
-
-        if(!hasRole) {
-            revert ErrorComponentServiceExpectedRoleMissing(instanceNftId, requiredRole, owner);
-        }
-    }
-
-    // internal view functions
-
-    function _getInstance(NftId instanceNftId) internal view returns (IInstance) {
-        IRegistry.ObjectInfo memory instanceInfo = getRegistry().getObjectInfo(instanceNftId);
-        return IInstance(instanceInfo.objectAddress);
-    }
-
-    function _getAndVerifyComponentInfoAndInstance(
-        //address component,
-        ObjectType expectedType
-    )
-        internal
-        view
-        returns(
-            IRegistry.ObjectInfo memory info, 
-            IInstance instance
-        )
-    {
-        IRegistry registry = getRegistry();
-        //TODO redundant check -> just check type
-        //NftId componentNftId = registry.getNftId(component); 
-        //require(componentNftId.gtz(), "ERROR_COMPONENT_UNKNOWN");
-
-        info = registry.getObjectInfo(msg.sender);
-        require(info.objectType == expectedType, "OBJECT_TYPE_INVALID");
-
-        address instanceAddress = registry.getObjectInfo(info.parentNftId).objectAddress;
-        instance = IInstance(instanceAddress);
-
-        InstanceAccessManager accessManager = InstanceAccessManager(instance.authority());
-        if (accessManager.isTargetLocked(info.objectAddress)) {
-            revert IAccess.ErrorIAccessTargetLocked(info.objectAddress);
-        }
-    }
-}

package/contracts/instance/base/KeyValueStore.sol

@@ -1,172 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {Blocknumber, blockBlocknumber, zeroBlocknumber} from "../../types/Blocknumber.sol";
-import {Key32, KeyId, Key32Lib} from "../../types/Key32.sol";
-import {NftId} from "../../types/NftId.sol";
-import {ObjectType} from "../../types/ObjectType.sol";
-import {StateId, ACTIVE} from "../../types/StateId.sol";
-import {Timestamp, TimestampLib} from "../../types/Timestamp.sol";
-
-import {Lifecycle} from "./Lifecycle.sol";
-import {IKeyValueStore} from "./IKeyValueStore.sol";
-
-contract KeyValueStore is Lifecycle, IKeyValueStore {
-
-    mapping(Key32 key32 => Value value) private _value;
-
-    function create(
-        Key32 key32, 
-        bytes memory data
-    )
-        internal
-    {
-        _create(key32, data);
-    }
-
-    function _create(
-        Key32 key32, 
-        bytes memory data
-    )
-        internal
-    {
-        ObjectType objectType = key32.toObjectType();
-        require(objectType.gtz(), "ERROR:KVS-010:TYPE_UNDEFINED");
-
-        Metadata storage metadata = _value[key32].metadata;
-        require(metadata.state.eqz(), "ERROR:KVS-012:ALREADY_CREATED");
-
-        address createdBy = msg.sender;
-        Blocknumber blocknumber = blockBlocknumber();
-        StateId initialState = hasLifecycle(objectType) ? getInitialState(objectType) : ACTIVE();
-
-        // set metadata
-        metadata.objectType = objectType;
-        metadata.state = initialState;
-        metadata.updatedBy = createdBy;
-        metadata.updatedIn = blocknumber;
-        metadata.createdIn = blocknumber;
-
-        // set data
-        _value[key32].data = data;
-
-        // solhint-disable-next-line avoid-tx-origin
-        emit LogInfoCreated(key32.toObjectType(), key32.toKeyId(), initialState, createdBy, tx.origin);
-    }
-
-    function update(
-        Key32 key32, 
-        bytes memory data,
-        StateId state
-    ) 
-        internal
-    {
-        _update(key32, data, state);
-    }
-
-    function _update(
-        Key32 key32, 
-        bytes memory data,
-        StateId state
-    ) 
-        internal
-    {
-        require(state.gtz(), "ERROR:KVS-020:STATE_UNDEFINED");
-        Metadata storage metadata = _value[key32].metadata;
-        StateId stateOld = metadata.state;
-        require(stateOld.gtz(), "ERROR:KVS-021:NOT_EXISTING");
-
-        // update data
-        _value[key32].data = data;
-
-        // update metadata (and state)
-        address updatedBy = msg.sender;
-        Blocknumber lastUpdatedIn = metadata.updatedIn;
-        metadata.state = state;
-        metadata.updatedBy = updatedBy;
-        metadata.updatedIn = blockBlocknumber();
-
-        // create log entries
-        // solhint-disable avoid-tx-origin
-        emit LogStateUpdated(key32.toObjectType(), key32.toKeyId(), state, stateOld, updatedBy, tx.origin, lastUpdatedIn);
-        emit LogInfoUpdated(key32.toObjectType(), key32.toKeyId(), state, updatedBy, tx.origin, lastUpdatedIn);
-        // solhing-enable
-    }
-
-    function updateData(Key32 key32, bytes memory data) 
-        internal
-    {
-        _updateData(key32, data);
-    }
-
-    function _updateData(Key32 key32, bytes memory data) 
-        internal
-    {
-        Metadata storage metadata = _value[key32].metadata;
-        StateId state = metadata.state;
-        require(state.gtz(), "ERROR:KVS-030:NOT_EXISTING");
-
-        // update data
-        _value[key32].data = data;
-
-        // update metadata
-        address updatedBy = msg.sender;
-        Blocknumber lastUpdatedIn = metadata.updatedIn;
-        metadata.updatedBy = updatedBy;
-        metadata.updatedIn = blockBlocknumber();
-
-        // create log entry
-        // solhint-disable-next-line avoid-tx-origin
-        emit LogInfoUpdated(key32.toObjectType(), key32.toKeyId(), state, updatedBy, tx.origin, lastUpdatedIn);
-    }
-
-    function updateState(Key32 key32, StateId state)
-        internal
-    {
-        _updateState(key32, state);
-    }
-
-    function _updateState(Key32 key32, StateId state)
-        internal
-    {
-        require(state.gtz(), "ERROR:KVS-040:STATE_UNDEFINED");
-        Metadata storage metadata = _value[key32].metadata;
-        StateId stateOld = metadata.state;
-        require(stateOld.gtz(), "ERROR:KVS-041:NOT_EXISTING");
-
-        // update metadata (and state)
-        address updatedBy = msg.sender;
-        Blocknumber lastUpdatedIn = metadata.updatedIn;
-        metadata.state = state;
-        metadata.updatedBy = updatedBy;
-        metadata.updatedIn = blockBlocknumber();
-
-        // create log entry
-        // solhint-disable-next-line avoid-tx-origin
-        emit LogStateUpdated(key32.toObjectType(), key32.toKeyId(), state, stateOld, updatedBy, tx.origin, lastUpdatedIn);
-    }
-
-    function exists(Key32 key32) public view returns (bool) {
-        return _value[key32].metadata.state.gtz();
-    }
-
-    function get(Key32 key32) public view returns (Value memory value) {
-        return _value[key32];
-    }
-
-    function getMetadata(Key32 key32) public view returns (Metadata memory metadata) {
-        return _value[key32].metadata;
-    }
-
-    function getData(Key32 key32) public view returns (bytes memory data) {
-        return _value[key32].data;
-    }
-
-    function getState(Key32 key32) public view returns (StateId state) {
-        return _value[key32].metadata.state;
-    }
-
-    function toKey32(ObjectType objectType, KeyId id) external pure override returns(Key32) {
-        return Key32Lib.toKey32(objectType, id);
-    }
-}

package/contracts/instance/base/Lifecycle.sol

@@ -1,100 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {NftId} from "../../types/NftId.sol";
-import {ObjectType, COMPONENT, BUNDLE, POLICY, RISK} from "../../types/ObjectType.sol";
-import {StateId, ACTIVE, PAUSED, ARCHIVED, CLOSED, APPLIED, UNDERWRITTEN, REVOKED, DECLINED} from "../../types/StateId.sol";
-import {ILifecycle} from "./ILifecycle.sol";
-
-contract Lifecycle is ILifecycle {
-    mapping(ObjectType objectType => StateId initialState)
-        private _initialState;
-
-    mapping(ObjectType objectType => mapping(StateId stateFrom => mapping(StateId stateTo => bool isValid)))
-        private _isValidTransition;
-
-    constructor() {
-        _setupBundleLifecycle();
-        _setupComponentLifecycle();
-        _setupPolicyLifecycle();
-        _setupRiskLifecycle();
-    }
-
-    function hasLifecycle(
-        ObjectType objectType
-    )
-        public
-        view
-        override
-        returns (bool)
-    {
-        return _initialState[objectType].gtz();
-    }
-
-    function getInitialState(
-        ObjectType objectType
-    )
-        public
-        view
-        returns (StateId)
-    {
-        return _initialState[objectType];
-    }
-
-    function checkTransition(
-        ObjectType objectType,
-        StateId fromId,
-        StateId toId
-    )
-        public
-        view
-    {
-        // return if no life cycle support
-        if (_initialState[objectType].eqz()) {
-            return;
-        }
-
-        // enforce valid state transition
-        if (!_isValidTransition[objectType][fromId][toId]) {
-            revert ErrorInvalidStateTransition(objectType, fromId, toId);
-        }
-    }
-
-    function isValidTransition(
-        ObjectType objectType,
-        StateId fromId,
-        StateId toId
-    ) public view returns (bool) {
-        return _isValidTransition[objectType][fromId][toId];
-    }
-
-    function _setupComponentLifecycle() internal {
-        _initialState[COMPONENT()] = ACTIVE();
-        _isValidTransition[COMPONENT()][ACTIVE()][PAUSED()] = true;
-        _isValidTransition[COMPONENT()][PAUSED()][ACTIVE()] = true;
-        _isValidTransition[COMPONENT()][PAUSED()][ARCHIVED()] = true;
-    }
-
-    function _setupBundleLifecycle() internal {
-        _initialState[BUNDLE()] = ACTIVE();
-        _isValidTransition[BUNDLE()][ACTIVE()][PAUSED()] = true;
-        _isValidTransition[BUNDLE()][PAUSED()][ACTIVE()] = true;
-        _isValidTransition[BUNDLE()][PAUSED()][CLOSED()] = true;
-    }
-
-    function _setupPolicyLifecycle() internal {
-        _initialState[POLICY()] = APPLIED();
-        _isValidTransition[POLICY()][APPLIED()][REVOKED()] = true;
-        _isValidTransition[POLICY()][APPLIED()][DECLINED()] = true;
-        _isValidTransition[POLICY()][APPLIED()][UNDERWRITTEN()] = true;
-        _isValidTransition[POLICY()][UNDERWRITTEN()][ACTIVE()] = true;
-        _isValidTransition[POLICY()][ACTIVE()][CLOSED()] = true;
-    }
-
-    function _setupRiskLifecycle() internal {
-        _initialState[RISK()] = ACTIVE();
-        _isValidTransition[RISK()][ACTIVE()][PAUSED()] = true;
-        _isValidTransition[RISK()][PAUSED()][ACTIVE()] = true;
-        _isValidTransition[RISK()][PAUSED()][ARCHIVED()] = true;
-    }
-}

package/contracts/instance/module/ITreasury.sol

@@ -1,23 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
-
-import {Fee} from "../../types/Fee.sol";
-import {NftId} from "../../types/NftId.sol";
-import {TokenHandler} from "../../shared/TokenHandler.sol";
-
-interface ITreasury {
-    struct TreasuryInfo {
-        IERC20Metadata token;
-        TokenHandler tokenHandler;
-        NftId distributionNftId;
-        NftId poolNftId;
-        Fee distributionFee; // default distribution fee (no referral id)
-        Fee productFee; // product fee on net premium
-        Fee processingFee; // product fee on payout amounts
-        Fee poolFee; // pool fee on net premium
-        Fee stakingFee; // pool fee on staked capital from investor
-        Fee performanceFee; // pool fee on profits from capital investors
-    }
-}

package/contracts/instance/service/ApplicationService.sol

@@ -1,268 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {IRisk} from "../module/IRisk.sol";
-import {IService} from "./IApplicationService.sol";
-
-import {IRegistry} from "../../registry/IRegistry.sol";
-import {IProductComponent} from "../../components/IProductComponent.sol";
-import {Product} from "../../components/Product.sol";
-import {IPoolComponent} from "../../components/IPoolComponent.sol";
-import {IDistributionComponent} from "../../components/IDistributionComponent.sol";
-import {IInstance} from "../IInstance.sol";
-import {IPolicy} from "../module/IPolicy.sol";
-import {IRisk} from "../module/IRisk.sol";
-import {IBundle} from "../module/IBundle.sol";
-import {IProductService} from "./IProductService.sol";
-import {ITreasury} from "../module/ITreasury.sol";
-import {ISetup} from "../module/ISetup.sol";
-
-import {TokenHandler} from "../../shared/TokenHandler.sol";
-
-import {IVersionable} from "../../shared/IVersionable.sol";
-import {Versionable} from "../../shared/Versionable.sol";
-
-import {Timestamp, TimestampLib, zeroTimestamp} from "../../types/Timestamp.sol";
-import {UFixed, UFixedLib} from "../../types/UFixed.sol";
-import {Blocknumber, blockNumber} from "../../types/Blocknumber.sol";
-import {ObjectType, INSTANCE, PRODUCT, POOL, APPLICATION, POLICY, BUNDLE} from "../../types/ObjectType.sol";
-import {APPLIED, REVOKED, UNDERWRITTEN, ACTIVE, KEEP_STATE, CLOSED} from "../../types/StateId.sol";
-import {NftId, NftIdLib, zeroNftId} from "../../types/NftId.sol";
-import {Fee, FeeLib} from "../../types/Fee.sol";
-import {ReferralId} from "../../types/Referral.sol";
-import {RiskId} from "../../types/RiskId.sol";
-import {StateId} from "../../types/StateId.sol";
-import {Version, VersionLib} from "../../types/Version.sol";
-
-import {ComponentService} from "../base/ComponentService.sol";
-import {InstanceReader} from "../InstanceReader.sol";
-import {IApplicationService} from "./IApplicationService.sol";
-import {IBundleService} from "./IBundleService.sol";
-import {IPoolService} from "./IPoolService.sol";
-import {IService} from "../../shared/IService.sol";
-import {Service} from "../../shared/Service.sol";
-
-
-contract ApplicationService is 
-    ComponentService, 
-    IApplicationService
-{
-
-    function _initialize(
-        address owner, 
-        bytes memory data
-    )
-        internal
-        virtual override
-        initializer()
-    {
-        // TODO check this, might no longer be the way, refactor if necessary
-        address registryAddress;
-        address initialOwner;
-        (registryAddress, initialOwner) = abi.decode(data, (address, address));
-
-        initializeService(registryAddress, owner);
-        registerInterface(type(IApplicationService).interfaceId);
-    }
-
-
-    function getDomain() public pure override(IService, Service) returns(ObjectType) {
-        return APPLICATION();
-    }
-
-
-    function create(
-        address applicationOwner,
-        RiskId riskId,
-        uint256 sumInsuredAmount,
-        uint256 lifetime,
-        NftId bundleNftId,
-        ReferralId referralId,
-        bytes memory applicationData
-    )
-        external
-        virtual
-        returns (NftId applicationNftId)
-    {
-        (IRegistry.ObjectInfo memory productInfo, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
-        // TODO: add validations (see create bundle in pool service)
-
-        applicationNftId = getRegistryService().registerPolicy(
-            IRegistry.ObjectInfo(
-                zeroNftId(),
-                productInfo.nftId,
-                POLICY(),
-                false, // intercepting property for policies is defined on product
-                address(0),
-                applicationOwner,
-                ""
-            )
-        );
-
-        (uint256 premiumAmount,,,,) = calculatePremium(
-            riskId,
-            sumInsuredAmount,
-            lifetime,
-            applicationData,
-            bundleNftId,
-            referralId
-        );
-
-        IPolicy.PolicyInfo memory policyInfo = IPolicy.PolicyInfo(
-            productInfo.nftId,
-            bundleNftId,
-            referralId,
-            riskId,
-            sumInsuredAmount,
-            premiumAmount,
-            0,
-            lifetime,
-            applicationData,
-            "",
-            0,
-            0,
-            0,
-            zeroTimestamp(),
-            zeroTimestamp(),
-            zeroTimestamp()
-        );
-        
-        instance.createApplication(applicationNftId, policyInfo);
-        instance.updateApplicationState(applicationNftId, APPLIED());
-
-        // TODO: add logging
-    }
-
-
-    function renew(
-        NftId policyNftId, // policy to be renewd (renewal inherits policy attributes)
-        NftId bundleNftId // will likely need a newer bundle for underwriting
-    )
-        external
-        virtual override
-        returns (NftId applicationNftId)
-    {
-
-    }
-
-
-    function adjust(
-        NftId applicationNftId,
-        RiskId riskId,
-        NftId bundleNftId,
-        ReferralId referralId,
-        uint256 sumInsuredAmount,
-        uint256 lifetime,
-        bytes memory applicationData
-    )
-        external
-        virtual override
-    {
-
-    }
-
-    function revoke(NftId applicationNftId)
-        external
-        virtual override
-    {
-        (, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
-        instance.updateApplicationState(applicationNftId, REVOKED());
-    }
-
-
-    function calculatePremium(
-        RiskId riskId,
-        uint256 sumInsuredAmount,
-        uint256 lifetime,
-        bytes memory applicationData,
-        NftId bundleNftId,
-        ReferralId referralId
-    )
-        public
-        view
-        virtual override
-        returns (
-            uint256 premiumAmount,
-            uint256 distributionFeeAmount,
-            uint256 productFeeAmount,
-            uint256 poolFeeAmount,
-            uint256 bundleFeeAmount
-        )
-    {
-        Product product = _getAndVerifyInstanceAndProduct();
-        uint256 netPremiumAmount = product.calculateNetPremium(
-            sumInsuredAmount,
-            riskId,
-            lifetime,
-            applicationData
-        );
-
-        (
-            productFeeAmount,
-            poolFeeAmount,
-            bundleFeeAmount,
-            distributionFeeAmount
-        ) = _calculateFeeAmounts(
-            netPremiumAmount,
-            product,
-            bundleNftId,
-            referralId
-        );
-
-        premiumAmount = netPremiumAmount + productFeeAmount;
-        premiumAmount += poolFeeAmount + bundleFeeAmount;
-        premiumAmount += distributionFeeAmount;
-    }
-
-
-    // internal functions
-
-    function _calculateFeeAmounts(
-        uint256 netPremiumAmount,
-        Product product,
-        NftId bundleNftId,
-        ReferralId referralId
-    )
-        internal
-        view
-        returns (
-            uint256 productFeeAmount,
-            uint256 poolFeeAmount,
-            uint256 bundleFeeAmount,
-            uint256 distributionFeeAmount
-        )
-    {
-        InstanceReader instanceReader;
-        {
-            IInstance instance = product.getInstance();
-            instanceReader = instance.getInstanceReader();
-        }
-        
-        NftId poolNftId = product.getPoolNftId();
-        IBundle.BundleInfo memory bundleInfo = instanceReader.getBundleInfo(bundleNftId);
-        require(bundleInfo.poolNftId == poolNftId,"ERROR:PRS-035:BUNDLE_POOL_MISMATCH");
-
-        {
-            ISetup.ProductSetupInfo memory productSetupInfo = instanceReader.getProductSetupInfo(product.getProductNftId());
-            (productFeeAmount,) = FeeLib.calculateFee(productSetupInfo.productFee, netPremiumAmount);
-        }
-        {
-            ISetup.PoolSetupInfo memory poolSetupInfo = instanceReader.getPoolSetupInfo(poolNftId);
-            (poolFeeAmount,) = FeeLib.calculateFee(poolSetupInfo.poolFee, netPremiumAmount);
-        }
-        {
-            NftId distributionNftId = product.getDistributionNftId();
-            ISetup.DistributionSetupInfo memory distributionSetupInfo = instanceReader.getDistributionSetupInfo(distributionNftId);
-            (distributionFeeAmount,) = FeeLib.calculateFee(distributionSetupInfo.distributionFee, netPremiumAmount);
-        }
-        
-        (bundleFeeAmount,) = FeeLib.calculateFee(bundleInfo.fee, netPremiumAmount);
-    }
-
-
-    function _getAndVerifyInstanceAndProduct() internal view returns (Product product) {
-        IRegistry.ObjectInfo memory productInfo;
-        (productInfo,) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
-        product = Product(productInfo.objectAddress);
-    }
-}