@etherisc/gif-next 0.0.2-b060f43-287 → 0.0.2-b1059a4-617

package/contracts/instance/service/IPolicyService.sol

@@ -0,0 +1,89 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRisk} from "../module/IRisk.sol";
+import {IService} from "../../shared/IService.sol";
+
+import {NftId} from "../../types/NftId.sol";
+import {ReferralId} from "../../types/Referral.sol";
+import {RiskId} from "../../types/RiskId.sol";
+import {StateId} from "../../types/StateId.sol";
+import {Timestamp} from "../../types/Timestamp.sol";
+import {UFixed} from "../../types/UFixed.sol";
+import {Fee} from "../../types/Fee.sol";
+
+interface IPolicyService is IService {
+    
+    error ErrorIPolicyServiceInsufficientAllowance(address customer, address tokenHandlerAddress, uint256 amount);
+    error ErrorIPolicyServicePremiumAlreadyPaid(NftId policyNftId, uint256 premiumPaidAmount);
+    error ErrorIPolicyServicePolicyNotActivated(NftId policyNftId);
+    error ErrorIPolicyServicePolicyAlreadyClosed(NftId policyNftId);
+    error ErrorIPolicyServicePolicyNotActive(NftId policyNftId, StateId state);
+    error ErrorIPolicyServicePremiumNotFullyPaid(NftId policyNftId, uint256 premiumAmount, uint256 premiumPaidAmount);
+    error ErrorIPolicyServiceOpenClaims(NftId policyNftId, uint16 openClaimsCount);
+    error ErrorIPolicyServicePolicyHasNotExpired(NftId policyNftId, Timestamp expiredAt);
+
+    /// @dev declines an application represented by {policyNftId}
+    /// an application can only be declined in applied state
+    /// only the related product may decline an application
+    function decline(NftId policyNftId) external;
+
+    /// @dev underwrites the policy represented by {policyNftId}
+    /// sets the policy state to underwritten
+    /// may set the policy state to activated and set the activation date
+    /// optionally collects premiums and activates the policy.
+    /// - premium payment is only attempted if requirePremiumPayment is set to true
+    /// - activation is only done if activateAt is a non-zero timestamp
+    /// an application can only be underwritten in applied state
+    /// only the related product may underwrite an application
+    function underwrite(
+        NftId policyNftId,
+        bool requirePremiumPayment,
+        Timestamp activateAt
+    ) external;
+
+    /// @dev collects the premium token for the specified policy
+    function collectPremium(NftId policyNftId, Timestamp activateAt) external;
+
+    /// @dev activates the specified policy and sets the activation date in the policy metadata
+    /// to activate a policy it needs to be in underwritten state
+    function activate(NftId policyNftId, Timestamp activateAt) external;
+
+    /// @dev expires the specified policy and sets the expiry date in the policy metadata
+    /// to expire a policy it must be in active state, policies may be expired even when the predefined expiry date is still in the future
+    /// a policy can only be closed when it has been expired. in addition, it must not have any open claims
+    /// this function can only be called by a product. the policy needs to match with the calling product
+    function expire(NftId policyNftId) external;
+
+    /// @dev closes the specified policy and sets the closed data in the policy metadata
+    /// a policy can only be closed when it has been expired. in addition, it must not have any open claims
+    /// this function can only be called by a product. the policy needs to match with the calling product
+    function close(NftId policyNftId) external;
+
+    /// @dev calculates the total premium amount for the specified attributes
+    /// also returns the various fees included in the total premium amount
+    function calculatePremium(
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        uint256 lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        external
+        view
+        returns (
+            uint256 premiumAmount,
+            uint256 productFeeAmount,
+            uint256 poolFeeAmount,
+            uint256 bundleFeeAmount,
+            uint256 distributionFeeAmount
+        );
+
+    // TODO move function to pool service
+    function calculateRequiredCollateral(
+        UFixed collateralizationLevel, 
+        uint256 sumInsuredAmount
+    ) external pure returns(uint256 collateralAmount);
+
+}

package/contracts/instance/service/IPoolService.sol

@@ -9,43 +9,12 @@ import {IBundle} from "../module/IBundle.sol";
 import {IInstance} from "../../instance/IInstance.sol";
 
 interface IPoolService is IService {
-    error ErrorIPoolServiceInsufficientAllowance(address bundleOwner, address tokenHandlerAddress, uint256 amount);
+
+    function register(address poolAddress) external returns(NftId);
 
     function setFees(
         Fee memory poolFee,
         Fee memory stakingFee,
         Fee memory performanceFee
     ) external;
-
-    function createBundle(
-        address owner,
-        Fee memory fee, 
-        uint256 amount,
-        uint256 lifetime, 
-        bytes calldata filter
-    ) external returns(NftId bundleNftId);
-
-    function setBundleFee(
-        NftId bundleNftId,
-        Fee memory fee
-    ) external;
-
-    function updateBundle(NftId instanceNftId, NftId bundleNftId, IBundle.BundleInfo memory bundleInfo, StateId state) external;
-
-    function underwritePolicy(IInstance instanceNftId,
-        NftId policyNftId, 
-        NftId bundleNftId, 
-        uint256 collateralAmount,
-        uint256 netPremium
-    ) external;
-
-    // function fundBundle(NftId bundleNftId, uint256 amount) external returns(uint256 netAmount);
-
-    // function defundBundle(NftId bundleNftId, uint256 amount) external returns(uint256 netAmount);
-
-    function lockBundle(NftId bundleNftId) external;
-
-    function unlockBundle(NftId bundleNftId) external;
-
-    // function closeBundle(NftId bundleNftId) external;
 }

package/contracts/instance/service/IProductService.sol

@@ -13,9 +13,9 @@ import {UFixed} from "../../types/UFixed.sol";
 import {Fee} from "../../types/Fee.sol";
 
 interface IProductService is IService {
-
-    error ErrorIProductServiceInsufficientAllowance(address customer, address tokenHandlerAddress, uint256 amount);
     
+    function register(address productAddress) external returns(NftId);
+
     function setFees(
         Fee memory productFee,
         Fee memory processingFee
@@ -37,74 +37,4 @@ interface IProductService is IService {
         RiskId riskId,
         StateId newState
     ) external;
-
-
-    function calculatePremium(
-        RiskId riskId,
-        uint256 sumInsuredAmount,
-        uint256 lifetime,
-        bytes memory applicationData,
-        NftId bundleNftId,
-        ReferralId referralId
-    )
-        external
-        view
-        returns (
-            uint256 premiumAmount,
-            uint256 productFeeAmount,
-            uint256 poolFeeAmount,
-            uint256 bundleFeeAmount,
-            uint256 distributionFeeAmount
-        );
-
-
-    function createApplication(
-        address applicationOwner,
-        RiskId riskId,
-        uint256 sumInsuredAmount,
-        uint256 lifetime,
-        bytes memory applicationData,
-        NftId bundleNftId,
-        ReferralId referralId
-    ) external returns (NftId nftId);
-
-    /**
-     * @dev revokes the application represented by {policyNftId}.
-     * an application can only be revoked in applied state.
-     * only the application holder may revoke an application.
-     */
-    function revoke(NftId policyNftId) external;
-
-    /**
-     * @dev underwrites the policy represented by {policyNftId}.
-     * optionally collects premiums and activates the policy.
-     * - premium payment is only attempted if requirePremiumPayment is set to true
-     * - activation is only done if activateAt is a non-zero timestamp
-     */
-    function underwrite(
-        NftId policyNftId,
-        bool requirePremiumPayment,
-        Timestamp activateAt
-    ) external;
-
-    // function decline(uint256 nftId) external;
-    // function expire(uint256 nftId) external;
-
-    function collectPremium(NftId policyNftId, Timestamp activateAt) external;
-
-    function activate(NftId policyNftId, Timestamp activateAt) external;
-
-
-    function close(NftId nftId) external;
-
-    // function createClaim(uint256 nftId, uint256 claimAmount) external;
-    // function confirmClaim(uint256 nftId, uint256 claimId, uint256 claimAmount) external;
-    // function declineClaim(uint256 nftId, uint256 claimId) external;
-    // function closeClaim(uint256 nftId, uint256 claimId) external;
-
-    function calculateRequiredCollateral(
-        UFixed collateralizationLevel, 
-        uint256 sumInsuredAmount
-    ) external pure returns(uint256 collateralAmount);
-
 }

package/contracts/instance/service/PolicyService.sol

@@ -0,0 +1,474 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IProductComponent} from "../../components/IProductComponent.sol";
+import {Product} from "../../components/Product.sol";
+import {IPoolComponent} from "../../components/IPoolComponent.sol";
+import {IDistributionComponent} from "../../components/IDistributionComponent.sol";
+import {IInstance} from "../IInstance.sol";
+import {IPolicy} from "../module/IPolicy.sol";
+import {IRisk} from "../module/IRisk.sol";
+import {IBundle} from "../module/IBundle.sol";
+import {IProductService} from "./IProductService.sol";
+import {ITreasury} from "../module/ITreasury.sol";
+import {ISetup} from "../module/ISetup.sol";
+
+import {TokenHandler} from "../../shared/TokenHandler.sol";
+
+import {IVersionable} from "../../shared/IVersionable.sol";
+import {Versionable} from "../../shared/Versionable.sol";
+
+import {Timestamp, TimestampLib, zeroTimestamp} from "../../types/Timestamp.sol";
+import {UFixed, UFixedLib} from "../../types/UFixed.sol";
+import {Blocknumber, blockNumber} from "../../types/Blocknumber.sol";
+import {ObjectType, INSTANCE, PRODUCT, POOL, POLICY, BUNDLE} from "../../types/ObjectType.sol";
+import {APPLIED, UNDERWRITTEN, ACTIVE, KEEP_STATE, CLOSED} from "../../types/StateId.sol";
+import {NftId, NftIdLib, zeroNftId} from "../../types/NftId.sol";
+import {Fee, FeeLib} from "../../types/Fee.sol";
+import {ReferralId} from "../../types/Referral.sol";
+import {RiskId} from "../../types/RiskId.sol";
+import {StateId} from "../../types/StateId.sol";
+import {Version, VersionLib} from "../../types/Version.sol";
+//import {RoleId, PRODUCT_OWNER_ROLE} from "../../types/RoleId.sol";
+
+import {IService} from "../../shared/IService.sol";
+import {Service} from "../../shared/Service.sol";
+import {ComponentService} from "../base/ComponentService.sol";
+import {IPolicyService} from "./IPolicyService.sol";
+import {InstanceReader} from "../InstanceReader.sol";
+import {IPoolService} from "./IPoolService.sol";
+import {IBundleService} from "./IBundleService.sol";
+
+
+contract PolicyService is
+    ComponentService, 
+    IPolicyService
+{
+    using NftIdLib for NftId;
+    using TimestampLib for Timestamp;
+
+    IPoolService internal _poolService;
+    IBundleService internal _bundleService;
+
+    event LogProductServiceSender(address sender);
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer
+    {
+        address registryAddress;
+        address initialOwner;
+        (registryAddress, initialOwner) = abi.decode(data, (address, address));
+
+        initializeService(registryAddress, owner);
+
+        _poolService = IPoolService(getRegistry().getServiceAddress(POOL(), getMajorVersion()));
+        _bundleService = IBundleService(getRegistry().getServiceAddress(BUNDLE(), getMajorVersion()));
+
+        registerInterface(type(IPolicyService).interfaceId);
+    }
+
+
+    function getDomain() public pure override(IService, Service) returns(ObjectType) {
+        return POLICY();
+    }
+
+
+    function _getAndVerifyInstanceAndProduct() internal view returns (Product product) {
+        IRegistry.ObjectInfo memory productInfo;
+        (productInfo,) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+        product = Product(productInfo.objectAddress);
+    }
+
+    // TODO: no access restrictions
+    function calculatePremium(
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        uint256 lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        public
+        view 
+        virtual override
+        returns (
+            uint256 premiumAmount,
+            uint256 productFeeAmount,
+            uint256 poolFeeAmount,
+            uint256 bundleFeeAmount,
+            uint256 distributionFeeAmount
+        )
+    {
+        Product product = _getAndVerifyInstanceAndProduct();
+        uint256 netPremiumAmount = product.calculateNetPremium(
+            sumInsuredAmount,
+            riskId,
+            lifetime,
+            applicationData
+        );
+
+        (
+            productFeeAmount,
+            poolFeeAmount,
+            bundleFeeAmount,
+            distributionFeeAmount
+        ) = _calculateFeeAmounts(
+            netPremiumAmount,
+            product,
+            bundleNftId,
+            referralId
+        );
+
+        premiumAmount = netPremiumAmount + productFeeAmount;
+        premiumAmount += poolFeeAmount + bundleFeeAmount;
+        premiumAmount += distributionFeeAmount;
+    }
+
+    function _calculateFeeAmounts(
+        uint256 netPremiumAmount,
+        Product product,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        internal
+        view
+        returns (
+            uint256 productFeeAmount,
+            uint256 poolFeeAmount,
+            uint256 bundleFeeAmount,
+            uint256 distributionFeeAmount
+        )
+    {
+        InstanceReader instanceReader;
+        {
+            IInstance instance = product.getInstance();
+            instanceReader = instance.getInstanceReader();
+        }
+        
+        NftId poolNftId = product.getPoolNftId();
+        IBundle.BundleInfo memory bundleInfo = instanceReader.getBundleInfo(bundleNftId);
+        require(bundleInfo.poolNftId == poolNftId,"ERROR:PRS-035:BUNDLE_POOL_MISMATCH");
+
+        {
+            ISetup.ProductSetupInfo memory productSetupInfo = instanceReader.getProductSetupInfo(product.getProductNftId());
+            (productFeeAmount,) = FeeLib.calculateFee(productSetupInfo.productFee, netPremiumAmount);
+        }
+        {
+            ISetup.PoolSetupInfo memory poolSetupInfo = instanceReader.getPoolSetupInfo(poolNftId);
+            (poolFeeAmount,) = FeeLib.calculateFee(poolSetupInfo.poolFee, netPremiumAmount);
+        }
+        {
+            NftId distributionNftId = product.getDistributionNftId();
+            ISetup.DistributionSetupInfo memory distributionSetupInfo = instanceReader.getDistributionSetupInfo(distributionNftId);
+            (distributionFeeAmount,) = FeeLib.calculateFee(distributionSetupInfo.distributionFee, netPremiumAmount);
+        }
+        
+        (bundleFeeAmount,) = FeeLib.calculateFee(bundleInfo.fee, netPremiumAmount);
+    }
+
+    function _getAndVerifyUnderwritingSetup(
+        IInstance instance,
+        InstanceReader instanceReader,
+        IPolicy.PolicyInfo memory policyInfo,
+        ISetup.ProductSetupInfo memory productSetupInfo
+    )
+        internal
+        view
+        returns (
+            NftId poolNftId,
+            NftId bundleNftId,
+            IBundle.BundleInfo memory bundleInfo,
+            uint256 collateralAmount
+        )
+    {
+        // check match between policy and bundle (via pool)
+        poolNftId = productSetupInfo.poolNftId;
+        bundleNftId = policyInfo.bundleNftId;
+        bundleInfo = instanceReader.getBundleInfo(bundleNftId);
+        require(bundleInfo.poolNftId == poolNftId, "POLICY_BUNDLE_MISMATCH");
+
+        // calculate required collateral
+        ISetup.PoolSetupInfo memory poolInfo = instanceReader.getPoolSetupInfo(poolNftId);
+
+        // obtain remaining return values
+        // TODO required collateral amount should be calculated by pool service, not policy service
+        collateralAmount = calculateRequiredCollateral(poolInfo.collateralizationLevel, policyInfo.sumInsuredAmount);
+    }
+
+
+    function decline(
+        NftId policyNftId
+    )
+        external
+        override
+    {
+        require(false, "ERROR:PRS-235:NOT_YET_IMPLEMENTED");
+    }
+
+
+    /// @dev underwites application which includes the locking of the required collateral from the pool.
+    function underwrite(
+        NftId applicationNftId, // = policyNftId
+        bool requirePremiumPayment,
+        Timestamp activateAt
+    )
+        external 
+        virtual override
+    {
+        // check caller is registered product
+        IInstance instance;
+        InstanceReader instanceReader;
+        NftId productNftId;
+        {
+            IRegistry.ObjectInfo memory productInfo;
+            (productInfo, instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+            instanceReader = instance.getInstanceReader();
+            productNftId = productInfo.nftId;
+        }
+
+        // check policy matches with calling product
+        IPolicy.PolicyInfo memory policyInfo = instanceReader.getPolicyInfo(applicationNftId);
+        require(policyInfo.productNftId == productNftId, "POLICY_PRODUCT_MISMATCH");
+
+        // check policy is in state applied
+        require(instanceReader.getPolicyState(applicationNftId) == APPLIED(), "ERROR:PRS-021:STATE_NOT_APPLIED");
+        
+        (
+            NftId poolNftId,
+            NftId bundleNftId,
+            IBundle.BundleInfo memory bundleInfo,
+            uint256 collateralAmount
+        ) = _getAndVerifyUnderwritingSetup(
+            instance,
+            instanceReader,
+            policyInfo,
+            instanceReader.getProductSetupInfo(productNftId)
+        );
+        
+        StateId newPolicyState = UNDERWRITTEN();
+
+        // optional activation of policy
+        if(activateAt > zeroTimestamp()) {
+            newPolicyState = ACTIVE();
+            policyInfo.activatedAt = activateAt;
+            policyInfo.expiredAt = activateAt.addSeconds(policyInfo.lifetime);
+        }
+
+        // lock bundle collateral
+        uint256 netPremiumAmount = 0; // > 0 if immediate premium payment 
+
+        // optional collection of premium
+        if(requirePremiumPayment) {
+            netPremiumAmount = _processPremiumByTreasury(
+                instance, 
+                productNftId,
+                applicationNftId, 
+                policyInfo.premiumAmount);
+
+            policyInfo.premiumPaidAmount += policyInfo.premiumAmount;
+        }
+
+        // lock collateral and update bundle book keeping
+        // TODO introduct indirection via pool service?
+        // well pool would only need to be involved when a part of the collateral
+        // is provided by a "re insurance policy" of the pool
+        // but then again the policiy would likely best be attached to the bundle. really? why?
+        // retention level: fraction of sum insured that product will cover from pool funds directly
+        // eg retention level 30%, payouts up to 30% of the sum insured will be made from the product's pool directly
+        // for the remaining 70% the pool owns a policy that will cover claims that exceed the 30% of the sum insured
+        // open points:
+        // - do we need a link of a bundle to this policy or is it enough to know that the pool has an active policy?
+        // - when to buy such policies and for which amount? manual trigger or link to bundle creation and/or funding?
+        bundleInfo = _bundleService.lockCollateral(
+            instance,
+            applicationNftId, 
+            bundleNftId,
+            collateralAmount,
+            netPremiumAmount);
+
+        instance.updatePolicy(applicationNftId, policyInfo, newPolicyState);
+
+        // also verify/confirm application by pool if necessary
+        if(instanceReader.getPoolSetupInfo(poolNftId).isVerifyingApplications) {
+            IPoolComponent pool = IPoolComponent(
+                getRegistry().getObjectInfo(poolNftId).objectAddress);
+
+            pool.verifyApplication(
+                applicationNftId, 
+                policyInfo.applicationData, 
+                bundleInfo.filter,
+                collateralAmount);
+        }
+
+        // TODO: add logging
+    }
+
+
+    function calculateRequiredCollateral(UFixed collateralizationLevel, uint256 sumInsuredAmount) public pure override returns(uint256 collateralAmount) {
+        UFixed sumInsuredUFixed = UFixedLib.toUFixed(sumInsuredAmount);
+        UFixed collateralUFixed =  collateralizationLevel * sumInsuredUFixed;
+        return collateralUFixed.toInt();
+    } 
+
+    function collectPremium(NftId policyNftId, Timestamp activateAt) external override {
+        // check caller is registered product
+        (IRegistry.ObjectInfo memory productInfo, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+        InstanceReader instanceReader = instance.getInstanceReader();
+        IPolicy.PolicyInfo memory policyInfo = instanceReader.getPolicyInfo(policyNftId);
+
+        if (policyInfo.premiumPaidAmount == policyInfo.premiumAmount) {
+            revert ErrorIPolicyServicePremiumAlreadyPaid(policyNftId, policyInfo.premiumPaidAmount);
+        }
+
+        uint256 unpaidPremiumAmount = policyInfo.premiumAmount - policyInfo.premiumPaidAmount;
+
+        uint256 netPremiumAmount = _processPremiumByTreasury(
+                instance, 
+                productInfo.nftId,
+                policyNftId, 
+                unpaidPremiumAmount);
+
+        policyInfo.premiumPaidAmount += unpaidPremiumAmount;
+
+        _bundleService.increaseBalance(instance, policyInfo.bundleNftId, netPremiumAmount);
+        instance.updatePolicy(policyNftId, policyInfo, KEEP_STATE());
+
+        if(activateAt.gtz() && policyInfo.activatedAt.eqz()) {
+            activate(policyNftId, activateAt);
+        }
+
+        // TODO: add logging
+    }
+
+    function activate(NftId policyNftId, Timestamp activateAt) public override {
+        // check caller is registered product
+        (, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        IPolicy.PolicyInfo memory policyInfo = instanceReader.getPolicyInfo(policyNftId);
+
+        require(
+            policyInfo.activatedAt.eqz(),
+            "ERROR:PRS-020:ALREADY_ACTIVATED");
+
+        policyInfo.activatedAt = activateAt;
+        policyInfo.expiredAt = activateAt.addSeconds(policyInfo.lifetime);
+
+        instance.updatePolicy(policyNftId, policyInfo, ACTIVE());
+
+        // TODO: add logging
+    }
+
+
+    function expire(
+        NftId policyNftId
+    )
+        external
+        override
+        // solhint-disable-next-line no-empty-blocks
+    {
+        
+    }
+
+    function close(
+        NftId policyNftId
+    )
+        external 
+        override
+    {
+        (, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        IPolicy.PolicyInfo memory policyInfo = instanceReader.getPolicyInfo(policyNftId);
+
+        if (policyInfo.activatedAt.eqz()) {
+            revert ErrorIPolicyServicePolicyNotActivated(policyNftId);
+        }
+
+        StateId state = instanceReader.getPolicyState(policyNftId);
+        if (state != ACTIVE()) {
+            revert ErrorIPolicyServicePolicyNotActive(policyNftId, state);
+        }
+
+        if (policyInfo.closedAt.gtz()) {
+            revert ErrorIPolicyServicePolicyAlreadyClosed(policyNftId);
+        }
+
+        if (policyInfo.premiumAmount != policyInfo.premiumPaidAmount) {
+            revert ErrorIPolicyServicePremiumNotFullyPaid(policyNftId, policyInfo.premiumAmount, policyInfo.premiumPaidAmount);
+        }
+
+        if (policyInfo.openClaimsCount > 0) {
+            revert ErrorIPolicyServiceOpenClaims(policyNftId, policyInfo.openClaimsCount);
+        }
+
+        if (TimestampLib.blockTimestamp().lte(policyInfo.expiredAt) && (policyInfo.payoutAmount < policyInfo.sumInsuredAmount)) {
+            revert ErrorIPolicyServicePolicyHasNotExpired(policyNftId, policyInfo.expiredAt);
+        }
+
+        policyInfo.closedAt = TimestampLib.blockTimestamp();
+
+        _bundleService.closePolicy(instance, policyNftId, policyInfo.bundleNftId, policyInfo.sumInsuredAmount);
+        instance.updatePolicy(policyNftId, policyInfo, CLOSED());
+    }
+
+    function _getPoolNftId(
+        IInstance instance,
+        NftId productNftId
+    )
+        internal
+        view
+        returns (NftId poolNftid)
+    {
+        InstanceReader instanceReader = instance.getInstanceReader();
+        ISetup.ProductSetupInfo memory productSetupInfo = instanceReader.getProductSetupInfo(productNftId);
+        return productSetupInfo.poolNftId;
+    }
+
+
+    function _processPremiumByTreasury(
+        IInstance instance,
+        NftId productNftId,
+        NftId policyNftId,
+        uint256 premiumAmount
+    )
+        internal
+        returns (uint256 netPremiumAmount)
+    {
+        // process token transfer(s)
+        if(premiumAmount > 0) {
+            ISetup.ProductSetupInfo memory productSetupInfo = instance.getInstanceReader().getProductSetupInfo(productNftId);
+            TokenHandler tokenHandler = productSetupInfo.tokenHandler;
+            address policyOwner = getRegistry().ownerOf(policyNftId);
+            ISetup.PoolSetupInfo memory poolSetupInfo = instance.getInstanceReader().getPoolSetupInfo(productSetupInfo.poolNftId);
+            address poolWallet = poolSetupInfo.wallet;
+            netPremiumAmount = premiumAmount;
+            Fee memory productFee = productSetupInfo.productFee;
+
+            if (FeeLib.feeIsZero(productFee)) {
+                tokenHandler.transfer(
+                    policyOwner,
+                    poolWallet,
+                    premiumAmount
+                );
+            } else {
+                (uint256 productFeeAmount, uint256 netAmount) = FeeLib.calculateFee(productSetupInfo.productFee, netPremiumAmount);
+                address productWallet = productSetupInfo.wallet;
+                if (tokenHandler.getToken().allowance(policyOwner, address(tokenHandler)) < premiumAmount) {
+                    revert ErrorIPolicyServiceInsufficientAllowance(policyOwner, address(tokenHandler), premiumAmount);
+                }
+                tokenHandler.transfer(policyOwner, productWallet, productFeeAmount);
+                tokenHandler.transfer(policyOwner, poolWallet, netAmount);
+                netPremiumAmount = netAmount;
+            }
+        }
+
+        // TODO: add logging
+    }
+}