@etherisc/gif-next 0.0.2-af8c650-079 → 0.0.2-b060f43-678

package/contracts/instance/ObjectManager.sol

@@ -0,0 +1,101 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Cloneable} from "./Cloneable.sol";
+
+import {IInstance} from "./IInstance.sol";
+import {INSTANCE} from "../types/ObjectType.sol";
+import {InstanceReader} from "./InstanceReader.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {LibNftIdSet} from "../types/NftIdSet.sol";
+import {NftId} from "../types/NftId.sol";
+
+contract ObjectManager is
+    Cloneable
+{
+
+    event LogObjectManagerInitialized(NftId instanceNftId, address instanceReader);
+
+    error ErrorObjectManagerNftIdInvalid(NftId instanceNftId);
+    error ErrorObjectManagerAlreadyAdded(NftId componentNftId, NftId objectNftId);
+
+    mapping(NftId compnentNftId => LibNftIdSet.Set objects) internal _activeObjects;
+    mapping(NftId compnentNftId => LibNftIdSet.Set objects) internal _allObjects;
+    NftId internal _instanceNftId;
+    InstanceReader internal _instanceReader;
+
+    constructor() Cloneable() {
+        _instanceReader = InstanceReader(address(0));
+    }
+
+    /// @dev call to initialize MUST be made in the same transaction as cloning of the contract
+    function initialize(
+        address authority,
+        address registry,
+        NftId instanceNftId
+    )
+        external 
+    {
+        initialize(authority, registry);
+
+        // check/handle instance nft id/instance reader
+        IRegistry.ObjectInfo memory instanceInfo = _registry.getObjectInfo(instanceNftId);
+        if (instanceInfo.objectType != INSTANCE()) {
+            revert ErrorObjectManagerNftIdInvalid(instanceNftId);
+        }
+
+        IInstance instance = IInstance(instanceInfo.objectAddress);
+        _instanceReader = instance.getInstanceReader();
+        _instanceNftId = instanceNftId;
+        
+        emit LogObjectManagerInitialized(instanceNftId, address(_instanceReader));
+    }
+
+    function getInstanceReader() external view returns (InstanceReader) {
+        return _instanceReader;
+    }
+
+    function getInstanceNftId() external view returns (NftId) {
+        return _instanceNftId;
+    }
+
+    function _add(NftId componentNftId, NftId objectNftId) internal {
+        LibNftIdSet.Set storage allSet = _allObjects[componentNftId];
+        LibNftIdSet.Set storage activeSet = _activeObjects[componentNftId];
+
+        LibNftIdSet.add(allSet, objectNftId);
+        LibNftIdSet.add(activeSet, objectNftId);
+    }
+
+    function _activate(NftId componentNftId, NftId objectNftId) internal {
+        LibNftIdSet.add(_activeObjects[componentNftId], objectNftId);
+    }
+
+    function _deactivate(NftId componentNftId, NftId objectNftId) internal {
+        LibNftIdSet.remove(_activeObjects[componentNftId], objectNftId);
+    }
+
+    function _objects(NftId componentNftId) internal view returns (uint256) {
+        return LibNftIdSet.size(_allObjects[componentNftId]);
+    }
+
+    function _contains(NftId componentNftId, NftId objectNftId) internal view returns (bool) {
+        return LibNftIdSet.contains(_allObjects[componentNftId], objectNftId);
+    }
+
+    function _getObject(NftId componentNftId, uint256 idx) internal view returns (NftId) {
+        return LibNftIdSet.getElementAt(_allObjects[componentNftId], idx);
+    }
+
+    function _activeObjs(NftId componentNftId) internal view returns (uint256)  {
+        return LibNftIdSet.size(_activeObjects[componentNftId]);
+    }
+
+    function _isActive(NftId componentNftId, NftId objectNftId) internal view returns (bool) {
+        return LibNftIdSet.contains(_activeObjects[componentNftId], objectNftId);
+    }
+
+    function _getActiveObject(NftId componentNftId, uint256 idx) internal view returns (NftId) {
+        return LibNftIdSet.getElementAt(_activeObjects[componentNftId], idx);
+    }
+}

package/contracts/instance/base/ComponentServiceBase.sol

@@ -0,0 +1,134 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IRegistryService} from "../../registry/IRegistryService.sol";
+import {IInstance} from "../../instance/IInstance.sol";
+import {ObjectType, INSTANCE, PRODUCT, POOL, DISTRIBUTION, ORACLE} from "../../types/ObjectType.sol";
+import {NftId, NftIdLib} from "../../types/NftId.sol";
+import {RoleId, PRODUCT_OWNER_ROLE, POOL_OWNER_ROLE, DISTRIBUTION_OWNER_ROLE, ORACLE_OWNER_ROLE} from "../../types/RoleId.sol";
+
+import {BaseComponent} from "../../components/BaseComponent.sol";
+import {Product} from "../../components/Product.sol";
+import {INftOwnable} from "../../shared/INftOwnable.sol";
+import {Service} from "../../shared/Service.sol";
+import {InstanceService} from "../InstanceService.sol";
+import {Version, VersionPart, VersionLib} from "../../types/Version.sol";
+
+abstract contract ComponentServiceBase is Service {
+
+    error ExpectedRoleMissing(RoleId expected, address caller);
+    error ComponentTypeInvalid(ObjectType componentType);
+
+    mapping (ObjectType => RoleId) internal _objectTypeToExpectedRole;
+
+    /// @dev modifier to check if caller has a role on the instance the component is registered in
+    modifier onlyComponentOwnerRole(address componentAddress) {
+        BaseComponent component = BaseComponent(componentAddress);
+        ObjectType objectType = _getObjectType(component);
+        RoleId expectedRole = _objectTypeToExpectedRole[objectType];
+
+        address componentOwner = msg.sender;
+        INftOwnable nftOwnable = INftOwnable(address(component.getInstance()));
+        if(! getInstanceService().hasRole(componentOwner, expectedRole, nftOwnable.getNftId())) {
+            revert ExpectedRoleMissing(expectedRole, componentOwner);
+        }
+        _;
+    }
+
+    /// @dev modifier to check if caller is a registered service
+    modifier onlyService() {
+        address caller = msg.sender;
+        require(getRegistry().isRegisteredService(caller), "ERROR_NOT_SERVICE");
+        _;
+    }
+
+    function _initializeService(
+        address registry, 
+        address initialOwner
+    )
+        internal
+        override
+    {
+        super._initializeService(registry, initialOwner);
+        _objectTypeToExpectedRole[PRODUCT()] = PRODUCT_OWNER_ROLE();
+        _objectTypeToExpectedRole[POOL()] = POOL_OWNER_ROLE();
+        _objectTypeToExpectedRole[DISTRIBUTION()] = DISTRIBUTION_OWNER_ROLE();
+        _objectTypeToExpectedRole[ORACLE()] = ORACLE_OWNER_ROLE();
+    }
+
+    function getInstanceService() public view returns (InstanceService) {
+        return InstanceService(getRegistry().getServiceAddress("InstanceService", getMajorVersion()));
+    }
+
+    function register(address componentAddress) 
+        external 
+        onlyComponentOwnerRole(componentAddress)
+        returns (NftId componentNftId)
+    {
+        address componentOwner = msg.sender;
+        BaseComponent component = BaseComponent(componentAddress);
+        ObjectType objectType = _getObjectType(component);
+        IRegistryService registryService = getRegistryService();
+
+        IRegistry.ObjectInfo memory objInfo;
+        bytes memory initialObjData;
+
+        if (objectType == DISTRIBUTION()) {
+            (objInfo, initialObjData) = registryService.registerDistribution(component, componentOwner);
+        } else if (objectType == PRODUCT()) {
+            (objInfo, initialObjData) = registryService.registerProduct(component, componentOwner);
+        } else if (objectType == POOL()) {
+            (objInfo, initialObjData) = registryService.registerPool(component, componentOwner);
+        // TODO: implement this for oracle - currently missing in registry
+        // } else if (objectType == ORACLE()) {
+        //     (objInfo, initialObjData) = registryService.registerOracle(component, componentOwner);
+        } else {
+            revert ComponentTypeInvalid(objectType);
+        }
+
+        componentNftId = objInfo.nftId;
+        {
+            IInstance instance = _getInstance(objInfo);
+            _finalizeComponentRegistration(componentNftId, initialObjData, instance);
+        }
+    }
+
+    function _finalizeComponentRegistration(NftId componentNftId, bytes memory initialObjData, IInstance instance) internal virtual;
+
+    function _getObjectType(BaseComponent component) internal view returns (ObjectType) {
+        (IRegistry.ObjectInfo memory compInitialInfo, )  = component.getInitialInfo();
+        return compInitialInfo.objectType;
+    }
+    
+    function _getInstance(IRegistry.ObjectInfo memory compObjInfo) internal view returns (IInstance) {
+        IRegistry registry = getRegistry();
+        IRegistry.ObjectInfo memory instanceInfo = registry.getObjectInfo(compObjInfo.parentNftId);
+        return IInstance(instanceInfo.objectAddress);
+    }
+
+    function _getAndVerifyComponentInfoAndInstance(
+        ObjectType objectType
+    )
+        internal
+        view
+        returns(
+            IRegistry.ObjectInfo memory info, 
+            IInstance instance
+        )
+    {
+        NftId componentNftId = _registry.getNftId(msg.sender);
+        require(componentNftId.gtz(), "ERROR_COMPONENT_UNKNOWN");
+
+        info = getRegistry().getObjectInfo(componentNftId);
+        require(info.objectType == objectType, "OBJECT_TYPE_INVALID");
+
+        address instanceAddress = getRegistry().getObjectInfo(info.parentNftId).objectAddress;
+        instance = IInstance(instanceAddress);
+    }
+
+    function getRegistryService() public view virtual returns (IRegistryService) {
+        address service = getRegistry().getServiceAddress("RegistryService", getMajorVersion());
+        return IRegistryService(service);
+    }
+}

package/contracts/instance/base/IInstanceBase.sol

@@ -0,0 +1,23 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Key32} from "../../types/Key32.sol";
+import {StateId} from "../../types/StateId.sol";
+
+import {IKeyValueStore} from "./IKeyValueStore.sol";
+
+import {IComponentOwnerService} from "../service/IComponentOwnerService.sol";
+import {IDistributionService} from "../service/IDistributionService.sol";
+import {IProductService} from "../service/IProductService.sol";
+import {IPoolService} from "../service/IPoolService.sol";
+
+interface IInstanceBase {
+    function getKeyValueStore() external view returns (IKeyValueStore keyValueStore);
+    function updateState(Key32 key, StateId state) external;
+    function getState(Key32 key) external view returns (StateId state);
+
+    function getComponentOwnerService() external view returns(IComponentOwnerService);
+    function getDistributionService() external view returns(IDistributionService);
+    function getProductService() external view returns(IProductService service);
+    function getPoolService() external view returns(IPoolService service);
+}

package/contracts/instance/base/IKeyValueStore.sol

@@ -0,0 +1,49 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Blocknumber, blockBlocknumber, zeroBlocknumber} from "../../types/Blocknumber.sol";
+import {Key32, KeyId} from "../../types/Key32.sol";
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId} from "../../types/StateId.sol";
+
+import {ILifecycle} from "./ILifecycle.sol";
+
+// TODO remove - internal only?
+interface IKeyValueStore is ILifecycle {
+
+    struct Value {
+        Metadata metadata;
+        bytes data;
+    }
+
+    struct Metadata {
+        ObjectType objectType;
+        StateId state;
+        // TODO updatedBy needs concept that says what value should go here
+        // eg account outside gif objects that initiated the tx
+        // implies the caller needs to be propagated through all calls up to key values store itself
+        // to always have the instance address there doesn't seem to make sense
+        address updatedBy;
+        Blocknumber updatedIn;
+        Blocknumber createdIn;
+    }
+
+    event LogInfoCreated(ObjectType objectType, KeyId keyId, StateId state, address createdBy, address txOrigin);
+    event LogInfoUpdated(ObjectType objectType, KeyId keyId, StateId state, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
+    event LogStateUpdated(ObjectType objectType, KeyId keyId, StateId stateOld, StateId stateNew, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
+
+    // generic state changing functions
+    // function create(Key32 key, bytes memory data) external;
+    // function update(Key32 key, bytes memory data, StateId state) external;
+    // function updateData(Key32 key, bytes memory data) external;
+    // function updateState(Key32 key, StateId state) external;
+
+    function exists(Key32 key) external view returns (bool);
+    function get(Key32 key) external view returns (Value memory value);
+    function getData(Key32 key) external view returns (bytes memory data);
+    function getMetadata(Key32 key) external view returns (Metadata memory metadata);
+    function getState(Key32 key) external view returns (StateId state);
+
+    function toKey32(ObjectType objectType, KeyId id) external pure returns(Key32);
+}

package/contracts/instance/base/ILifecycle.sol

@@ -0,0 +1,30 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId} from "../../types/StateId.sol";
+
+interface ILifecycle {
+
+    error ErrorNoLifecycle(NftId nftId, ObjectType objectType);
+    error ErrorInvalidStateTransition(
+        ObjectType objectType,
+        StateId fromStateId,
+        StateId toStateId
+    );
+
+    function hasLifecycle(
+        ObjectType objectType
+    ) external view returns (bool);
+
+    function getInitialState(
+        ObjectType objectType
+    ) external view returns (StateId);
+
+    function isValidTransition(
+        ObjectType objectType,
+        StateId fromId,
+        StateId toId
+    ) external view returns (bool);
+}

package/contracts/instance/base/KeyValueStore.sol

@@ -0,0 +1,172 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Blocknumber, blockBlocknumber, zeroBlocknumber} from "../../types/Blocknumber.sol";
+import {Key32, KeyId, Key32Lib} from "../../types/Key32.sol";
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId, ACTIVE} from "../../types/StateId.sol";
+import {Timestamp, TimestampLib} from "../../types/Timestamp.sol";
+
+import {Lifecycle} from "./Lifecycle.sol";
+import {IKeyValueStore} from "./IKeyValueStore.sol";
+
+contract KeyValueStore is Lifecycle, IKeyValueStore {
+
+    mapping(Key32 key32 => Value value) private _value;
+
+    function create(
+        Key32 key32, 
+        bytes memory data
+    )
+        internal
+    {
+        _create(key32, data);
+    }
+
+    function _create(
+        Key32 key32, 
+        bytes memory data
+    )
+        internal
+    {
+        ObjectType objectType = key32.toObjectType();
+        require(objectType.gtz(), "ERROR:KVS-010:TYPE_UNDEFINED");
+
+        Metadata storage metadata = _value[key32].metadata;
+        require(metadata.state.eqz(), "ERROR:KVS-012:ALREADY_CREATED");
+
+        address createdBy = msg.sender;
+        Blocknumber blocknumber = blockBlocknumber();
+        StateId initialState = hasLifecycle(objectType) ? getInitialState(objectType) : ACTIVE();
+
+        // set metadata
+        metadata.objectType = objectType;
+        metadata.state = initialState;
+        metadata.updatedBy = createdBy;
+        metadata.updatedIn = blocknumber;
+        metadata.createdIn = blocknumber;
+
+        // set data
+        _value[key32].data = data;
+
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogInfoCreated(key32.toObjectType(), key32.toKeyId(), initialState, createdBy, tx.origin);
+    }
+
+    function update(
+        Key32 key32, 
+        bytes memory data,
+        StateId state
+    ) 
+        internal
+    {
+        _update(key32, data, state);
+    }
+
+    function _update(
+        Key32 key32, 
+        bytes memory data,
+        StateId state
+    ) 
+        internal
+    {
+        require(state.gtz(), "ERROR:KVS-020:STATE_UNDEFINED");
+        Metadata storage metadata = _value[key32].metadata;
+        StateId stateOld = metadata.state;
+        require(stateOld.gtz(), "ERROR:KVS-021:NOT_EXISTING");
+
+        // update data
+        _value[key32].data = data;
+
+        // update metadata (and state)
+        address updatedBy = msg.sender;
+        Blocknumber lastUpdatedIn = metadata.updatedIn;
+        metadata.state = state;
+        metadata.updatedBy = updatedBy;
+        metadata.updatedIn = blockBlocknumber();
+
+        // create log entries
+        // solhint-disable avoid-tx-origin
+        emit LogStateUpdated(key32.toObjectType(), key32.toKeyId(), state, stateOld, updatedBy, tx.origin, lastUpdatedIn);
+        emit LogInfoUpdated(key32.toObjectType(), key32.toKeyId(), state, updatedBy, tx.origin, lastUpdatedIn);
+        // solhing-enable
+    }
+
+    function updateData(Key32 key32, bytes memory data) 
+        internal
+    {
+        _updateData(key32, data);
+    }
+
+    function _updateData(Key32 key32, bytes memory data) 
+        internal
+    {
+        Metadata storage metadata = _value[key32].metadata;
+        StateId state = metadata.state;
+        require(state.gtz(), "ERROR:KVS-030:NOT_EXISTING");
+
+        // update data
+        _value[key32].data = data;
+
+        // update metadata
+        address updatedBy = msg.sender;
+        Blocknumber lastUpdatedIn = metadata.updatedIn;
+        metadata.updatedBy = updatedBy;
+        metadata.updatedIn = blockBlocknumber();
+
+        // create log entry
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogInfoUpdated(key32.toObjectType(), key32.toKeyId(), state, updatedBy, tx.origin, lastUpdatedIn);
+    }
+
+    function updateState(Key32 key32, StateId state)
+        internal
+    {
+        _updateState(key32, state);
+    }
+
+    function _updateState(Key32 key32, StateId state)
+        internal
+    {
+        require(state.gtz(), "ERROR:KVS-040:STATE_UNDEFINED");
+        Metadata storage metadata = _value[key32].metadata;
+        StateId stateOld = metadata.state;
+        require(stateOld.gtz(), "ERROR:KVS-041:NOT_EXISTING");
+
+        // update metadata (and state)
+        address updatedBy = msg.sender;
+        Blocknumber lastUpdatedIn = metadata.updatedIn;
+        metadata.state = state;
+        metadata.updatedBy = updatedBy;
+        metadata.updatedIn = blockBlocknumber();
+
+        // create log entry
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogStateUpdated(key32.toObjectType(), key32.toKeyId(), state, stateOld, updatedBy, tx.origin, lastUpdatedIn);
+    }
+
+    function exists(Key32 key32) public view returns (bool) {
+        return _value[key32].metadata.state.gtz();
+    }
+
+    function get(Key32 key32) public view returns (Value memory value) {
+        return _value[key32];
+    }
+
+    function getMetadata(Key32 key32) public view returns (Metadata memory metadata) {
+        return _value[key32].metadata;
+    }
+
+    function getData(Key32 key32) public view returns (bytes memory data) {
+        return _value[key32].data;
+    }
+
+    function getState(Key32 key32) public view returns (StateId state) {
+        return _value[key32].metadata.state;
+    }
+
+    function toKey32(ObjectType objectType, KeyId id) external pure override returns(Key32) {
+        return Key32Lib.toKey32(objectType, id);
+    }
+}

package/contracts/instance/{module/lifecycle/LifecycleModule.sol → base/Lifecycle.sol}

@@ -1,12 +1,12 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
 
-import {NftId} from "../../../types/NftId.sol";
-import {ObjectType, PRODUCT, ORACLE, POOL, BUNDLE, POLICY} from "../../../types/ObjectType.sol";
-import {StateId, ACTIVE, PAUSED, ARCHIVED, CLOSED, APPLIED, UNDERWRITTEN, REVOKED, DECLINED} from "../../../types/StateId.sol";
-import {ILifecycleModule} from "./ILifecycle.sol";
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType, COMPONENT, BUNDLE, POLICY, RISK} from "../../types/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED, ARCHIVED, CLOSED, APPLIED, UNDERWRITTEN, REVOKED, DECLINED} from "../../types/StateId.sol";
+import {ILifecycle} from "./ILifecycle.sol";
 
-contract LifecycleModule is ILifecycleModule {
+contract Lifecycle is ILifecycle {
     mapping(ObjectType objectType => StateId initialState)
         private _initialState;
 
@@ -14,46 +14,50 @@ contract LifecycleModule is ILifecycleModule {
         private _isValidTransition;
 
     constructor() {
-        _setupComponentLifecycle(PRODUCT());
-        _setupComponentLifecycle(ORACLE());
-        _setupComponentLifecycle(POOL());
-
         _setupBundleLifecycle();
+        _setupComponentLifecycle();
         _setupPolicyLifecycle();
+        _setupRiskLifecycle();
+    }
+
+    function hasLifecycle(
+        ObjectType objectType
+    )
+        public
+        view
+        override
+        returns (bool)
+    {
+        return _initialState[objectType].gtz();
+    }
+
+    function getInitialState(
+        ObjectType objectType
+    )
+        public
+        view
+        returns (StateId)
+    {
+        return _initialState[objectType];
     }
 
-    function checkAndLogTransition(
-        NftId nftId,
+    function checkTransition(
         ObjectType objectType,
         StateId fromId,
         StateId toId
-    ) public returns (StateId) // add only currentcontract? would that work?
+    )
+        public
+        view
     {
-        if (!_isValidTransition[objectType][fromId][toId]) {
-            revert ErrorInvalidStateTransition(nftId, objectType, fromId, toId);
+        // return if no life cycle support
+        if (_initialState[objectType].eqz()) {
+            return;
         }
 
-        if (objectType == POLICY()) {
-            emit LogPolicyStateChanged(nftId, fromId, toId);
-        } else if (objectType == BUNDLE()) {
-            emit LogBundleStateChanged(nftId, fromId, toId);
-        } else if (
-            objectType == PRODUCT() ||
-            objectType == ORACLE() ||
-            objectType == POOL()
-        ) {
-            emit LogComponentStateChanged(nftId, objectType, fromId, toId);
-        } else {
-            revert ErrorNoLifecycle(nftId, objectType);
+        // enforce valid state transition
+        if (!_isValidTransition[objectType][fromId][toId]) {
+            revert ErrorInvalidStateTransition(objectType, fromId, toId);
         }
-
-        return toId;
-    }
-
-    function getInitialState(
-        ObjectType objectType
-    ) public view returns (StateId) {
-        return _initialState[objectType];
     }
 
     function isValidTransition(
@@ -64,11 +68,11 @@ contract LifecycleModule is ILifecycleModule {
         return _isValidTransition[objectType][fromId][toId];
     }
 
-    function _setupComponentLifecycle(ObjectType objectType) internal {
-        _initialState[objectType] = ACTIVE();
-        _isValidTransition[objectType][ACTIVE()][PAUSED()] = true;
-        _isValidTransition[objectType][PAUSED()][ACTIVE()] = true;
-        _isValidTransition[objectType][PAUSED()][ARCHIVED()] = true;
+    function _setupComponentLifecycle() internal {
+        _initialState[COMPONENT()] = ACTIVE();
+        _isValidTransition[COMPONENT()][ACTIVE()][PAUSED()] = true;
+        _isValidTransition[COMPONENT()][PAUSED()][ACTIVE()] = true;
+        _isValidTransition[COMPONENT()][PAUSED()][ARCHIVED()] = true;
     }
 
     function _setupBundleLifecycle() internal {
@@ -86,4 +90,11 @@ contract LifecycleModule is ILifecycleModule {
         _isValidTransition[POLICY()][UNDERWRITTEN()][ACTIVE()] = true;
         _isValidTransition[POLICY()][ACTIVE()][CLOSED()] = true;
     }
+
+    function _setupRiskLifecycle() internal {
+        _initialState[RISK()] = ACTIVE();
+        _isValidTransition[RISK()][ACTIVE()][PAUSED()] = true;
+        _isValidTransition[RISK()][PAUSED()][ACTIVE()] = true;
+        _isValidTransition[RISK()][PAUSED()][ARCHIVED()] = true;
+    }
 }

package/contracts/instance/module/IAccess.sol

@@ -0,0 +1,38 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {EnumerableSet} from "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
+import {ShortString, ShortStrings} from "@openzeppelin/contracts/utils/ShortStrings.sol";
+
+import {RoleId} from "../../types/RoleId.sol";
+
+interface IAccess {
+    struct RoleInfo {
+        ShortString name;
+        bool isCustom;
+    }
+
+    struct TargetInfo {
+        ShortString name;
+        bool isCustom;
+    }
+
+    error ErrorTargetAddressZero();
+    error ErrorTargetAlreadyExists(address target, ShortString name);
+    error ErrorTargetDoesNotExist(address target);
+    error ErrorTargetNameEmpty(address target);
+    error ErrorTargetNameExists(address target, address existingTarget, ShortString name);
+
+    error ErrorRoleIdInvalid(RoleId roleId);
+    error ErrorRoleIdTooBig(RoleId roleId);
+    error ErrorRoleIdTooSmall(RoleId roleId);
+    error ErrorRoleIdAlreadyExists(RoleId roleId, ShortString name);
+    error ErrorRoleIdNotActive(RoleId roleId);
+    error ErrorRoleNameEmpty(RoleId roleId);
+    error ErrorRoleNameNotUnique(RoleId roleId, ShortString name);
+    error ErrorRoleInvalidUpdate(RoleId roleId, bool isCustom);
+    error ErrorGrantNonexstentRole(RoleId roleId);
+    error ErrorRevokeNonexstentRole(RoleId roleId);
+    error ErrorRenounceNonexstentRole(RoleId roleId);
+
+}