@etherisc/gif-next 0.0.2-af8c650-079 → 0.0.2-afc9e82-014

package/contracts/type/ClaimId.sol

@@ -0,0 +1,75 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+// uint16 allows for 65'535 claims per policy
+type ClaimId is uint16;
+
+import {CLAIM} from "./ObjectType.sol";
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {NftId} from "./NftId.sol";
+
+// type bindings
+using {
+    eqClaimId as ==, 
+    neClaimId as !=, 
+    ClaimIdLib.eqz,
+    ClaimIdLib.gtz,
+    ClaimIdLib.toInt,
+    ClaimIdLib.toKey32
+} for ClaimId global;
+
+
+// pure free functions for operators
+function eqClaimId(ClaimId a, ClaimId b) pure returns (bool isSame) {
+    return ClaimId.unwrap(a) == ClaimId.unwrap(b);
+}
+
+function neClaimId(ClaimId a, ClaimId b) pure returns (bool isDifferent) {
+    return ClaimId.unwrap(a) != ClaimId.unwrap(b);
+}
+
+// library functions that operate on user defined type
+library ClaimIdLib {
+    /// @dev claim id min value (0), use only for non-initialized values
+    function zero() public pure returns (ClaimId) {
+        return ClaimId.wrap(0);
+    }
+    /// @dev claim id max value (2**16-1), use only for non-initialized values
+    function max() public pure returns (ClaimId) {
+        return ClaimId.wrap(type(uint16).max);
+    }
+
+    /// @dev Converts an uint into a ClaimId.
+    function toClaimId(uint256 a) public pure returns (ClaimId) {
+        return ClaimId.wrap(uint16(a));
+    }
+
+    /// @dev Converts the ClaimId to a uint.
+    function toInt(ClaimId a) public pure returns (uint16) {
+        return uint16(ClaimId.unwrap(a));
+    }
+
+    /// @dev Converts the ClaimId and NftId to a Key32.
+    function toKey32(ClaimId claimId, NftId policyNftId) public pure returns (Key32) {
+        return Key32Lib.toKey32(CLAIM(), toKeyId(claimId, policyNftId));
+    }
+
+    /// @dev Converts the ClaimId and NftId to a Key32.
+    function toKeyId(ClaimId claimId, NftId policyNftId) public pure returns (KeyId) {
+        return KeyId.wrap(
+            bytes31(
+                bytes14(
+                    uint112(
+                        NftId.unwrap(policyNftId) << 16 + ClaimId.unwrap(claimId)))));
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(ClaimId a) public pure returns (bool) {
+        return ClaimId.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(ClaimId a) public pure returns (bool) {
+        return ClaimId.unwrap(a) == 0;
+    }
+}

package/contracts/type/DistributorType.sol

@@ -0,0 +1,55 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {NftId} from "./NftId.sol";
+import {DISTRIBUTOR_TYPE} from "./ObjectType.sol";
+
+type DistributorType is bytes8;
+
+// type bindings
+using {
+    eqDistributorType as ==,
+    neDistributorType as !=,
+    DistributorTypeLib.toKey32
+} for DistributorType global;
+
+// general pure free functions
+
+// pure free functions for operators
+function eqDistributorType(
+    DistributorType a, 
+    DistributorType b
+) pure returns (bool isSame) {
+    return DistributorType.unwrap(a) == DistributorType.unwrap(b);
+}
+
+function neDistributorType(
+    DistributorType a,
+    DistributorType b
+) pure returns (bool isDifferent) {
+    return DistributorType.unwrap(a) != DistributorType.unwrap(b);
+}
+
+// library functions that operate on user defined type
+library DistributorTypeLib {
+
+    function zero() public pure returns (DistributorType) {
+        return DistributorType.wrap(bytes8(0));
+    }
+
+    // @dev Converts a referral string into an id.
+    function toDistributorType(NftId distributionNftId, string memory name) public pure returns (DistributorType) {
+        return DistributorType.wrap(bytes8(keccak256(abi.encode(distributionNftId, name))));
+    }
+
+    /// @dev Returns the key32 value for the specified nft id and object type.
+    function toKey32(DistributorType id) public pure returns (Key32 key) {
+        return Key32Lib.toKey32(DISTRIBUTOR_TYPE(), toKeyId(id));
+    }
+
+    /// @dev Returns the key id value for the specified nft id
+    function toKeyId(DistributorType id) public pure returns (KeyId keyId) {
+        return KeyId.wrap(bytes31(DistributorType.unwrap(id)));
+    }
+}

package/contracts/type/Fee.sol

@@ -0,0 +1,65 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Amount, AmountLib} from "./Amount.sol";
+import {UFixed, UFixedLib} from "./UFixed.sol";
+
+struct Fee {
+    UFixed fractionalFee;
+    uint256 fixedFee;
+}
+
+library FeeLib {
+
+    function calculateFee(
+        Fee memory fee,
+        Amount amount
+    )
+        public
+        pure
+        returns (
+            Amount feeAmount, 
+            Amount netAmount
+        )
+    {
+        netAmount = amount;
+        if(gtz(fee)) {
+            UFixed fractionalAmount = 
+                amount.toUFixed() * fee.fractionalFee;
+            feeAmount = AmountLib.toAmount(fractionalAmount.toInt() + fee.fixedFee);
+            netAmount = netAmount - feeAmount;
+        }
+    }
+
+    /// @dev Converts the uint256 to a fee struct.
+    function toFee(
+        UFixed fractionalFee,
+        uint256 fixedFee
+    ) public pure returns (Fee memory fee) {
+        return Fee(fractionalFee, fixedFee);
+    }
+
+    /// @dev Return the percent fee struct (x%, 0)
+    function percentageFee(uint8 percent) public pure returns (Fee memory fee) {
+        return Fee(UFixedLib.toUFixed(percent, -2), 0);
+    }
+
+    // TODO rename to zero
+    /// @dev Return a zero fee struct (0, 0)
+    function zeroFee() public pure returns (Fee memory fee) {
+        return Fee(UFixed.wrap(0), 0);
+    }
+
+    // pure free functions for operators
+    function feeIsSame(Fee memory a, Fee memory b) public pure returns (bool isSame) {
+        return a.fixedFee == b.fixedFee && a.fractionalFee == b.fractionalFee;
+    }
+
+    function gtz(Fee memory fee) public pure returns (bool) {
+        return UFixed.unwrap(fee.fractionalFee) > 0 || fee.fixedFee > 0;
+    }
+
+    function eqz(Fee memory fee) public pure returns (bool) {
+        return fee.fixedFee == 0 && UFixed.unwrap(fee.fractionalFee) == 0;
+    }
+}

package/contracts/type/Key32.sol

@@ -0,0 +1,50 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ObjectType} from "./ObjectType.sol";
+
+type Key32 is bytes32;
+type KeyId is bytes31;
+
+// type bindings
+using {
+    eqKey32 as ==, 
+    neKey32 as !=,
+    Key32Lib.toKeyId,
+    Key32Lib.toObjectType
+} for Key32 global;
+
+// @dev Returns true iff keys are identical
+function eqKey32(Key32 a, Key32 b) pure returns (bool isSame) {
+    return Key32.unwrap(a) == Key32.unwrap(b);
+}
+
+// @dev Returns true iff keys are different
+function neKey32(Key32 a, Key32 b) pure returns (bool isDifferent) {
+    return Key32.unwrap(a) != Key32.unwrap(b);
+}
+
+library Key32Lib {
+
+    uint8 public constant TYPE_SHIFT = 31 * 8;
+    uint8 public constant ID_SHIFT = uint8(32 * 8 - TYPE_SHIFT);
+    bytes32 public constant TYPE_MASK = bytes32(bytes1(type(uint8).max)); // first byte in bytes32
+    bytes32 public constant ID_MASK = bytes32(~TYPE_MASK); // remaining bytes in bytes32
+
+    function toKey32(ObjectType objectType, KeyId id) public pure returns (Key32) {
+        uint256 uintObjectType = ObjectType.unwrap(objectType);
+        uint256 uintId = uint248(KeyId.unwrap(id));
+        uint256 uintKey = (uintObjectType << TYPE_SHIFT) + uintId;
+        return Key32.wrap(bytes32(uintKey));
+    }
+
+    function toObjectType(Key32 key) public pure returns (ObjectType objectType) {
+        bytes32 key32 = Key32.unwrap(key);
+        objectType = ObjectType.wrap(uint8(uint256(key32 & TYPE_MASK) >> TYPE_SHIFT));
+    }
+
+    function toKeyId(Key32 key) public pure returns (KeyId id) {
+        bytes32 key32 = Key32.unwrap(key);
+        id = KeyId.wrap(bytes31((key32 & ID_MASK) << ID_SHIFT));
+    }
+}

package/contracts/{types → type}/NftId.sol

@@ -1,6 +1,9 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.19;
 
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {ObjectType} from "./ObjectType.sol";
+
 // uint96 allows for chain ids up to 13 digits
 type NftId is uint96;
 
@@ -10,7 +13,9 @@ using {
     neNftId as !=, 
     NftIdLib.toInt,
     NftIdLib.gtz,
-    NftIdLib.eqz
+    NftIdLib.eqz,
+    NftIdLib.toKeyId,
+    NftIdLib.toKey32
 } for NftId global;
 
 // general pure free functions
@@ -19,6 +24,7 @@ function toNftId(uint256 id) pure returns (NftId) {
     return NftId.wrap(uint96(id));
 }
 
+// TODO move to NftIdLib and rename to zero()
 /// @dev Return the NftId zero (0)
 function zeroNftId() pure returns (NftId) {
     return NftId.wrap(0);
@@ -35,6 +41,13 @@ function neNftId(NftId a, NftId b) pure returns (bool isDifferent) {
 
 // library functions that operate on user defined type
 library NftIdLib {
+
+    /// @dev the zero nft id
+    /// is never a valid nft id and implies a non-initialized value
+    function zero() public pure returns (NftId) {
+        return NftId.wrap(0);
+    }
+
     /// @dev Converts the NftId to a uint256.
     function toInt(NftId nftId) public pure returns (uint96) {
         return uint96(NftId.unwrap(nftId));
@@ -54,4 +67,14 @@ library NftIdLib {
     function eq(NftId a, NftId b) public pure returns (bool isSame) {
         return eqNftId(a, b);
     }
+
+    /// @dev Returns the key32 value for the specified nft id and object type.
+    function toKey32(NftId id, ObjectType objectType) public pure returns (Key32 key) {
+        return Key32Lib.toKey32(objectType, toKeyId(id));
+    }
+
+    /// @dev Returns the key id value for the specified nft id
+    function toKeyId(NftId id) public pure returns (KeyId keyId) {
+        return KeyId.wrap(bytes31(uint248(NftId.unwrap(id))));
+    }
 }

package/contracts/type/NftIdSet.sol

@@ -0,0 +1,62 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../type/NftId.sol";
+
+// based on https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/utils/structs/EnumerableSet.sol
+library LibNftIdSet {
+
+    struct Set {
+        NftId[] ids;
+        mapping(NftId nftid => uint256 index) at;
+    }
+
+    error ErrorNftIdSetAlreadyAdded(NftId nftId);
+    error ErrorNftIdSetNotInSet(NftId nftId);
+
+
+    function add(Set storage set, NftId nftId) external {
+        if (set.at[nftId] > 0) {
+            revert ErrorNftIdSetAlreadyAdded(nftId);
+        }
+
+        set.ids.push(nftId);
+        set.at[nftId] = set.ids.length;
+    }
+
+    function remove(Set storage set, NftId nftId) external {
+        uint256 nftIdIndex = set.at[nftId];
+
+        if (nftIdIndex == 0) {
+            revert ErrorNftIdSetNotInSet(nftId);
+        }
+
+        uint256 toDeleteIndex = nftIdIndex - 1;
+        uint256 lastIndex = set.ids.length - 1;
+
+        if (lastIndex != toDeleteIndex) {
+            NftId lastId = set.ids[lastIndex];
+            set.ids[toDeleteIndex] = lastId;
+            set.at[lastId] = nftIdIndex; // Replace lastValue's index to valueIndex
+        }
+
+        set.ids.pop();
+        delete set.at[nftId];
+    }
+
+    function isEmpty(Set storage set) external view returns(bool empty) {
+        return set.ids.length == 0;
+    }
+
+    function contains(Set storage set, NftId nftId) external view returns(bool inSet) {
+        return set.at[nftId] > 0;
+    }
+
+    function size(Set storage set) external view returns(uint256 length) {
+        return set.ids.length;
+    }
+
+    function getElementAt(Set storage set, uint256 index) external view returns(NftId nftId) {
+        return set.ids[index];
+    }
+}

package/contracts/{types → type}/ObjectType.sol

@@ -1,5 +1,5 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
 
 type ObjectType is uint8;
 
@@ -8,6 +8,7 @@ using {
     eqObjectType as ==,
     neObjectType as !=,
     ObjectTypeLib.toInt,
+    ObjectTypeLib.eqz,
     ObjectTypeLib.gtz
 } for ObjectType global;
 
@@ -17,56 +18,101 @@ function PROTOCOL() pure returns (ObjectType) {
     return toObjectType(10);
 }
 
-function REGISTRY() pure returns (ObjectType) {
+function ROLE() pure returns (ObjectType) {
     return toObjectType(20);
 }
 
-function TOKEN() pure returns (ObjectType) {
+function TARGET() pure returns (ObjectType) {
     return toObjectType(30);
 }
 
-function SERVICE() pure returns (ObjectType) {
+function REGISTRY() pure returns (ObjectType) {
     return toObjectType(40);
 }
 
-function INSTANCE() pure returns (ObjectType) {
+function TOKEN() pure returns (ObjectType) {
     return toObjectType(50);
 }
 
-function STAKE() pure returns (ObjectType) {
+function SERVICE() pure returns (ObjectType) {
     return toObjectType(60);
 }
 
-function PRODUCT() pure returns (ObjectType) {
+function INSTANCE() pure returns (ObjectType) {
+    return toObjectType(70);
+}
+
+function STAKE() pure returns (ObjectType) {
+    return toObjectType(80);
+}
+
+function COMPONENT() pure returns (ObjectType) {
     return toObjectType(100);
 }
 
-function DISTRIBUTOR() pure returns (ObjectType) {
+// TODO replace by PRODUCT_SETUP
+function TREASURY() pure returns (ObjectType) {
+    return toObjectType(101);
+}
+
+function PRODUCT_SETUP() pure returns (ObjectType) {
+    return toObjectType(101);
+}
+
+function PRODUCT() pure returns (ObjectType) {
     return toObjectType(110);
 }
 
-function ORACLE() pure returns (ObjectType) {
+function DISTRIBUTION() pure returns (ObjectType) {
     return toObjectType(120);
 }
 
-function POOL() pure returns (ObjectType) {
+function DISTRIBUTOR_TYPE() pure returns (ObjectType) {
+    return toObjectType(121);
+}
+
+function DISTRIBUTOR() pure returns (ObjectType) {
+    return toObjectType(122);
+}
+
+function REFERRAL() pure returns (ObjectType) {
+    return toObjectType(123);
+}
+
+function ORACLE() pure returns (ObjectType) {
     return toObjectType(130);
 }
 
-function POLICY() pure returns (ObjectType) {
-    return toObjectType(200);
+function POOL() pure returns (ObjectType) {
+    return toObjectType(140);
 }
 
 function BUNDLE() pure returns (ObjectType) {
+    return toObjectType(220);
+}
+
+function RISK() pure returns (ObjectType) {
+    return toObjectType(200);
+}
+
+function APPLICATION() pure returns (ObjectType) {
     return toObjectType(210);
 }
 
+function POLICY() pure returns (ObjectType) {
+    return toObjectType(211);
+}
+
 function CLAIM() pure returns (ObjectType) {
-    return toObjectType(201);
+    return toObjectType(212);
 }
 
 function PAYOUT() pure returns (ObjectType) {
-    return toObjectType(202);
+    return toObjectType(213); 
+}
+
+function PRICE() pure returns (ObjectType) {
+    return toObjectType(230);
 }
 
 /// @dev Converts the uint8 to a ObjectType.
@@ -74,6 +120,7 @@ function toObjectType(uint256 objectType) pure returns (ObjectType) {
     return ObjectType.wrap(uint8(objectType));
 }
 
+// TODO move to ObjecTypeLib and rename to zero()
 /// @dev Return the ObjectType zero (0)
 function zeroObjectType() pure returns (ObjectType) {
     return ObjectType.wrap(0);
@@ -112,4 +159,4 @@ library ObjectTypeLib {
     function eq(ObjectType a, ObjectType b) public pure returns (bool isSame) {
         return eqObjectType(a, b);
     }
-}
+}

package/contracts/type/PayoutId.sol

@@ -0,0 +1,82 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+// uint24 allows for 65'535 claims with 255 payouts each per policy
+type PayoutId is uint24;
+
+import {ClaimId} from "./ClaimId.sol";
+import {PAYOUT} from "./ObjectType.sol";
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {NftId} from "./NftId.sol";
+
+// type bindings
+using {
+    eqPayoutId as ==, 
+    nePayoutId as !=, 
+    PayoutIdLib.eqz,
+    PayoutIdLib.gtz,
+    PayoutIdLib.toInt,
+    PayoutIdLib.toClaimId,
+    PayoutIdLib.toPayoutNo,
+    PayoutIdLib.toKey32
+} for PayoutId global;
+
+
+// pure free functions for operators
+function eqPayoutId(PayoutId a, PayoutId b) pure returns (bool isSame) {
+    return PayoutId.unwrap(a) == PayoutId.unwrap(b);
+}
+
+function nePayoutId(PayoutId a, PayoutId b) pure returns (bool isDifferent) {
+    return PayoutId.unwrap(a) != PayoutId.unwrap(b);
+}
+
+// library functions that operate on user defined type
+library PayoutIdLib {
+    /// @dev Converts the PayoutId to a uint.
+    function zero() public pure returns (PayoutId) {
+        return PayoutId.wrap(0);
+    }
+
+    /// @dev Converts an uint into a PayoutId.
+    function toPayoutId(ClaimId claimId, uint8 payoutNo) public pure returns (PayoutId) {
+        return PayoutId.wrap((ClaimId.unwrap(claimId) << 8) + payoutNo);
+    }
+
+    function toClaimId(PayoutId payoutId) public pure returns (ClaimId) {
+        return ClaimId.wrap(uint16(PayoutId.unwrap(payoutId) >> 8));
+    }
+
+    function toPayoutNo(PayoutId payoutId) public pure returns (uint8) {
+        return uint8(PayoutId.unwrap(payoutId) & 255);
+    }
+
+    /// @dev Converts the PayoutId to a uint.
+    function toInt(PayoutId a) public pure returns (uint24) {
+        return uint24(PayoutId.unwrap(a));
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(PayoutId a) public pure returns (bool) {
+        return PayoutId.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(PayoutId a) public pure returns (bool) {
+        return PayoutId.unwrap(a) == 0;
+    }
+
+    /// @dev Converts the PayoutId and NftId to a Key32.
+    function toKey32(PayoutId payoutId, NftId policyNftId) public pure returns (Key32) {
+        return Key32Lib.toKey32(PAYOUT(), toKeyId(payoutId, policyNftId));
+    }
+
+    /// @dev Converts the PayoutId and NftId to a Key32.
+    function toKeyId(PayoutId payoutId, NftId policyNftId) public pure returns (KeyId) {
+        return KeyId.wrap(
+            bytes31(
+                bytes15(
+                    uint120(
+                        (NftId.unwrap(policyNftId) << 24) + PayoutId.unwrap(payoutId)))));
+    }
+}

package/contracts/type/Referral.sol

@@ -0,0 +1,89 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {NftId} from "./NftId.sol";
+import {REFERRAL} from "./ObjectType.sol";
+
+type ReferralId is bytes8;
+type ReferralStatus is uint8;
+
+// type bindings
+using {
+    eqReferralId as ==, 
+    neReferralId as !=,
+    ReferralLib.toKey32
+} for ReferralId global;
+
+using {
+    eqReferralStatus as ==, 
+    neReferralStatus as !=
+} for ReferralStatus global;
+
+// general pure free functions
+
+// @dev Returns true iff a and b are identical
+function eqReferralId(ReferralId a, ReferralId b) pure returns (bool isSame) {
+    return ReferralId.unwrap(a) == ReferralId.unwrap(b);
+}
+
+// @dev Returns true iff a and b are different
+function neReferralId(ReferralId a, ReferralId b) pure returns (bool isDifferent) {
+    return ReferralId.unwrap(a) != ReferralId.unwrap(b);
+}
+
+// @dev Returns true iff a and b are identical
+function eqReferralStatus(ReferralStatus a, ReferralStatus b) pure returns (bool isSame) {
+    return ReferralStatus.unwrap(a) == ReferralStatus.unwrap(b);
+}
+
+// @dev Returns true iff a and b are different
+function neReferralStatus(ReferralStatus a, ReferralStatus b) pure returns (bool isDifferent) {
+    return ReferralStatus.unwrap(a) != ReferralStatus.unwrap(b);
+}
+
+function REFERRAL_OK() pure returns (ReferralStatus) {
+    return ReferralStatus.wrap(10);
+}
+
+function REFERRAL_ERROR_UNKNOWN() pure returns (ReferralStatus) {
+    return ReferralStatus.wrap(100);
+}
+
+function REFERRAL_ERROR_EXPIRED() pure returns (ReferralStatus) {
+    return ReferralStatus.wrap(110);
+}
+
+function REFERRAL_ERROR_EXHAUSTED() pure returns (ReferralStatus) {
+    return ReferralStatus.wrap(120);
+}
+
+library ReferralLib {
+
+    function zero() public pure returns (ReferralId) {
+        return ReferralId.wrap(bytes8(0));
+    }
+
+    // @dev Converts a referral string into an id.
+    function toReferralId(NftId distributionNftId, string memory referral) public pure returns (ReferralId) {
+        return ReferralId.wrap(bytes8(keccak256(abi.encode(distributionNftId, referral))));
+    }
+
+    function toReferralStatus(uint8 status) public pure returns (ReferralStatus) {
+        return ReferralStatus.wrap(status);
+    }
+
+    /// @dev Returns the key32 value for the specified nft id and object type.
+    function toKey32(ReferralId id) public pure returns (Key32 key) {
+        return Key32Lib.toKey32(REFERRAL(), toKeyId(id));
+    }
+
+    /// @dev Returns the key id value for the specified nft id
+    function toKeyId(ReferralId id) public pure returns (KeyId keyId) {
+        return KeyId.wrap(bytes31(ReferralId.unwrap(id)));
+    }
+
+    function eqz(ReferralId id) public pure returns (bool) {
+        return eqReferralId(id, zero());
+    }
+}