@etherisc/gif-next 0.0.2-a8ee67b-545 → 0.0.2-a996a07-088

package/contracts/instance/base/BalanceStore.sol

@@ -0,0 +1,123 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Blocknumber, BlocknumberLib} from "../../type/Blocknumber.sol";
+import {NftId} from "../../type/NftId.sol";
+import {Amount} from "../../type/Amount.sol";
+
+contract BalanceStore {
+
+    error ErrorBalanceStoreTargetAlreadyRegistered(NftId targetNftId);
+    error ErrorBalanceStoreTargetNotRegistered(NftId targetNftId);
+
+    event LogBalanceStoreTargetRegistered(NftId targetNftId);
+
+    event LogBalanceStoreFeesIncreased(NftId targetNftId, Amount addedAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+    event LogBalanceStoreFeesDecreased(NftId targetNftId, Amount addedAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+
+    event LogBalanceStoreLockedIncreased(NftId targetNftId, Amount addedAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+    event LogBalanceStoreLockedDecreased(NftId targetNftId, Amount addedAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+
+    event LogBalanceStoreBalanceIncreased(NftId targetNftId, Amount addedAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+    event LogBalanceStoreBalanceDecreased(NftId targetNftId, Amount addedAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+
+    mapping(NftId nftId => Amount balance) private _balanceAmount;
+    mapping(NftId nftId => Amount locked) private _lockedAmount;
+    mapping(NftId nftId => Amount fees) private _feeAmount;
+    mapping(NftId nftId => bool isRegistered) private _isRegistered;
+
+    // TODO check if this is made redundant by *Info struct updates
+    mapping(NftId nftId => Blocknumber lastUpdatedIn) private _lastUpdatedIn;
+
+    modifier onlyRegisteredTarget(NftId targetNftId) {
+        if (!_isRegistered[targetNftId]) {
+            revert ErrorBalanceStoreTargetNotRegistered(targetNftId);
+        }
+        _;
+    }
+
+    function getBalanceAmount(NftId targetNftId) external view returns (Amount balanceAmount) { return _balanceAmount[targetNftId]; }
+    function getLockedAmount(NftId targetNftId) external view returns (Amount lockedAmount) { return _lockedAmount[targetNftId]; }
+    function getFeeAmount(NftId targetNftId) external view returns (Amount feeAmount) { return _feeAmount[targetNftId]; }
+
+    function getAmounts(NftId targetNftId)
+        external
+        view
+        returns (
+            Amount balanceAmount,
+            Amount lockedAmount,
+            Amount feeAmount
+        )
+    {
+        balanceAmount = _balanceAmount[targetNftId];
+        lockedAmount = _lockedAmount[targetNftId];
+        feeAmount = _feeAmount[targetNftId];
+    }
+
+    function _registerBalanceTarget(NftId targetNftId) internal {
+        if (_isRegistered[targetNftId]) {
+            revert ErrorBalanceStoreTargetAlreadyRegistered(targetNftId);
+        }
+
+        _isRegistered[targetNftId] = true;
+        _setLastUpdatedIn(targetNftId);
+
+        emit LogBalanceStoreTargetRegistered(targetNftId);
+    }
+
+    //--- fee management ----------------------------------------------------//
+    function _increaseFees(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
+        newBalance = _feeAmount[targetNftId] + amount;
+        _feeAmount[targetNftId] = newBalance;
+
+        emit LogBalanceStoreFeesIncreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
+        _setLastUpdatedIn(targetNftId);
+    }
+
+    function _decreaseFees(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
+        newBalance = _feeAmount[targetNftId] - amount;
+        _feeAmount[targetNftId] = newBalance;
+
+        emit LogBalanceStoreFeesDecreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
+        _setLastUpdatedIn(targetNftId);
+    }
+
+    //--- locked management -------------------------------------------------//
+    function _increaseLocked(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
+        newBalance = _lockedAmount[targetNftId] + amount;
+        _lockedAmount[targetNftId] = newBalance;
+
+        emit LogBalanceStoreLockedIncreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
+        _setLastUpdatedIn(targetNftId);
+    }
+
+    function _decreaseLocked(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
+        newBalance = _lockedAmount[targetNftId] - amount;
+        _lockedAmount[targetNftId] = newBalance;
+
+        emit LogBalanceStoreLockedDecreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
+        _setLastUpdatedIn(targetNftId);
+    }
+
+    //--- balance management ------------------------------------------------//
+    function _increaseBalance(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
+        newBalance = _balanceAmount[targetNftId] + amount;
+        _balanceAmount[targetNftId] = newBalance;
+
+        emit LogBalanceStoreBalanceIncreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
+        _setLastUpdatedIn(targetNftId);
+    }
+
+    function _decreaseBalance(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
+        newBalance = _balanceAmount[targetNftId] - amount;
+        _balanceAmount[targetNftId] = newBalance;
+
+        emit LogBalanceStoreBalanceDecreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
+        _setLastUpdatedIn(targetNftId);
+    }
+
+    //--- internal/private functions ----------------------------------------//
+    function _setLastUpdatedIn(NftId targetNftId) internal {
+        _lastUpdatedIn[targetNftId] = BlocknumberLib.currentBlocknumber();
+    }
+}

package/contracts/instance/base/Cloneable.sol

@@ -0,0 +1,28 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+
+abstract contract Cloneable is 
+    AccessManagedUpgradeable
+{
+    IRegistry internal _registry;
+
+    /// @dev call to initialize MUST be made in the same transaction as cloning of the contract
+    function __Cloneable_init(
+        address authority,
+        address registry
+    )
+        internal 
+        onlyInitializing
+    {
+        __AccessManaged_init(authority);
+        _registry = IRegistry(registry);
+    }
+
+    function getRegistry() external view returns (IRegistry) {
+        return _registry;
+    }
+}

package/contracts/instance/base/ObjectCounter.sol

@@ -0,0 +1,21 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Blocknumber, BlocknumberLib} from "../../type/Blocknumber.sol";
+import {NftId} from "../../type/NftId.sol";
+import {Amount} from "../../type/Amount.sol";
+import {RequestId, RequestIdLib} from "../../type/RequestId.sol";
+
+contract ObjectCounter {
+
+    // TODO refactor risk id
+    // mapping(NftId productNftId => uint64 risks) private _riskCounter;
+
+    uint256 private _requestCounter;
+
+    // TODO introduce RequestId (uint64)
+    function _createNextRequestId() internal returns (RequestId requestId) {
+        _requestCounter++;
+        requestId = RequestIdLib.toRequestId(_requestCounter);
+    }
+}

package/contracts/instance/base/ObjectManager.sol

@@ -0,0 +1,80 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Cloneable} from "./Cloneable.sol";
+
+import {IInstance} from "../IInstance.sol";
+import {INSTANCE} from "../../type/ObjectType.sol";
+import {InstanceReader} from "../InstanceReader.sol";
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {LibNftIdSet} from "../../type/NftIdSet.sol";
+import {NftId} from "../../type/NftId.sol";
+
+contract ObjectManager is
+    Cloneable
+{
+
+    event LogObjectManagerInitialized(address instance);
+
+    error ErrorObjectManagerNftIdInvalid(NftId instanceNftId);
+
+    mapping(NftId compnentNftId => LibNftIdSet.Set objects) internal _activeObjects;
+    mapping(NftId compnentNftId => LibNftIdSet.Set objects) internal _allObjects;
+    IInstance internal _instance; // store instance address -> more flexible, instance may not be registered during ObjectManager initialization
+
+    /// @dev call to initialize MUST be made in the same transaction as cloning of the contract
+    function initialize(address instanceAddress) 
+        initializer
+        external 
+    {
+        IInstance instance = IInstance(instanceAddress);
+        __Cloneable_init(instance.authority(), address(instance.getRegistry()));
+        _instance = instance;
+        
+        emit LogObjectManagerInitialized(instanceAddress);
+    }
+
+    function getInstance() external view returns (IInstance) {
+        return _instance;
+    }
+
+    function _add(NftId componentNftId, NftId objectNftId) internal {
+        LibNftIdSet.Set storage allSet = _allObjects[componentNftId];
+        LibNftIdSet.Set storage activeSet = _activeObjects[componentNftId];
+
+        LibNftIdSet.add(allSet, objectNftId);
+        LibNftIdSet.add(activeSet, objectNftId);
+    }
+
+    function _activate(NftId componentNftId, NftId objectNftId) internal {
+        LibNftIdSet.add(_activeObjects[componentNftId], objectNftId);
+    }
+
+    function _deactivate(NftId componentNftId, NftId objectNftId) internal {
+        LibNftIdSet.remove(_activeObjects[componentNftId], objectNftId);
+    }
+
+    function _objects(NftId componentNftId) internal view returns (uint256) {
+        return LibNftIdSet.size(_allObjects[componentNftId]);
+    }
+
+    function _contains(NftId componentNftId, NftId objectNftId) internal view returns (bool) {
+        return LibNftIdSet.contains(_allObjects[componentNftId], objectNftId);
+    }
+
+    function _getObject(NftId componentNftId, uint256 idx) internal view returns (NftId) {
+        return LibNftIdSet.getElementAt(_allObjects[componentNftId], idx);
+    }
+
+    function _activeObjs(NftId componentNftId) internal view returns (uint256)  {
+        return LibNftIdSet.size(_activeObjects[componentNftId]);
+    }
+
+    function _isActive(NftId componentNftId, NftId objectNftId) internal view returns (bool) {
+        return LibNftIdSet.contains(_activeObjects[componentNftId], objectNftId);
+    }
+
+    function _getActiveObject(NftId componentNftId, uint256 idx) internal view returns (NftId) {
+        return LibNftIdSet.getElementAt(_activeObjects[componentNftId], idx);
+    }
+}

package/contracts/instance/module/IAccess.sol

@@ -0,0 +1,46 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ShortString, ShortStrings} from "@openzeppelin/contracts/utils/ShortStrings.sol";
+
+import {NftId} from "../../type/NftId.sol";
+import {RoleId} from "../../type/RoleId.sol";
+import {Timestamp} from "../../type/Timestamp.sol";
+
+interface IAccess {
+
+    enum Type {
+        NotInitialized,
+        Core,
+        Gif,
+        Custom        
+    }
+
+    struct RoleInfo {
+        ShortString name;
+        Type rtype;
+        //bool isLocked;
+        RoleId admin;
+        Timestamp createdAt;
+        Timestamp updatedAt;
+    }
+
+    struct TargetInfo {
+        ShortString name;
+        Type ttype;
+        bool isLocked;
+        Timestamp createdAt;
+        Timestamp updatedAt;
+    }
+
+    error ErrorIAccessRoleIdTooBig(RoleId roleId);
+    error ErrorIAccessRoleIdTooSmall(RoleId roleId);
+    error ErrorIAccessRoleTypeInvalid(RoleId roleId, Type rtype);
+
+    error ErrorIAccessTargetAddressZero();
+    error ErrorIAccessTargetTypeInvalid(address target, Type ttype);
+    error ErrorIAccessTargetLocked(address target);
+    error ErrorIAccessTargetNotRegistered(address target);
+    error ErrorIAccessTargetAuthorityInvalid(address target, address targetAuthority);
+    error ErrorIAccessTargetInstanceMismatch(address target, NftId targetParentNftId, NftId instanceNftId);
+}

package/contracts/instance/module/IBundle.sol

@@ -0,0 +1,20 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount} from "../../type/Amount.sol";
+import {NftId} from "../../type/NftId.sol";
+import {Fee} from "../../type/Fee.sol";
+import {Seconds} from "../../type/Seconds.sol";
+import {Timestamp} from "../../type/Timestamp.sol";
+
+interface IBundle {
+
+    struct BundleInfo {
+        NftId poolNftId;
+        Fee fee; // bundle fee on net premium amounts
+        bytes filter; // required conditions for applications to be considered for collateralization by this bundle
+        Seconds lifetime; // lifetime of bundle after creation
+        Timestamp expiredAt; // no new policies starting with this timestamp
+        Timestamp closedAt; // no open policies, locked amount = 0
+    }
+}

package/contracts/instance/module/IComponents.sol

@@ -0,0 +1,52 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {Amount} from "../../type/Amount.sol";
+import {Fee} from "../../type/Fee.sol";
+import {NftId} from "../../type/NftId.sol";
+import {RoleId} from "../../type/RoleId.sol";
+import {TokenHandler} from "../../shared/TokenHandler.sol";
+import {UFixed} from "../../type/UFixed.sol";
+
+interface IComponents {
+
+    struct ComponentInfo {
+        string name; // component name (needs to be unique per instance)
+        NftId productNftId;
+        IERC20Metadata token;
+        TokenHandler tokenHandler;
+        address wallet;
+        bytes data; // will hold component type specific additional info (eg encoded pool info)
+    }
+
+
+    struct ProductInfo {
+        NftId distributionNftId;
+        NftId poolNftId;
+        Fee productFee; // product fee on net premium
+        Fee processingFee; // product fee on payout amounts        
+        Fee distributionFee; // distribution fee for sales that do not include commissions
+        Fee minDistributionOwnerFee; // min fee required by distribution owner (not including commissions for distributors)
+        Fee poolFee; // pool fee on net premium
+        Fee stakingFee; // pool fee on staked capital from investor
+        Fee performanceFee; // pool fee on profits from capital investors
+    }
+
+
+    struct PoolInfo {
+        NftId productNftId; // the nft of the product this pool is linked to
+        RoleId bundleOwnerRole; // the required role for bundle owners
+        // TODO maxCapitalAmount -> maxBalanceAmount
+        Amount maxCapitalAmount; // max capital amount allowed for pool
+        bool isInterceptingBundleTransfers; // intercepts nft transfers for bundles
+        bool isExternallyManaged; // funding bundles is restricted to book keeping, actual funds may be provided as needed to support payouts
+        bool isVerifyingApplications; // underwriting requires the pool component checks/confirms the applications 
+        UFixed collateralizationLevel; // factor to calculate collateral for sum insurance (default 100%)
+        UFixed retentionLevel; // amount of collateral held in pool (default 100%)
+        Fee poolFee; // pool fee on net premium
+        Fee stakingFee; // pool fee on staked capital from investor
+        Fee performanceFee; // pool fee on profits from capital investors
+    }
+}

package/contracts/instance/module/IDistribution.sol

@@ -0,0 +1,42 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount} from "../../type/Amount.sol";
+import {DistributorType} from "../../type/DistributorType.sol";
+import {NftId} from "../../type/NftId.sol";
+import {Timestamp} from "../../type/Timestamp.sol";
+import {UFixed} from "../../type/UFixed.sol";
+
+interface IDistribution {
+
+    struct DistributorTypeInfo {
+        string name;
+        UFixed minDiscountPercentage;
+        UFixed maxDiscountPercentage;
+        UFixed commissionPercentage;
+        uint32 maxReferralCount;
+        uint32 maxReferralLifetime;
+        bool allowSelfReferrals;
+        bool allowRenewals;
+        bytes data;
+    }
+
+    struct DistributorInfo {
+        DistributorType distributorType;
+        bool active;
+        bytes data;
+        Amount commissionAmount;
+        uint32 numPoliciesSold;
+    }
+
+    struct ReferralInfo {   
+        NftId distributorNftId;
+        string referralCode;
+        UFixed discountPercentage;
+        uint32 maxReferrals;
+        uint32 usedReferrals;
+        Timestamp expiryAt;
+        bytes data;
+    }
+
+}

package/contracts/instance/module/IPolicy.sol

@@ -0,0 +1,84 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount} from "../../type/Amount.sol";
+import {NftId} from "../../type/NftId.sol";
+import {ClaimId} from "../../type/ClaimId.sol";
+import {ReferralId} from "../../type/Referral.sol";
+import {RiskId} from "../../type/RiskId.sol";
+import {Seconds} from "../../type/Seconds.sol";
+import {Timestamp} from "../../type/Timestamp.sol";
+
+interface IPolicy {
+
+    struct Premium {
+        // premium splitting per target wallet
+        Amount productFeeAmount;
+        Amount distributionFeeAndCommissionAmount;
+        Amount poolPremiumAndFeeAmount;
+
+        // detailed positions
+        // this is the net premium calculated by the product 
+        uint256 netPremiumAmount;
+        // fullPremium = netPremium + all fixed amounts + all variable amounts (excl commission and minDistribtuionOwnerFee variable part)
+        uint256 fullPremiumAmount;
+        // premium = fullPremium - discount
+        uint256 premiumAmount;
+        uint256 productFeeFixAmount;
+        uint256 poolFeeFixAmount;
+        uint256 bundleFeeFixAmount;
+        uint256 distributionFeeFixAmount;
+        uint256 productFeeVarAmount;
+        uint256 poolFeeVarAmount;
+        uint256 bundleFeeVarAmount;
+        uint256 distributionFeeVarAmount;
+        uint256 distributionOwnerFeeFixAmount;
+        // this is the remaining amount when the commission and discount are subtracted from the distribution fee variable part (must be at least the minDistributionOwnerFee)
+        uint256 distributionOwnerFeeVarAmount;
+        // this value is based on distributor type referenced in the referral 
+        uint256 commissionAmount;
+        // this is based on referral used
+        uint256 discountAmount;
+    }
+
+    /// @dev policy data for the full policy lifecycle
+    struct PolicyInfo {
+        NftId productNftId;
+        NftId bundleNftId;
+        ReferralId referralId;
+        RiskId riskId;
+        Amount sumInsuredAmount;
+        Amount premiumAmount; // expected premium at application time
+        Amount premiumPaidAmount; // actual paid premium 
+        Seconds lifetime;
+        // policy application data, no changes after applying for a policy
+        bytes applicationData;
+        bytes processData;
+        uint16 claimsCount;
+        uint16 openClaimsCount;
+        Amount claimAmount; // sum of confirmed claim amounts (max = sum insured amount)
+        Amount payoutAmount; // sum of payouts (max = sum confirmed claim amountst)
+        Timestamp activatedAt; // time of underwriting
+        Timestamp expiredAt; // no new claims (activatedAt + lifetime)
+        Timestamp closedAt; // no locked capital (or declinedAt)
+    }
+
+    // claimId neeeds to be encoded policyNftId:claimId combination
+    struct ClaimInfo {
+        Amount claimAmount;
+        Amount paidAmount;
+        uint8 payoutsCount;
+        uint8 openPayoutsCount;
+        bytes submissionData; // claim submission data, no changes after submitting the claim
+        bytes processData; // data that may include information supporting confirm or decline
+        Timestamp closedAt; // payment of confirmed claim amount (or declinedAt)
+    }
+
+    // claimId neeeds to be encoded policyNftId:claimId combination
+    struct PayoutInfo {
+        ClaimId claimId;
+        Amount amount;
+        bytes data;
+        Timestamp paidAt; // payoment of confirmed claim amount (or declinedAt)
+    }
+}

package/contracts/instance/module/IRisk.sol

@@ -0,0 +1,11 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {NftId} from "../../type/NftId.sol";
+
+interface IRisk {
+    struct RiskInfo {
+        NftId productNftId;
+        bytes data;
+    }
+}

package/contracts/{test/Usdc.sol → mock/Dip.sol}

@@ -1,14 +1,14 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
 
 import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
 
-contract USDC is ERC20 {
+contract Dip is ERC20 {
 
     // https://etherscan.io/token/0xc719d010b63e5bbf2c0551872cd5316ed26acd83#readContract
-    string public constant NAME = "USDC - DUMMY";
-    string public constant SYMBOL = "USDC";
-    uint8 public constant DECIMALS = 6;
+    string public constant NAME = "Decentralized Insurance Protocol - DUMMY";
+    string public constant SYMBOL = "DIP";
+    uint8 public constant DECIMALS = 18;
     uint256 public constant INITIAL_SUPPLY = 10**9 * 10**DECIMALS; // 1 Billion 1'000'000'000
     // decimals == 18 (openzeppelin erc20 default)
     constructor()

package/contracts/oracle/IOracle.sol

@@ -0,0 +1,20 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {NftId} from "../type/NftId.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+
+interface IOracle {
+
+    struct RequestInfo {
+        NftId requesterNftId; // originator of the request
+        string callbackMethodName; // callback function of the requestor to call to provide response data
+        NftId oracleNftId; // responsible oracle component
+        bytes requestData; 
+        bytes responseData; 
+        Timestamp respondedAt; // response timestamp
+        Timestamp expiredAt; // expiry timestamp
+        bool isCancelled;
+    }
+}

package/contracts/oracle/IOracleComponent.sol

@@ -0,0 +1,32 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Fee} from "../type/Fee.sol";
+import {IInstanceLinkedComponent} from "../shared/IInstanceLinkedComponent.sol";
+import {ReferralId, ReferralStatus} from "../type/Referral.sol";
+import {NftId} from "../type/NftId.sol";
+import {DistributorType} from "../type/DistributorType.sol";
+import {RequestId} from "../type/RequestId.sol";
+import {UFixed} from "../type/UFixed.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+interface IOracleComponent is IInstanceLinkedComponent {
+
+    /// @dev callback method for requesting some data from the oracle
+    function request(
+        RequestId requestId,
+        NftId requesterNftId,
+        bytes calldata requestData,
+        Timestamp expiryAt
+    ) external;
+
+
+    /// @dev callback method for cancelling the specified oracle request
+    function cancel(
+        RequestId requestId
+    ) external;
+
+
+    /// @dev returns true iff the component needs to be called when selling/renewing policis
+    function isVerifying() external view returns (bool verifying);
+}

package/contracts/oracle/IOracleService.sol

@@ -0,0 +1,65 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IService} from "../shared/IService.sol";
+import {NftId} from "../type/NftId.sol";
+import {RequestId} from "../type/RequestId.sol";
+import {StateId} from "../type/StateId.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+
+interface IOracleService is IService {
+
+    event LogOracleServiceRequestCreated(RequestId requestId, NftId requesterNftId, NftId oracleNftId, Timestamp expiryAt);
+    event LogOracleServiceResponseProcessed(RequestId requestId, NftId oracleNftId);
+    event LogOracleServiceDeliveryFailed(RequestId requestId, address requesterAddress, string functionSignature);
+    event LogOracleServiceResponseResent(RequestId requestId, NftId requesterNftId);
+    event LogOracleServiceRequestCancelled(RequestId requestId, NftId requesterNftId);
+
+    // create request
+    error ErrorOracleServiceInstanceMismatch(NftId expectedInstanceNftId, NftId oracleInstanceNftId);
+    error ErrorOracleServiceExpiryInThePast(Timestamp blockTimestamp, Timestamp expiryAt);
+    error ErrorOracleServiceCallbackMethodNameEmpty();
+
+    // respond
+    error ErrorOracleServiceNotResponsibleOracle(RequestId requestId, NftId expectedOracleNftId, NftId oracleNftId);
+
+    // get request info
+    error ErrorOracleServiceRequestStateNotActive(RequestId requestId, StateId state);
+    error ErrorOracleServiceCallerNotResponsibleOracle(RequestId requestId, NftId oracleNftId, NftId callerNftId);
+    error ErrorOracleServiceCallerNotRequester(RequestId requestId, NftId requesterNftId, NftId callerNftId);
+    error ErrorOracleServiceRequestExpired(RequestId requestId, Timestamp expiredAt);
+    
+    /// @dev send an oracle request to the specified oracle component.
+    /// the function returns the id of the newly created request.
+    /// permissioned: only registered components may send requests to oracles.
+    function request(
+        NftId oracleNftId,
+        bytes calldata requestData,
+        Timestamp expiryAt,
+        string calldata callbackMethodName
+    ) external returns (RequestId requestId);
+
+    /// @dev respond to oracle request by oracle compnent.
+    /// the response data is amende in the request info stored with the instance.
+    /// the request state changes to FULFILLED (when calling the callback method of the requester is successful)
+    /// or to FAILED when calling the requester is not succesful.
+    /// the function returns true iff the state changes to FULFILLED.
+    /// permissioned: only the oracle component linked to the request id may call this method
+    function respond(
+        RequestId requestId,
+        bytes calldata responseData
+    ) external returns (bool success);
+
+    /// @dev re send a failed response to the requester.
+    /// only requests in state FAILED may be re sent.
+    /// the request state changes to FULFILLED when calling the callback method of the requester is successful.
+    /// permissioned: only the requester may resend a request
+    function resend(RequestId requestId) external;
+
+    /// @dev notify the oracle component that the specified request has become invalid.
+    /// only requests in state ACTIVE may be cancelled.
+    /// permissioned: only the requester may cancel a request
+    function cancel(RequestId requestId) external;
+
+}