@etherisc/gif-next 0.0.2-a6f9f86-582 → 0.0.2-a733491-751

package/contracts/components/Component.sol

@@ -0,0 +1,241 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+
+import {IComponent} from "./IComponent.sol";
+import {IProductService} from "../instance/service/IProductService.sol";
+import {IInstanceService} from "../instance/IInstanceService.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {InstanceAccessManager} from "../instance/InstanceAccessManager.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {NftId} from "../types/NftId.sol";
+import {ObjectType, INSTANCE, PRODUCT} from "../types/ObjectType.sol";
+import {VersionPart} from "../types/Version.sol";
+import {Registerable} from "../shared/Registerable.sol";
+import {RoleId, RoleIdLib} from "../types/RoleId.sol";
+import {IAccess} from "../instance/module/IAccess.sol";
+import {VersionPart} from "../types/Version.sol";
+
+// TODO discuss to inherit from oz accessmanaged
+// then add (Distribution|Pool|Product)Upradeable that also intherit from Versionable
+// same pattern as for Service which is also upgradeable
+abstract contract Component is
+    Registerable,
+    IComponent,
+    AccessManagedUpgradeable
+{
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.component.Component.sol")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant CONTRACT_LOCATION_V1 = 0xffe8d4462baed26a47154f4b8f6db497d2f772496965791d25bd456e342b7f00;
+
+    struct ComponentStorage {
+        IInstance _instance; // instance for this component
+        InstanceReader _instanceReader; // instance reader for this component
+        string _name; // unique (per instance) component name
+        IERC20Metadata _token; // token for this component
+        address _wallet; // wallet for this component (default = component contract itself)
+        bool _isNftInterceptor; // declares if component is involved in nft transfers
+        IInstanceService _instanceService; // instance service for this component
+
+        NftId _productNftId; // only relevant for components that are linked to a aproduct
+        IProductService _productService; // product service for component, might not be relevant for some component types (eg oracles)
+    }
+
+
+    modifier onlyChainNft() {
+        if(msg.sender != getRegistry().getChainNftAddress()) {
+            revert ErrorComponentNotChainNft(msg.sender);
+        }
+        _;
+    }
+
+
+    modifier onlyProductService() {
+        if(msg.sender != address(_getComponentStorage()._productService)) {
+            revert ErrorComponentNotProductService(msg.sender);
+        }
+        _;
+    }
+
+    function _getComponentStorage() private pure returns (ComponentStorage storage $) {
+        assembly {
+            $.slot := CONTRACT_LOCATION_V1
+        }
+    }
+
+    function initializeComponent(
+        address registry,
+        NftId instanceNftId,
+        string memory name,
+        address token,
+        ObjectType componentType,
+        bool isInterceptor,
+        address initialOwner,
+        bytes memory data
+    )
+        public
+        virtual
+        onlyInitializing()
+    {
+        ComponentStorage storage $ = _getComponentStorage();
+        initializeRegisterable(registry, instanceNftId, componentType, isInterceptor, initialOwner, data);
+
+        // set unique name of component
+        $._name = name;
+        $._isNftInterceptor = isInterceptor;
+
+        // set and check linked instance
+        IRegistry.ObjectInfo memory instanceInfo = getRegistry().getObjectInfo(instanceNftId);
+        $._instance = IInstance(instanceInfo.objectAddress);
+        if(!$._instance.supportsInterface(type(IInstance).interfaceId)) {
+            revert ErrorComponentNotInstance(instanceNftId, instanceInfo.objectAddress);
+        }
+
+        // initialize AccessManagedUpgradeable
+        __AccessManaged_init($._instance.authority());
+
+        // set linked services
+        VersionPart gifVersion = $._instance.getMajorVersion();
+        $._instanceService = IInstanceService(getRegistry().getServiceAddress(INSTANCE(), gifVersion));
+        $._instanceReader = $._instance.getInstanceReader();
+        $._productService = IProductService(getRegistry().getServiceAddress(PRODUCT(), gifVersion));
+
+        // set wallet and token
+        $._wallet = address(this);
+        $._token = IERC20Metadata(token);
+
+        registerInterface(type(IComponent).interfaceId);
+    }
+
+    /// @dev callback function for nft transfers. may only be called by chain nft contract.
+    /// default implementation is empty. overriding functions MUST add onlyChainNft modifier
+    function nftTransferFrom(address from, address to, uint256 tokenId)
+        external
+        virtual override
+        onlyChainNft()
+    { }
+
+    function lock() external onlyOwner override {
+        _getComponentStorage()._instanceService.setComponentLocked(true);
+    }
+    
+    function unlock() external onlyOwner override {
+        _getComponentStorage()._instanceService.setComponentLocked(false);
+    }
+
+    // only product service may set product nft id during registration of product setup
+    function setProductNftId(NftId productNftId)
+        external
+        override
+        onlyProductService() 
+    {
+        ComponentStorage storage $ = _getComponentStorage();
+
+        if($._productNftId.gtz()) {
+            revert ErrorComponentProductNftAlreadySet();
+        }
+
+        $._productNftId = productNftId;
+    }
+
+    /// @dev Sets the wallet address for the component. 
+    /// if the current wallet has tokens, these will be transferred. 
+    /// if the new wallet address is externally owned, an approval from the 
+    /// owner of the external wallet for the component to move all tokens must exist. 
+    function setWallet(address newWallet)
+        external
+        override
+        onlyOwner
+    {
+        ComponentStorage storage $ = _getComponentStorage();
+
+        address currentWallet = $._wallet;
+        uint256 currentBalance = $._token.balanceOf(currentWallet);
+
+        // checks
+        if (newWallet == address(0)) {
+            revert ErrorComponentWalletAddressZero();
+        }
+        if (newWallet == currentWallet) {
+            revert ErrorComponentWalletAddressIsSameAsCurrent(newWallet);
+        }
+
+        if (currentBalance > 0) {
+            if (currentWallet == address(this)) {
+                // move tokens from component smart contract to external wallet
+            } else {
+                // move tokens from external wallet to component smart contract or another external wallet
+                uint256 allowance = $._token.allowance(currentWallet, address(this));
+                if (allowance < currentBalance) {
+                    revert ErrorComponentWalletAllowanceTooSmall(currentWallet, newWallet, allowance, currentBalance);
+                }
+            }
+        }
+
+        // effects
+        $._wallet = newWallet;
+        emit LogComponentWalletAddressChanged(newWallet);
+
+        // interactions
+        if (currentBalance > 0) {
+            // transfer tokens from current wallet to new wallet
+            if (currentWallet == address(this)) {
+                // transferFrom requires self allowance too
+                $._token.approve(address(this), currentBalance);
+            }
+            
+            SafeERC20.safeTransferFrom($._token, currentWallet, newWallet, currentBalance);
+            emit LogComponentWalletTokensTransferred(currentWallet, newWallet, currentBalance);
+        }
+    }
+
+    function getWallet()
+        public
+        view
+        override
+        returns (address walletAddress)
+    {
+        return _getComponentStorage()._wallet;
+    }
+
+    function getToken() public view override returns (IERC20Metadata token) {
+        return _getComponentStorage()._token;
+    }
+
+    function isNftInterceptor() public view override returns(bool isInterceptor) {
+        return _getComponentStorage()._isNftInterceptor;
+    }
+
+    function getInstance() public view override returns (IInstance instance) {
+        return _getComponentStorage()._instance;
+    }
+
+    function getInstanceReader() public view returns (InstanceReader reader) {
+        return _getComponentStorage()._instanceReader;
+    }
+
+    function getServiceAddress(ObjectType domain) public view returns (address service) {
+        VersionPart majorVersion = getInstance().getMajorVersion();
+        return getRegistry().getServiceAddress(domain, majorVersion);
+    }
+
+    function getName() public view override returns(string memory name) {
+        return _getComponentStorage()._name;
+    }
+
+    function getProductNftId() public view override returns (NftId productNftId) {
+        return _getComponentStorage()._productNftId;
+    }
+
+    function getInstanceService() public view returns (IInstanceService) {
+        return _getComponentStorage()._instanceService;
+    }
+
+    function getProductService() public view returns (IProductService) {
+        return _getComponentStorage()._productService;
+    }
+
+}

package/contracts/components/Distribution.sol

@@ -0,0 +1,308 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {DISTRIBUTION} from "../types/ObjectType.sol";
+import {IDistributionService} from "../instance/service/IDistributionService.sol";
+import {IProductService} from "../instance/service/IProductService.sol";
+import {NftId, zeroNftId, NftIdLib, toNftId} from "../types/NftId.sol";
+import {ReferralId, ReferralStatus, ReferralLib} from "../types/Referral.sol";
+import {Fee, FeeLib} from "../types/Fee.sol";
+import {Component} from "./Component.sol";
+import {IDistributionComponent} from "./IDistributionComponent.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+import {Registerable} from "../shared/Registerable.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {UFixed} from "../types/UFixed.sol";
+import {DistributorType} from "../types/DistributorType.sol";
+import {Timestamp} from "../types/Timestamp.sol";
+import {ITransferInterceptor} from "../registry/ITransferInterceptor.sol";
+
+
+abstract contract Distribution is
+    Component,
+    IDistributionComponent
+{
+    // keccak256(abi.encode(uint256(keccak256("etherisc.storage.Distribution")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant DISTRIBUTION_STORAGE_LOCATION_V1 = 0xaab7c5ea03d290056d6c060e0833d3ebcbe647f7694616a2ec52738a64b2f900;
+
+    struct DistributionStorage {
+        Fee _distributionFee;
+        TokenHandler _tokenHandler;
+        IDistributionService _distributionService;
+        mapping(address distributor => NftId distributorNftId) _distributorNftId;
+    }
+
+    function initializeDistribution(
+        address registry,
+        NftId instanceNftId,
+        string memory name,
+        address token,
+        Fee memory distributionFee,
+        address initialOwner,
+        bytes memory data
+    )
+        public
+        virtual
+        onlyInitializing()
+    {
+        initializeComponent(registry, instanceNftId, name, token, DISTRIBUTION(), true, initialOwner, data);
+
+        DistributionStorage storage $ = _getDistributionStorage();
+        // TODO add validation
+        $._distributionFee = distributionFee;
+        $._tokenHandler = new TokenHandler(token);
+        $._distributionService = getInstance().getDistributionService();
+
+        registerInterface(type(IDistributionComponent).interfaceId);
+    }
+
+    function setFees(
+        Fee memory distributionFee
+    )
+        external
+        override
+        onlyOwner
+        restricted()
+    {
+        _getDistributionStorage()._distributionService.setFees(distributionFee);
+    }
+
+    function getDistributionFee() external view returns (Fee memory distributionFee) {
+        DistributionStorage storage $ = _getDistributionStorage();
+        return $._distributionFee;
+    }
+
+    function createDistributorType(
+        string memory name,
+        UFixed minDiscountPercentage,
+        UFixed maxDiscountPercentage,
+        UFixed commissionPercentage,
+        uint32 maxReferralCount,
+        uint32 maxReferralLifetime,
+        bool allowSelfReferrals,
+        bool allowRenewals,
+        bytes memory data
+    )
+        public
+        returns (DistributorType distributorType)
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        distributorType = $._distributionService.createDistributorType(
+            name,
+            minDiscountPercentage,
+            maxDiscountPercentage,
+            commissionPercentage,
+            maxReferralCount,
+            maxReferralLifetime,
+            allowSelfReferrals,
+            allowRenewals,
+            data);
+    }
+
+    function createDistributor(
+        address distributor,
+        DistributorType distributorType,
+        bytes memory data
+    )
+        public
+        returns(NftId distributorNftId)
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        require($._distributorNftId[distributor].eqz(), "ERROR:DST-030:ALREADY_DISTRIBUTOR");
+
+        distributorNftId = $._distributionService.createDistributor(
+            distributor,
+            distributorType,
+            data);
+
+        $._distributorNftId[distributor] = distributorNftId;
+    }
+
+    function updateDistributorType(
+        NftId distributorNftId,
+        DistributorType distributorType,
+        bytes memory data
+    )
+        public
+        // TODO figure out what we need for authz
+        // and add it
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        $._distributionService.updateDistributorType(
+            distributorNftId,
+            distributorType,
+            data);
+    }
+
+    /**
+     * @dev lets distributors create referral codes.
+     * referral codes need to be unique
+     */
+    function createReferral(
+        NftId distributorNftId,
+        string memory code,
+        UFixed discountPercentage,
+        uint32 maxReferrals,
+        Timestamp expiryAt,
+        bytes memory data
+    )
+        public
+        // TODO add authz (only active distributor)
+        returns (ReferralId referralId)
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        referralId = $._distributionService.createReferral(
+            distributorNftId,
+            code,
+            discountPercentage,
+            maxReferrals,
+            expiryAt,
+            data);
+    }
+
+    function calculateFeeAmount(
+        ReferralId referralId,
+        uint256 netPremiumAmount
+    )
+        external
+        view
+        virtual override
+        returns (uint256 feeAmount)
+    {
+        ISetup.DistributionSetupInfo memory setupInfo = getSetupInfo();
+        Fee memory fee = setupInfo.distributionFee;
+        (feeAmount,) = FeeLib.calculateFee(fee, netPremiumAmount);
+        // TODO: use this? 
+        // return _distributionService.calculateFeeAmount(referralId, premiumAmount);        
+    }
+
+    function isDistributor(address candidate)
+        public
+        view
+        returns (bool)
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        return $._distributorNftId[candidate].gtz();
+    }
+
+    function getDistributorNftId(address distributor)
+        public
+        view
+        returns (NftId distributorNftId)
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        return $._distributorNftId[distributor];
+    }
+
+    function getDiscountPercentage(string memory referralCode)
+        external
+        view
+        returns (
+            UFixed discountPercentage, 
+            ReferralStatus status
+        )
+    {
+        ReferralId referralId = getReferralId(referralCode);
+        return getInstanceReader().getDiscountPercentage(referralId);
+    }
+
+
+    function getReferralId(
+        string memory referralCode
+    )
+        public
+        view 
+        returns (ReferralId referralId)
+    {
+        return ReferralLib.toReferralId(
+            getNftId(), 
+            referralCode);      
+    }
+
+    function calculateRenewalFeeAmount(
+        ReferralId referralId,
+        uint256 netPremiumAmount
+    )
+        external
+        view
+        virtual override
+        returns (uint256 feeAmount)
+    {
+        // default is no fees
+        return 0 * netPremiumAmount;
+    }
+
+    function processSale(
+        ReferralId referralId,
+        uint256 premiumAmount
+    )
+        external
+        onlyOwner
+        restricted()
+        virtual override
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        $._distributionService.processSale(referralId, premiumAmount);        
+    }
+
+    function processRenewal(
+        ReferralId referralId,
+        uint256 feeAmount
+    )
+        external
+        onlyOwner
+        restricted()
+        virtual override
+    {
+        // default is no action
+    }
+
+    function referralIsValid(ReferralId referralId) external view returns (bool isValid) {
+        // default is invalid
+        return false;
+    }
+
+    function getSetupInfo() public view returns (ISetup.DistributionSetupInfo memory setupInfo) {
+        InstanceReader reader = getInstance().getInstanceReader();
+        setupInfo = reader.getDistributionSetupInfo(getNftId());
+
+        // fallback to initial setup info (wallet is always != address(0))
+        if(setupInfo.wallet == address(0)) {
+            setupInfo = _getInitialSetupInfo();
+        }
+    }
+
+    function _getInitialSetupInfo() internal view returns (ISetup.DistributionSetupInfo memory setupInfo) {
+        DistributionStorage storage $ = _getDistributionStorage();
+        return ISetup.DistributionSetupInfo(
+            zeroNftId(),
+            $._tokenHandler,
+            $._distributionFee,
+            address(this)
+        );
+    }
+
+
+    function nftTransferFrom(address from, address to, uint256 tokenId) external virtual override (Component, ITransferInterceptor) {
+        // keep track of distributor nft owner
+        emit LogDistributorUpdated(to, msg.sender);
+        DistributionStorage storage $ = _getDistributionStorage();
+        $._distributorNftId[from] = zeroNftId();
+        $._distributorNftId[to] = toNftId(tokenId);
+    }
+    
+
+    /// @dev returns true iff the component needs to be called when selling/renewing policis
+    function isVerifying() external view returns (bool verifying) {
+        return true;
+    }
+
+    function _getDistributionStorage() private pure returns (DistributionStorage storage $) {
+        assembly {
+            $.slot := DISTRIBUTION_STORAGE_LOCATION_V1
+        }
+    }
+}

package/contracts/components/IComponent.sol

@@ -0,0 +1,54 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {IInstance} from "../instance/IInstance.sol";
+import {IInstanceService} from "../instance/IInstanceService.sol";
+import {IProductService} from "../instance/service/IProductService.sol";
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {ITransferInterceptor} from "../registry/ITransferInterceptor.sol";
+import {NftId} from "../types/NftId.sol";
+import {ObjectType} from "../types/ObjectType.sol";
+
+interface IComponent is 
+    IRegisterable,
+    ITransferInterceptor
+{
+
+    error ErrorComponentNotChainNft(address caller);
+    error ErrorComponentNotProductService(address caller);
+    error ErrorComponentNotInstance(NftId instanceNftId, address instance);
+    error ErrorComponentProductNftAlreadySet();
+    error ErrorComponentWalletAddressZero();
+    error ErrorComponentWalletAddressIsSameAsCurrent(address newWallet);
+    error ErrorComponentWalletAllowanceTooSmall(address oldWallet, address newWallet, uint256 allowance, uint256 balance);
+    error ErrorComponentUnauthorized(address caller, uint64 requiredRoleIdNum);
+
+    event LogComponentWalletAddressChanged(address newWallet);
+    event LogComponentWalletTokensTransferred(address from, address to, uint256 amount);
+
+    function getName() external view returns (string memory name);
+
+    function lock() external;
+    function unlock() external;
+
+    function getToken() external view returns (IERC20Metadata token);
+
+    function setWallet(address walletAddress) external;
+    function getWallet() external view returns (address walletAddress);
+
+    function isNftInterceptor() external view returns(bool isInterceptor);
+
+    function getInstance() external view returns (IInstance instance);
+
+    /// @dev returns the service address for the specified domain
+    /// gets address via lookup from registry using the major version form the linked instance
+    function getServiceAddress(ObjectType domain) external view returns (address service);
+
+    function setProductNftId(NftId productNftId) external;
+    function getProductNftId() external view returns (NftId productNftId);
+
+    function getInstanceService() external view returns (IInstanceService);
+    function getProductService() external view returns (IProductService);
+}

package/contracts/components/IDistributionComponent.sol

@@ -0,0 +1,100 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Fee} from "../types/Fee.sol";
+import {IComponent} from "./IComponent.sol";
+import {ISetup} from "../instance/module/ISetup.sol";
+import {ReferralId, ReferralStatus} from "../types/Referral.sol";
+import {NftId} from "../types/NftId.sol";
+import {DistributorType} from "../types/DistributorType.sol";
+import {UFixed} from "../types/UFixed.sol";
+import {Timestamp} from "../types/Timestamp.sol";
+
+interface IDistributionComponent is IComponent {
+
+    event LogDistributorUpdated(address to, address caller);
+
+    function getSetupInfo() external view returns (ISetup.DistributionSetupInfo memory setupInfo);
+
+    function setFees(
+        Fee memory distributionFee
+    ) external;
+
+    function createDistributorType(
+        string memory name,
+        UFixed minDiscountPercentage,
+        UFixed maxDiscountPercentage,
+        UFixed commissionPercentage,
+        uint32 maxReferralCount,
+        uint32 maxReferralLifetime,
+        bool allowSelfReferrals,
+        bool allowRenewals,
+        bytes memory data
+    ) external returns (DistributorType distributorType);
+
+    function createDistributor(
+        address distributor,
+        DistributorType distributorType,
+        bytes memory data
+    ) external returns(NftId distributorNftId);
+
+    function updateDistributorType(
+        NftId distributorNftId,
+        DistributorType distributorType,
+        bytes memory data
+    ) external;
+
+    /**
+     * @dev lets distributors create referral codes.
+     * referral codes need to be unique
+     * distributor is identified via msg.sender.
+     */
+    function createReferral(
+        NftId distributorNftId,
+        string memory code,
+        UFixed discountPercentage,
+        uint32 maxReferrals,
+        Timestamp expiryAt,
+        bytes memory data
+    ) external returns (ReferralId referralId);
+
+    function calculateFeeAmount(
+        ReferralId referralId,
+        uint256 netPremiumAmount
+    ) external view returns (uint256 feeAmount);
+
+    function calculateRenewalFeeAmount(
+        ReferralId referralId,
+        uint256 netPremiumAmount
+    ) external view returns (uint256 feeAmount);
+
+    /// @dev callback from product service when selling a policy for a specific referralId
+    /// the used referral id and the collected fee are provided as parameters
+    /// the component implementation can then process this information accordingly
+    function processSale(
+        ReferralId referralId,
+        uint256 feeAmount
+    ) external;
+
+    /// @dev callback from product service when a policy is renews for a specific referralId
+    function processRenewal(
+        ReferralId referralId,
+        uint256 feeAmount
+    ) external;
+
+    function getDiscountPercentage(
+        string memory referralCode
+    ) external view returns (UFixed discountPercentage, ReferralStatus status);
+
+    function getDistributionFee() external view returns (Fee memory distibutionFee);
+
+    function getReferralId(
+        string memory referralCode
+    ) external returns (ReferralId referralId);
+
+    /// @dev returns true iff the referral id is valid
+    function referralIsValid(ReferralId referralId) external view returns (bool isValid);
+
+    /// @dev returns true iff the component needs to be called when selling/renewing policis
+    function isVerifying() external view returns (bool verifying);
+}