@etherisc/gif-next 0.0.2-a63347a-883 → 0.0.2-a6ce659-551

package/contracts/components/Component.sol

@@ -1,216 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
-import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
-import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
-
-import {IComponent} from "./IComponent.sol";
-import {IProductService} from "../instance/service/IProductService.sol";
-import {IInstanceService} from "../instance/IInstanceService.sol";
-import {IInstance} from "../instance/IInstance.sol";
-import {InstanceAccessManager} from "../instance/InstanceAccessManager.sol";
-import {IRegistry} from "../registry/IRegistry.sol";
-import {NftId} from "../types/NftId.sol";
-import {ObjectType, INSTANCE, PRODUCT} from "../types/ObjectType.sol";
-import {VersionPart} from "../types/Version.sol";
-import {Registerable} from "../shared/Registerable.sol";
-import {RoleId, RoleIdLib} from "../types/RoleId.sol";
-import {IAccess} from "../instance/module/IAccess.sol";
-
-// TODO discuss to inherit from oz accessmanaged
-// TODO make contract upgradeable
-// then add (Distribution|Pool|Product)Upradeable that also intherit from Versionable
-// same pattern as for Service which is also upgradeable
-abstract contract Component is
-    Registerable,
-    IComponent,
-    AccessManagedUpgradeable
-{
-    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.component.Component.sol")) - 1)) & ~bytes32(uint256(0xff));
-    bytes32 public constant CONTRACT_LOCATION_V1 = 0xffe8d4462baed26a47154f4b8f6db497d2f772496965791d25bd456e342b7f00;
-
-    struct ComponentStorage {
-        IInstance _instance; // instance for this component
-        string _name; // unique (per instance) component name
-        IERC20Metadata _token; // token for this component
-        address _wallet; // wallet for this component (default = component contract itself)
-        IInstanceService _instanceService; // instance service for this component
-
-        NftId _productNftId; // only relevant for components that are linked to a aproduct
-        IProductService _productService; // product service for component, might not be relevant for some component types (eg oracles)
-    }
-
-
-    modifier onlyProductService() {
-        if(msg.sender != address(_getComponentStorage()._productService)) {
-            revert ErrorComponentNotProductService(msg.sender);
-        }
-        _;
-    }
-
-    constructor(
-        address registry,
-        NftId instanceNftId,
-        string memory name,
-        address token,
-        ObjectType componentType,
-        bool isInterceptor,
-        address initialOwner,
-        bytes memory data
-    ) {
-        _initializeComponent(registry, instanceNftId, name, token, componentType, isInterceptor, initialOwner, data);
-    }
-
-    function _getComponentStorage() private pure returns (ComponentStorage storage $) {
-        assembly {
-            $.slot := CONTRACT_LOCATION_V1
-        }
-    }
-
-    function _initializeComponent(
-        address registry,
-        NftId instanceNftId,
-        string memory name,
-        address token,
-        ObjectType componentType,
-        bool isInterceptor,
-        address initialOwner,
-        bytes memory data
-    )
-        internal
-        initializer 
-        virtual
-    {
-        ComponentStorage storage $ = _getComponentStorage();
-        _initializeRegisterable(registry, instanceNftId, componentType, isInterceptor, initialOwner, data);
-
-        // set unique name of component
-        $._name = name;
-
-        // set and check linked instance
-        IRegistry.ObjectInfo memory instanceInfo = getRegistry().getObjectInfo(instanceNftId);
-        $._instance = IInstance(instanceInfo.objectAddress);
-        if(!$._instance.supportsInterface(type(IInstance).interfaceId)) {
-            revert ErrorComponentNotInstance(instanceNftId, instanceInfo.objectAddress);
-        }
-
-        // initialize AccessManagedUpgradeable
-        __AccessManaged_init($._instance.authority());
-
-        // set linked services
-        VersionPart gifVersion = $._instance.getMajorVersion();
-        $._instanceService = IInstanceService(getRegistry().getServiceAddress(INSTANCE(), gifVersion));
-        $._productService = IProductService(getRegistry().getServiceAddress(PRODUCT(), gifVersion));
-
-        // set wallet and token
-        $._wallet = address(this);
-        $._token = IERC20Metadata(token);
-
-        _registerInterface(type(IComponent).interfaceId);
-    }
-
-    function lock() external onlyOwner override {
-        _getComponentStorage()._instanceService.setTargetLocked(getName(), true);
-    }
-    
-    function unlock() external onlyOwner override {
-        _getComponentStorage()._instanceService.setTargetLocked(getName(), false);
-    }
-
-    // only product service may set product nft id during registration of product setup
-    function setProductNftId(NftId productNftId)
-        external
-        override
-        onlyProductService() 
-    {
-        ComponentStorage storage $ = _getComponentStorage();
-
-        if($._productNftId.gtz()) {
-            revert ErrorComponentProductNftAlreadySet();
-        }
-
-        $._productNftId = productNftId;
-    }
-
-    /// @dev Sets the wallet address for the component. 
-    /// if the current wallet has tokens, these will be transferred. 
-    /// if the new wallet address is externally owned, an approval from the 
-    /// owner of the external wallet for the component to move all tokens must exist. 
-    function setWallet(address newWallet) external override onlyOwner {
-        ComponentStorage storage $ = _getComponentStorage();
-
-        address currentWallet = $._wallet;
-        uint256 currentBalance = $._token.balanceOf(currentWallet);
-
-        // checks
-        if (newWallet == address(0)) {
-            revert ErrorComponentWalletAddressZero();
-        }
-        if (newWallet == currentWallet) {
-            revert ErrorComponentWalletAddressIsSameAsCurrent(newWallet);
-        }
-
-        if (currentBalance > 0) {
-            if (currentWallet == address(this)) {
-                // move tokens from component smart contract to external wallet
-            } else {
-                // move tokens from external wallet to component smart contract or another external wallet
-                uint256 allowance = $._token.allowance(currentWallet, address(this));
-                if (allowance < currentBalance) {
-                    revert ErrorComponentWalletAllowanceTooSmall(currentWallet, newWallet, allowance, currentBalance);
-                }
-            }
-        }
-
-        // effects
-        $._wallet = newWallet;
-        emit LogComponentWalletAddressChanged(newWallet);
-
-        // interactions
-        if (currentBalance > 0) {
-            // transfer tokens from current wallet to new wallet
-            if (currentWallet == address(this)) {
-                // transferFrom requires self allowance too
-                $._token.approve(address(this), currentBalance);
-            }
-            
-            SafeERC20.safeTransferFrom($._token, currentWallet, newWallet, currentBalance);
-            emit LogComponentWalletTokensTransferred(currentWallet, newWallet, currentBalance);
-        }
-    }
-
-    function getWallet()
-        public
-        view
-        override
-        returns (address walletAddress)
-    {
-        return _getComponentStorage()._wallet;
-    }
-
-    function getToken() public view override returns (IERC20Metadata token) {
-        return _getComponentStorage()._token;
-    }
-
-    function getInstance() public view override returns (IInstance instance) {
-        return _getComponentStorage()._instance;
-    }
-
-    function getName() public view override returns(string memory name) {
-        return _getComponentStorage()._name;
-    }
-
-    function getProductNftId() public view override returns (NftId productNftId) {
-        return _getComponentStorage()._productNftId;
-    }
-
-    function getInstanceService() public view returns (IInstanceService) {
-        return _getComponentStorage()._instanceService;
-    }
-
-    function getProductService() public view returns (IProductService) {
-        return _getComponentStorage()._productService;
-    }
-
-}

package/contracts/components/Distribution.sol

@@ -1,153 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {DISTRIBUTION} from "../types/ObjectType.sol";
-import {IDistributionService} from "../instance/service/IDistributionService.sol";
-import {IProductService} from "../instance/service/IProductService.sol";
-import {NftId, zeroNftId, NftIdLib} from "../types/NftId.sol";
-import {ReferralId} from "../types/Referral.sol";
-import {Fee, FeeLib} from "../types/Fee.sol";
-import {Component} from "./Component.sol";
-import {IDistributionComponent} from "./IDistributionComponent.sol";
-import {IRegistry} from "../registry/IRegistry.sol";
-import {IRegisterable} from "../shared/IRegisterable.sol";
-import {ISetup} from "../instance/module/ISetup.sol";
-import {Registerable} from "../shared/Registerable.sol";
-import {TokenHandler} from "../shared/TokenHandler.sol";
-import {InstanceReader} from "../instance/InstanceReader.sol";
-
-abstract contract Distribution is
-    Component,
-    IDistributionComponent
-{
-    using NftIdLib for NftId;
-
-    bool internal _isVerifying;
-    Fee internal _initialDistributionFee;
-
-    TokenHandler internal _tokenHandler;
-
-    IDistributionService private _distributionService;
-
-    constructor(
-        address registry,
-        NftId instanceNftId,
-        // TODO refactor into tokenNftId
-        string memory name,
-        address token,
-        bool verifying,
-        Fee memory distributionFee,
-        address initialOwner,
-        bytes memory data
-    ) Component (
-        registry, 
-        instanceNftId, 
-        name, token, 
-        DISTRIBUTION(), 
-        true, 
-        initialOwner, 
-        data
-    ) {
-        _isVerifying = verifying;
-        _initialDistributionFee = distributionFee;
-
-        _tokenHandler = new TokenHandler(token);
-        _distributionService = getInstance().getDistributionService();
-
-        _registerInterface(type(IDistributionComponent).interfaceId);
-    }
-
-    function setFees(
-        Fee memory distributionFee
-    )
-        external
-        override
-        onlyOwner
-        restricted()
-    {
-        _distributionService.setFees(distributionFee);
-    }
-
-    function calculateFeeAmount(
-        ReferralId referralId,
-        uint256 netPremiumAmount
-    )
-        external
-        view
-        virtual override
-        returns (uint256 feeAmount)
-    {
-        ISetup.DistributionSetupInfo memory setupInfo = getSetupInfo();
-        Fee memory fee = setupInfo.distributionFee;
-        (feeAmount,) = FeeLib.calculateFee(fee, netPremiumAmount);
-    }
-
-
-    function calculateRenewalFeeAmount(
-        ReferralId referralId,
-        uint256 netPremiumAmount
-    )
-        external
-        view
-        virtual override
-        returns (uint256 feeAmount)
-    {
-        // default is no fees
-        return 0 * netPremiumAmount;
-    }
-
-    function processSale(
-        ReferralId referralId,
-        uint256 feeAmount
-    )
-        external
-        onlyOwner
-        restricted()
-        virtual override
-    {
-        // default is no action
-    }
-
-    function processRenewal(
-        ReferralId referralId,
-        uint256 feeAmount
-    )
-        external
-        onlyOwner
-        restricted()
-        virtual override
-    {
-        // default is no action
-    }
-
-    function referralIsValid(ReferralId referralId) external view returns (bool isValid) {
-        // default is invalid
-        return false;
-    }
-
-    function getSetupInfo() public view returns (ISetup.DistributionSetupInfo memory setupInfo) {
-        InstanceReader reader = getInstance().getInstanceReader();
-        setupInfo = reader.getDistributionSetupInfo(getNftId());
-
-        // fallback to initial setup info (wallet is always != address(0))
-        if(setupInfo.wallet == address(0)) {
-            setupInfo = _getInitialSetupInfo();
-        }
-    }
-
-    function _getInitialSetupInfo() internal view returns (ISetup.DistributionSetupInfo memory setupInfo) {
-        return ISetup.DistributionSetupInfo(
-            zeroNftId(),
-            _tokenHandler,
-            _initialDistributionFee,
-            _isVerifying,
-            address(this)
-        );
-    }
-    
-
-    /// @dev returns true iff the component needs to be called when selling/renewing policis
-    function isVerifying() external view returns (bool verifying) {
-        return _isVerifying;
-    }
-}

package/contracts/components/IComponent.sol

@@ -1,43 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
-
-import {IRegisterable} from "../shared/IRegisterable.sol";
-import {IInstance} from "../instance/IInstance.sol";
-import {IInstanceService} from "../instance/IInstanceService.sol";
-import {IProductService} from "../instance/service/IProductService.sol";
-import {NftId} from "../types/NftId.sol";
-
-interface IComponent is IRegisterable {
-
-    error ErrorComponentNotInstance(NftId instanceNftId, address instance);
-    error ErrorComponentProductNftAlreadySet();
-    error ErrorComponentWalletAddressZero();
-    error ErrorComponentWalletAddressIsSameAsCurrent(address newWallet);
-    error ErrorComponentWalletAllowanceTooSmall(address oldWallet, address newWallet, uint256 allowance, uint256 balance);
-    error ErrorComponentUnauthorized(address caller, uint64 requiredRoleIdNum);
-    error ErrorComponentNotProductService(address caller);
-
-    event LogComponentWalletAddressChanged(address newWallet);
-    event LogComponentWalletTokensTransferred(address from, address to, uint256 amount);
-
-    function getName() external view returns (string memory name);
-
-    // TODO remove and replace with accessmanaged target locking mechanism
-    function lock() external;
-    function unlock() external;
-
-    function getToken() external view returns (IERC20Metadata token);
-
-    function setWallet(address walletAddress) external;
-    function getWallet() external view returns (address walletAddress);
-
-    function getInstance() external view returns (IInstance instance);
-
-    function setProductNftId(NftId productNftId) external;
-    function getProductNftId() external view returns (NftId productNftId);
-
-    function getInstanceService() external view returns (IInstanceService);
-    function getProductService() external view returns (IProductService);
-}

package/contracts/components/IDistributionComponent.sol

@@ -1,47 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {Fee} from "../types/Fee.sol";
-import {IComponent} from "./IComponent.sol";
-import {ISetup} from "../instance/module/ISetup.sol";
-import {ReferralId} from "../types/Referral.sol";
-import {NftId} from "../types/NftId.sol";
-
-interface IDistributionComponent is IComponent {
-
-    function getSetupInfo() external view returns (ISetup.DistributionSetupInfo memory setupInfo);
-
-    function setFees(
-        Fee memory distributionFee
-    ) external;
-
-    function calculateFeeAmount(
-        ReferralId referralId,
-        uint256 netPremiumAmount
-    ) external view returns (uint256 feeAmount);
-
-    function calculateRenewalFeeAmount(
-        ReferralId referralId,
-        uint256 netPremiumAmount
-    ) external view returns (uint256 feeAmount);
-
-    /// @dev callback from product service when selling a policy for a specific referralId
-    /// the used referral id and the collected fee are provided as parameters
-    /// the component implementation can then process this information accordingly
-    function processSale(
-        ReferralId referralId,
-        uint256 feeAmount
-    ) external;
-
-    /// @dev callback from product service when a policy is renews for a specific referralId
-    function processRenewal(
-        ReferralId referralId,
-        uint256 feeAmount
-    ) external;
-
-    /// @dev returns true iff the referral id is valid
-    function referralIsValid(ReferralId referralId) external view returns (bool isValid);
-
-    /// @dev returns true iff the component needs to be called when selling/renewing policis
-    function isVerifying() external view returns (bool verifying);
-}

package/contracts/components/IPoolComponent.sol

@@ -1,51 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {Fee} from "../types/Fee.sol";
-import {IComponent} from "./IComponent.sol";
-import {ISetup} from "../instance/module/ISetup.sol";
-import {NftId} from "../types/NftId.sol";
-import {UFixed} from "../types/UFixed.sol";
-
-interface IPoolComponent is IComponent {
-
-    event LogUnderwrittenByPool(NftId policyNftId, uint256 collateralizationAmount, address pool);
-
-    function getSetupInfo() external view returns (ISetup.PoolSetupInfo memory setupInfo);
-
-    function setFees(
-        Fee memory poolFee,
-        Fee memory stakingFee,
-        Fee memory performanceFee
-    ) external;
-
-    /** 
-     * @dev this is a callback function that is called by the product service when underwriting a policy.
-     * the pool has the option to check the details and object to underwriting by reverting.
-     * the function is only called for "active" pools that ask to be involved/notified
-     * by product related state changes.
-     */
-    function underwrite(
-        NftId policyNftId, 
-        bytes memory policyData,
-        bytes memory bundleFilter,
-        uint256 collateralizationAmount
-    ) external;
-
-    /**
-     * @dev returns true iff the policy application data in policyData matches
-     * with the bundle filter criteria encoded in bundleFilter. 
-     */
-    function policyMatchesBundle(
-        bytes memory policyData,
-        bytes memory bundleFilter
-    )
-        external
-        view
-        returns (bool isMatching);
-
-    function isConfirmingApplication() external view returns (bool isConfirmingApplication);
-
-    function getCollateralizationLevel() external view returns (UFixed collateralizationLevel);
-
-}

package/contracts/components/IProductComponent.sol

@@ -1,39 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {Fee} from "../types/Fee.sol";
-import {IComponent} from "./IComponent.sol";
-import {ISetup} from "../instance/module/ISetup.sol";
-import {NftId} from "../types/NftId.sol";
-import {ReferralId} from "../types/Referral.sol";
-import {RiskId} from "../types/RiskId.sol";
-
-interface IProductComponent is IComponent {
-
-    function getSetupInfo() external view returns (ISetup.ProductSetupInfo memory setupInfo);
-
-    function setFees(
-        Fee memory productFee,
-        Fee memory processingFee
-    ) external;
-
-    function calculatePremium(
-        uint256 sumInsuredAmount,
-        RiskId riskId,
-        uint256 lifetime,
-        bytes memory applicationData,
-        NftId bundleNftId,
-        ReferralId referralId
-    ) external view returns (uint256 premiumAmount);
-
-    function calculateNetPremium(
-        uint256 sumInsuredAmount,
-        RiskId riskId,
-        uint256 lifetime,
-        bytes memory applicationData
-    ) external view returns (uint256 netPremiumAmount);    
-
-    
-    function getPoolNftId() external view returns (NftId poolNftId);
-    function getDistributionNftId() external view returns (NftId distributionNftId);
-}