@etherisc/gif-next 0.0.2-a0d749a → 0.0.2-a105567-464

package/contracts/shared/Versionable.sol

@@ -0,0 +1,59 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
+
+import {IVersionable} from "./IVersionable.sol";
+import {Version, VersionLib} from "../type/Version.sol";
+
+
+abstract contract Versionable is 
+    Initializable,
+    IVersionable 
+{
+    constructor() {
+        _disableInitializers();
+    }
+
+    function initializeVersionable(
+        address activatedBy,
+        bytes memory data
+    )
+        public
+        initializer
+    {
+        _initialize(activatedBy, data);
+    }
+
+    function upgradeVersionable(
+        bytes memory data
+    )
+        external
+        reinitializer(VersionLib.toUint64(getVersion()))
+    {
+        _upgrade(data);
+    }
+
+    function getVersion() public pure virtual returns(Version);
+
+    // IMPORTANT each version must implement this function 
+    // each implementation MUST use onlyInitialising modifier
+    // each implementation MUST call intializers of all base contracts...
+    function _initialize(address owner, bytes memory data) 
+        internal
+        onlyInitializing
+        virtual 
+    {
+        revert();
+    }
+
+    // IMPORTANT each version except version "1" must implement this function 
+    // each implementation MUST use onlyInitialising modifier
+    function _upgrade(bytes memory data)
+        internal
+        onlyInitializing
+        virtual
+    {
+        revert();
+    }
+}

package/contracts/staking/IStaking.sol

@@ -0,0 +1,152 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount} from "../type/Amount.sol";
+import {IComponent} from "../shared/IComponent.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {NftId} from "../type/NftId.sol";
+import {NftIdSetManager} from "../shared/NftIdSetManager.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {StakingReader} from "./StakingReader.sol";
+import {StakingStore} from "./StakingStore.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+import {UFixed} from "../type/UFixed.sol";
+
+interface IStaking is 
+    IComponent,
+    IVersionable
+{
+
+    // target parameters
+    event LogStakingLockingPeriodSet(NftId targetNftId, Seconds oldLockingPeriod, Seconds lockingPeriod);
+    event LogStakingRewardRateSet(NftId targetNftId, UFixed oldRewardRate, UFixed rewardRate);
+
+    // modifiers
+    error ErrorStakingNotStake(NftId stakeNftId);
+    error ErrorStakingNotTarget(NftId targetNftId);
+
+    error ErrorStakingNotStakingOwner();
+    error ErrorStakingNotNftOwner(NftId nftId);
+
+    // check dip balance and allowance
+    error ErrorStakingDipBalanceInsufficient(address owner, uint256 amount, uint256 dipBalance);
+    error ErrorStakingDipAllowanceInsufficient(address owner, address tokenHandler, uint256 amount, uint256 dipAllowance);
+
+    error ErrorStakingStakingReaderStakingMismatch(address stakingByStakingReader);
+    error ErrorStakingTargetAlreadyRegistered(NftId targetNftId);
+    error ErrorStakingTargetNftIdZero();
+    error ErrorStakingTargetTypeNotSupported(NftId targetNftId, ObjectType objectType);
+    error ErrorStakingTargetUnexpectedObjectType(NftId targetNftId, ObjectType expectedObjectType, ObjectType actualObjectType);
+    error ErrorStakingLockingPeriodZero(NftId targetNftId);
+    error ErrorStakingLockingPeriodTooLong(NftId targetNftId, Seconds maxLockingPeriod, Seconds lockingPeriod);
+    error ErrorStakingRewardRateTooHigh(NftId targetNftId, UFixed maxRewardRate, UFixed rewardRate);
+    error ErrorStakingTargetNotFound(NftId targetNftId);
+    error ErrorStakingTargetTokenNotFound(NftId targetNftId, uint256 chainId, address token);
+
+    error ErrorStakingTargetNotActive(NftId targetNftId);
+    error ErrorStakingStakeAmountZero(NftId targetNftId);
+
+    // info for individual stake
+    struct StakeInfo {
+        Timestamp lockedUntil;
+    }
+
+    struct TargetInfo {
+        ObjectType objectType;
+        uint256 chainId;
+        Seconds lockingPeriod;
+        UFixed rewardRate;
+    }
+
+    // rate management 
+    function setStakingRate(uint256 chainId, address token, UFixed stakingRate) external;
+
+
+    // target management
+
+    function registerTarget(
+        NftId targetNftId,
+        ObjectType expectedObjectType,
+        uint256 chainId,
+        Seconds initialLockingPeriod,
+        UFixed initialRewardRate
+    ) external;
+
+    /// @dev set the stake locking period to the specified duration.
+    function setLockingPeriod(NftId targetNftId, Seconds lockingPeriod) external;
+
+    function setRewardRate(NftId targetNftId, UFixed rewardRate) external;
+    function refillRewardReserves(NftId targetNftId, Amount dipAmount) external;
+    function withdrawRewardReserves(NftId targetNftId, Amount dipAmount) external;
+
+    function increaseTvl(NftId targetNftId, address token, Amount amount) external;
+    function decreaseTvl(NftId targetNftId, address token, Amount amount) external;
+
+    function updateRemoteTvl(NftId targetNftId, address token, Amount amount) external;
+
+    // staking functions
+
+    /// @dev register a new stake info object
+    /// permissioned: only staking service may call this function.
+    function registerStake(NftId stakeNftId, NftId targetNftId, Amount dipAmount) external;
+
+    /// @dev increase the staked dip by dipAmount for the specified stake
+    function stake(NftId stakeNftId, Amount dipAmount) external;
+
+    /// @dev restakes the dips to a new target.
+    /// the sum of the staked dips and the accumulated rewards will be restaked.
+    /// permissioned: only staking service may call this function.
+    function restake(NftId stakeNftId) external;
+
+    /// @dev retuns the specified amount of dips to the holder of the specified stake nft.
+    /// if dipAmount is set to Amount.max() all staked dips and all rewards are transferred to 
+    /// permissioned: only staking service may call this function.
+    function unstake(NftId stakeNftId)
+        external
+        returns (
+            Amount unstakedAmount,
+            Amount rewardsClaimedAmount
+        );
+
+    /// @dev update stake rewards for current time.
+    /// may be called before an announement of a decrease of a reward rate reduction.
+    /// calling this functions ensures that reward balance is updated using the current (higher) reward rate.
+    /// unpermissioned.
+    function updateRewards(NftId stakeNftId) external;
+
+    /// @dev transfers all rewards accumulated so far to the holder of the specified stake nft.
+    /// permissioned: only staking service may call this function.
+    function claimRewards(NftId stakeNftId)
+        external
+        returns (
+            Amount rewardsClaimedAmount
+        );
+
+    //--- helper functions --------------------------------------------------//
+
+    /// @dev transfers the specified amount of dips from the from address to the staking wallet.
+    function collectDipAmount(address from, Amount dipAmount) external;
+
+    /// @dev transfers the specified amount of dips from the staking wallet to the to addess.
+    function transferDipAmount(address to, Amount dipAmount) external;
+
+    //--- view and pure functions -------------------------------------------//
+
+    function getStakingStore() external view returns (StakingStore stakingStore);
+    function getStakingReader() external view returns (StakingReader reader);
+
+    // function getStakeInfo(NftId stakeNftId) external view returns (StakeInfo memory stakeInfo);
+    // function getTargetInfo(NftId targetNftId) external view returns (TargetInfo memory targetInfo);
+
+    function getTvlAmount(NftId targetNftId, address token) external view returns (Amount tvlAmount);
+    function getStakedAmount(NftId targetNftId) external view returns (Amount stakeAmount);
+
+    function getStakingRate(uint256 chainId, address token) external view returns (UFixed stakingRate);
+
+    function calculateRewardIncrementAmount(
+        NftId targetNftId,
+        Timestamp rewardsLastUpdatedAt
+    ) external view returns (Amount rewardIncrementAmount);
+
+}

package/contracts/staking/IStakingManager.sol

@@ -0,0 +1,15 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+interface IStakingManager {
+
+    /// @dev initializes staking manager with authority of registry access manager.
+    function initialize(
+        address authority
+    )
+        external;
+
+
+    function getStakingAddress() external view returns (address staking);
+
+}

package/contracts/staking/IStakingService.sol

@@ -0,0 +1,162 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {Amount} from "../type/Amount.sol";
+import {IService} from "../shared/IService.sol";
+import {IStaking} from "./IStaking.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {UFixed} from "../type/UFixed.sol";
+
+
+interface IStakingService is IService
+{
+
+    event LogStakingServiceProtocolTargetRegistered(NftId protocolNftId);
+    event LogStakingServiceInstanceTargetRegistered(NftId instanceNftId, uint256 chainId);
+    event LogStakingServiceLockingPeriodSet(NftId targetNftId, Seconds oldLockingDuration, Seconds lockingDuration);
+    event LogStakingServiceRewardRateSet(NftId targetNftId, UFixed oldRewardRate, UFixed rewardRate);
+
+    event LogStakingServiceStakeCreated(NftId stakeNftId, NftId targetNftId, address owner, Amount stakedAmount);
+    event LogStakingServiceStakeIncreased(NftId stakeNftId, address owner, Amount stakedAmount);
+    event LogStakingServiceRewardsUpdated(NftId stakeNftId);
+
+    // modifiers
+    error ErrorStakingServiceNotNftOwner(NftId nftId, address expectedOwner, address owner);
+    error ErrorStakingServiceNotStaking(address stakingAddress);
+    error ErrorStakingServiceNotSupportingIStaking(address stakingAddress);
+
+    // create
+    error ErrorStakingServiceZeroTargetNftId();
+    error ErrorStakingServiceNotTargetNftId(NftId targetNftId);
+    error ErrorStakingServiceNotActiveTargetNftId(NftId targetNftId);
+    error ErrorStakingServiceDipBalanceInsufficient(NftId targetNftId, uint256 amount, uint256 balance);
+    error ErrorStakingServiceDipAllowanceInsufficient(NftId targetNftId, address tokenHandler, uint256 amount, uint256 allowance);
+
+    /// @dev creates/registers an on-chain instance staking target.
+    /// function granted to instance service
+    function createInstanceTarget(
+        NftId targetNftId,
+        Seconds initialLockingPeriod,
+        UFixed initialRewardRate
+    ) external;
+
+    /// @dev set the stake locking period to the specified duration.
+    /// permissioned: only the owner of the specified target may set the locking period
+    function setLockingPeriod(NftId targetNftId, Seconds lockingPeriod) external;
+
+    /// @dev set the reward rate to the specified value
+    /// permissioned: only the owner of the specified target may set the locking period
+    function setRewardRate(NftId targetNftId, UFixed rewardRate) external;
+
+    /// @dev create a new stake with amount DIP to the specified target
+    /// returns the id of the newly minted stake nft
+    /// permissionless function
+    function create(
+        NftId targetNftId,
+        Amount amount
+    )
+        external
+        returns (
+            NftId stakeNftId
+        );
+
+
+    /// @dev increase an existing stake by amount DIP
+    /// updates the staking reward amount
+    /// function restricted to the current stake owner
+    function stake(
+        NftId stakeNftId,
+        Amount amount
+    )
+        external;
+
+
+    /// @dev re-stakes the current staked DIP as well as all accumulated rewards to the new stake target.
+    /// all related stakes and all accumulated reward DIP are transferred to the current stake holder
+    /// function restricted to the current stake owner
+    function restake(
+        NftId stakeNftId
+    )
+        external;
+
+
+    /// @dev re-stakes the current staked DIP as well as all accumulated rewards to the new stake target.
+    /// all related stakes and all accumulated reward DIP are transferred to the current stake holder
+    /// function restricted to the current stake owner
+    function restakeToNewTarget(
+        NftId stakeNftId,
+        NftId newTargetNftId
+    )
+        external
+        returns (
+            NftId newStakeNftId
+        );
+
+
+    /// @dev decrease an existing stake by amount DIP
+    /// updates the staking reward amount
+    /// function restricted to the current stake owner
+    function unstake(
+        NftId stakeNftId,
+        Amount amount
+    )
+        external;
+
+    /// @dev updates the reward balance of the stake using the current reward rate.
+    function updateRewards(
+        NftId stakeNftId
+    )
+        external;
+
+
+    /// @dev increases the total value locked amount for the specified target by the provided token amount.
+    /// function is called when a new policy is collateralized
+    /// function restricted to the pool service
+    function increaseTotalValueLocked(
+        NftId targetNftId,
+        address token,
+        Amount amount
+    )
+        external
+        returns (Amount totalValueLocked);
+
+
+    /// @dev decreases the total value locked amount for the specified target by the provided token amount.
+    /// function is called when a new policy is closed or payouts are executed
+    /// function restricted to the pool service
+    function decreaseTotalValueLocked(
+        NftId targetNftId,
+        address token,
+        Amount amount
+    )
+        external
+        returns (Amount totalValueLocked);
+
+
+    /// @dev sets total value locked data for a target contract on a different chain.
+    /// this is done via CCIP (cross chain communication) 
+    function setTotalValueLocked(
+        NftId targetNftId,
+        address token,
+        Amount amount
+    )
+        external;
+
+    function getDipToken()
+        external
+        returns (IERC20Metadata dip);
+
+    function getTokenHandler()
+        external
+        returns (TokenHandler tokenHandler);
+
+    function getStaking()
+        external
+        returns (IStaking staking);
+}

package/contracts/staking/IStakingStore.sol

@@ -0,0 +1,130 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManaged} from "@openzeppelin/contracts/access/manager/AccessManaged.sol";
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {Blocknumber, BlocknumberLib} from "../type/Blocknumber.sol";
+import {ChainNft} from "../registry/ChainNft.sol";
+import {Component} from "../shared/Component.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegistryService} from "../registry/IRegistryService.sol";
+import {IStaking} from "./IStaking.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {Key32} from "../type/Key32.sol";
+import {KeyValueStore} from "../shared/KeyValueStore.sol";
+import {KEEP_STATE} from "../type/StateId.sol";
+import {LibNftIdSet} from "../type/NftIdSet.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {NftIdSetManager} from "../shared/NftIdSetManager.sol";
+import {ObjectType, INSTANCE, PROTOCOL, STAKE, STAKING, TARGET} from "../type/ObjectType.sol";
+import {Seconds, SecondsLib} from "../type/Seconds.sol";
+import {StakingReader} from "./StakingReader.sol";
+import {TargetManagerLib} from "./TargetManagerLib.sol";
+import {Timestamp, TimestampLib} from "../type/Timestamp.sol";
+import {TokenRegistry} from "../registry/TokenRegistry.sol";
+import {UFixed, UFixedLib} from "../type/UFixed.sol";
+import {Version, VersionLib} from "../type/Version.sol";
+import {Versionable} from "../shared/Versionable.sol";
+
+
+interface IStakingStore {
+
+    // event LogStakingStoreStakesIncreased(NftId nftId, Amount addedAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+    // event LogStakingStoreStakesDecreased(NftId nftId, Amount addedAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+
+    // event LogStakingStoreRewardsIncreased(NftId nftId, Amount addedAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+    // event LogStakingStoreRewardsDecreased(NftId nftId, Amount addedAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+
+    // event LogStakingStoreRewardsRestaked(NftId nftId, Amount amount, Amount rewardAmount, Amount rewardIncrementAmount, Amount newBalance, Blocknumber lastUpdatedIn);
+
+    // // creating and updating of balance
+    // error ErrorStakingStoreBalanceAlreadyInitialized(NftId nftId);
+    // error ErrorStakingStoreBalanceNotInitialized(NftId nftId);
+
+    //--- target specific functions ------------------------------------//
+
+    function createTarget(
+        NftId targetNftId,
+        IStaking.TargetInfo memory targetInfo
+    )
+        external;
+
+
+    function updateTarget(
+        NftId targetNftId, 
+        IStaking.TargetInfo memory targetInfo
+    )
+        external;
+
+    //--- stake specific functions -------------------------------------//
+
+    function create(
+        NftId stakeNftId, 
+        IStaking.StakeInfo memory stakeInfo,
+        Amount stakeAmount
+    )
+        external;
+
+    function update(
+        NftId stakeNftId, 
+        IStaking.StakeInfo memory stakeInfo
+    )
+        external;
+
+    //--- general functions --------------------------------------------//
+
+
+    function increaseBalance(NftId nftId, Amount amount, Amount rewardIncrementAmount)
+        external;
+
+
+    function restakeRewards(
+        NftId nftId, 
+        Amount rewardIncrementAmount
+    )
+        external;
+
+
+    function updateRewards(
+        NftId nftId, 
+        Amount rewardIncrementAmount
+    )
+        external;
+
+
+    function claimUpTo(
+        NftId nftId, 
+        Amount maxRewardAmount
+    )
+        external
+        returns (Amount rewardsClaimedAmount);
+
+
+    function unstakeUpTo(
+        NftId nftId, 
+        Amount maxUnstakeAmount,
+        Amount maxClaimAmount
+    )
+        external
+        returns (
+            Amount unstakedAmount,
+            Amount claimedAmount
+        );
+
+    //--- view functions -----------------------------------------------//
+
+    function getTargetManager() external view returns (NftIdSetManager targetManager);
+
+    function getStakeBalance(NftId nftId) external view returns (Amount balanceAmount);
+    function getRewardBalance(NftId nftId) external view returns (Amount rewardAmount);
+    function getBalanceUpdatedAt(NftId nftId) external view returns (Timestamp updatedAt);
+
+    function getBalanceAndLastUpdatedAt(NftId nftId)
+        external
+        view
+        returns (
+            Amount stakeBalance,
+            Timestamp lastUpdatedAt
+        );
+}

package/contracts/staking/StakeManagerLib.sol

@@ -0,0 +1,156 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {Component} from "../shared/Component.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegistryService} from "../registry/IRegistryService.sol";
+import {IStaking} from "./IStaking.sol";
+import {Key32} from "../type/Key32.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType, INSTANCE, PROTOCOL, TARGET} from "../type/ObjectType.sol";
+import {Seconds, SecondsLib} from "../type/Seconds.sol";
+import {StakingReader} from "./StakingReader.sol";
+import {Timestamp, TimestampLib} from "../type/Timestamp.sol";
+import {UFixed, UFixedLib} from "../type/UFixed.sol";
+
+
+library StakeManagerLib {
+
+    function checkActiveTarget(
+        StakingReader stakingReader,
+        NftId targetNftId
+    )
+        public
+        view
+    {
+        // target nft id must be registered
+        if (!stakingReader.isTarget(targetNftId)) {
+            revert IStaking.ErrorStakingNotTarget(targetNftId);
+        }
+
+        // only accept stakes for active targets
+        if (!stakingReader.isActive(targetNftId)) {
+            revert IStaking.ErrorStakingTargetNotActive(targetNftId);
+        }
+    }
+
+
+    function checkStakeParameters(
+        StakingReader stakingReader,
+        NftId targetNftId, 
+        Amount dipAmount
+    )
+        external
+        view
+        returns (
+            Timestamp lockedUntil
+        )
+    {
+        // target nft id must be registered
+        if (!stakingReader.isTarget(targetNftId)) {
+            revert IStaking.ErrorStakingNotTarget(targetNftId);
+        }
+
+        // only accept stakes for active targets
+        if (!stakingReader.isActive(targetNftId)) {
+            revert IStaking.ErrorStakingTargetNotActive(targetNftId);
+        }
+
+        checkDipAmount(targetNftId, dipAmount);
+
+        Timestamp currentTime = TimestampLib.blockTimestamp();
+        lockedUntil = currentTime.addSeconds(
+            stakingReader.getTargetInfo(targetNftId).lockingPeriod);
+    }
+
+
+    function checkDipAmount(
+        NftId targetNftId, 
+        Amount dipAmount
+    )
+        public 
+        pure 
+    {
+        // check stake amount > 0
+        if (dipAmount.eqz()) {
+            revert IStaking.ErrorStakingStakeAmountZero(targetNftId);
+        }
+
+        // TODO add check for target specific max dip amount (min stake + tvl * stake rate + buffer)
+    }
+
+
+    function checkDipBalanceAndAllowance(
+        IERC20Metadata dip, 
+        address owner, 
+        address tokenHandlerAddress, 
+        Amount dipAmount
+    )
+        public
+        view
+    {
+        // check balance
+        uint256 amount = dipAmount.toInt();
+        uint256 dipBalance = dip.balanceOf(owner);
+        if (dipBalance < amount) {
+            revert IStaking.ErrorStakingDipBalanceInsufficient(owner, amount, dipBalance);
+        }
+
+        // check allowance
+        uint256 dipAllowance = dip.allowance(owner, tokenHandlerAddress);
+        if (dipAllowance < amount) {
+            revert IStaking.ErrorStakingDipAllowanceInsufficient(owner, tokenHandlerAddress, amount, dipAllowance);
+        }
+    }
+
+
+    function calculateRewardIncrease(
+        StakingReader stakingReader,
+        NftId stakeNftId
+    )
+        public
+        view
+        returns (Amount rewardIncreaseAmount)
+    {
+        (
+            UFixed rewardRate,
+            Amount stakeAmount,
+            Timestamp lastUpdatedAt
+        ) = stakingReader.getRewardCalculationInput(stakeNftId);
+
+        Seconds duration = SecondsLib.toSeconds(
+            block.timestamp - lastUpdatedAt.toInt());
+        
+        rewardIncreaseAmount = calculateRewardAmount(
+            rewardRate,
+            duration,
+            stakeAmount);
+    }
+
+
+    function calculateRewardAmount(
+        UFixed rewardRate,
+        Seconds duration, 
+        Amount stakeAmount
+    )
+        public 
+        pure 
+        returns(
+            Amount rewardAmount
+        )
+    {
+        UFixed yearFraction = getYearFraction(duration);
+        UFixed rewardRateFraction = yearFraction * rewardRate;
+        UFixed amountUFixed = rewardRateFraction * stakeAmount.toUFixed();
+        rewardAmount = AmountLib.toAmount(amountUFixed.toInt());
+    }
+
+
+    function getYearFraction(Seconds duration) public pure returns (UFixed yearFraction) {
+        return UFixedLib.toUFixed(duration.toInt()) / UFixedLib.toUFixed(SecondsLib.oneYear().toInt());
+    }
+
+}