@etherisc/gif-next 0.0.2-a04040f-684 → 0.0.2-a092cff-725

package/contracts/pool/BasicPoolAuthorization.sol

@@ -0,0 +1,76 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAccess} from "../authorization/IAccess.sol";
+import {IInstanceLinkedComponent} from "../shared/IInstanceLinkedComponent.sol";
+import {IPoolComponent} from "./IPoolComponent.sol";
+
+import {Authorization} from "../authorization/Authorization.sol";
+import {BasicPool} from "./BasicPool.sol"; 
+import {COMPONENT, POOL} from "../type/ObjectType.sol";
+import {PUBLIC_ROLE} from "../../contracts/type/RoleId.sol";
+import {RoleId} from "../type/RoleId.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+
+
+contract BasicPoolAuthorization
+     is Authorization
+{
+
+     constructor(string memory poolName)
+          Authorization(poolName, POOL())
+     {}
+
+     function _setupServiceTargets()
+          internal
+          virtual override
+     {
+          _addServiceTargetWithRole(COMPONENT());
+          _addServiceTargetWithRole(POOL());
+     }
+
+     function _setupTokenHandlerAuthorizations() internal virtual override {
+          // authorize token handler functions for component service role
+          IAccess.FunctionInfo[] storage functions;
+          functions = _authorizeForTarget(getTokenHandlerName(), getServiceRole(COMPONENT()));
+          _authorize(functions, TokenHandler.approve.selector, "approve");
+          _authorize(functions, TokenHandler.setWallet.selector, "setWallet");
+          _authorize(functions, TokenHandler.pushFeeToken.selector, "pushFeeToken");
+
+          // authorize token handler functions for pool service role
+          functions = _authorizeForTarget(getTokenHandlerName(), getServiceRole(POOL()));
+          _authorize(functions, TokenHandler.pullToken.selector, "pullToken");
+          _authorize(functions, TokenHandler.pushToken.selector, "pushToken");
+     }
+
+     function _setupTargetAuthorizations()
+          internal
+          virtual override
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          // authorize public role (open access to any account, only allows to lock target)
+          functions = _authorizeForTarget(getMainTargetName(), PUBLIC_ROLE());
+          _authorize(functions, BasicPool.stake.selector, "stake");
+          _authorize(functions, BasicPool.unstake.selector, "unstake");
+          _authorize(functions, BasicPool.extend.selector, "extend");
+          _authorize(functions, BasicPool.lockBundle.selector, "lockBundle");
+          _authorize(functions, BasicPool.unlockBundle.selector, "unlockBundle");
+          _authorize(functions, BasicPool.closeBundle.selector, "closeBundle");
+          _authorize(functions, BasicPool.setBundleFee.selector, "setBundleFee");
+
+          _authorize(functions, BasicPool.setMaxBalanceAmount.selector, "setMaxBalanceAmount");
+          _authorize(functions, BasicPool.setFees.selector, "setFees");
+          _authorize(functions, BasicPool.stake.selector, "stake");
+          _authorize(functions, BasicPool.unstake.selector, "unstake");
+          _authorize(functions, BasicPool.extend.selector, "extend");
+
+          _authorize(functions, IInstanceLinkedComponent.withdrawFees.selector, "withdrawFees");
+          _authorize(functions, BasicPool.withdrawBundleFees.selector, "withdrawBundleFees");
+
+          // authorize pool service
+          functions = _authorizeForTarget(getMainTargetName(), getServiceRole(POOL()));
+          _authorize(functions, IPoolComponent.verifyApplication.selector, "verifyApplication");
+     }
+}
+

package/contracts/pool/BundleService.sol

@@ -0,0 +1,395 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAccountingService} from "../accounting/IAccountingService.sol";
+import {IBundle} from "../instance/module/IBundle.sol";
+import {IBundleService} from "./IBundleService.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IComponentService} from "../shared/IComponentService.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegistryService} from "../registry/IRegistryService.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {InstanceStore} from "../instance/InstanceStore.sol";
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {BundleSet} from "../instance/BundleSet.sol";
+import {ComponentVerifyingService} from "../shared/ComponentVerifyingService.sol";
+import {Fee} from "../type/Fee.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {ObjectType, ACCOUNTING, COMPONENT, POOL, BUNDLE, POLICY, REGISTRY} from "../type/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED, CLOSED, KEEP_STATE} from "../type/StateId.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {Timestamp, TimestampLib, zeroTimestamp} from "../type/Timestamp.sol";
+
+string constant BUNDLE_SERVICE_NAME = "BundleService";
+
+contract BundleService is 
+    ComponentVerifyingService, 
+    IBundleService 
+{
+    
+    string public constant NAME = "BundleService";
+
+    address private _registryAddress;
+    IRegistryService private _registryService;
+    IAccountingService private _accountingService;
+    IComponentService private _componentService;
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        (
+            address authority,
+            address registry
+        ) = abi.decode(data, (address, address));
+
+        __Service_init(authority, registry, owner);
+
+        _registryService = IRegistryService(_getServiceAddress(REGISTRY()));
+        _accountingService = IAccountingService(_getServiceAddress(ACCOUNTING()));
+        _componentService = IComponentService(_getServiceAddress(COMPONENT()));
+
+        _registerInterface(type(IBundleService).interfaceId);
+    }
+
+
+    function setFee(
+        NftId bundleNftId,
+        Fee memory fee
+    )
+        external
+        virtual
+        restricted()
+    {
+        _checkNftType(bundleNftId, BUNDLE());
+
+        (NftId poolNftId,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+        InstanceReader instanceReader = instance.getInstanceReader();
+        IBundle.BundleInfo memory bundleInfo = instanceReader.getBundleInfo(bundleNftId);
+        if(bundleInfo.poolNftId.eqz()) {
+            revert ErrorBundleServiceBundleUnknown(bundleNftId);
+        }
+
+        if(bundleInfo.poolNftId != poolNftId) {
+            revert ErrorBundleServiceBundlePoolMismatch(bundleNftId, bundleInfo.poolNftId, poolNftId);
+        }
+
+        bundleInfo.fee = fee;
+        instance.getInstanceStore().updateBundle(bundleNftId, bundleInfo, KEEP_STATE());
+    }
+
+
+    function create(
+        address owner, 
+        Fee memory bundleFee, 
+        Seconds lifetime, 
+        bytes calldata filter
+    )
+        external
+        virtual
+        restricted()
+        returns(NftId bundleNftId)
+    {
+        (NftId poolNftId,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+
+        // register bundle with registry
+        bundleNftId = _registryService.registerBundle(
+            IRegistry.ObjectInfo(
+                NftIdLib.zero(), 
+                poolNftId,
+                BUNDLE(),
+                false, // intercepting property for bundles is defined on pool
+                address(0),
+                owner,
+                "" // bundle data to be stored in registry
+            )
+        );
+
+        // create bundle info in instance
+        InstanceStore instanceStore = instance.getInstanceStore();
+        instanceStore.createBundle(
+            bundleNftId, 
+            IBundle.BundleInfo({
+                poolNftId: poolNftId,
+                fee: bundleFee,
+                filter: filter,
+                activatedAt: TimestampLib.blockTimestamp(),
+                expiredAt: TimestampLib.blockTimestamp().addSeconds(lifetime),
+                closedAt: zeroTimestamp()
+            })
+        );
+
+        // put bundle under bundle managemet
+        BundleSet bundleManager = instance.getBundleSet();
+        bundleManager.add(bundleNftId);
+
+        emit LogBundleServiceBundleCreated(bundleNftId, poolNftId);
+    }
+
+
+    // the bundle MUST be unlocked (active) for linking (underwriting) and registered with this instance
+    function lockCollateral(
+        IInstance instance,
+        NftId policyNftId, 
+        NftId bundleNftId, 
+        Amount collateralAmount // required local amount to collateralize policy
+    ) 
+        external
+        virtual
+        restricted()
+    {
+        // checks
+        _checkNftType(policyNftId, POLICY());
+        _checkNftType(bundleNftId, BUNDLE());
+
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        {
+            StateId bundleState = instance.getInstanceReader().getBundleState(bundleNftId);
+            IBundle.BundleInfo memory bundleInfo = instanceReader.getBundleInfo(bundleNftId);
+
+            // ensure bundle is active and not yet expired
+            if(bundleState != ACTIVE() || bundleInfo.expiredAt < TimestampLib.blockTimestamp()) {
+                revert ErrorBundleServiceBundleNotOpen(bundleNftId, bundleState, bundleInfo.expiredAt);
+            }
+        }
+
+        InstanceStore instanceStore = instance.getInstanceStore();
+
+        {
+            // ensure bundle capacity is sufficent to collateralize policy
+            (
+                Amount balanceAmount,
+                Amount lockedAmount,
+                Amount feeAmount
+            ) = instanceStore.getAmounts(bundleNftId);
+
+            Amount capacity = balanceAmount - (lockedAmount + feeAmount);
+            if(capacity < collateralAmount) {
+                revert ErrorBundleServiceCapacityInsufficient(bundleNftId, capacity, collateralAmount);
+            }
+        }
+
+        // effects
+        // updated locked amount
+        instanceStore.increaseLocked(bundleNftId, collateralAmount);
+    }
+
+
+    function lock(NftId bundleNftId) 
+        external
+        virtual
+        restricted()
+    {
+        // checks
+        _checkNftType(bundleNftId, BUNDLE());
+
+        (,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+
+        // udpate bundle state
+        instance.getInstanceStore().updateBundleState(bundleNftId, PAUSED());
+
+        // effects
+        // update set of active bundles
+        BundleSet bundleManager = instance.getBundleSet();
+        bundleManager.lock(bundleNftId);
+
+        emit LogBundleServiceBundleLocked(bundleNftId);
+    }
+
+
+    function unlock(NftId bundleNftId) 
+        external
+        virtual
+        restricted()
+    {
+        // checks
+        _checkNftType(bundleNftId, BUNDLE());
+
+        (,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+
+        // effects
+        // udpate bundle state
+        instance.getInstanceStore().updateBundleState(bundleNftId, ACTIVE());
+
+        // update set of active bundles
+        BundleSet bundleManager = instance.getBundleSet();
+        bundleManager.unlock(bundleNftId);
+
+        emit LogBundleServiceBundleActivated(bundleNftId);
+    }
+
+
+    function close(
+        IInstance instance,
+        NftId bundleNftId
+    ) 
+        external
+        virtual
+        restricted()
+        returns (Amount unstakedAmount, Amount feeAmount)
+    {
+        // checks
+        _checkNftType(bundleNftId, BUNDLE());
+
+        InstanceReader instanceReader = instance.getInstanceReader();
+
+        // ensure no open policies attached to bundle
+        BundleSet bundleManager = instance.getBundleSet();
+        uint256 openPolicies = bundleManager.activePolicies(bundleNftId);
+        if(openPolicies > 0) {
+            revert ErrorBundleServiceBundleWithOpenPolicies(bundleNftId, openPolicies);
+        }
+
+        // effects
+        {
+            // update bundle state
+            InstanceStore instanceStore = instance.getInstanceStore();
+            instanceStore.updateBundleState(bundleNftId, CLOSED());
+            bundleManager.lock(bundleNftId);
+
+            // decrease bundle counters
+            Amount balanceAmountWithFees = instanceReader.getBalanceAmount(bundleNftId);
+            feeAmount = instanceReader.getFeeAmount(bundleNftId);
+            unstakedAmount = balanceAmountWithFees - feeAmount;
+            _accountingService.decreaseBundleBalance(instanceStore, bundleNftId, unstakedAmount, feeAmount);
+        }
+    }
+
+    /// @inheritdoc IBundleService
+    function stake(
+        InstanceReader instanceReader,
+        InstanceStore instanceStore,
+        NftId bundleNftId, 
+        Amount amount
+    ) 
+        external 
+        virtual
+        restricted()
+    {
+        // checks
+        _checkNftType(bundleNftId, BUNDLE());
+
+        IBundle.BundleInfo memory bundleInfo = instanceReader.getBundleInfo(bundleNftId);
+        StateId bundleState = instanceReader.getBundleState(bundleNftId);
+
+        if( (bundleState != ACTIVE() && bundleState != PAUSED()) // locked bundles can be staked
+            || bundleInfo.expiredAt < TimestampLib.blockTimestamp() 
+            || bundleInfo.closedAt.gtz()) {
+            revert ErrorBundleServiceBundleNotOpen(bundleNftId, bundleState, bundleInfo.expiredAt);
+        }
+
+        // effects
+        _accountingService.increaseBundleBalance(
+            instanceStore, 
+            bundleNftId, 
+            amount, 
+            AmountLib.zero());
+    }
+
+    /// @inheritdoc IBundleService
+    function unstake(
+        InstanceStore instanceStore,
+        NftId bundleNftId, 
+        Amount amount
+    ) 
+        external 
+        virtual
+        restricted()
+        returns (Amount unstakedAmount)
+    {
+        // checks
+        _checkNftType(bundleNftId, BUNDLE());
+
+        (
+            Amount balanceAmount,
+            Amount lockedAmount,
+            Amount feeAmount
+        ) = instanceStore.getAmounts(bundleNftId);
+
+        unstakedAmount = amount;
+        Amount availableAmount = balanceAmount - (lockedAmount + feeAmount);
+
+        // if amount is max, then unstake all available 
+        if (amount.gte(AmountLib.max())) {
+            unstakedAmount = availableAmount;
+        }
+        
+        // ensure unstaked amount does not exceed available amount
+        if (unstakedAmount > availableAmount) {
+            revert ErrorBundleServiceUnstakeAmountExceedsLimit(amount, availableAmount);
+        }
+
+        // effects
+        _accountingService.decreaseBundleBalance(
+            instanceStore, 
+            bundleNftId, 
+            unstakedAmount, 
+            AmountLib.zero());
+    }
+
+    /// @inheritdoc IBundleService
+    function extend(NftId bundleNftId, Seconds lifetimeExtension) 
+        external 
+        virtual
+        restricted()
+        returns (Timestamp extendedExpiredAt) 
+    {
+        // checks
+        _checkNftType(bundleNftId, BUNDLE());
+
+        (NftId poolNftId,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+        IBundle.BundleInfo memory bundleInfo = instance.getInstanceReader().getBundleInfo(bundleNftId);
+        StateId bundleState = instance.getInstanceReader().getBundleState(bundleNftId);
+
+        // ensure bundle belongs to the pool
+        if (bundleInfo.poolNftId != poolNftId) {
+            revert ErrorBundleServiceBundlePoolMismatch(bundleNftId, bundleInfo.poolNftId, poolNftId);
+        }
+
+        // ensure bundle is active and not yet expired
+        if(bundleState != ACTIVE() || bundleInfo.expiredAt < TimestampLib.blockTimestamp()) {
+            revert ErrorBundleServiceBundleNotOpen(bundleNftId, bundleState, bundleInfo.expiredAt);
+        }
+
+        if (lifetimeExtension.eqz()) {
+            revert ErrorBundleServiceExtensionLifetimeIsZero();
+        }
+
+        // effects
+        bundleInfo.expiredAt = bundleInfo.expiredAt.addSeconds(lifetimeExtension);
+        extendedExpiredAt = bundleInfo.expiredAt;
+
+        instance.getInstanceStore().updateBundle(bundleNftId, bundleInfo, KEEP_STATE());
+
+        emit LogBundleServiceBundleExtended(bundleNftId, lifetimeExtension, extendedExpiredAt);
+    }
+
+
+    function releaseCollateral(
+        InstanceStore instanceStore,
+        NftId policyNftId, 
+        NftId bundleNftId, 
+        Amount collateralAmount
+    ) 
+        external
+        virtual
+        restricted()
+    {
+        _checkNftType(policyNftId, POLICY());
+        _checkNftType(bundleNftId, BUNDLE());
+
+        instanceStore.decreaseLocked(bundleNftId, collateralAmount);
+    }
+
+
+    function _getDomain() internal pure override returns(ObjectType) {
+        return BUNDLE();
+    }
+}

package/contracts/pool/BundleServiceManager.sol

@@ -0,0 +1,39 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {ProxyManager} from "../upgradeability/ProxyManager.sol";
+import {BundleService} from "./BundleService.sol";
+
+contract BundleServiceManager is ProxyManager {
+
+    BundleService private _bundleService;
+
+    /// @dev initializes proxy manager with pool service implementation 
+    constructor(
+        address authority, 
+        address registry,
+        bytes32 salt
+    ) 
+    {
+        BundleService svc = new BundleService{salt: salt}();
+        bytes memory data = abi.encode(authority, registry);
+        IVersionable versionable = initialize(
+            registry,
+            address(svc), 
+            data,
+            salt);
+
+        _bundleService = BundleService(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getBundleService()
+        external
+        view
+        returns (BundleService)
+    {
+        return _bundleService;
+    }
+
+}

package/contracts/pool/IBundleService.sol

@@ -0,0 +1,115 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IService} from "../shared/IService.sol";
+import {IInstance} from "../instance/IInstance.sol";
+
+import {Amount} from "../type/Amount.sol";
+import {NftId} from "../type/NftId.sol";
+import {Fee} from "../type/Fee.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {InstanceStore} from "../instance/InstanceStore.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {StateId} from "../type/StateId.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+interface IBundleService is IService {
+
+    event LogBundleServiceBundleCreated(NftId bundleNftId, NftId poolNftId);
+    event LogBundleServiceBundleActivated(NftId bundleNftId);
+    event LogBundleServiceBundleLocked(NftId bundleNftId);
+
+    error ErrorBundleServiceInsufficientAllowance(address bundleOwner, address tokenHandlerAddress, Amount amount);
+    error ErrorBundleServiceBundleNotOpen(NftId bundleNftId, StateId state, Timestamp expiredAt);
+    error ErrorBundleServiceCapacityInsufficient(NftId bundleNftId, Amount capacityAmount, Amount collateralAmount);
+    error ErrorBundleServiceBundleWithOpenPolicies(NftId bundleNftId, uint256 openPoliciesCount);
+
+    error ErrorBundleServiceBundleUnknown(NftId bundleNftId);
+    error ErrorBundleServiceBundlePoolMismatch(NftId bundleNftId, NftId expectedPool, NftId actualPool);
+
+    error ErrorBundleServicePolicyNotCloseable(NftId policyNftId);
+    
+    error ErrorBundleServiceUnstakeAmountExceedsLimit(Amount amount, Amount limit);
+
+    error ErrorBundleServiceExtensionLifetimeIsZero();
+
+    event LogBundleServiceBundleExtended(NftId bundleNftId, Seconds lifetimeExtension, Timestamp extendedExpiredAt);
+
+    /// @dev Create a new bundle for the specified attributes.
+    function create(
+        address owner, // initial bundle owner
+        Fee memory fee, // fees deducted from premium that go to bundle owner
+        Seconds lifetime, // initial duration for which new policies are covered
+        bytes calldata filter // optional use case specific criteria that define if a policy may be covered by this bundle
+    )
+        external 
+        returns(NftId bundleNftId); // the nft id of the newly created bundle
+
+
+    /// @dev increase bundle stakes by the specified amount. bundle must not be expired or closed
+    /// may only be called by the pool service
+    function stake(
+        InstanceReader instanceReader,
+        InstanceStore instanceStore,
+        NftId bundleNftId, 
+        Amount amount
+    ) external;
+
+    /// @dev decrease bundle stakes by the specified amount
+    /// may only be called by the pool service
+    function unstake(InstanceStore instanceStore, NftId bundleNftId, Amount amount) external returns (Amount unstakedAmount);
+
+    /// @dev extend the lifetime of the bundle by the specified time in seconds
+    function extend(NftId bundleNftId, Seconds lifetimeExtension) external returns (Timestamp extendedExpiredAt);
+
+    /// @dev locks the specified bundle, locked bundles are not available to collateralize new policies
+    /// only active bundles may be locked
+    /// may only be called by registered and unlocked pool components
+    function lock(NftId bundleNftId) external;
+
+    /// @dev activates the specified bundle
+    /// only locked bundles may be unlocked
+    /// may only be called by registered and unlocked pool components
+    function unlock(NftId bundleNftId) external;
+
+    /// @dev closes the specified bundle
+    /// only open bundles (active or locked) may be closed
+    /// to close a bundle it may not have any non-closed polices attached to it
+    /// may only be called by registered and unlocked pool components
+    /// @return balanceAmount the unstaked amount that was remaining in the bundle
+    /// @return feeAmount the fee amount that was remaining for the bundle
+    function close(
+        IInstance instance, 
+        NftId bundleNftId
+    ) external returns (Amount balanceAmount, Amount feeAmount);
+
+    /// @dev set bundle fee to provided value
+    /// may only be called by registered and unlocked pool components
+    function setFee(
+        NftId bundleNftId,
+        Fee memory fee
+    ) external;
+
+
+    /// @dev locks the specified collateral in the bundle
+    /// the locked collateral is added to the bundle locked capital
+    /// the bundles' fees are updated with the fees for this premium
+    /// the premium (minus bundle fee) is added to the bundle capital
+    /// may only be called by pool service
+    function lockCollateral(
+        IInstance instance, 
+        NftId policyNftId, 
+        NftId bundleNftId, 
+        Amount collateralAmount
+    ) external;
+
+
+    /// @dev releases the specified collateral in the bundle
+    /// may only be called by pool service
+    function releaseCollateral(
+        InstanceStore instanceStore, 
+        NftId policyNftId, 
+        NftId bundleNftId, 
+        Amount collateralAmount
+    ) external;
+}

package/contracts/pool/IPoolComponent.sol

@@ -0,0 +1,62 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount} from "../type/Amount.sol";
+import {ClaimId} from "../type/ClaimId.sol";
+import {Fee} from "../type/Fee.sol";
+import {IInstanceLinkedComponent} from "../shared/IInstanceLinkedComponent.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {NftId} from "../type/NftId.sol";
+import {RoleId} from "../type/RoleId.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {UFixed} from "../type/UFixed.sol";
+
+/// @dev pool components hold and manage the collateral to cover active policies
+/// pools come in different flavors
+interface IPoolComponent is IInstanceLinkedComponent {
+
+    error ErrorPoolNotBundleOwner(NftId bundleNftId, address caller);
+    error ErrorPoolNotPoolService(address caller);
+    error ErrorPoolApplicationBundleMismatch(NftId applicationNftId);
+
+    event LogPoolVerifiedByPool(address pool, NftId applicationNftId, Amount collateralizationAmount);
+
+    /// @dev This is a callback function that is called by the product service when underwriting a policy.
+    /// The pool has the option to check the details and object to underwriting by reverting.
+    /// The function is only called for "active" pools that ask to be involved/notified.
+    /// The default implementation is empty.
+    function verifyApplication(
+        NftId applicationNftId, 
+        NftId bundleNftId, 
+        Amount collateralizationAmount
+    ) external;
+
+    /// @dev Returns true iff the application matches with the bundle.
+    /// This is a callback function that is only called if a pool declares itself as a verifying pool
+    /// The default implementation returns true.
+    function applicationMatchesBundle(
+        NftId applicationNftId, 
+        bytes memory applicationData,
+        NftId bundleNftId, 
+        bytes memory bundleFilter,
+        Amount collateralizationAmount
+    )
+        external
+        view
+        returns (bool isMatching);
+
+
+    /// @dev This is a callback function that is called by the claim service when a claim is confirmed.
+    /// The pool has the option to implement custom behavirous such as triggering a reinsurance claim or blocking the claim confirmaation.
+    /// The default implementation is empty.
+    function processConfirmedClaim(
+        NftId policyNftId, 
+        ClaimId claimId, 
+        Amount amount
+    ) external;
+
+
+    /// @dev Returns initial pool specific infos for this pool
+    function getInitialPoolInfo() external view returns (IComponents.PoolInfo memory info);
+
+}