@etherisc/gif-next 0.0.2-9dd41ff-671 → 0.0.2-9ed3c41-176

package/contracts/instance/base/{ObjectManager.sol → ObjectSet.sol}

@@ -10,30 +10,27 @@ import {IRegistry} from "../../registry/IRegistry.sol";
 import {LibNftIdSet} from "../../type/NftIdSet.sol";
 import {NftId} from "../../type/NftId.sol";
 
-contract ObjectManager is
+contract ObjectSet is
     Cloneable
 {
 
-    event LogObjectManagerInitialized(address instance);
+    event LogObjectSetInitialized(address instance);
 
-    error ErrorObjectManagerNftIdInvalid(NftId instanceNftId);
-    error ErrorObjectManagerAlreadyAdded(NftId componentNftId, NftId objectNftId);
+    error ErrorObjectSetNftIdInvalid(NftId instanceNftId);
 
     mapping(NftId compnentNftId => LibNftIdSet.Set objects) internal _activeObjects;
     mapping(NftId compnentNftId => LibNftIdSet.Set objects) internal _allObjects;
-    IInstance internal _instance; // store instance address -> more flexible, instance may not be registered during ObjectManager initialization
+    IInstance internal _instance; // store instance address -> more flexible, instance may not be registered during ObjectSet initialization
 
-    /// @dev call to initialize MUST be made in the same transaction as cloning of the contract
-    function initialize(address instanceAddress) 
-        initializer
-        external 
+    /// @dev This initializer needs to be called from the instance itself.
+    function initialize() 
+        external
+        initializer()
     {
-        IInstance instance = IInstance(instanceAddress);
-        initialize(instance.authority(), address(instance.getRegistry()));
-
-        _instance = instance;
+        _instance = IInstance(msg.sender);
+        __Cloneable_init(_instance.authority(), address(_instance.getRegistry()));
         
-        emit LogObjectManagerInitialized(instanceAddress);
+        emit LogObjectSetInitialized(address(_instance));
     }
 
     function getInstance() external view returns (IInstance) {

package/contracts/instance/module/IAccess.sol

@@ -3,6 +3,7 @@ pragma solidity ^0.8.20;
 
 import {ShortString, ShortStrings} from "@openzeppelin/contracts/utils/ShortStrings.sol";
 
+import {NftId} from "../../type/NftId.sol";
 import {RoleId} from "../../type/RoleId.sol";
 import {Timestamp} from "../../type/Timestamp.sol";
 
@@ -41,4 +42,5 @@ interface IAccess {
     error ErrorIAccessTargetLocked(address target);
     error ErrorIAccessTargetNotRegistered(address target);
     error ErrorIAccessTargetAuthorityInvalid(address target, address targetAuthority);
+    error ErrorIAccessTargetInstanceMismatch(address target, NftId targetParentNftId, NftId instanceNftId);
 }

package/contracts/instance/module/IBundle.sol

@@ -13,10 +13,7 @@ interface IBundle {
         NftId poolNftId;
         Fee fee; // bundle fee on net premium amounts
         bytes filter; // required conditions for applications to be considered for collateralization by this bundle
-        Amount capitalAmount; // net stakings + net premiums - payouts
-        Amount lockedAmount; // capital amount linked to collateralizaion of non-closed policies (<= capital amount)
-        Amount feeAmount; // accumulated fee amount
-        Seconds lifetime;
+        Seconds lifetime; // lifetime of bundle after creation
         Timestamp expiredAt; // no new policies starting with this timestamp
         Timestamp closedAt; // no open policies, locked amount = 0
     }

package/contracts/instance/module/IComponents.sol

@@ -14,21 +14,32 @@ interface IComponents {
 
     struct ComponentInfo {
         string name; // component name (needs to be unique per instance)
+        NftId productNftId;
         IERC20Metadata token;
         TokenHandler tokenHandler;
         address wallet;
-        Amount balanceAmount; // calculated balance (may not necessarily match withg wallet balance)
-        Amount feeAmount; // accumulated fees belonging to component owner
         bytes data; // will hold component type specific additional info (eg encoded pool info)
     }
 
+
+    struct ProductInfo {
+        NftId distributionNftId;
+        NftId poolNftId;
+        Fee productFee; // product fee on net premium
+        Fee processingFee; // product fee on payout amounts        
+        Fee distributionFee; // distribution fee for sales that do not include commissions
+        Fee minDistributionOwnerFee; // min fee required by distribution owner (not including commissions for distributors)
+        Fee poolFee; // pool fee on net premium
+        Fee stakingFee; // pool fee on staked capital from investor
+        Fee performanceFee; // pool fee on profits from capital investors
+    }
+
+
     struct PoolInfo {
         NftId productNftId; // the nft of the product this pool is linked to
         RoleId bundleOwnerRole; // the required role for bundle owners
         // TODO maxCapitalAmount -> maxBalanceAmount
         Amount maxCapitalAmount; // max capital amount allowed for pool
-        Amount balanceAmount; // current pool balance (accounting view)
-        Amount feeAmount; // accumulated fee amount
         bool isInterceptingBundleTransfers; // intercepts nft transfers for bundles
         bool isExternallyManaged; // funding bundles is restricted to book keeping, actual funds may be provided as needed to support payouts
         bool isVerifyingApplications; // underwriting requires the pool component checks/confirms the applications 

package/contracts/instance/module/IPolicy.sol

@@ -12,6 +12,12 @@ import {Timestamp} from "../../type/Timestamp.sol";
 interface IPolicy {
 
     struct Premium {
+        // premium splitting per target wallet
+        Amount productFeeAmount;
+        Amount distributionFeeAndCommissionAmount;
+        Amount poolPremiumAndFeeAmount;
+
+        // detailed positions
         // this is the net premium calculated by the product 
         uint256 netPremiumAmount;
         // fullPremium = netPremium + all fixed amounts + all variable amounts (excl commission and minDistribtuionOwnerFee variable part)
@@ -42,8 +48,8 @@ interface IPolicy {
         ReferralId referralId;
         RiskId riskId;
         Amount sumInsuredAmount;
-        Amount premiumAmount;
-        Amount premiumPaidAmount; // when lower than premium amount: max payout decreased accordingly
+        Amount premiumAmount; // expected premium at application time
+        Amount premiumPaidAmount; // actual paid premium 
         Seconds lifetime;
         // policy application data, no changes after applying for a policy
         bytes applicationData;

package/contracts/mock/Dip.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
+
+contract Dip is ERC20 {
+
+    // https://etherscan.io/token/0xc719d010b63e5bbf2c0551872cd5316ed26acd83#readContract
+    string public constant NAME = "Decentralized Insurance Protocol - DUMMY";
+    string public constant SYMBOL = "DIP";
+    uint8 public constant DECIMALS = 18;
+    uint256 public constant INITIAL_SUPPLY = 10**9 * 10**DECIMALS; // 1 Billion 1'000'000'000
+    // decimals == 18 (openzeppelin erc20 default)
+    constructor()
+        ERC20(NAME, SYMBOL)
+    {
+        _mint(
+            _msgSender(),
+            INITIAL_SUPPLY
+        );   
+    }
+
+    function decimals() public pure override returns(uint8) {
+        return DECIMALS;
+    }
+}

package/contracts/oracle/BasicOracle.sol

@@ -0,0 +1,48 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAuthorization} from "../../contracts/authorization/IAuthorization.sol";
+import {NftId} from "../../contracts/type/NftId.sol";
+import {Oracle} from "../../contracts/oracle/Oracle.sol";
+import {RequestId} from "../../contracts/type/RequestId.sol";
+
+contract BasicOracle is
+    Oracle
+{
+
+    /// Function to provide reponse data releated to request id.
+    function respond(
+        RequestId requestId,
+        bytes memory responseData
+    )
+        external
+        virtual
+        restricted()
+    {
+        _respond(requestId, responseData);
+    }
+
+    function _initializeBasicOracle(
+        address registry,
+        NftId instanceNftId,
+        IAuthorization authorization,
+        address initialOwner,
+        string memory name,
+        address token
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+
+        _initializeOracle(
+            registry,
+            instanceNftId,
+            authorization,
+            initialOwner,
+            name,
+            token,
+            "",
+            "");
+    }
+}

package/contracts/oracle/BasicOracleAuthorization.sol

@@ -0,0 +1,46 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Authorization} from "../authorization/Authorization.sol";
+import {BasicOracle} from "./BasicOracle.sol"; 
+import {ORACLE} from "../type/ObjectType.sol";
+import {IAccess} from "../authorization/IAccess.sol";
+import {IOracle} from "./IOracle.sol"; 
+import {PUBLIC_ROLE} from "../../contracts/type/RoleId.sol";
+import {RoleId} from "../type/RoleId.sol";
+
+
+contract BasicOracleAuthorization
+     is Authorization
+{
+
+     constructor(string memory componentName)
+          Authorization(componentName)
+     {}
+
+     function _setupTargets()
+          internal
+          virtual override
+     {
+          // basic component target
+          _addComponentTargetWithRole(ORACLE()); 
+     }
+
+
+     function _setupTargetAuthorizations()
+          internal
+          virtual override
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          // authorize public role (open access to any account, only allows to lock target)
+          functions = _authorizeForTarget(getTargetName(), getServiceRole(ORACLE()));
+          _authorize(functions, IOracle.request.selector, "request");
+          _authorize(functions, IOracle.cancel.selector, "cancel");
+
+          // authorize public role (open access to any account, only allows to lock target)
+          functions = _authorizeForTarget(getTargetName(), PUBLIC_ROLE());
+          _authorize(functions, BasicOracle.respond.selector, "respond");
+     }
+}
+

package/contracts/oracle/IOracle.sol

@@ -0,0 +1,36 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {NftId} from "../type/NftId.sol";
+import {RequestId} from "../type/RequestId.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+
+interface IOracle {
+
+    struct RequestInfo {
+        NftId requesterNftId; // originator of the request
+        string callbackMethodName; // callback function of the requestor to call to provide response data
+        NftId oracleNftId; // responsible oracle component
+        bytes requestData; 
+        bytes responseData; 
+        Timestamp respondedAt; // response timestamp
+        Timestamp expiredAt; // expiry timestamp
+        bool isCancelled;
+    }
+
+
+    /// @dev Callback function for oracle service to notify this oracle component to retreive some oracle data.
+    function request(
+        RequestId requestId,
+        NftId requesterId,
+        bytes calldata requestData,
+        Timestamp expiryAt
+    ) external;
+
+
+    /// @dev Callback function for oracle service to notify this oracle component that the specified oracle request has ben cancelled by the requestor.
+    function cancel(
+        RequestId requestId
+    ) external;
+}

package/contracts/oracle/IOracleComponent.sol

@@ -0,0 +1,32 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Fee} from "../type/Fee.sol";
+import {IInstanceLinkedComponent} from "../shared/IInstanceLinkedComponent.sol";
+import {ReferralId, ReferralStatus} from "../type/Referral.sol";
+import {NftId} from "../type/NftId.sol";
+import {DistributorType} from "../type/DistributorType.sol";
+import {RequestId} from "../type/RequestId.sol";
+import {UFixed} from "../type/UFixed.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+interface IOracleComponent is IInstanceLinkedComponent {
+
+    /// @dev callback method for requesting some data from the oracle
+    function request(
+        RequestId requestId,
+        NftId requesterNftId,
+        bytes calldata requestData,
+        Timestamp expiryAt
+    ) external;
+
+
+    /// @dev callback method for cancelling the specified oracle request
+    function cancel(
+        RequestId requestId
+    ) external;
+
+
+    /// @dev returns true iff the component needs to be called when selling/renewing policis
+    function isVerifying() external view returns (bool verifying);
+}

package/contracts/oracle/IOracleService.sol

@@ -0,0 +1,65 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IService} from "../shared/IService.sol";
+import {NftId} from "../type/NftId.sol";
+import {RequestId} from "../type/RequestId.sol";
+import {StateId} from "../type/StateId.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+
+interface IOracleService is IService {
+
+    event LogOracleServiceRequestCreated(RequestId requestId, NftId requesterNftId, NftId oracleNftId, Timestamp expiryAt);
+    event LogOracleServiceResponseProcessed(RequestId requestId, NftId oracleNftId);
+    event LogOracleServiceDeliveryFailed(RequestId requestId, address requesterAddress, string functionSignature);
+    event LogOracleServiceResponseResent(RequestId requestId, NftId requesterNftId);
+    event LogOracleServiceRequestCancelled(RequestId requestId, NftId requesterNftId);
+
+    // create request
+    error ErrorOracleServiceInstanceMismatch(NftId expectedInstanceNftId, NftId oracleInstanceNftId);
+    error ErrorOracleServiceExpiryInThePast(Timestamp blockTimestamp, Timestamp expiryAt);
+    error ErrorOracleServiceCallbackMethodNameEmpty();
+
+    // respond
+    error ErrorOracleServiceNotResponsibleOracle(RequestId requestId, NftId expectedOracleNftId, NftId oracleNftId);
+
+    // get request info
+    error ErrorOracleServiceRequestStateNotActive(RequestId requestId, StateId state);
+    error ErrorOracleServiceCallerNotResponsibleOracle(RequestId requestId, NftId oracleNftId, NftId callerNftId);
+    error ErrorOracleServiceCallerNotRequester(RequestId requestId, NftId requesterNftId, NftId callerNftId);
+    error ErrorOracleServiceRequestExpired(RequestId requestId, Timestamp expiredAt);
+    
+    /// @dev send an oracle request to the specified oracle component.
+    /// the function returns the id of the newly created request.
+    /// permissioned: only registered components may send requests to oracles.
+    function request(
+        NftId oracleNftId,
+        bytes calldata requestData,
+        Timestamp expiryAt,
+        string calldata callbackMethodName
+    ) external returns (RequestId requestId);
+
+    /// @dev respond to oracle request by oracle compnent.
+    /// the response data is amende in the request info stored with the instance.
+    /// the request state changes to FULFILLED (when calling the callback method of the requester is successful)
+    /// or to FAILED when calling the requester is not succesful.
+    /// the function returns true iff the state changes to FULFILLED.
+    /// permissioned: only the oracle component linked to the request id may call this method
+    function respond(
+        RequestId requestId,
+        bytes calldata responseData
+    ) external returns (bool success);
+
+    /// @dev re send a failed response to the requester.
+    /// only requests in state FAILED may be re sent.
+    /// the request state changes to FULFILLED when calling the callback method of the requester is successful.
+    /// permissioned: only the requester may resend a request
+    function resend(RequestId requestId) external;
+
+    /// @dev notify the oracle component that the specified request has become invalid.
+    /// only requests in state ACTIVE may be cancelled.
+    /// permissioned: only the requester may cancel a request
+    function cancel(RequestId requestId) external;
+
+}

package/contracts/oracle/Oracle.sol

@@ -0,0 +1,157 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {COMPONENT, ORACLE} from "../type/ObjectType.sol";
+import {IAuthorization} from "../authorization/IAuthorization.sol";
+import {IComponentService} from "../shared/IComponentService.sol";
+import {IOracleComponent} from "./IOracleComponent.sol";
+import {IOracleService} from "./IOracleService.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {ITransferInterceptor} from "../registry/ITransferInterceptor.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {InstanceLinkedComponent} from "../shared/InstanceLinkedComponent.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {RequestId} from "../type/RequestId.sol";
+import {Timestamp, TimestampLib} from "../type/Timestamp.sol";
+import {UFixed} from "../type/UFixed.sol";
+
+
+abstract contract Oracle is
+    InstanceLinkedComponent,
+    IOracleComponent
+{
+    // keccak256(abi.encode(uint256(keccak256("etherisc.storage.Oracle")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant ORACLE_STORAGE_LOCATION_V1 = 0xaab7c0ea03d290e56d6c060e0733d3ebcbe647f7694616a2ec52738a64b2f900;
+
+    struct OracleStorage {
+        IComponentService _componentService;
+        IOracleService _oracleService;
+    }
+
+
+    function register()
+        external
+        virtual
+        onlyOwner()
+    {
+        _getOracleStorage()._componentService.registerOracle();
+    }
+
+
+    function request(
+        RequestId requestId,
+        NftId requesterId,
+        bytes calldata requestData,
+        Timestamp expiryAt
+    )
+        external
+        virtual
+        restricted()
+    {
+        _request(requestId, requesterId, requestData, expiryAt);
+    }
+
+
+    function cancel(
+        RequestId requestId
+    )
+        external
+        virtual
+        restricted()
+    {
+        _cancel(requestId);
+    }
+
+
+    /// @dev Not relevant for oracle components, always returns false.
+    function isVerifying()
+        external 
+        virtual 
+        view 
+        returns (bool verifying)
+    {
+        return false;
+    }
+
+
+    function _initializeOracle(
+        address registry,
+        NftId instanceNftId,
+        IAuthorization authorization,
+        address initialOwner,
+        string memory name,
+        address token,
+        bytes memory registryData, // writeonly data that will saved in the object info record of the registry
+        bytes memory componentData // component specifidc data 
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+        _initializeInstanceLinkedComponent(
+            registry, 
+            instanceNftId, 
+            name, 
+            token, 
+            ORACLE(), 
+            authorization,
+            true, 
+            initialOwner, 
+            registryData, 
+            componentData);
+
+        OracleStorage storage $ = _getOracleStorage();
+        $._oracleService = IOracleService(_getServiceAddress(ORACLE())); 
+        $._componentService = IComponentService(_getServiceAddress(COMPONENT())); 
+
+        registerInterface(type(IOracleComponent).interfaceId);
+    }
+
+
+    /// @dev Internal function for handling requests.
+    /// Empty implementation.
+    /// Overwrite this function to implement use case specific handling for oracle calls.
+    function _request(
+        RequestId requestId,
+        NftId requesterId,
+        bytes calldata requestData,
+        Timestamp expiryAt
+    )
+        internal
+        virtual
+    {
+    }
+
+
+    /// @dev Internal function for cancelling requests.
+    /// Empty implementation.
+    /// Overwrite this function to implement use case specific cancelling.
+    function _cancel(
+        RequestId requestId
+    )
+        internal
+        virtual
+    {
+    }
+
+
+    /// @dev Internal function for handling oracle responses.
+    /// Default implementation sends response back to oracle service.
+    /// Use this function in use case specific external/public functions to handle use case specific response handling.
+    function _respond(
+        RequestId requestId,
+        bytes memory responseData
+    )
+        internal
+        virtual
+    {
+        _getOracleStorage()._oracleService.respond(
+            requestId, responseData);
+    }
+
+    function _getOracleStorage() private pure returns (OracleStorage storage $) {
+        assembly {
+            $.slot := ORACLE_STORAGE_LOCATION_V1
+        }
+    }
+}