@etherisc/gif-next 0.0.2-9b97b55 → 0.0.2-9d3eab3-323

package/contracts/registry/ReleaseManager.sol

@@ -0,0 +1,378 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManaged} from "@openzeppelin/contracts/access/manager/AccessManaged.sol";
+import {AccessManager} from "@openzeppelin/contracts/access/manager/AccessManager.sol";
+
+import {NftId} from "../types/NftId.sol";
+import {RoleId} from "../types/RoleId.sol";
+import {ObjectType, zeroObjectType, SERVICE} from "../types/ObjectType.sol";
+import {VersionPart, VersionPartLib} from "../types/Version.sol";
+
+import {IVersionable} from "../shared/IVersionable.sol";
+import {IService} from "../shared/IService.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
+
+import {IRegistry} from "./IRegistry.sol";
+import {Registry} from "./Registry.sol";
+import {IRegistryService} from "./IRegistryService.sol";
+import {RegistryService} from "./RegistryService.sol";
+import {RegistryServiceManager} from "./RegistryServiceManager.sol";
+import {RegistryAccessManager} from "./RegistryAccessManager.sol";
+
+
+contract ReleaseManager is AccessManaged
+{
+    event LogReleaseCreation(VersionPart version, IService registryService); 
+    event LogServiceRegistration(VersionPart majorVersion, ObjectType serviceDomain); 
+    event LogReleaseActivation(VersionPart version);
+
+    // createNextRelease
+    error NotRegistryService();
+    error UnexpectedServiceAuthority(address expected, address found);
+
+    // registerService
+    error NotService();
+    error ServiceNotInRelease(IService service, ObjectType serviceDomain);
+    error ServiceAlreadyRegistered(address service);
+
+    // activateNextRelease
+    //error ReleaseNotCreated();
+    //error ReleaseRegistrationNotFinished();
+
+    // _getAndVerifyContractInfo
+    error UnexpectedRegisterableType(ObjectType expected, ObjectType found);
+    error NotRegisterableOwner(address expectedOwner);
+    error SelfRegistration();
+    error RegisterableOwnerIsRegistered();
+
+    // _verifyServiceInfo
+    error UnexpectedServiceVersion(VersionPart expected, VersionPart found);
+    error UnexpectedServiceDomain(ObjectType expected, ObjectType found);
+    
+    // _verifyAndStoreConfig
+    error ConfigMissing();
+    error ConfigServiceTypeInvalid();
+    error ConfigSelectorMissing(); 
+    error ConfigSelectorZero(); 
+    error ConfigSelectorAlreadyExists(VersionPart serviceVersion, ObjectType serviceDomain);
+
+    struct ReleaseInfo {
+        ObjectType[] types; // service types in release
+    }
+
+    // unique role for some service function
+    struct ConfigInfo {
+        bytes4[] selector; // selector used by service
+        RoleId roleId; // roleId granted to service
+    }
+
+    RegistryAccessManager private immutable _accessManager;
+    IRegistry private immutable _registry;
+
+    VersionPart _latest;// latest active version
+    VersionPart immutable _initial;// first active version
+
+    mapping(VersionPart version => ReleaseInfo info) _release;
+
+    mapping(VersionPart version => mapping(ObjectType serviceDomain => ConfigInfo)) _config;
+
+    mapping(VersionPart version => mapping(ObjectType serviceDomain => address)) _service;
+
+    uint _awaitingRegistration; // "services left to register" counter
+
+    mapping(address => bool) _isActiveRegistryService;
+
+    constructor(
+        RegistryAccessManager accessManager, 
+        VersionPart initialVersion)
+        AccessManaged(accessManager.authority())
+    {
+        _accessManager = accessManager;
+
+        _initial = initialVersion;
+
+        _registry = new Registry(address(this), initialVersion);
+    }
+
+    // TODO deploy proxy and initialize with given implementation instead of using given proxy?
+    function createNextRelease(IRegistryService registryService)
+        external
+        restricted // GIF_ADMIN_ROLE
+        returns(NftId nftId)
+    {
+        if(!registryService.supportsInterface(type(IRegistryService).interfaceId)) {
+            revert NotRegistryService();
+        }
+
+        if(registryService.authority() != _accessManager.authority()) {
+            revert UnexpectedServiceAuthority(
+                _accessManager.authority(), 
+                registryService.authority()); 
+        }
+
+        (
+            IRegistry.ObjectInfo memory info, 
+            bytes memory data
+        ) = _getAndVerifyContractInfo(registryService, SERVICE(), msg.sender);
+
+        VersionPart nextVersion = getNextVersion();
+        _verifyServiceInfo(info, nextVersion, SERVICE());
+
+        _verifyAndStoreConfig(data);
+
+        //setTargetClosed(newRegistryService, true);
+
+        _registerService(address(registryService), nextVersion, SERVICE());
+        
+        nftId = _registry.registerService(info);
+
+        // external call
+        registryService.linkToRegisteredNftId();
+
+        emit LogReleaseCreation(nextVersion, registryService); 
+    }
+
+    function registerService(IService service) 
+        external
+        restricted // GIF_MANAGER_ROLE
+        returns(NftId nftId)
+    {
+        if(!service.supportsInterface(type(IService).interfaceId)) {
+            revert NotService();
+        }
+
+        (
+            IRegistry.ObjectInfo memory info, 
+            //bytes memory data
+        ) = _getAndVerifyContractInfo(service, SERVICE(), msg.sender);
+
+        VersionPart nextVersion = getNextVersion();
+        ObjectType serviceDomain = _verifyServiceInfo(info, nextVersion, zeroObjectType());
+
+        bytes4[] memory selector = _config[nextVersion][serviceDomain].selector;
+
+        // service type is in release
+        if(selector.length == 0) {
+            revert ServiceNotInRelease(service, serviceDomain); 
+        }
+
+        // setup and grant unique role
+        address registryService = _registry.getServiceAddress(SERVICE(), nextVersion);
+        RoleId roleId = _accessManager.setAndGrantUniqueRole(
+            address(service), 
+            registryService, 
+            selector);
+
+        _config[nextVersion][serviceDomain].roleId = roleId;
+        _awaitingRegistration--;
+
+        // activate release
+        if(_awaitingRegistration == 0) {
+            _latest = nextVersion;
+            _isActiveRegistryService[registryService] = true;  
+
+            emit LogReleaseActivation(nextVersion);
+        }
+
+        _registerService(address(service), nextVersion, serviceDomain);
+
+        nftId = _registry.registerService(info);
+
+        // external call
+        service.linkToRegisteredNftId(); 
+    }
+
+    /*function activateNextRelease() 
+        external 
+        restricted // GIF_ADMIN_ROLE
+    {
+        VersionPart nextVersion = getNextVersion();
+        address service = _service[nextVersion][SERVICE()];
+
+        // release was created
+        if(service == address(0)) {
+            revert ReleaseNotCreated();
+        }
+
+        // release fully deployed
+        if(_awaitingRegistration > 0) {
+            revert ReleaseRegistrationNotFinished();
+        }
+
+        //setTargetClosed(newRegistryService, false);
+
+        _latest = nextVersion;
+        _isActiveRegistryService[service] = true;
+
+        LogReleaseActivation(nextVersion);
+    }*/
+
+    //--- view functions ----------------------------------------------------//
+
+    function isActiveRegistryService(address service) external view returns(bool)
+    {
+        return _isActiveRegistryService[service];
+    }
+
+    function getRegistry() external view returns(address)
+    {
+        return (address(_registry));
+    }
+
+    function getService(VersionPart serviceVersion, ObjectType serviceDomain) external view returns(address)
+    {
+        return _service[serviceVersion][serviceDomain];
+    }
+
+    function getReleaseInfo(VersionPart releaseVersion) external view returns(ReleaseInfo memory)
+    {
+        return _release[releaseVersion];
+    }
+
+    function getNextVersion() public view returns(VersionPart) 
+    {
+        uint256 latest = _latest.toInt();
+
+        return latest == 0 ?
+            _initial : // no active releases yet
+            VersionPartLib.toVersionPart(latest + 1);
+    }
+
+    function getLatestVersion() external view returns(VersionPart) {
+        return _latest;
+    }
+
+    function getInitialVersion() external view returns(VersionPart) {
+        return _initial;
+    }
+
+    //--- private functions ----------------------------------------------------//
+
+    function _registerService(address service, VersionPart version, ObjectType serviceDomain) 
+        internal
+    {
+        if(_service[version][serviceDomain] > address(0)) {
+            revert ServiceAlreadyRegistered(service);
+        }
+
+        _service[version][serviceDomain] = service;
+
+        emit LogServiceRegistration(version, serviceDomain);
+    }
+
+    function _getAndVerifyContractInfo(
+        IService service,
+        ObjectType expectedType,
+        address expectedOwner // assume alway valid, can not be 0
+    )
+        internal
+        view
+        returns(
+            IRegistry.ObjectInfo memory info, 
+            bytes memory data
+        )
+    {
+        (info, data) = service.getInitialInfo();
+        info.objectAddress = address(service);
+        info.isInterceptor = false; // service is never interceptor, at least now
+
+        if(info.objectType != expectedType) {// type is checked in registry anyway...but service logic may depend on expected value
+            revert UnexpectedRegisterableType(expectedType, info.objectType);
+        }
+
+        address owner = info.initialOwner;
+
+        if(owner != expectedOwner) { // registerable owner protection
+            revert NotRegisterableOwner(expectedOwner); 
+        }
+
+        if(owner == address(service)) {
+            revert SelfRegistration();
+        }
+
+        /*if(owner == address(0)) { // never 0
+            revert();// RegisterableOwnerIsZero();
+        }*/
+        
+        if(_registry.isRegistered(owner)) { 
+            revert RegisterableOwnerIsRegistered(); 
+        }
+
+        /*NftId parentNftId = info.parentNftId;
+        IRegistry.ObjectInfo memory parentInfo = getRegistry().getObjectInfo(parentNftId);
+
+        if(parentInfo.objectType != parentType) { // parent registration + type
+            revert InvalidParent(parentNftId);
+        }*/
+
+        return(info, data);
+    }
+
+    function _verifyServiceInfo(
+        IRegistry.ObjectInfo memory info,
+        VersionPart expectedVersion,
+        ObjectType expectedType
+    )
+        internal
+        view
+        returns(ObjectType)
+    {
+        (
+            ObjectType serviceDomain,
+            VersionPart serviceVersion
+        ) = abi.decode(info.data, (ObjectType, VersionPart));
+
+        if(serviceVersion != expectedVersion) {
+            revert UnexpectedServiceVersion(expectedVersion, serviceVersion);
+        }
+
+        if(expectedType != zeroObjectType()) { 
+            if(serviceDomain != expectedType) {
+                revert UnexpectedServiceDomain(expectedType, serviceDomain);
+            }
+        }
+
+        return serviceDomain;
+    }
+
+    function _verifyAndStoreConfig(bytes memory configBytes)
+        internal
+    {
+        VersionPart nextVersion = getNextVersion();
+        IRegistryService.FunctionConfig[] memory config = abi.decode(configBytes, (IRegistryService.FunctionConfig[]));
+
+        if(config.length == 0) {
+            revert ConfigMissing();
+        }
+        // always in release
+        _release[nextVersion].types.push(SERVICE());
+
+        for(uint idx = 0; idx < config.length; idx++)
+        {
+            ObjectType serviceDomain = config[idx].serviceDomain;
+            bytes4[] memory selector = config[idx].selector;
+
+            // not "registry service" type
+            if(serviceDomain == SERVICE()) { revert ConfigServiceTypeInvalid(); } 
+
+            // at least one selector exists
+            if(selector.length == 0) { revert ConfigSelectorMissing(); }
+
+            // no zero selectors
+            for(uint jdx = 0; jdx < selector.length; jdx++) {
+                if(selector[jdx] == 0) { revert ConfigSelectorZero(); }
+            }
+
+            // no overwrite
+            if(_config[nextVersion][serviceDomain].selector.length > 0) { 
+                revert ConfigSelectorAlreadyExists(nextVersion, serviceDomain); 
+            }
+            
+            _config[nextVersion][serviceDomain].selector = selector;
+            _release[nextVersion].types.push(serviceDomain);
+        }
+
+        _awaitingRegistration = config.length;
+    }
+}

package/contracts/registry/TokenRegistry.sol

@@ -0,0 +1,110 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {ERC165Checker} from "@openzeppelin/contracts/utils/introspection/ERC165Checker.sol";
+
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {IRegistry} from "./IRegistry.sol";
+import {Version, VersionPart, VersionLib, VersionPartLib} from "../types/Version.sol";
+import {ObjectType, SERVICE} from "../types/ObjectType.sol";
+import {NftOwnable} from "../shared/NftOwnable.sol";
+
+/// @title contract to register token per GIF major release.
+contract TokenRegistry is
+    NftOwnable
+{
+    event LogRegistered(address token, string symbol, uint256 decimals);
+    event LogTokenStateSet(address token, VersionPart majorVersion, bool active);
+
+    error NotContract(address account);
+    error NotToken(address account);
+    error TokenDecimalsZero();
+    error TokenMajorVersionInvalid(VersionPart majorVersion);
+
+    address [] internal _token;
+    mapping(address token => bool registered) internal _registered;
+    mapping(address token => mapping(VersionPart majorVersion => bool isActive)) internal _active;
+
+    constructor()
+        NftOwnable()
+    { }
+
+
+    /// @dev link ownership of token registry to nft owner of registry service
+    function linkToNftOwnable(address registryAddress) 
+        external
+        onlyOwner
+    {
+        IRegistry registry = IRegistry(registryAddress);
+        // TODO use _latest instead of next version -> _latest is 0 before first release activation
+        address registryServiceAddress = registry.getServiceAddress(SERVICE(), registry.getMajorVersionMax());
+
+        _linkToNftOwnable(registryAddress, registryServiceAddress);
+    }
+
+    /// @dev token state is informative, registry have no clue about used tokens
+    // component owner is responsible for token selection and operations
+    // service MUST deny registration of component with inactive token 
+    function setActive(address token, VersionPart majorVersion, bool active)
+        external
+        onlyOwner
+    {
+        // verify that token is registered
+        if (!_registered[token]) {
+            _registerToken(token);
+        }
+
+        // verify valid major version
+        // ensure major version increments is one
+        uint256 version = majorVersion.toInt();
+        if (version < _registry.getMajorVersionMin().toInt() || version > _registry.getMajorVersionMax().toInt()) {
+            revert TokenMajorVersionInvalid(majorVersion);
+        }
+
+        _active[token][majorVersion] = active;
+
+        emit LogTokenStateSet(token, majorVersion, active);
+    }
+
+    function tokens() external view returns (uint256) {
+        return _token.length;
+    }
+
+    function getToken(uint256 idx) external view returns (IERC20Metadata token) {
+        return IERC20Metadata(_token[idx]);
+    }
+
+    function isRegistered(address token) external view returns (bool) {
+        return _registered[token];
+    }
+
+    function isActive(address token, VersionPart majorVersion) external view returns (bool) {
+        return _active[token][majorVersion];
+    }
+
+    /// @dev some sanity checks to prevent unintended registration
+    function _registerToken(address token) internal {
+
+        // MUST be contract
+        if(token.code.length == 0) {
+            revert NotContract(token);
+        }
+
+        // MUST not be GIF registerable
+        if(ERC165Checker.supportsInterface(token, type(IRegisterable).interfaceId)) {
+            revert NotToken(token);
+        }
+
+        // MUST have decimals > 0
+        IERC20Metadata erc20 = IERC20Metadata(token);
+        if(erc20.decimals() == 0) {
+            revert TokenDecimalsZero();
+        }
+
+        _registered[token] = true;
+        _token.push(token);
+
+        emit LogRegistered(token, erc20.symbol(), erc20.decimals());
+    }
+}

package/contracts/shared/ContractDeployerLib.sol

@@ -0,0 +1,72 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+library ContractDeployerLib {
+
+    event LogContractDeployed(address contractAddress);
+
+    error ErrorCreationCodeHashMismatch(bytes32 expectedHash, bytes32 actualHash);
+
+    /// @dev deploys a new contract using the provided creation code
+    function deploy(
+        bytes memory creationCode,
+        bytes32 expectedCreationCodeHash
+    ) 
+        public
+        returns (address contractAdress)
+    {
+        // check against expected hash, if provided
+        if (expectedCreationCodeHash != bytes32(0)) {
+            bytes32 creationCodeHash = getHash(creationCode);
+            if (creationCodeHash != expectedCreationCodeHash) {
+                revert ErrorCreationCodeHashMismatch(expectedCreationCodeHash, creationCodeHash);
+            }
+        }
+
+        // solhint-disable no-inline-assembly
+        assembly {
+            contractAdress := create(0, add(creationCode, 0x20), mload(creationCode))  
+
+            if iszero(extcodesize(contractAdress)) {
+                revert(0, 0)
+            }
+        }
+        // solhint enable
+
+        emit LogContractDeployed(contractAdress);
+    }
+
+    /// @dev gets the creation code for the new contract
+    // for terminology see eg https://www.rareskills.io/post/ethereum-contract-creation-code
+    function getCreationCode(
+        bytes memory byteCodeWithInitCode, // what you get with type(<Contract>).creationCode
+        bytes memory encodedConstructorArguments // what you get with 
+    )
+        public
+        pure
+        returns (bytes memory creationCode)
+    {
+        return abi.encodePacked(byteCodeWithInitCode, encodedConstructorArguments);
+    }
+
+
+    function matchesWithHash(
+        bytes memory creationCode,
+        bytes32 expectedHash
+    )
+        public
+        pure
+        returns (bool isMatching)
+    {
+        return getHash(creationCode) == expectedHash;
+    }
+
+
+    function getHash(bytes memory creationCode)
+        public
+        pure
+        returns (bytes32 hash)
+    {
+        return keccak256(creationCode);
+    }
+}

package/contracts/shared/ERC165.sol

@@ -0,0 +1,25 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+
+contract ERC165 is IERC165 {
+    mapping(bytes4 => bool) private _isSupported;
+
+    constructor() {
+        _initializeERC165();
+    }
+
+    function supportsInterface(bytes4 interfaceId) external view override returns (bool) {
+        return _isSupported[interfaceId];
+    }
+
+    // @dev register support for ERC165 itself
+    function _initializeERC165() internal {
+        _isSupported[type(IERC165).interfaceId] = true;
+    }
+
+    function _registerInterface(bytes4 interfaceId) internal {
+        _isSupported[interfaceId] = true;
+    }
+}

package/contracts/shared/INftOwnable.sol

@@ -0,0 +1,22 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {NftId} from "../types/NftId.sol";
+
+interface INftOwnable {
+    error ErrorNotOwner(address account);
+
+    error ErrorAlreadyLinked(address registry, NftId nftId);
+    error ErrorRegistryAlreadyInitialized(address registry);
+    error ErrorRegistryNotInitialized();
+    error ErrorRegistryAddressZero();
+    error ErrorNotRegistry(address registryAddress);
+    error ErrorContractNotRegistered(address contractAddress);
+
+    function linkToRegisteredNftId() external;
+
+    function getRegistry() external view returns (IRegistry);
+    function getNftId() external view returns (NftId);
+    function getOwner() external view returns (address);
+}

package/contracts/shared/IRegisterable.sol

@@ -0,0 +1,17 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+
+import {INftOwnable} from "./INftOwnable.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {NftId} from "../types/NftId.sol";
+import {ObjectType} from "../types/ObjectType.sol";
+
+interface IRegisterable is IERC165, INftOwnable {
+
+    function getInitialInfo() 
+        external 
+        view
+        returns (IRegistry.ObjectInfo memory, bytes memory data);
+}

package/contracts/shared/IService.sol

@@ -0,0 +1,16 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {VersionPart} from "../types/Version.sol";
+import {ObjectType} from "../types/ObjectType.sol";
+
+import {IRegisterable} from "./IRegisterable.sol";
+import {IVersionable} from "./IVersionable.sol";
+
+interface IService is 
+    IRegisterable,
+    IVersionable
+{
+    function getDomain() external pure returns(ObjectType serviceDomain);
+    function getMajorVersion() external view returns(VersionPart majorVersion);
+}