@etherisc/gif-next 0.0.2-9b434da-265 → 0.0.2-9b58b75-869

package/contracts/shared/NftOwnable.sol

@@ -1,136 +1,107 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.20;
 
+import {ERC165} from "./ERC165.sol";
 import {INftOwnable} from "./INftOwnable.sol";
-import {IRegistry} from "../registry/IRegistry.sol";
-import {NftId, zeroNftId} from "../types/NftId.sol";
-
-contract NftOwnable is INftOwnable {
-
-    IRegistry internal _registry;
-    NftId private _nftId;
-    address private _initialOwner; 
+import {NftId} from "../type/NftId.sol";
+import {RegistryLinked} from "./RegistryLinked.sol";
+
+contract NftOwnable is
+    ERC165,
+    RegistryLinked,
+    INftOwnable
+{
+    // keccak256(abi.encode(uint256(keccak256("etherisc.storage.NftOwnable")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant NFT_OWNABLE_STORAGE_LOCATION_V1 = 0x07ebcf49758b6ed3af50fa146bec0abe157c0218fe65dc0874c286e9d5da4f00;
+
+    struct NftOwnableStorage {
+        NftId _nftId;
+        address _initialOwner; 
+    }
 
     /// @dev enforces msg.sender is owner of nft (or initial owner of nft ownable)
     modifier onlyOwner() {
-        address owner = getOwner();
-
-        // owner == address(0) is eg uninitialized upgradable contract
-        if (owner != address(0) && msg.sender != owner) {
-            revert ErrorNotOwner(msg.sender);
+        if (msg.sender != getOwner()) {
+            revert ErrorNftOwnableNotOwner(msg.sender);
         }
         _;
     }
 
-    constructor() {
-        _initialOwner = msg.sender;
-    }
-
-    /// @dev links this contract to nft after registration
-    // needs to be done once per registered contract and 
-    // reduces registry calls to check ownership
-    // does not need any protection as function can only do the "right thing"
-    function linkToRegisteredNftId() public {
-        if (_nftId.gtz()) {
-            revert ErrorAlreadyLinked(address(_registry), _nftId);
-        }
-
-        if (address(_registry) == address(0)) {
-            revert ErrorRegistryNotInitialized();
-        }
 
-        address contractAddress = address(this);
+    /// @dev initialization for upgradable contracts
+    // used in _initializeRegisterable
+    function initializeNftOwnable(
+        address initialOwner,
+        address registryAddress
+    )
+        public
+        virtual
+        onlyInitializing()
+    {
+        initializeRegistryLinked(registryAddress);
+        initializeERC165();
 
-        if (!_registry.isRegistered(contractAddress)) {
-            revert ErrorContractNotRegistered(contractAddress);
+        if(initialOwner == address(0)) {
+            revert ErrorNftOwnableInitialOwnerZero();
         }
 
-        _nftId = _registry.getNftId(contractAddress);
+        _getNftOwnableStorage()._initialOwner = initialOwner;
     }
 
 
-    function getRegistry() public view virtual override returns (IRegistry) {
-        return _registry;
+    /// @dev links this contract to nft after registration
+    // needs to be done once per registered contract and 
+    // reduces registry calls to check ownership
+    // does not need any protection as function can only do the "right thing"
+    function linkToRegisteredNftId()
+        public
+        virtual
+        returns (NftId nftId)
+    {
+        return _linkToNftOwnable(address(this));
     }
 
-
     function getNftId() public view virtual override returns (NftId) {
-        return _nftId;
+        return _getNftOwnableStorage()._nftId;
     }
 
-
     function getOwner() public view virtual override returns (address) {
-        if (_nftId.gtz()) {
-            return _registry.ownerOf(_nftId);
+        NftOwnableStorage storage $ = _getNftOwnableStorage();
+
+        if ($._nftId.gtz()) {
+            return getRegistry().ownerOf($._nftId);
         }
 
-        return _initialOwner;
+        return $._initialOwner;
     }
 
-
-    /// @dev initialization for upgradable contracts
-    // used in _initializeRegisterable
-    function _initializeNftOwnable(
-        address initialOwner,
-        address registryAddress
-    )
-        internal
-        virtual
-    {
-        _initialOwner = initialOwner;
-        _setRegistry(registryAddress);
-    }
-
-
     /// @dev used in constructor of registry service manager
     // links ownership of registry service manager ot nft owner of registry service
     function _linkToNftOwnable(
-        address registryAddress,
         address nftOwnableAddress
     )
         internal
-        onlyOwner()
         returns (NftId)
     {
-        if (_nftId.gtz()) {
-            revert ErrorAlreadyLinked(address(_registry), _nftId);
-        }
+        NftOwnableStorage storage $ = _getNftOwnableStorage();
 
-        _setRegistry(registryAddress);
-
-        if (!_registry.isRegistered(nftOwnableAddress)) {
-            revert ErrorContractNotRegistered(nftOwnableAddress);
+        if ($._nftId.gtz()) {
+            revert ErrorNftOwnableAlreadyLinked($._nftId);
         }
 
-        _nftId = _registry.getNftId(nftOwnableAddress);
-
-        return _nftId;
-    }
-
-
-    function _setRegistry(address registryAddress)
-        private
-    {
-        if (address(_registry) != address(0)) {
-            revert ErrorRegistryAlreadyInitialized(address(_registry));
+        if (!getRegistry().isRegistered(nftOwnableAddress)) {
+            revert ErrorNftOwnableContractNotRegistered(nftOwnableAddress);
         }
 
-        if (registryAddress == address(0)) {
-            revert ErrorRegistryAddressZero();
-        }
+        $._nftId = getRegistry().getNftId(nftOwnableAddress);
 
-        if (registryAddress.code.length == 0) {
-            revert ErrorNotRegistry(registryAddress);
-        }
+        return $._nftId;
+    }
 
-        _registry = IRegistry(registryAddress);
 
-        try _registry.supportsInterface(type(IRegistry).interfaceId) returns (bool isRegistry) {
-            if (!isRegistry) {
-                revert ErrorNotRegistry(registryAddress);
-            }
-        } catch {
-            revert ErrorNotRegistry(registryAddress);
+    function _getNftOwnableStorage() private pure returns (NftOwnableStorage storage $) {
+        assembly {
+            $.slot := NFT_OWNABLE_STORAGE_LOCATION_V1
         }
     }
 }

package/contracts/shared/Registerable.sol

@@ -1,29 +1,22 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.20;
 
-import {Initializable} from "@openzeppelin5/contracts/proxy/utils/Initializable.sol"; 
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol"; 
 
-import {NftId, zeroNftId} from "../types/NftId.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
 import {NftOwnable} from "../shared/NftOwnable.sol";
-import {ObjectType} from "../types/ObjectType.sol";
+import {ObjectType} from "../type/ObjectType.sol";
 
 import {IRegistry} from "../registry/IRegistry.sol";
 import {IRegisterable} from "./IRegisterable.sol";
-import {Versionable} from "./Versionable.sol";
-
-import {ERC165} from "./ERC165.sol";
 
 contract Registerable is
-    ERC165,
-    Initializable,
     NftOwnable,
     IRegisterable
 {
     // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.shared.Registerable.sol")) - 1)) & ~bytes32(uint256(0xff));
     bytes32 public constant REGISTERABLE_LOCATION_V1 = 0x6548007c3f4340f82f348c576c0ff69f4f529cadd5ad41f96aae61abceeaa300;
 
-    error ErrorRegisterableNotRegistry(address registryAddress);
-
     struct RegisterableStorage {
         NftId _parentNftId;
         ObjectType _objectType;
@@ -31,38 +24,31 @@ contract Registerable is
         bytes _data;
     }
 
-    function _getRegisterableStorage() private pure returns (RegisterableStorage storage $) {
-        assembly {
-            $.slot := REGISTERABLE_LOCATION_V1
-        }
-    }
-
-    function _initializeRegisterable(
+    function initializeRegisterable(
         address registryAddress,
         NftId parentNftId,
         ObjectType objectType,
         bool isInterceptor,
         address initialOwner,
-        bytes memory data
+        bytes memory registryData // writeonly data that will saved in the object info record of the registry
     )
-        internal
-        //onlyInitializing//TODO uncomment when "fully" upgradeable
+        public
         virtual
+        onlyInitializing
     {
-        _initializeNftOwnable(
+        initializeNftOwnable(
             initialOwner,
             registryAddress);
 
-        // TODO check parentNftId -> registry.isRegistered(parentNftId)
-        // TODO check object-parent type pair -> registry.isValidTypeCombo() or something...verify with registry that setup will be able to register...
+        RegisterableStorage storage $;
+        assembly {
+            $.slot := REGISTERABLE_LOCATION_V1
+        }
 
-        RegisterableStorage storage $ = _getRegisterableStorage();
         $._parentNftId = parentNftId;
         $._objectType = objectType;
         $._isInterceptor = isInterceptor;
-        $._data = data;
-
-        _registerInterface(type(IRegisterable).interfaceId);
+        $._data = registryData;
     }
 
 
@@ -70,20 +56,20 @@ contract Registerable is
         public 
         view 
         virtual 
-        returns (IRegistry.ObjectInfo memory, bytes memory data) 
+        returns (IRegistry.ObjectInfo memory info) 
     {
-        RegisterableStorage storage $ = _getRegisterableStorage();
-        return (
-            IRegistry.ObjectInfo(
-                zeroNftId(),
-                $._parentNftId,
-                $._objectType,
-                $._isInterceptor,
-                address(this), 
-                getOwner(),
-                $._data
-            ),
-            bytes("")
-        );
+        RegisterableStorage storage $;
+        assembly {
+            $.slot := REGISTERABLE_LOCATION_V1
+        }
+
+        info = IRegistry.ObjectInfo(
+            NftIdLib.zero(),
+            $._parentNftId,
+            $._objectType,
+            $._isInterceptor,
+            address(this), 
+            getOwner(),
+            $._data);
     }
 }

package/contracts/shared/RegistryLinked.sol

@@ -0,0 +1,43 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol"; 
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegistryLinked} from "./IRegistryLinked.sol";
+
+contract RegistryLinked is
+    Initializable,
+    IRegistryLinked
+{
+
+    IRegistry private _registry;
+
+    /// @dev initialization for upgradable contracts
+    // used in _initializeRegisterable
+    function initializeRegistryLinked(
+        address registryAddress
+    )
+        public
+        virtual
+        onlyInitializing()
+    {
+        if (registryAddress.code.length == 0) {
+            revert ErrorNotRegistry(registryAddress);
+        }
+
+        _registry = IRegistry(registryAddress);
+
+        try _registry.supportsInterface(type(IRegistry).interfaceId) returns (bool isRegistry) {
+            if (!isRegistry) {
+                revert ErrorNotRegistry(registryAddress);
+            }
+        } catch {
+            revert ErrorNotRegistry(registryAddress);
+        }
+    }
+
+
+    function getRegistry() public view returns (IRegistry) {
+        return _registry;
+    }
+}

package/contracts/shared/Service.sol

@@ -0,0 +1,82 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+import {IAccessManaged} from "@openzeppelin/contracts/access/manager/IAccessManaged.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IService} from "./IService.sol";
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {ObjectType, REGISTRY, SERVICE} from "../type/ObjectType.sol";
+import {Registerable} from "./Registerable.sol";
+import {RoleId, RoleIdLib} from "../type/RoleId.sol";
+import {Version, VersionLib, VersionPartLib} from "../type/Version.sol";
+import {Versionable} from "../upgradeability/Versionable.sol";
+
+
+/// @dev service base contract
+abstract contract Service is 
+    Registerable,
+    Versionable,
+    AccessManagedUpgradeable,
+    IService
+{
+
+    uint8 private constant GIF_MAJOR_VERSION = 3;
+
+
+    function initializeService(
+        address registry, 
+        address authority, // real authority for registry service adress(0) for other services
+        address initialOwner
+    )
+        public
+        virtual
+        onlyInitializing()
+    {
+        initializeRegisterable(
+            registry, 
+            IRegistry(registry).getNftId(), 
+            SERVICE(), 
+            false, // is interceptor
+            initialOwner, 
+            ""); // data
+
+        // externally provided authority
+        if(authority != address(0)) {
+            __AccessManaged_init(authority);
+        } else {
+            address registryServiceAddress = _getServiceAddress(REGISTRY());
+
+            // copy authority from already registered registry services
+            __AccessManaged_init(IAccessManaged(registryServiceAddress).authority());
+        }
+
+        registerInterface(type(IAccessManaged).interfaceId);
+        registerInterface(type(IService).interfaceId);
+    }
+
+    function getDomain() external virtual pure returns(ObjectType serviceDomain) {
+        return _getDomain();
+    }
+
+    function getRoleId() external virtual pure returns(RoleId serviceRoleId) {
+        return RoleIdLib.roleForTypeAndVersion(_getDomain(), VersionPartLib.toVersionPart(GIF_MAJOR_VERSION));
+    }
+
+    // from Versionable
+    function getVersion()
+        public 
+        pure 
+        virtual override (IVersionable, Versionable)
+        returns(Version)
+    {
+        return VersionLib.toVersion(GIF_MAJOR_VERSION,0,0);
+    }
+
+    function _getDomain() internal virtual pure returns (ObjectType);
+
+    function _getServiceAddress(ObjectType domain) internal view returns (address) {
+        return getRegistry().getServiceAddress(domain, VersionPartLib.toVersionPart(GIF_MAJOR_VERSION));
+    }
+}

package/contracts/shared/TokenHandler.sol

@@ -1,9 +1,14 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.20;
 
-import {IERC20Metadata} from "@openzeppelin5/contracts/token/ERC20/extensions/IERC20Metadata.sol";
-import {SafeERC20} from "@openzeppelin5/contracts/token/ERC20/utils/SafeERC20.sol";
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
 
+import {Amount} from "../type/Amount.sol";
+
+/// @dev token specific transfer helper
+/// a default token contract is provided via contract constructor
+/// relies internally on oz SafeERC20.safeTransferFrom
 contract TokenHandler {
     IERC20Metadata private _token;
 
@@ -11,17 +16,43 @@ contract TokenHandler {
         _token = IERC20Metadata(token);
     }
 
-    // TODO add logging
+    /// @dev transfer amount default tokens 
     function transfer(
         address from,
         address to,
-        uint256 amount // TODO add authz (only treasury/instance/product/pool/ service)
-    ) external {
-        SafeERC20.safeTransferFrom(_token, from, to, amount);
-        // _token.transferFrom(from, to, amount);
+        Amount amount
+    )
+        external
+    {
+        SafeERC20.safeTransferFrom(
+            _token, 
+            from, 
+            to, 
+            amount.toInt());
+    }
+
+    /// @dev transfer amount of the specified token
+    function safeTransferFrom(
+        address token,
+        address from,
+        address to,
+        Amount amount
+    )
+        external
+    {
+        SafeERC20.safeTransferFrom(
+            IERC20Metadata(token), 
+            from, 
+            to, 
+            amount.toInt());
     }
 
-    function getToken() external view returns (IERC20Metadata) {
+    /// @dev returns the default token defined for this TokenHandler
+    function getToken()
+        external
+        view 
+        returns (IERC20Metadata)
+    {
         return _token;
     }
 }

package/contracts/staking/IStaking.sol

@@ -0,0 +1,167 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount} from "../type/Amount.sol";
+import {IComponent} from "../shared/IComponent.sol";
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {StakingReader} from "./StakingReader.sol";
+import {StakingStore} from "./StakingStore.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+import {UFixed} from "../type/UFixed.sol";
+
+interface IStaking is 
+    IComponent,
+    IVersionable
+{
+    // staking rate
+    event LogStakingStakingRateSet(uint256 chainId, address token, UFixed oldStakingRate, UFixed newStakingRate);
+
+    // target parameters
+    event LogStakingLockingPeriodSet(NftId targetNftId, Seconds oldLockingPeriod, Seconds lockingPeriod);
+    event LogStakingRewardRateSet(NftId targetNftId, UFixed oldRewardRate, UFixed rewardRate);
+
+    // modifiers
+    error ErrorStakingNotStake(NftId stakeNftId);
+    error ErrorStakingNotTarget(NftId targetNftId);
+
+    error ErrorStakingNotStakingOwner();
+    error ErrorStakingNotNftOwner(NftId nftId);
+
+    // staking rate
+    error ErrorStakingTokenNotRegistered(uint256 chainId, address token);
+
+    // check dip balance and allowance
+    error ErrorStakingDipBalanceInsufficient(address owner, uint256 amount, uint256 dipBalance);
+    error ErrorStakingDipAllowanceInsufficient(address owner, address tokenHandler, uint256 amount, uint256 dipAllowance);
+
+    error ErrorStakingStakingReaderStakingMismatch(address stakingByStakingReader);
+    error ErrorStakingTargetAlreadyRegistered(NftId targetNftId);
+    error ErrorStakingTargetNftIdZero();
+    error ErrorStakingTargetTypeNotSupported(NftId targetNftId, ObjectType objectType);
+    error ErrorStakingTargetUnexpectedObjectType(NftId targetNftId, ObjectType expectedObjectType, ObjectType actualObjectType);
+    error ErrorStakingLockingPeriodZero(NftId targetNftId);
+    error ErrorStakingLockingPeriodTooLong(NftId targetNftId, Seconds maxLockingPeriod, Seconds lockingPeriod);
+    error ErrorStakingRewardRateTooHigh(NftId targetNftId, UFixed maxRewardRate, UFixed rewardRate);
+    error ErrorStakingTargetNotFound(NftId targetNftId);
+    error ErrorStakingTargetTokenNotFound(NftId targetNftId, uint256 chainId, address token);
+
+    error ErrorStakingTargetNotActive(NftId targetNftId);
+    error ErrorStakingStakeAmountZero(NftId targetNftId);
+
+    // info for individual stake
+    struct StakeInfo {
+        Timestamp lockedUntil;
+    }
+
+    struct TargetInfo {
+        ObjectType objectType;
+        uint256 chainId;
+        Seconds lockingPeriod;
+        UFixed rewardRate;
+    }
+
+    // staking rate management 
+
+    /// @dev sets the rate that converts 1 token of total value locked into the
+    /// the required staked dip amount to back up the locked token value
+    function setStakingRate(uint256 chainId, address token, UFixed stakingRate) external;
+
+
+    // target management
+
+    function registerTarget(
+        NftId targetNftId,
+        ObjectType expectedObjectType,
+        uint256 chainId,
+        Seconds initialLockingPeriod,
+        UFixed initialRewardRate
+    ) external;
+
+
+    /// @dev set the stake locking period to the specified duration.
+    /// permissioned: only the staking service may call this function
+    function setLockingPeriod(NftId targetNftId, Seconds lockingPeriod) external;
+
+    /// @dev update the target specific reward rate.
+    /// permissioned: only the staking service may call this function
+    function setRewardRate(NftId targetNftId, UFixed rewardRate) external;
+
+    /// @dev (re)fills the staking reward reserves for the specified target
+    /// unpermissioned: anybody may fill up staking reward reserves
+    function refillRewardReserves(NftId targetNftId, Amount dipAmount) external returns (Amount newBalance);
+
+    /// @dev defunds the staking reward reserves for the specified target
+    /// permissioned: only the staking service may call this function
+    function withdrawRewardReserves(NftId targetNftId, Amount dipAmount) external returns (Amount newBalance);
+
+
+    /// @dev increases the total value locked amount for the specified target by the provided token amount.
+    /// function is called when a new policy is collateralized.
+    /// function restricted to the pool service.
+    function increaseTotalValueLocked(NftId targetNftId, address token, Amount amount) external returns (Amount newBalance);
+
+
+    /// @dev decreases the total value locked amount for the specified target by the provided token amount.
+    /// function is called when a new policy is closed or payouts are executed.
+    /// function restricted to the pool service.
+    function decreaseTotalValueLocked(NftId targetNftId, address token, Amount amount) external returns (Amount newBalance);
+
+
+    function updateRemoteTvl(NftId targetNftId, address token, Amount amount) external;
+
+    // staking functions
+
+    /// @dev creat a new stake info object
+    /// permissioned: only staking service may call this function.
+    function createStake(NftId stakeNftId, NftId targetNftId, Amount dipAmount) external;
+
+    /// @dev increase the staked dip by dipAmount for the specified stake.
+    /// staking rewards are updated and added to the staked dips as well.
+    /// the function returns the new total amount of staked dips.
+    function stake(NftId stakeNftId, Amount dipAmount) external returns (Amount stakeBalance);
+
+    /// @dev restakes the dips to a new target.
+    /// the sum of the staked dips and the accumulated rewards will be restaked.
+    /// permissioned: only staking service may call this function.
+    function restake(NftId stakeNftId, NftId newTargetNftId) external returns (NftId newStakeNftId);
+
+    /// @dev retuns the specified amount of dips to the holder of the specified stake nft.
+    /// if dipAmount is set to Amount.max() all staked dips and all rewards are transferred to 
+    /// permissioned: only staking service may call this function.
+    function unstake(NftId stakeNftId)
+        external
+        returns (
+            Amount unstakedAmount,
+            Amount rewardsClaimedAmount
+        );
+
+    /// @dev update stake rewards for current time.
+    /// may be called before an announement of a decrease of a reward rate reduction.
+    /// calling this functions ensures that reward balance is updated using the current (higher) reward rate.
+    /// unpermissioned.
+    function updateRewards(NftId stakeNftId) external;
+
+    /// @dev transfers all rewards accumulated so far to the holder of the specified stake nft.
+    /// permissioned: only staking service may call this function.
+    function claimRewards(NftId stakeNftId)
+        external
+        returns (
+            Amount rewardsClaimedAmount
+        );
+
+    //--- helper functions --------------------------------------------------//
+
+    /// @dev transfers the specified amount of dips from the from address to the staking wallet.
+    function collectDipAmount(address from, Amount dipAmount) external;
+
+    /// @dev transfers the specified amount of dips from the staking wallet to the to addess.
+    function transferDipAmount(address to, Amount dipAmount) external;
+
+    //--- view and pure functions -------------------------------------------//
+
+    function getStakingStore() external view returns (StakingStore stakingStore);
+    function getStakingReader() external view returns (StakingReader reader);
+}