@etherisc/gif-next 0.0.2-9a02a95-445 → 0.0.2-9a680f3-735

package/contracts/staking/IStakingService.sol

@@ -0,0 +1,168 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {Amount} from "../type/Amount.sol";
+import {IService} from "../shared/IService.sol";
+import {IStaking} from "./IStaking.sol";
+import {NftId} from "../type/NftId.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {UFixed} from "../type/UFixed.sol";
+
+
+interface IStakingService is IService
+{
+
+    event LogStakingServiceProtocolTargetRegistered(NftId protocolNftId);
+    event LogStakingServiceInstanceTargetRegistered(NftId instanceNftId, uint256 chainId);
+    event LogStakingServiceLockingPeriodSet(NftId targetNftId, Seconds oldLockingDuration, Seconds lockingDuration);
+    event LogStakingServiceRewardRateSet(NftId targetNftId, UFixed oldRewardRate, UFixed rewardRate);
+
+    event LogStakingServiceRewardReservesIncreased(NftId targetNftId, address rewardProvider, Amount dipAmount, Amount newBalance);
+    event LogStakingServiceRewardReservesDecreased(NftId targetNftId, address targetOwner, Amount dipAmount, Amount newBalance);
+
+    event LogStakingServiceStakeCreated(NftId stakeNftId, NftId targetNftId, address owner, Amount stakedAmount);
+    event LogStakingServiceStakeIncreased(NftId stakeNftId, address owner, Amount stakedAmount, Amount stakeBalance);
+    event LogStakingServiceUnstaked(NftId stakeNftId, address stakeOwner, Amount totalAmount);
+    event LogStakingServiceStakeRestaked(address stakeOwner, NftId indexed stakeNftId, NftId newStakeNftId, NftId indexed newTargetNftId, Amount indexed newStakeBalance);
+
+    event LogStakingServiceRewardsUpdated(NftId stakeNftId);
+    event LogStakingServiceRewardsClaimed(NftId stakeNftId, address stakeOwner, Amount rewardsClaimedAmount);
+
+    // modifiers
+    error ErrorStakingServiceNotStakingOwner(address account);
+    error ErrorStakingServiceNotStaking(address stakingAddress);
+    error ErrorStakingServiceNotSupportingIStaking(address stakingAddress);
+
+    // create
+    error ErrorStakingServiceTargetUnknown(NftId targetNftId);
+    error ErrorStakingServiceZeroTargetNftId();
+    error ErrorStakingServiceNotTargetNftId(NftId targetNftId);
+    error ErrorStakingServiceNotActiveTargetNftId(NftId targetNftId);
+    error ErrorStakingServiceDipBalanceInsufficient(NftId targetNftId, uint256 amount, uint256 balance);
+    error ErrorStakingServiceDipAllowanceInsufficient(NftId targetNftId, address tokenHandler, uint256 amount, uint256 allowance);
+
+    /// @dev Set the protocol reward rate stake locking period to the specified duration.
+    /// Permissioned: only staking owner
+    // TODO implement
+    // function setProtocolRewardRate(UFixed rewardRate) external;
+    // function setProtocolLockingPeriod(Seconds lockingPeriod) external;
+    // TODO also make sure that protocol rewards can be refilled and withdrawn
+
+    /// @dev Approves the staking token handler.
+    /// Reverts if the staking token handler wallet is not the token handler itself.
+    function approveTokenHandler(
+        IERC20Metadata token,
+        Amount amount
+    ) external;
+
+    /// @dev creates/registers an on-chain instance staking target.
+    /// function granted to instance service
+    function createInstanceTarget(
+        NftId targetNftId,
+        Seconds initialLockingPeriod,
+        UFixed initialRewardRate
+    ) external;
+
+    /// @dev Set the instance stake locking period to the specified duration.
+    /// Permissioned: Only owner of the specified target.
+    function setInstanceLockingPeriod(NftId instanceNftId, Seconds lockingPeriod) external;
+
+    /// @dev Set the instance reward rate to the specified value.
+    /// Permissioned: Only owner of the specified target.
+    function setInstanceRewardRate(NftId instanceNftId, UFixed rewardRate) external;
+
+    /// @dev (Re)fills the staking reward reserves for the specified target using the dips provided by the reward provider.
+    /// unpermissioned: anybody may fill up staking reward reserves
+    function refillInstanceRewardReserves(NftId instanceNftId, address rewardProvider, Amount dipAmount) external returns (Amount newBalance);
+
+    /// @dev (Re)fills the staking reward reserves for the specified target using the dips provided by the sender
+    /// unpermissioned: anybody may fill up staking reward reserves
+    function refillRewardReservesBySender(NftId targetNftId, Amount dipAmount) external returns (Amount newBalance);
+
+    /// @dev Defunds the staking reward reserves for the specified target
+    /// Permissioned: only the target owner may call this function
+    function withdrawInstanceRewardReserves(NftId instanceNftId, Amount dipAmount) external returns (Amount newBalance);
+
+    /// @dev create a new stake with amount DIP to the specified target
+    /// returns the id of the newly minted stake nft
+    /// permissionless function
+    function create(
+        NftId targetNftId,
+        Amount amount
+    )
+        external
+        returns (
+            NftId stakeNftId
+        );
+
+
+    /// @dev increase an existing stake by amount DIP
+    /// updates and restakes the staking reward amount
+    /// function restricted to the current stake owner
+    function stake(
+        NftId stakeNftId,
+        Amount amount
+    )
+        external;
+
+
+    /// @dev re-stakes the current staked DIP as well as all accumulated rewards to the new stake target.
+    /// all related stakes and all accumulated reward DIP are transferred to the current stake holder
+    /// function restricted to the current stake owner
+    function restakeToNewTarget(
+        NftId stakeNftId,
+        NftId newTargetNftId
+    )
+        external
+        returns (
+            NftId newStakeNftId,
+            Amount newStakeBalance
+        );
+
+
+    /// @dev updates the reward balance of the stake using the current reward rate.
+    function updateRewards(
+        NftId stakeNftId
+    )
+        external;
+
+
+    /// @dev claims all available rewards.
+    function claimRewards(
+        NftId stakeNftId
+    )
+        external;
+
+
+    /// @dev unstakes all dips (stakes and rewards) of an existing stake.
+    /// function restricted to the current stake owner
+    function unstake(
+        NftId stakeNftId
+    )
+        external;
+
+
+    /// @dev sets total value locked data for a target contract on a different chain.
+    /// this is done via CCIP (cross chain communication) 
+    function setTotalValueLocked(
+        NftId targetNftId,
+        address token,
+        Amount amount
+    )
+        external;
+
+    function getDipToken()
+        external
+        returns (IERC20Metadata dip);
+
+    function getTokenHandler()
+        external
+        returns (TokenHandler tokenHandler);
+
+    function getStaking()
+        external
+        returns (IStaking staking);
+}

package/contracts/staking/Staking.sol

@@ -0,0 +1,530 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRelease} from "../registry/IRelease.sol";
+import {IStaking} from "./IStaking.sol";
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {Component} from "../shared/Component.sol";
+import {IComponent} from "../shared/IComponent.sol";
+import {IComponentService} from "../shared/IComponentService.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType, STAKE, STAKING} from "../type/ObjectType.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {Registerable} from "../shared/Registerable.sol";
+import {StakingLib} from "./StakingLib.sol";
+import {StakingReader} from "./StakingReader.sol";
+import {StakingStore} from "./StakingStore.sol";
+import {TargetManagerLib} from "./TargetManagerLib.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {TokenHandlerDeployerLib} from "../shared/TokenHandlerDeployerLib.sol";
+import {TokenRegistry} from "../registry/TokenRegistry.sol";
+import {UFixed} from "../type/UFixed.sol";
+import {Version, VersionLib, VersionPart, VersionPartLib} from "../type/Version.sol";
+import {Versionable} from "../upgradeability/Versionable.sol";
+
+contract Staking is 
+    Component,
+    Versionable,
+    IStaking
+{
+    string public constant CONTRACT_NAME = "Staking";
+
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.component.Staking.sol")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant STAKING_LOCATION_V1 = 0xafe8d4462b2ed26a47154f4b8f6d1497d2f772496965791d25bd456e342b7f00;
+
+    struct StakingStorage {
+        TokenRegistry _tokenRegistry;
+        TokenHandler _tokenHandler;
+        StakingStore _store;
+        StakingReader _reader;
+        NftId _protocolNftId;
+    }
+
+
+    modifier onlyStake(NftId stakeNftId) {
+        if (!_getStakingStorage()._store.exists(stakeNftId)) {
+            revert ErrorStakingNotStake(stakeNftId);
+        }
+        _;
+    }
+
+
+    modifier onlyTarget(NftId targetNftId) {
+        if (!_getStakingStorage()._store.getTargetNftIdSet().exists(targetNftId)) {
+            revert ErrorStakingNotTarget(targetNftId);
+        }
+        _;
+    }
+
+    function initializeTokenHandler()
+        external
+    {
+        if (msg.sender != address(getRegistry())) {
+            revert ErrorStakingNotRegistry(msg.sender);
+        }
+
+        StakingStorage storage $ = _getStakingStorage();
+        $._tokenHandler = TokenHandlerDeployerLib.deployTokenHandler(
+            address(getRegistry()),
+            address(this),
+            address(getToken()), 
+            getRegistry().getAuthority());
+    }
+
+
+    function approveTokenHandler(IERC20Metadata token, Amount amount)
+        public
+        restricted()
+        onlyOwner()
+    {
+        _approveTokenHandler(token, amount);
+    }
+
+
+    // set/update staking reader
+    function setStakingReader(StakingReader stakingReader)
+        external
+        virtual
+        onlyOwner()
+    {
+        if(stakingReader.getStaking() != IStaking(this)) {
+            revert ErrorStakingStakingReaderStakingMismatch(address(stakingReader.getStaking()));
+        }
+
+        _getStakingStorage()._reader = stakingReader;
+    }
+
+
+    // rate management 
+    function setStakingRate(uint256 chainId, address token, UFixed stakingRate)
+        external
+        virtual
+        onlyOwner()
+    {
+        StakingStorage storage $ = _getStakingStorage();
+        
+        if (!$._tokenRegistry.isRegistered(chainId, token)) {
+            revert ErrorStakingTokenNotRegistered(chainId, token);
+        }
+
+        UFixed oldStakingRate = $._store.getStakingRate(chainId, token);
+        $._store.setStakingRate(chainId, token, stakingRate);
+
+        emit LogStakingStakingRateSet(chainId, token, oldStakingRate, stakingRate);
+    }
+
+    // target management
+
+    function registerTarget(
+        NftId targetNftId,
+        ObjectType expectedObjectType,
+        uint256 chainId,
+        Seconds initialLockingPeriod,
+        UFixed initialRewardRate
+    )
+        external
+        virtual
+        restricted()
+    {
+        TargetManagerLib.checkTargetParameters(
+            getRegistry(), 
+            _getStakingStorage()._reader,
+            targetNftId, 
+            expectedObjectType, 
+            initialLockingPeriod, 
+            initialRewardRate);
+
+        _getStakingStorage()._store.createTarget(
+            targetNftId,
+            TargetInfo({
+                objectType: expectedObjectType,
+                chainId: chainId,
+                lockingPeriod: initialLockingPeriod,
+                rewardRate: initialRewardRate}));
+    }
+
+
+    function setLockingPeriod(
+        NftId targetNftId, 
+        Seconds lockingPeriod
+    )
+        external
+        virtual
+        restricted()
+        onlyTarget(targetNftId)
+    {
+        (
+            Seconds oldLockingPeriod,
+            TargetInfo memory targetInfo
+        ) = TargetManagerLib.updateLockingPeriod(
+            this,
+            targetNftId,
+            lockingPeriod);
+        
+        _getStakingStorage()._store.updateTarget(targetNftId, targetInfo);
+
+        emit LogStakingLockingPeriodSet(targetNftId, oldLockingPeriod, lockingPeriod);
+    }
+
+    // TODO add function to set protocol reward rate: onlyOwner
+    // get protocol nft id (from where)
+
+    function setRewardRate(NftId targetNftId, UFixed rewardRate)
+        external
+        virtual
+        restricted()
+        onlyTarget(targetNftId)
+    {
+        (
+            UFixed oldRewardRate,
+            TargetInfo memory targetInfo
+        ) = TargetManagerLib.updateRewardRate(
+            this,
+            targetNftId,
+            rewardRate);
+        
+        _getStakingStorage()._store.updateTarget(targetNftId, targetInfo);
+
+        emit LogStakingRewardRateSet(targetNftId, oldRewardRate, rewardRate);
+    }
+
+
+    function refillRewardReserves(NftId targetNftId, Amount dipAmount)
+        external
+        virtual
+        restricted()
+        returns (Amount newBalance)
+    {
+        // update book keeping of reward reserves
+        StakingStorage storage $ = _getStakingStorage();
+        newBalance = $._store.increaseReserves(targetNftId, dipAmount);
+    }
+
+
+    function withdrawRewardReserves(NftId targetNftId, Amount dipAmount)
+        external
+        virtual
+        restricted()
+        returns (Amount newBalance)
+    {
+        // update book keeping of reward reserves
+        StakingStorage storage $ = _getStakingStorage();
+        newBalance = $._store.decreaseReserves(targetNftId, dipAmount);
+    }
+
+
+    function increaseTotalValueLocked(NftId targetNftId, address token, Amount amount)
+        external
+        virtual
+        restricted() // only pool service
+        returns (Amount newBalance)
+    {
+        StakingStorage storage $ = _getStakingStorage();
+        uint chainId = $._reader.getTargetInfo(targetNftId).chainId;
+        UFixed stakingRate = $._reader.getStakingRate(chainId, token);
+        newBalance = $._store.increaseTotalValueLocked(targetNftId, stakingRate, token, amount);
+    }
+
+
+    function decreaseTotalValueLocked(NftId targetNftId, address token, Amount amount)
+        external
+        virtual
+        restricted() // only pool service
+        returns (Amount newBalance)
+    {
+        StakingStorage storage $ = _getStakingStorage();
+        uint chainId = $._reader.getTargetInfo(targetNftId).chainId;
+        UFixed stakingRate = $._reader.getStakingRate(chainId, token);
+        newBalance = $._store.decreaseTotalValueLocked(targetNftId, stakingRate, token, amount);
+    }
+
+
+    function registerRemoteTarget(NftId targetNftId, TargetInfo memory targetInfo)
+        external
+        virtual
+        restricted()
+        onlyOwner // or CCIP
+    {
+        
+    }
+
+    function updateRemoteTvl(NftId targetNftId, address token, Amount amount)
+        external
+        virtual
+        restricted()
+        onlyOwner // or CCIP
+    {
+        
+    }
+
+    //--- staking functions -------------------------------------------------//
+
+    function createStake(
+        NftId stakeNftId, 
+        NftId targetNftId, 
+        Amount stakeAmount
+    )
+        external
+        virtual
+        restricted() // only staking service
+    {
+        StakingStorage storage $ = _getStakingStorage();
+        Timestamp lockedUntil = StakingLib.checkCreateParameters(
+            $._reader,
+            targetNftId,
+            stakeAmount);
+
+        // create new stake
+        $._store.create(
+            stakeNftId, 
+            StakeInfo({
+                lockedUntil: lockedUntil}));
+        
+        // update target stake balance
+        $._store.increaseStake(
+            stakeNftId,
+            targetNftId, 
+            stakeAmount);
+    }
+
+
+    function stake(
+        NftId stakeNftId, 
+        Amount stakeAmount
+    )
+        external
+        virtual
+        restricted() // only staking service
+        onlyStake(stakeNftId)
+        returns (Amount stakeBalance)
+    {
+        StakingStorage storage $ = _getStakingStorage();
+        stakeBalance = StakingLib.stake(
+            getRegistry(),
+            $._reader,
+            $._store,
+            stakeNftId,
+            stakeAmount);
+    }
+
+
+    function restake(
+        NftId stakeNftId, 
+        NftId newStakeNftId
+    )
+        external
+        virtual
+        restricted() // only staking service
+        onlyStake(stakeNftId)
+        returns (Amount newStakeBalance)
+    {
+        _checkNftType(stakeNftId, STAKE());
+        _checkNftType(newStakeNftId, STAKE());
+
+        // TODO add check that allows additional staking amount
+        StakingStorage storage $ = _getStakingStorage();
+        newStakeBalance = StakingLib.restake(
+            $._reader,
+            $._store,
+            stakeNftId,
+            newStakeNftId);    
+    }
+
+    function updateRewards(NftId stakeNftId)
+        external
+        virtual
+        restricted() // only staking service
+        onlyStake(stakeNftId)
+    {
+        StakingStorage storage $ = _getStakingStorage();
+        _updateRewards($._reader, $._store, stakeNftId);
+    }
+
+
+    function claimRewards(NftId stakeNftId)
+        external
+        virtual
+        restricted() // only staking service
+        onlyStake(stakeNftId)
+        returns (
+            Amount rewardsClaimedAmount
+        )
+    {
+        StakingStorage storage $ = _getStakingStorage();
+
+        // update rewards since last update
+        NftId targetNftId = _updateRewards($._reader, $._store, stakeNftId);
+
+        // unstake all available rewards
+        rewardsClaimedAmount = $._store.claimUpTo(
+            stakeNftId,
+            targetNftId, 
+            AmountLib.max());
+
+        // update reward reserves
+        $._store.decreaseReserves(targetNftId, rewardsClaimedAmount);
+    }
+
+
+    function unstake(NftId stakeNftId)
+        external
+        virtual
+        restricted() // only staking service
+        onlyStake(stakeNftId)
+        returns (
+            Amount unstakedAmount,
+            Amount rewardsClaimedAmount
+        )
+    {
+        StakingStorage storage $ = _getStakingStorage();
+        
+        StakingLib.checkUnstakeParameters($._reader, stakeNftId);
+        
+        // update rewards since last update
+        NftId targetNftId = _updateRewards($._reader, $._store, stakeNftId);
+
+        // unstake all available dips
+        (
+            unstakedAmount, 
+            rewardsClaimedAmount
+        ) = $._store.unstakeUpTo(
+            stakeNftId,
+            targetNftId,
+            AmountLib.max(), // unstake all stakes
+            AmountLib.max()); // claim all rewards
+
+        // update reward reserves
+        $._store.decreaseReserves(targetNftId, rewardsClaimedAmount);
+    }
+
+
+    //--- view functions ----------------------------------------------------//
+
+    function getStakingReader() public view returns (StakingReader reader) {
+        return _getStakingStorage()._reader;
+    }
+
+    function getStakingStore() external view returns (StakingStore stakingStore) {
+        return _getStakingStorage()._store;
+    }
+
+    function getTokenRegistryAddress() external view returns (address tokenRegistry) {
+        return address(_getStakingStorage()._tokenRegistry);
+    }
+
+    function getTokenHandler() public virtual override(Component, IComponent) view returns (TokenHandler tokenHandler) {
+        return _getStakingStorage()._tokenHandler;
+    }
+
+    // from IRegisterable
+    function getRelease()
+        public 
+        pure 
+        virtual override (IRelease, Registerable)
+        returns(VersionPart)
+    {
+        return VersionPartLib.toVersionPart(3);
+    }
+
+    // from IVersionable
+    function getVersion()
+        public 
+        pure 
+        virtual override (Component, IVersionable, Versionable)
+        returns(Version)
+    {
+        return VersionLib.toVersion(3,0,0);
+    }
+
+    //--- internal functions ------------------------------------------------//
+
+    function _updateRewards(
+        StakingReader reader,
+        StakingStore store,
+        NftId stakeNftId
+    )
+        internal
+        virtual
+        returns (NftId targetNftId)
+    {
+        UFixed rewardRate;
+
+        (targetNftId, rewardRate) = reader.getTargetRewardRate(stakeNftId);
+        (Amount rewardIncrement, ) = StakingLib.calculateRewardIncrease(
+            reader, 
+            stakeNftId,
+            rewardRate);
+
+        store.updateRewards(
+            stakeNftId, 
+            targetNftId,
+            rewardIncrement);
+    }
+
+
+    function _approveTokenHandler(IERC20Metadata token, Amount amount)
+        internal
+        virtual override
+    {
+        IComponentService(_getServiceAddress(STAKING())).approveTokenHandler(
+            token, 
+            amount);
+    }
+
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        (
+            address registryAddress,
+            address tokenRegistryAddress,
+            address stakingStoreAddress,
+            address stakingOwner
+        ) = abi.decode(data, (address, address, address, address));
+
+        // only admin(authority) and dip token address are set in registry at this point
+        IRegistry registry = IRegistry(registryAddress);
+        address authority = registry.getAuthority();
+        TokenRegistry tokenRegistry = TokenRegistry(tokenRegistryAddress);
+        address dipTokenAddress = tokenRegistry.getDipTokenAddress();
+
+        // wiring to external contracts
+        StakingStorage storage $ = _getStakingStorage();
+        $._protocolNftId = registry.getProtocolNftId();
+        $._store = StakingStore(stakingStoreAddress);
+        $._reader = StakingStore(stakingStoreAddress).getStakingReader();
+        $._tokenRegistry = TokenRegistry(tokenRegistryAddress);
+
+        _initializeComponent(
+            authority,
+            registryAddress, 
+            registry.getNftId(), // parent nft id
+            CONTRACT_NAME,
+            dipTokenAddress,
+            STAKING(), 
+            false, // is interceptor
+            stakingOwner, 
+            "", // registry data
+            ""); // component data
+
+        _registerInterface(type(IStaking).interfaceId);
+    }
+
+
+    function _getStakingStorage() private pure returns (StakingStorage storage $) {
+        assembly {
+            $.slot := STAKING_LOCATION_V1
+        }
+    }
+}