@etherisc/gif-next 0.0.2-98b8042-396 → 0.0.2-99c2cd1-219

package/contracts/instance/ObjectManager.sol

@@ -0,0 +1,84 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Cloneable} from "./Cloneable.sol";
+
+import {IInstance} from "./IInstance.sol";
+import {INSTANCE} from "../types/ObjectType.sol";
+import {InstanceReader} from "./InstanceReader.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {LibNftIdSet} from "../types/NftIdSet.sol";
+import {NftId} from "../types/NftId.sol";
+
+contract ObjectManager is
+    Cloneable
+{
+
+    event LogObjectManagerInitialized(address instance);
+
+    error ErrorObjectManagerNftIdInvalid(NftId instanceNftId);
+    error ErrorObjectManagerAlreadyAdded(NftId componentNftId, NftId objectNftId);
+
+    mapping(NftId compnentNftId => LibNftIdSet.Set objects) internal _activeObjects;
+    mapping(NftId compnentNftId => LibNftIdSet.Set objects) internal _allObjects;
+    IInstance internal _instance; // store instance address -> more flexible, instance may not be registered during ObjectManager initialization
+
+    /// @dev call to initialize MUST be made in the same transaction as cloning of the contract
+    function initialize(
+        address authority,
+        address registry,
+        address instance
+    )
+        external 
+    {
+        initialize(authority, registry);
+
+        _instance = IInstance(instance);
+        
+        emit LogObjectManagerInitialized(instance);
+    }
+
+    function getInstance() external view returns (IInstance) {
+        return _instance;
+    }
+
+    function _add(NftId componentNftId, NftId objectNftId) internal {
+        LibNftIdSet.Set storage allSet = _allObjects[componentNftId];
+        LibNftIdSet.Set storage activeSet = _activeObjects[componentNftId];
+
+        LibNftIdSet.add(allSet, objectNftId);
+        LibNftIdSet.add(activeSet, objectNftId);
+    }
+
+    function _activate(NftId componentNftId, NftId objectNftId) internal {
+        LibNftIdSet.add(_activeObjects[componentNftId], objectNftId);
+    }
+
+    function _deactivate(NftId componentNftId, NftId objectNftId) internal {
+        LibNftIdSet.remove(_activeObjects[componentNftId], objectNftId);
+    }
+
+    function _objects(NftId componentNftId) internal view returns (uint256) {
+        return LibNftIdSet.size(_allObjects[componentNftId]);
+    }
+
+    function _contains(NftId componentNftId, NftId objectNftId) internal view returns (bool) {
+        return LibNftIdSet.contains(_allObjects[componentNftId], objectNftId);
+    }
+
+    function _getObject(NftId componentNftId, uint256 idx) internal view returns (NftId) {
+        return LibNftIdSet.getElementAt(_allObjects[componentNftId], idx);
+    }
+
+    function _activeObjs(NftId componentNftId) internal view returns (uint256)  {
+        return LibNftIdSet.size(_activeObjects[componentNftId]);
+    }
+
+    function _isActive(NftId componentNftId, NftId objectNftId) internal view returns (bool) {
+        return LibNftIdSet.contains(_activeObjects[componentNftId], objectNftId);
+    }
+
+    function _getActiveObject(NftId componentNftId, uint256 idx) internal view returns (NftId) {
+        return LibNftIdSet.getElementAt(_activeObjects[componentNftId], idx);
+    }
+}

package/contracts/instance/base/ComponentService.sol

@@ -0,0 +1,134 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IComponent} from "../../components/IComponent.sol";
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IRegistryService} from "../../registry/IRegistryService.sol";
+import {IInstance} from "../../instance/IInstance.sol";
+import {IAccess} from "../module/IAccess.sol";
+import {ObjectType, INSTANCE, REGISTRY} from "../../types/ObjectType.sol";
+import {NftId} from "../../types/NftId.sol";
+import {RoleId} from "../../types/RoleId.sol";
+
+import {Service} from "../../shared/Service.sol";
+import {InstanceService} from "../InstanceService.sol";
+import {InstanceAccessManager} from "../InstanceAccessManager.sol";
+
+abstract contract ComponentService is Service {
+
+    error ErrorComponentServiceAlreadyRegistered(address component, NftId nftId);
+    error ErrorComponentServiceNotComponent(address component);
+    error ErrorComponentServiceInvalidType(address component, ObjectType requiredType, ObjectType componentType);
+    error ErrorComponentServiceSenderNotOwner(address component, address initialOwner, address sender);
+    error ErrorComponentServiceExpectedRoleMissing(NftId instanceNftId, RoleId requiredRole, address sender);
+    error ErrorComponentServiceComponentLocked(address component);
+
+    /// @dev modifier to check if caller is a registered service
+    modifier onlyService() {
+        address caller = msg.sender;
+        require(getRegistry().isRegisteredService(caller), "ERROR_NOT_SERVICE");
+        _;
+    }
+
+    // view functions
+
+    function getRegistryService() public view virtual returns (IRegistryService) {
+        address service = getRegistry().getServiceAddress(REGISTRY(), getMajorVersion());
+        return IRegistryService(service);
+    }
+
+    function getInstanceService() public view returns (InstanceService) {
+        address service = getRegistry().getServiceAddress(INSTANCE(), getMajorVersion());
+        return InstanceService(service);
+    }
+
+    // internal functions
+    function _checkComponentForRegistration(
+        address componentAddress,
+        ObjectType requiredType,
+        RoleId requiredRole
+    )
+        internal
+        view
+        returns (
+            IComponent component,
+            address owner,
+            IInstance instance,
+            NftId instanceNftId
+        )
+    {
+        // component may only be registerd by initial owner of component
+        owner = msg.sender;
+
+        // check component has not already been registerd
+        NftId compoentNftId = getRegistry().getNftId(componentAddress);
+        if(compoentNftId.gtz()) {
+            revert ErrorComponentServiceAlreadyRegistered(componentAddress, compoentNftId);
+        }
+
+        // check this is a component
+        component = IComponent(componentAddress);
+        if(!component.supportsInterface(type(IComponent).interfaceId)) {
+            revert ErrorComponentServiceNotComponent(componentAddress);
+        }
+
+        // check component is of required type
+        IRegistry.ObjectInfo memory componentInfo = component.getInitialInfo();
+        if(componentInfo.objectType != requiredType) {
+            revert ErrorComponentServiceInvalidType(componentAddress, requiredType, componentInfo.objectType);
+        }
+
+        // check msg.sender is component owner
+        address initialOwner = componentInfo.initialOwner;
+        if(owner != initialOwner) {
+            revert ErrorComponentServiceSenderNotOwner(componentAddress, componentInfo.initialOwner, owner);
+        }
+
+        // check instance has assigned required role to owner
+        instanceNftId = componentInfo.parentNftId;
+        instance = _getInstance(instanceNftId);
+        bool hasRole = getInstanceService().hasRole(
+            owner, 
+            requiredRole, 
+            address(instance));
+
+        if(!hasRole) {
+            revert ErrorComponentServiceExpectedRoleMissing(instanceNftId, requiredRole, owner);
+        }
+    }
+
+    // internal view functions
+
+    function _getInstance(NftId instanceNftId) internal view returns (IInstance) {
+        IRegistry.ObjectInfo memory instanceInfo = getRegistry().getObjectInfo(instanceNftId);
+        return IInstance(instanceInfo.objectAddress);
+    }
+
+    function _getAndVerifyComponentInfoAndInstance(
+        //address component,
+        ObjectType expectedType
+    )
+        internal
+        view
+        returns(
+            IRegistry.ObjectInfo memory info, 
+            IInstance instance
+        )
+    {
+        IRegistry registry = getRegistry();
+        //TODO redundant check -> just check type
+        //NftId componentNftId = registry.getNftId(component); 
+        //require(componentNftId.gtz(), "ERROR_COMPONENT_UNKNOWN");
+
+        info = registry.getObjectInfo(msg.sender);
+        require(info.objectType == expectedType, "OBJECT_TYPE_INVALID");
+
+        address instanceAddress = registry.getObjectInfo(info.parentNftId).objectAddress;
+        instance = IInstance(instanceAddress);
+
+        InstanceAccessManager accessManager = InstanceAccessManager(instance.authority());
+        if (accessManager.isTargetLocked(info.objectAddress)) {
+            revert IAccess.ErrorIAccessTargetLocked(info.objectAddress);
+        }
+    }
+}

package/contracts/instance/module/IAccess.sol

@@ -1,38 +1,47 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.20;
 
-import {EnumerableSet} from "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
 import {ShortString, ShortStrings} from "@openzeppelin/contracts/utils/ShortStrings.sol";
 
 import {RoleId} from "../../types/RoleId.sol";
+import {Timestamp} from "../../types/Timestamp.sol";
 
 interface IAccess {
+
     struct RoleInfo {
         ShortString name;
         bool isCustom;
+        bool isLocked;
+        Timestamp createdAt;
+        Timestamp updatedAt;
     }
 
     struct TargetInfo {
         ShortString name;
         bool isCustom;
+        bool isLocked;
+        Timestamp createdAt;
+        Timestamp updatedAt;
     }
 
-    error ErrorTargetAddressZero();
-    error ErrorTargetAlreadyExists(address target, ShortString name);
-    error ErrorTargetDoesNotExist(address target);
-    error ErrorTargetNameEmpty(address target);
-    error ErrorTargetNameExists(address target, address existingTarget, ShortString name);
-
-    error ErrorRoleIdInvalid(RoleId roleId);
-    error ErrorRoleIdTooBig(RoleId roleId);
-    error ErrorRoleIdTooSmall(RoleId roleId);
-    error ErrorRoleIdAlreadyExists(RoleId roleId, ShortString name);
-    error ErrorRoleIdNotActive(RoleId roleId);
-    error ErrorRoleNameEmpty(RoleId roleId);
-    error ErrorRoleNameNotUnique(RoleId roleId, ShortString name);
-    error ErrorRoleInvalidUpdate(RoleId roleId, bool isCustom);
-    error ErrorGrantNonexstentRole(RoleId roleId);
-    error ErrorRevokeNonexstentRole(RoleId roleId);
-    error ErrorRenounceNonexstentRole(RoleId roleId);
+    error ErrorIAccessRoleIdInvalid(RoleId roleId);
+    error ErrorIAccessRoleIdTooBig(RoleId roleId);
+    error ErrorIAccessRoleIdTooSmall(RoleId roleId);
+    error ErrorIAccessRoleIdAlreadyExists(RoleId roleId, ShortString name);
+    error ErrorIAccessRoleIdNotActive(RoleId roleId);
+    error ErrorIAccessRoleNameEmpty(RoleId roleId);
+    error ErrorIAccessRoleNameNotUnique(RoleId roleId, ShortString name);
+    error ErrorIAccessRoleInvalidUpdate(RoleId roleId, bool isCustom);
+    error ErrorIAccessRoleIsCustomIsImmutable(RoleId roleId, bool isCustom, bool isCustomExisting);
+    error ErrorIAccessGrantNonexstentRole(RoleId roleId);
+    error ErrorIAccessRevokeNonexstentRole(RoleId roleId); 
+    error ErrorIAccessRenounceNonexstentRole(RoleId roleId);
 
+    error ErrorIAccessTargetAddressZero();
+    error ErrorIAccessTargetDoesNotExist(ShortString name);
+    error ErrorIAccessTargetAddressDoesNotExist(address target);
+    error ErrorIAccessTargetExists(address target, ShortString name);
+    error ErrorIAccessTargetNameEmpty(address target);
+    error ErrorIAccessTargetNameExists(address target, address existingTarget, ShortString name);
+    error ErrorIAccessTargetLocked(address target);
 }

package/contracts/instance/module/IBundle.sol

@@ -3,6 +3,7 @@ pragma solidity ^0.8.20;
 
 import {NftId} from "../../types/NftId.sol";
 import {Fee} from "../../types/Fee.sol";
+import {Seconds} from "../../types/Seconds.sol";
 import {Timestamp} from "../../types/Timestamp.sol";
 
 interface IBundle {
@@ -13,7 +14,7 @@ interface IBundle {
         uint256 capitalAmount; // net investment capital + net premiums - payouts
         uint256 lockedAmount; // capital amount linked to collateralizaion of non-closed policies (<= balance)
         uint256 balanceAmount; // total amount of funds: capitalAmount + fees (balance >= captial)
-        uint256 lifetime;
+        Seconds lifetime;
         Timestamp expiredAt; // no new policies
         Timestamp closedAt; // no open policies, locked amount = 0
     }

package/contracts/instance/module/IPolicy.sol

@@ -2,12 +2,15 @@
 pragma solidity ^0.8.20;
 
 import {NftId} from "../../types/NftId.sol";
-import {NumberId} from "../../types/NumberId.sol";
+import {ClaimId} from "../../types/ClaimId.sol";
 import {ReferralId} from "../../types/Referral.sol";
 import {RiskId} from "../../types/RiskId.sol";
+import {Seconds} from "../../types/Seconds.sol";
 import {Timestamp} from "../../types/Timestamp.sol";
 
 interface IPolicy {
+
+    /// @dev policy data for the full policy lifecycle
     struct PolicyInfo {
         NftId productNftId;
         NftId bundleNftId;
@@ -16,7 +19,7 @@ interface IPolicy {
         uint256 sumInsuredAmount;
         uint256 premiumAmount;
         uint256 premiumPaidAmount;
-        uint256 lifetime;
+        Seconds lifetime;
         bytes applicationData;
         bytes policyData;
         uint16 claimsCount;
@@ -37,7 +40,7 @@ interface IPolicy {
 
     // claimId neeeds to be encoded policyNftId:claimId combination
     struct PayoutInfo {
-        NumberId claimId;
+        ClaimId claimId;
         uint256 amount;
         bytes data;
         Timestamp paidAt; // payoment of confirmed claim amount (or declinedAt)

package/contracts/instance/module/ISetup.sol

@@ -5,11 +5,34 @@ import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IER
 
 import {Fee} from "../../types/Fee.sol";
 import {NftId} from "../../types/NftId.sol";
-import {LibNftIdSet} from "../../types/NftIdSet.sol";
-import {UFixed} from "../../types/UFixed.sol";
+import {RoleId} from "../../types/RoleId.sol";
 import {TokenHandler} from "../../shared/TokenHandler.sol";
+import {UFixed} from "../../types/UFixed.sol";
 
 interface ISetup {
+
+    struct ComponentInfo {
+        string name; // component name (needs to be unique per instance)
+        IERC20Metadata token;
+        TokenHandler tokenHandler;
+        address wallet;
+        bytes data; // will hold component type specific additional info (eg encoded pool info)
+    }
+
+    struct PoolInfo {
+        NftId productNftId; // the nft of the product this pool is linked to
+        RoleId bundleOwnerRole; // the required role for bundle owners
+        uint256 maxCapitalAmount; // max capital amount allowed for pool
+        bool isInterceptingBundleTransfers; // intercepts nft transfers for bundles
+        bool isExternallyManaged; // funding bundles is restricted to book keeping, actual funds may be provided as needed to support payouts
+        bool isVerifyingApplications; // underwriting requires the pool component checks/confirms the applications 
+        UFixed collateralizationLevel; // factor to calculate collateral for sum insurance (default 100%)
+        UFixed retentionLevel; // amount of collateral held in pool (default 100%)
+        Fee poolFee; // pool fee on net premium
+        Fee stakingFee; // pool fee on staked capital from investor
+        Fee performanceFee; // pool fee on profits from capital investors
+    }
+
     struct ProductSetupInfo {
         IERC20Metadata token;
         TokenHandler tokenHandler;
@@ -29,19 +52,22 @@ interface ISetup {
         NftId productNftId;
         TokenHandler tokenHandler;
         Fee distributionFee; // default distribution fee (no referral id)
-        bool isIntercepting; // intercepts nft transfers (for distributors)
         address wallet;
     }
 
     struct PoolSetupInfo {
         NftId productNftId;
         TokenHandler tokenHandler;
-        UFixed collateralizationLevel;
+        RoleId bundleOwnerRole;
+        uint256 maxCapitalAmount; // max capital amount allowed for pool
+        bool isInterceptingBundleTransfers; // intercepts nft transfers for bundles
+        bool isExternallyManaged; // funding bundles is restricted to book keeping, actual funds may be provided as needed to support payouts
+        bool isVerifyingApplications; // underwriting requires the pool component checks/confirms the applications 
+        UFixed collateralizationLevel; // factor to calculate collateral for sum insurance (default 100%)
+        UFixed retentionLevel; // amount of collateral held in pool (default 100%)
         Fee poolFee; // pool fee on net premium
         Fee stakingFee; // pool fee on staked capital from investor
         Fee performanceFee; // pool fee on profits from capital investors
-        bool isIntercepting; // intercepts nft transfers (for bundles)
-        bool isConfirmingApplication; // confirms applications before they are underwritten
         address wallet;
     }
 }

package/contracts/instance/service/ApplicationService.sol

@@ -0,0 +1,270 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRisk} from "../module/IRisk.sol";
+import {IService} from "./IApplicationService.sol";
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IProductComponent} from "../../components/IProductComponent.sol";
+import {Product} from "../../components/Product.sol";
+import {IPoolComponent} from "../../components/IPoolComponent.sol";
+import {IDistributionComponent} from "../../components/IDistributionComponent.sol";
+import {IInstance} from "../IInstance.sol";
+import {IPolicy} from "../module/IPolicy.sol";
+import {IRisk} from "../module/IRisk.sol";
+import {IBundle} from "../module/IBundle.sol";
+import {IProductService} from "./IProductService.sol";
+import {ITreasury} from "../module/ITreasury.sol";
+import {ISetup} from "../module/ISetup.sol";
+
+import {TokenHandler} from "../../shared/TokenHandler.sol";
+
+import {IVersionable} from "../../shared/IVersionable.sol";
+import {Versionable} from "../../shared/Versionable.sol";
+
+import {Seconds} from "../../types/Seconds.sol";
+import {Timestamp, TimestampLib, zeroTimestamp} from "../../types/Timestamp.sol";
+import {UFixed, UFixedLib} from "../../types/UFixed.sol";
+import {Blocknumber, blockNumber} from "../../types/Blocknumber.sol";
+import {ObjectType, INSTANCE, PRODUCT, POOL, APPLICATION, POLICY, BUNDLE} from "../../types/ObjectType.sol";
+import {APPLIED, REVOKED, UNDERWRITTEN, ACTIVE, KEEP_STATE, CLOSED} from "../../types/StateId.sol";
+import {NftId, NftIdLib, zeroNftId} from "../../types/NftId.sol";
+import {Fee, FeeLib} from "../../types/Fee.sol";
+import {ReferralId} from "../../types/Referral.sol";
+import {RiskId} from "../../types/RiskId.sol";
+import {StateId} from "../../types/StateId.sol";
+import {Version, VersionLib} from "../../types/Version.sol";
+
+import {ComponentService} from "../base/ComponentService.sol";
+import {InstanceReader} from "../InstanceReader.sol";
+import {IApplicationService} from "./IApplicationService.sol";
+import {IBundleService} from "./IBundleService.sol";
+import {IPoolService} from "./IPoolService.sol";
+import {IService} from "../../shared/IService.sol";
+import {Service} from "../../shared/Service.sol";
+
+
+contract ApplicationService is 
+    ComponentService, 
+    IApplicationService
+{
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        // TODO check this, might no longer be the way, refactor if necessary
+        address registryAddress;
+        address initialOwner;
+        (registryAddress, initialOwner) = abi.decode(data, (address, address));
+
+        initializeService(registryAddress, owner);
+        registerInterface(type(IApplicationService).interfaceId);
+    }
+
+
+    function getDomain() public pure override(IService, Service) returns(ObjectType) {
+        return APPLICATION();
+    }
+
+
+    function create(
+        address applicationOwner,
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        Seconds lifetime,
+        NftId bundleNftId,
+        ReferralId referralId,
+        bytes memory applicationData
+    )
+        external
+        virtual
+        returns (NftId applicationNftId)
+    {
+        (IRegistry.ObjectInfo memory productInfo, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+        // TODO: add validations (see create bundle in pool service)
+
+        applicationNftId = getRegistryService().registerPolicy(
+            IRegistry.ObjectInfo(
+                zeroNftId(),
+                productInfo.nftId,
+                POLICY(),
+                false, // intercepting property for policies is defined on product
+                address(0),
+                applicationOwner,
+                ""
+            )
+        );
+
+        (uint256 premiumAmount,,,,) = calculatePremium(
+            riskId,
+            sumInsuredAmount,
+            lifetime,
+            applicationData,
+            bundleNftId,
+            referralId
+        );
+
+        IPolicy.PolicyInfo memory policyInfo = IPolicy.PolicyInfo(
+            productInfo.nftId,
+            bundleNftId,
+            referralId,
+            riskId,
+            sumInsuredAmount,
+            premiumAmount,
+            0,
+            lifetime,
+            applicationData,
+            "",
+            0,
+            0,
+            0,
+            zeroTimestamp(),
+            zeroTimestamp(),
+            zeroTimestamp()
+        );
+        
+        instance.createApplication(applicationNftId, policyInfo);
+        instance.updateApplicationState(applicationNftId, APPLIED());
+
+        // TODO: add logging
+    }
+
+
+    function renew(
+        NftId policyNftId, // policy to be renewd (renewal inherits policy attributes)
+        NftId bundleNftId // will likely need a newer bundle for underwriting
+    )
+        external
+        virtual override
+        returns (NftId applicationNftId)
+    {
+
+    }
+
+
+    function adjust(
+        NftId applicationNftId,
+        RiskId riskId,
+        NftId bundleNftId,
+        ReferralId referralId,
+        uint256 sumInsuredAmount,
+        uint256 lifetime,
+        bytes memory applicationData
+    )
+        external
+        virtual override
+    {
+
+    }
+
+    function revoke(NftId applicationNftId)
+        external
+        virtual override
+    {
+        (, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+        instance.updateApplicationState(applicationNftId, REVOKED());
+    }
+
+
+    function calculatePremium(
+        RiskId riskId,
+        uint256 sumInsuredAmount,
+        Seconds lifetime,
+        bytes memory applicationData,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        public
+        view
+        virtual override
+        returns (
+            uint256 premiumAmount,
+            uint256 distributionFeeAmount,
+            uint256 productFeeAmount,
+            uint256 poolFeeAmount,
+            uint256 bundleFeeAmount
+        )
+    {
+        Product product = _getAndVerifyInstanceAndProduct();
+        uint256 netPremiumAmount = product.calculateNetPremium(
+            sumInsuredAmount,
+            riskId,
+            lifetime,
+            applicationData
+        );
+
+        (
+            productFeeAmount,
+            poolFeeAmount,
+            bundleFeeAmount,
+            distributionFeeAmount
+        ) = _calculateFeeAmounts(
+            netPremiumAmount,
+            product,
+            bundleNftId,
+            referralId
+        );
+
+        premiumAmount = netPremiumAmount + productFeeAmount;
+        premiumAmount += poolFeeAmount + bundleFeeAmount;
+        premiumAmount += distributionFeeAmount;
+    }
+
+
+    // internal functions
+
+    function _calculateFeeAmounts(
+        uint256 netPremiumAmount,
+        Product product,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        internal
+        view
+        returns (
+            uint256 productFeeAmount,
+            uint256 poolFeeAmount,
+            uint256 bundleFeeAmount,
+            uint256 distributionFeeAmount
+        )
+    {
+        InstanceReader instanceReader;
+        {
+            IInstance instance = product.getInstance();
+            instanceReader = instance.getInstanceReader();
+        }
+        
+        NftId poolNftId = product.getPoolNftId();
+        IBundle.BundleInfo memory bundleInfo = instanceReader.getBundleInfo(bundleNftId);
+        require(bundleInfo.poolNftId == poolNftId,"ERROR:PRS-035:BUNDLE_POOL_MISMATCH");
+
+        {
+            ISetup.ProductSetupInfo memory productSetupInfo = instanceReader.getProductSetupInfo(product.getProductNftId());
+            (productFeeAmount,) = FeeLib.calculateFee(productSetupInfo.productFee, netPremiumAmount);
+        }
+        {
+            ISetup.PoolInfo memory poolInfo = abi.decode(
+                instanceReader.getComponentInfo(poolNftId).data, (ISetup.PoolInfo));
+            (poolFeeAmount,) = FeeLib.calculateFee(poolInfo.poolFee, netPremiumAmount);
+        }
+        {
+            NftId distributionNftId = product.getDistributionNftId();
+            ISetup.DistributionSetupInfo memory distributionSetupInfo = instanceReader.getDistributionSetupInfo(distributionNftId);
+            (distributionFeeAmount,) = FeeLib.calculateFee(distributionSetupInfo.distributionFee, netPremiumAmount);
+        }
+        
+        (bundleFeeAmount,) = FeeLib.calculateFee(bundleInfo.fee, netPremiumAmount);
+    }
+
+
+    function _getAndVerifyInstanceAndProduct() internal view returns (Product product) {
+        IRegistry.ObjectInfo memory productInfo;
+        (productInfo,) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+        product = Product(productInfo.objectAddress);
+    }
+}