@etherisc/gif-next 0.0.2-96b5b72-170 → 0.0.2-9723682-800

package/contracts/staking/StakingLib.sol

@@ -0,0 +1,281 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IStaking} from "./IStaking.sol";
+import {NftId} from "../type/NftId.sol";
+import {Seconds, SecondsLib} from "../type/Seconds.sol";
+import {StakingReader} from "./StakingReader.sol";
+import {StakingStore} from "./StakingStore.sol";
+import {Timestamp, TimestampLib} from "../type/Timestamp.sol";
+import {UFixed, UFixedLib} from "../type/UFixed.sol";
+
+
+library StakingLib {
+
+    function stake(
+        IRegistry registry,
+        StakingReader stakingReader,
+        StakingStore stakingStore,
+        NftId stakeNftId,
+        Amount stakeAmount
+    )
+        external
+        returns (Amount stakeBalance)
+    {
+        // check that target is active for staking
+        (
+            UFixed rewardRate,
+            Seconds lockingPeriod
+        ) = checkStakeParameters(
+            stakingReader, 
+            stakeNftId);        
+
+        // calculate new rewards (if any)
+        (
+            Amount rewardIncrementAmount, 
+            Amount currentTotalDipAmount
+        ) = calculateRewardIncrease(
+            stakingReader, 
+            stakeNftId,
+            rewardRate);
+
+        stakeBalance = currentTotalDipAmount + stakeAmount;
+
+        // TODO check that additional dip, rewards and rewards increment 
+        // are still ok with max target staking amount
+        NftId targetNftId = registry.getParentNftId(stakeNftId);
+        Amount maxStakedAmount = stakingReader.getTargetMaxStakedAmount(targetNftId);
+
+        if (stakeBalance > maxStakedAmount) {
+            revert IStaking.ErrorStakingTargetMaxStakedAmountExceeded(targetNftId, maxStakedAmount, stakeBalance);
+        }
+
+        stakingStore.restakeRewards(
+            stakeNftId, 
+            targetNftId, 
+            rewardIncrementAmount);
+
+        stakingStore.increaseStake(
+            stakeNftId, 
+            targetNftId, 
+            stakeAmount);
+
+        // update locked until with target locking period
+        stakingStore.update(
+            stakeNftId, 
+            IStaking.StakeInfo({
+                lockedUntil: TimestampLib.blockTimestamp().addSeconds(
+                    lockingPeriod)}));
+
+    }
+
+    function restake(
+        StakingReader stakingReader,
+        StakingStore stakingStore,
+        NftId oldStakeNftId,
+        NftId newStakeNftId
+    )
+        external
+        returns (Amount newStakeBalance)
+    {
+        checkUnstakeParameters(stakingReader, oldStakeNftId);
+        (NftId oldTargetNftId, UFixed oldRewardRate) = stakingReader.getTargetRewardRate(oldStakeNftId);
+        
+        // calculate new rewards update and unstake full amount
+        (
+            Amount rewardIncrementAmount,
+        ) = calculateRewardIncrease(
+            stakingReader, 
+            oldStakeNftId,
+            oldRewardRate);
+        stakingStore.updateRewards(
+            oldStakeNftId, 
+            oldTargetNftId, 
+            rewardIncrementAmount);
+        (
+            Amount unstakedAmount, 
+            Amount rewardsAmount
+        ) = stakingStore.unstakeUpTo(
+            oldStakeNftId,
+            oldTargetNftId,
+            AmountLib.max(), // unstake all stakes
+            AmountLib.max()); // claim all rewards
+
+        // calculate full restake amount
+        newStakeBalance = unstakedAmount + rewardsAmount;
+        NftId newTargetNftId = stakingReader.getTargetNftId(newStakeNftId);
+        
+        // create new staking target and increase stake
+        Timestamp newLockedUntil = _checkCreateParameters(stakingReader, newTargetNftId, newStakeBalance);
+        stakingStore.create(
+            newStakeNftId, 
+            IStaking.StakeInfo({
+                    lockedUntil: newLockedUntil
+                }));
+        stakingStore.increaseStake(
+            newStakeNftId, 
+            newTargetNftId, 
+            newStakeBalance);
+    }
+
+    function checkCreateParameters(
+        StakingReader stakingReader,
+        NftId targetNftId, 
+        Amount dipAmount
+    )
+        external
+        view
+        returns (
+            Timestamp lockedUntil
+        )
+    {
+        return _checkCreateParameters(stakingReader, targetNftId, dipAmount);
+    }
+
+    function _checkCreateParameters(
+        StakingReader stakingReader,
+        NftId targetNftId, 
+        Amount dipAmount
+    )
+        internal view
+        returns (
+            Timestamp lockedUntil
+        )
+    {
+        Seconds lockingPeriod = checkTarget(stakingReader, targetNftId);
+        checkDipAmount(stakingReader, targetNftId, dipAmount);
+
+        Timestamp currentTime = TimestampLib.blockTimestamp();
+        lockedUntil = currentTime.addSeconds(lockingPeriod);
+    }
+
+
+    function checkStakeParameters(
+        StakingReader stakingReader,
+        NftId stakeNftId
+    )
+        public
+        view
+        returns (
+            UFixed rewardRate,
+            Seconds lockingPeriod
+        )
+    {
+        NftId targetNftId = stakingReader.getTargetNftId(stakeNftId);
+
+        // target nft id must be registered
+        if (!stakingReader.isTarget(targetNftId)) {
+            revert IStaking.ErrorStakingNotTarget(targetNftId);
+        }
+        
+        IStaking.TargetInfo memory info = stakingReader.getTargetInfo(targetNftId);
+        rewardRate = info.rewardRate;
+        lockingPeriod = info.lockingPeriod;
+    }
+
+    function checkUnstakeParameters(
+        StakingReader stakingReader,
+        NftId stakeNftId
+    )
+        public
+        view
+        returns (
+            Seconds lockingPeriod
+        )
+    {
+        IStaking.StakeInfo memory stakeInfo = stakingReader.getStakeInfo(stakeNftId);
+        
+        if (stakeInfo.lockedUntil > TimestampLib.blockTimestamp()) {
+            revert IStaking.ErrorStakingStakeLocked(stakeNftId, stakeInfo.lockedUntil);
+        }
+    }
+
+
+    function checkTarget(
+        StakingReader stakingReader,
+        NftId targetNftId
+    )
+        public
+        view
+        returns (Seconds lockingPeriod)
+    {
+        // target nft id must be registered
+        if (!stakingReader.isTarget(targetNftId)) {
+            revert IStaking.ErrorStakingNotTarget(targetNftId);
+        }
+
+        lockingPeriod = stakingReader.getTargetInfo(targetNftId).lockingPeriod;
+    }
+
+
+    function checkDipAmount(
+        StakingReader stakingReader,
+        NftId targetNftId, 
+        Amount dipAmount
+    )
+        public 
+        view 
+    {
+        // check stake amount > 0
+        if (dipAmount.eqz()) {
+            revert IStaking.ErrorStakingStakeAmountZero(targetNftId);
+        }
+
+        Amount maxStakedAmount = stakingReader.getTargetMaxStakedAmount(targetNftId);
+        if (dipAmount > maxStakedAmount) {
+            revert IStaking.ErrorStakingTargetMaxStakedAmountExceeded(targetNftId, maxStakedAmount, dipAmount);
+        }
+    }
+
+    function calculateRewardIncrease(
+        StakingReader stakingReader,
+        NftId stakeNftId,
+        UFixed rewardRate
+    )
+        public
+        view
+        returns (
+            Amount rewardIncreaseAmount,
+            Amount totalDipAmount
+        )
+    {
+        (
+            Amount stakeAmount,
+            Amount rewardAmount,
+            Timestamp lastUpdatedAt
+        ) = stakingReader.getStakeBalances(stakeNftId);
+
+        Seconds duration = SecondsLib.toSeconds(
+            block.timestamp - lastUpdatedAt.toInt());
+        
+        rewardIncreaseAmount = calculateRewardAmount(
+            rewardRate,
+            duration,
+            stakeAmount);
+        
+        totalDipAmount = stakeAmount + rewardAmount + rewardIncreaseAmount;
+    }
+
+    function calculateRewardAmount(
+        UFixed rewardRate,
+        Seconds duration, 
+        Amount stakeAmount
+    )
+        public 
+        pure 
+        returns(
+            Amount rewardAmount
+        )
+    {
+        UFixed rewardRateFraction = getYearFraction(duration) * rewardRate;
+        rewardAmount = stakeAmount.multiplyWith(rewardRateFraction);
+    }
+
+
+    function getYearFraction(Seconds duration) public pure returns (UFixed yearFraction) {
+        return UFixedLib.toUFixed(duration.toInt()) / UFixedLib.toUFixed(SecondsLib.oneYear().toInt());
+    }
+
+}

package/contracts/staking/StakingLifecycle.sol

@@ -0,0 +1,23 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {TARGET, COMPONENT, STAKE} from "../type/ObjectType.sol";
+import {INITIAL} from "../type/StateId.sol";
+import {Lifecycle} from "../shared/Lifecycle.sol";
+
+contract StakingLifecycle is
+    Lifecycle
+{
+    constructor() {
+        _setupLifecycle();
+    }
+
+    function _setupLifecycle()
+        internal
+        override
+    {
+        setInitialState(TARGET(), INITIAL());
+        setInitialState(COMPONENT(), INITIAL());
+        setInitialState(STAKE(), INITIAL());
+    }
+}

package/contracts/staking/StakingManager.sol

@@ -1,41 +1,47 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.20;
 
-import {IVersionable} from "../shared/IVersionable.sol";
-import {ProxyManager} from "../shared/ProxyManager.sol";
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {ProxyManager} from "../upgradeability/ProxyManager.sol";
 import {Staking} from "./Staking.sol";
 
+
 contract StakingManager is
     ProxyManager
 {
-
     Staking private _staking;
+    address private _initialImplementation;
+    bytes private _initializationData;
 
     /// @dev initializes proxy manager with service implementation 
     constructor(
-        address initialAuthority,
-        address registryAddress,
-        address dipTokenAddress
+        address registry,
+        address tokenRegistry,
+        address stakingStore,
+        address initialOwner,
+        bytes32 salt
     )
-        ProxyManager(registryAddress)
     {
-        Staking stk = new Staking();
-        address initialOwner = msg.sender;
+        Staking stakingImplementation = new Staking();
 
-        bytes memory data = abi.encode(
-            initialAuthority, 
-            registryAddress, 
-            dipTokenAddress, 
+        _initialImplementation = address(stakingImplementation);
+        _initializationData = abi.encode(
+            registry,
+            tokenRegistry,
+            stakingStore,
             initialOwner);
-
-        IVersionable versionable = deploy(
-            address(stk), 
-            data);
+        
+        IVersionable versionable = initialize(
+            registry,
+            _initialImplementation,
+            _initializationData,
+            salt);
 
         _staking = Staking(address(versionable));
     }
 
     //--- view functions ----------------------------------------------------//
+
     function getStaking()
         external
         view
@@ -43,4 +49,4 @@ contract StakingManager is
     {
         return _staking;
     }
-}
+}

package/contracts/staking/StakingReader.sol

@@ -0,0 +1,199 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol"; 
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegistryLinked} from "../shared/IRegistryLinked.sol";
+import {IStaking} from "../staking/IStaking.sol";
+
+import {Amount} from "../type/Amount.sol";
+import {Blocknumber}  from "../type/Blocknumber.sol";
+import {NftId} from "../type/NftId.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {StakingStore} from "./StakingStore.sol";
+import {STAKE, TARGET} from "../type/ObjectType.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+import {UFixed} from "../type/UFixed.sol";
+
+contract StakingReader is
+    IRegistryLinked,
+    Initializable
+{
+
+    error ErrorStakingReaderUnauthorizedCaler();
+
+    address private _initializeOwner;
+    IRegistry private _registry;
+    IStaking private _staking;
+    StakingStore private _store;
+
+    constructor(IRegistry registry) {
+        _initializeOwner = msg.sender;
+        _registry = registry;
+    }
+
+    function initialize(
+        address stakingAddress,
+        address stakingStoreAddress
+    )
+        external
+        initializer()
+    {
+        if (msg.sender != _initializeOwner) {
+            revert ErrorStakingReaderUnauthorizedCaler();
+        }
+
+        _staking = IStaking(stakingAddress);
+        _store = StakingStore(stakingStoreAddress);
+    }
+
+    // view and pure functions 
+
+    function getRegistry() external view returns (IRegistry registry) {
+        return _registry;
+    }
+
+    function getStaking() external view returns (IStaking staking) {
+        return _staking;
+    }
+
+    function getProtocolNftId() external view returns (NftId protocolNftId) {
+        return _registry.getProtocolNftId();
+    }
+
+    function getStakingRate(uint256 chainId, address token) external view returns (UFixed stakingRate) { 
+        return _store.getStakingRate(chainId, token); 
+    }
+
+
+    function isTarget(NftId targetNftId) external view returns (bool) {
+        return _store.getTargetNftIdSet().exists(targetNftId);
+    }
+
+
+    function targets() external view returns (uint256) {
+        return _store.getTargetNftIdSet().nftIds();
+    }
+
+
+    function getTargetNftId(uint256 idx) external view returns (NftId) {
+        return _store.getTargetNftIdSet().getNftId(idx);
+    }
+
+
+    function getTargetNftId(NftId stakeNftId) public view returns (NftId targetNftId) {
+        return _registry.getParentNftId(stakeNftId);
+    }
+
+
+    function getTargetInfo(NftId targetNftId) public view returns (IStaking.TargetInfo memory info) {
+        bytes memory data = _store.getData(targetNftId.toKey32(TARGET()));
+        if (data.length > 0) {
+            return abi.decode(data, (IStaking.TargetInfo));
+        }
+    }
+
+
+    function getStakeInfo(NftId stakeNftId) external view returns (IStaking.StakeInfo memory stakeInfo) {
+        bytes memory data = _store.getData(stakeNftId.toKey32(STAKE()));
+        if (data.length > 0) {
+            return abi.decode(data, (IStaking.StakeInfo));
+        }
+    }
+
+
+    /// @dev Get the locking period that applies to the specified stake NFT ID.
+    function getTargetLockingPeriod(NftId stakeNftId) external view returns (NftId targetNftId, Seconds lockingPeriod) {
+        targetNftId = getTargetNftId(stakeNftId);
+        lockingPeriod = getTargetInfo(targetNftId).lockingPeriod;
+    }
+
+
+    /// @dev Get the reward rate that applies to the specified stake NFT ID.
+    function getTargetRewardRate(NftId stakeNftId) external view returns (NftId targetNftId, UFixed rewardRate) {
+        targetNftId = getTargetNftId(stakeNftId);
+        rewardRate = getTargetInfo(targetNftId).rewardRate;
+    }
+
+
+    /// @dev Get the max staked amount allowed for the specified target NFT ID.
+    function getTargetMaxStakedAmount(NftId targetNftId) external view returns (Amount maxStakedAmount) {
+        return getTargetInfo(targetNftId).maxStakedAmount;
+    }
+
+
+    /// @dev Get the reward rate for the specified target NFT ID.
+    function getLockingPeriod(NftId targetNftId) external view returns (Seconds lockingPeriod) {
+        return getTargetInfo(targetNftId).lockingPeriod;
+    }
+
+
+    /// @dev Get the reward rate for the specified target NFT ID.
+    function getRewardRate(NftId targetNftId) external view returns (UFixed rewardRate) {
+        return getTargetInfo(targetNftId).rewardRate;
+    }
+
+    /// @dev returns the current reward reserve balance for the specified target.
+    function getReserveBalance(NftId targetNftId) external view returns (Amount rewardReserveBalance) {
+        return _store.getReserveBalance(targetNftId); 
+    }
+
+    function getStakeBalance(NftId nftId) external view returns (Amount balanceAmount) { 
+        return _store.getStakeBalance(nftId); 
+    }
+
+    function getRewardBalance(NftId nftId) external view returns (Amount rewardAmount) {
+        return _store.getRewardBalance(nftId); 
+    }
+
+    function getBalanceUpdatedAt(NftId nftId) external view returns (Timestamp updatedAt) {
+        return _store.getBalanceUpdatedAt(nftId); 
+    }
+
+    function getBalanceUpdatedIn(NftId nftId) external view returns (Blocknumber blocknumber) {
+        return _store.getBalanceUpdatedIn(nftId); 
+    }
+
+    function getTotalValueLocked(NftId nftId, address token) external view returns (Amount totalValueLocked) {
+        return _store.getTotalValueLocked(nftId, token); 
+    }
+
+    function getRequiredStakeBalance(NftId nftId) external view returns (Amount requiredStakedAmount) {
+        return _store.getRequiredStakeBalance(nftId); 
+    }
+
+    function getTargetBalances(NftId stakeNftId) 
+        public
+        view
+        returns (
+            Amount balanceAmount,
+            Amount stakeAmount,
+            Amount rewardAmount,
+            Blocknumber lastUpdatedIn
+        )
+    {
+        (
+            balanceAmount,
+            stakeAmount,
+            rewardAmount,
+            lastUpdatedIn
+        ) = _store.getTargetBalances(stakeNftId);
+    }
+
+    function getStakeBalances(NftId stakeNftId) 
+        external
+        view
+        returns (
+            Amount stakeAmount,
+            Amount rewardAmount,
+            Timestamp lastUpdatedAt
+        )
+    {
+        (
+            stakeAmount,
+            rewardAmount,
+            lastUpdatedAt
+        ) = _store.getStakeBalances(stakeNftId);
+    }
+}