@etherisc/gif-next 0.0.2-95f8cce-959 → 0.0.2-9628b30-648

package/contracts/registry/TokenRegistry.sol

@@ -1,116 +1,317 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.20;
 
+import {AccessManaged} from "@openzeppelin/contracts/access/manager/AccessManaged.sol";
 import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
-import {ERC165Checker} from "@openzeppelin/contracts/utils/introspection/ERC165Checker.sol";
 
-import {IRegisterable} from "../shared/IRegisterable.sol";
 import {IRegistry} from "./IRegistry.sol";
-import {VersionPart} from "../types/Version.sol";
-import {REGISTRY} from "../types/ObjectType.sol";
-import {NftOwnable} from "../shared/NftOwnable.sol";
+import {IRegistryLinked} from "../shared/IRegistryLinked.sol";
+import {IStaking} from "../staking/IStaking.sol";
 
-/// @title contract to register token per GIF major release.
+import {ChainId, ChainIdLib} from "../type/ChainId.sol";
+import {RegistryAdmin} from "./RegistryAdmin.sol";
+import {VersionPart} from "../type/Version.sol";
+
+/// @dev The TokenRegistry contract is used to whitelist/manage ERC-20 of tokens per major release.
+/// Only whitelisted tokens can be used as default tokens for products, distribution and pools components.
 contract TokenRegistry is
-    NftOwnable
+    AccessManaged,
+    IRegistryLinked
 {
-    event LogRegistered(address token, string symbol, uint256 decimals);
-    event LogTokenStateSet(address token, VersionPart majorVersion, bool active);
+    event LogTokenRegistryTokenRegistered(ChainId chainId, address token, uint256 decimals, string symbol);
+    event LogTokenRegistryTokenGlobalStateSet(ChainId chainId, address token, bool active);
+    event LogTokenRegistryTokenStateSet(ChainId chainId, address token, VersionPart release, bool active);
 
-    error NotContract(address account);
-    error NotToken(address account);
-    error TokenDecimalsZero();
-    error TokenMajorVersionInvalid(VersionPart majorVersion);
+    error ErrorTokenRegistryChainIdZero();
+    error ErrorTokenRegistryTokenAddressZero();
 
-    address [] internal _token;
-    mapping(address token => bool registered) internal _registered;
-    mapping(address token => mapping(VersionPart majorVersion => bool isActive)) internal _active;
+    error ErrorTokenRegistryNotRemoteToken(ChainId chainId, address token);
+    error ErrorTokenRegistryTokenAlreadyRegistered(ChainId chainId, address token);
+    error ErrorTokenRegistryTokenNotContract(ChainId chainId, address token);
+    error ErrorTokenRegistryTokenNotErc20(ChainId chainId, address token);
 
-    constructor(
-        address registry
-    )
-    { 
-        initialize(registry);
+    error ErrorTokenRegistryTokenNotRegistered(ChainId chainId, address token);
+    error ErrorTokenRegistryMajorVersionInvalid(VersionPart release);
+
+    struct TokenInfo {
+        // slot 0
+        ChainId chainId; // 96
+        address token; // 20
+        uint8 decimals; // 8
+        bool active;
+        // slot 1
+        string symbol;
     }
 
-    function initialize(address registry)
-        public
-        initializer()
+    mapping(ChainId chainId => mapping(address token => TokenInfo info)) internal _tokenInfo;
+    mapping(ChainId chainId => mapping(address token => mapping(VersionPart release => bool isActive))) internal _active;
+    TokenInfo [] internal _token;
+
+    IRegistry internal _registry;
+    ChainId internal _chainId = ChainIdLib.current();
+    IERC20Metadata internal _dipToken;
+
+    /// @dev enforces msg.sender is owner of nft (or initial owner of nft ownable)
+    modifier onlyRegisteredToken(ChainId chainId, address token) {
+        if (!isRegistered(chainId, token)) {
+            revert ErrorTokenRegistryTokenNotRegistered(chainId, token);
+        }
+        _;
+    }
+
+    constructor(IRegistry registry, IERC20Metadata dipToken)
+        AccessManaged(msg.sender)
     {
-        initializeNftOwnable(msg.sender, registry);
+        // set authority
+        address authority = RegistryAdmin(registry.getRegistryAdminAddress()).authority();
+        setAuthority(authority);
+        
+        _registry = registry;
+
+        // TODO deal with chains without a dip token
+        _dipToken = _verifyOnchainToken(address(dipToken));
+
+        // register dip token
+        _registerToken(
+            _chainId, 
+            address(_dipToken), 
+            _dipToken.decimals(), 
+            _dipToken.symbol());
     }
 
 
-    /// @dev link ownership of token registry to nft owner of registry service
-    // TODO latter registry service will get new release, new address, new nft, TokenRegistry will not catch that -> use AccessManaged only for services
-    function linkToNftOwnable(address registryAddress) 
+    /// @dev register an onchain token.
+    /// this function verifies that the provided token address is a contract that implements
+    /// the non optional erc20 view functions.
+    function registerToken(address tokenAddress)
         external
-        onlyOwner
+        restricted()
     {
-        IRegistry registry = IRegistry(registryAddress);
-        // TODO use _latest instead of _initial -> but _latest is 0 before first release activation
-        address registryServiceAddress = registry.getServiceAddress(REGISTRY(), registry.getNextVersion());
+        // checks
+        IERC20Metadata token = _verifyOnchainToken(tokenAddress);
 
-        _linkToNftOwnable(registryServiceAddress);
+        // effects
+        _registerToken(_chainId, tokenAddress, token.decimals(), token.symbol());
     }
 
-    /// @dev token state is informative, registry have no clue about used tokens
-    // component owner is responsible for token selection and operations
-    // service MUST deny registration of component with inactive token 
-    function setActive(address token, VersionPart majorVersion, bool active)
+
+    /// @dev register the remote token with the provided attributes.
+    /// this function may not be used for tokens when chainId == block.chainid.
+    function registerRemoteToken(
+        ChainId chainId,
+        address token,
+        uint8 decimals,
+        string memory symbol
+    )
         external
-        onlyOwner
+        restricted()
     {
-        // verify that token is registered
-        if (!_registered[token]) {
-            _registerToken(token);
+        if (chainId == _chainId) {
+            revert ErrorTokenRegistryNotRemoteToken(chainId, token);
         }
 
+        _registerToken(chainId, token, decimals, symbol);
+    }
+
+
+    /// @dev set active flag on token itself.
+    /// when setting a token to active=false isActive will return false
+    /// regardless of release specific active value.
+    function setActive(
+        ChainId chainId, 
+        address token, 
+        bool active
+    )
+        external
+        restricted()
+        onlyRegisteredToken(chainId, token)
+    {
+        _tokenInfo[chainId][token].active = active;
+        emit LogTokenRegistryTokenGlobalStateSet(chainId, token, active);
+    }
+
+
+    /// @dev sets active state for specified token and release (major version).
+    /// internally calls setActiveWithVersionCheck() with enforcing version check.
+    /// token state is informative, registry have no clue about used tokens
+    /// component owner is responsible for token selection and operations
+    /// service MUST deny registration of component with inactive token.
+    function setActiveForVersion(
+        ChainId chainId, 
+        address token, 
+        VersionPart release, 
+        bool active
+    )
+        external
+        restricted()
+        onlyRegisteredToken(chainId, token)
+    {
+        _setActiveWithVersionCheck(chainId, token, release, active, true);
+    }
+
+
+    /// @dev as setActiveForVersion() with the option to skip the version check.
+    /// enforcing the version check checks if the provided major version with the release manager. 
+    /// the function reverts if the provided release is unknown to the release manager.
+    function setActiveWithVersionCheck(
+        ChainId chainId, 
+        address token, 
+        VersionPart release, 
+        bool active,
+        bool enforceVersionCheck
+    )
+        external
+        restricted()
+        onlyRegisteredToken(chainId, token)
+    {
+        _setActiveWithVersionCheck(chainId, token, release, active, enforceVersionCheck);
+    }
+
+
+    function _setActiveWithVersionCheck(
+        ChainId chainId, 
+        address token, 
+        VersionPart release, 
+        bool active,
+        bool enforceVersionCheck
+    )
+        internal
+    {
         // verify valid major version
-        // ensure major version increments is one
-        uint256 version = majorVersion.toInt();
-        if (!getRegistry().isValidRelease(majorVersion)) {
-            revert TokenMajorVersionInvalid(majorVersion);
+        if(enforceVersionCheck) {
+            uint256 version = release.toInt();
+            if (!getRegistry().isActiveRelease(release)) {
+                revert ErrorTokenRegistryMajorVersionInvalid(release);
+            }
         }
 
-        _active[token][majorVersion] = active;
+        _active[chainId][token][release] = active;
+
+        emit LogTokenRegistryTokenStateSet(chainId, token, release, active);
+    }
 
-        emit LogTokenStateSet(token, majorVersion, active);
+    /// @dev returns the dip token for this chain
+    function getDipToken() external view returns (IERC20Metadata dipToken) {
+        return _dipToken;
     }
 
+    /// @dev returns the number of registered tokens
     function tokens() external view returns (uint256) {
         return _token.length;
     }
 
-    function getToken(uint256 idx) external view returns (IERC20Metadata token) {
-        return IERC20Metadata(_token[idx]);
+    /// @dev returns the token info for the specified index position [0 .. tokens() - 1].
+    function getTokenInfo(uint256 idx) external view returns (TokenInfo memory tokenInfo) {
+        return _token[idx];
+    }
+
+    /// @dev returns the token info for the specified token coordinates.
+    function getTokenInfo(ChainId chainId, address token) external view returns (TokenInfo memory tokenInfo) {
+        return _tokenInfo[chainId][token];
     }
 
-    function isRegistered(address token) external view returns (bool) {
-        return _registered[token];
+    /// @dev returns true iff the specified token has been registered for this TokenRegistry contract.
+    function isRegistered(ChainId chainId, address token) public view returns (bool) {
+        return _tokenInfo[chainId][token].chainId.gtz();
+    }
+
+    /// @dev returns true iff both the token is active for the specfied release and the global token state is active
+    function isActive(ChainId chainId, address token, VersionPart release) external view returns (bool) {
+        if(!_tokenInfo[chainId][token].active) {
+            return false;
+        }
+
+        return _active[chainId][token][release];
     }
 
-    function isActive(address token, VersionPart majorVersion) external view returns (bool) {
-        return _active[token][majorVersion];
+    function getDipTokenAddress() external view returns (address) {
+        return address(_dipToken);
     }
 
-    /// @dev some sanity checks to prevent unintended registration
-    function _registerToken(address token) internal {
+    //--- IRegistryLinked --------------------------------------------------//
+
+    /// @dev returns the dip token for this chain
+    function getRegistry() public view returns (IRegistry) {
+        return _registry;
+    }
+
+    //--- internal functions ------------------------------------------------//
+
+
+    /// @dev checks if provided token address refers to a smart contract that implements 
+    /// erc20 functionality (via its non-optional functions)
+    function _verifyOnchainToken(address tokenAddress)
+        internal
+        virtual
+        view
+        returns (IERC20Metadata token)
+    {
+        token = IERC20Metadata(tokenAddress);
 
         // MUST be contract
-        if(token.code.length == 0) {
-            revert NotContract(token);
+        if(tokenAddress.code.length == 0) {
+            revert ErrorTokenRegistryTokenNotContract(ChainIdLib.current(), tokenAddress);
         }
 
-        // MUST have decimals > 0 (indicator that this is in fact an erc20 token)
-        IERC20Metadata erc20 = IERC20Metadata(token);
-        if(erc20.decimals() == 0) {
-            revert TokenDecimalsZero();
+        // MUST implement required erc20 view functions
+        if(!_implementsErc20Functions(token)) {
+            revert ErrorTokenRegistryTokenNotErc20(ChainIdLib.current(), tokenAddress);
         }
+    }
+
+
+    /// @dev checks availability of non-optional view functions
+    /// https://eips.ethereum.org/EIPS/eip-20#methods
+    function _implementsErc20Functions(IERC20Metadata token) internal view returns (bool implementsErc20Functions) {
+        try token.totalSupply() returns (uint256) {
+            // so far so goood
+        } catch {
+            return false;
+        }
+
+        try token.balanceOf(address(1)) returns (uint256) {
+            // so far so goood
+        } catch {
+            return false;
+        }
+
+        try token.allowance(address(1), address(2)) returns (uint256) {
+            // so far so goood
+        } catch {
+            return false;
+        }
+
+        return true;
+    }
+
+    /// @dev some sanity checks to prevent unintended registration:
+    /// - token not yet registered
+    /// - chainId not zero
+    /// - token address not zero
+    function _registerToken(ChainId chainId, address token, uint8 decimals, string memory symbol) internal {
+
+        if (isRegistered(chainId, token)) {
+            revert ErrorTokenRegistryTokenAlreadyRegistered(chainId, token);
+        }
+
+        if(chainId.eqz()) {
+            revert ErrorTokenRegistryChainIdZero();
+        }
+
+        if(token == address(0)) {
+            revert ErrorTokenRegistryTokenAddressZero();
+        }
+
+        TokenInfo memory tokenInfo = TokenInfo({
+            chainId: chainId,
+            token: token,
+            decimals: decimals,
+            symbol: symbol,
+            active: true});
 
-        _registered[token] = true;
-        _token.push(token);
+        _tokenInfo[chainId][token] = tokenInfo;
+        _token.push(tokenInfo);
 
-        emit LogRegistered(token, erc20.symbol(), erc20.decimals());
+        emit LogTokenRegistryTokenRegistered(chainId, token, decimals, symbol);
     }
 }

package/contracts/shared/Component.sol

@@ -0,0 +1,214 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAccessManaged} from "@openzeppelin/contracts/access/manager/IAccessManaged.sol";
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {IComponent} from "./IComponent.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IComponentService} from "./IComponentService.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType, COMPONENT} from "../type/ObjectType.sol";
+import {Registerable} from "../shared/Registerable.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {Version, VersionLib} from "../type/Version.sol";
+
+
+abstract contract Component is
+    Registerable,
+    IComponent
+{
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.component.Component.sol")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant COMPONENT_LOCATION_V1 = 0xffe8d4462baed26a47154f4b8f6db497d2f772496965791d25bd456e342b7f00;
+
+    struct ComponentStorage {
+        string _name; // unique (per instance) component name
+        bool _isInterceptor;
+        bytes _data;
+        IComponentService _componentService;
+    }
+
+
+    modifier onlyChainNft() {
+        if(msg.sender != getRegistry().getChainNftAddress()) {
+            revert ErrorComponentNotChainNft(msg.sender);
+        }
+        _;
+    }
+
+
+    function _getComponentStorage() private pure returns (ComponentStorage storage $) {
+        // solhint-disable-next-line no-inline-assembly
+        assembly {
+            $.slot := COMPONENT_LOCATION_V1
+        }
+    }
+
+
+    function __Component_init(
+        address authority,
+        address registry,
+        NftId parentNftId,
+        string memory name,
+        ObjectType componentType,
+        bool isInterceptor,
+        address initialOwner,
+        bytes memory registryData, // writeonly data that will saved in the object info record of the registry
+        bytes memory componentData // other component specific data
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+        if (bytes(name).length == 0) {
+            revert ErrorComponentNameLengthZero();
+        }
+
+        __Registerable_init(
+            authority,
+            registry, 
+            parentNftId, 
+            componentType, 
+            isInterceptor, 
+            initialOwner, 
+            registryData);
+
+        // set component state
+        ComponentStorage storage $ = _getComponentStorage();
+        $._name = name;
+        $._isInterceptor = isInterceptor;
+        $._data = componentData;
+        $._componentService = IComponentService(_getServiceAddress(COMPONENT()));
+
+        _registerInterface(type(IAccessManaged).interfaceId);
+        _registerInterface(type(IComponent).interfaceId);
+    }
+
+
+    /// @dev callback function for nft transfers
+    /// may only be called by chain nft contract.
+    /// override internal function _nftTransferFrom to implement custom behaviour
+    function nftTransferFrom(address from, address to, uint256 tokenId, address operator)
+        external
+        onlyChainNft
+    {
+        _nftTransferFrom(from, to, tokenId, operator);
+    }
+
+
+    function getWallet() public view virtual returns (address walletAddress) {
+        return getTokenHandler().getWallet();
+    }
+
+    function getTokenHandler() public virtual view returns (TokenHandler tokenHandler) {
+        return getComponentInfo().tokenHandler;
+    }
+
+    function getToken() public view virtual returns (IERC20Metadata token) {
+        return getTokenHandler().TOKEN();
+    }
+
+    function getName() public view override returns(string memory name) {
+        return getComponentInfo().name;
+    }
+
+    function getVersion() public view virtual returns (Version version) {
+        return VersionLib.toVersion(1, 0, 0);
+    }
+
+    function getComponentInfo() public virtual view returns (IComponents.ComponentInfo memory info) {
+        if (isRegistered()) {
+            return _getComponentInfo();
+        } else {
+            return getInitialComponentInfo();
+        }
+    }
+
+    /// @dev defines initial component specification
+    /// overwrite this function according to your use case
+    function getInitialComponentInfo() public virtual view returns (IComponents.ComponentInfo memory info) {
+        return _getComponentInfo();
+    }
+
+
+    function isNftInterceptor() public virtual view returns(bool isInterceptor) {
+        if (isRegistered()) {
+            return getRegistry().getObjectInfo(address(this)).isInterceptor;
+        } else {
+            return _getComponentStorage()._isInterceptor;
+        }
+    }
+
+
+    function isRegistered() public virtual view returns (bool) {
+        return getRegistry().getNftIdForAddress(address(this)).gtz();
+    }
+
+
+    /// @dev Approves token hanlder to spend up to the specified amount of tokens.
+    /// Reverts if component wallet is not token handler itself.
+    /// Only component owner (nft holder) is authorizes to call this function.
+    function _approveTokenHandler(IERC20Metadata token, Amount amount)
+        internal
+        virtual
+        returns (Amount oldAllowanceAmount)
+    {
+        oldAllowanceAmount = AmountLib.toAmount(
+            token.allowance(address(getTokenHandler()), address(this)));
+
+        _getComponentStorage()._componentService.approveTokenHandler(
+            token, 
+            amount);
+    }
+
+
+    /// @dev internal function for nft transfers.
+    /// handling logic that deals with nft transfers need to overwrite this function
+    function _nftTransferFrom(address from, address to, uint256 tokenId, address operator)
+        internal
+        virtual
+    // solhint-disable-next-line no-empty-blocks
+    { 
+        // empty default implementation
+    }
+
+
+    /// @dev Sets the components wallet to the specified address.
+    /// Depending on the source of the component information this function needs to be overwritten. 
+    /// eg for instance linked components that externally store this information with the instance store contract
+    function _setWallet(
+        address newWallet
+    )
+        internal
+        virtual
+    {
+        _getComponentStorage()._componentService.setWallet(newWallet);
+    }
+
+    function _setLocked(bool locked)
+        internal
+        virtual
+    {
+        _getComponentStorage()._componentService.setLocked(locked);
+    }
+
+
+    /// @dev depending on the source of the component information this function needs to be overwritten. 
+    /// eg for instance linked components that externally store this information with the instance store contract
+    function _getComponentInfo() internal virtual view returns (IComponents.ComponentInfo memory info) {
+        ComponentStorage storage $ = _getComponentStorage();
+        
+        return IComponents.ComponentInfo({
+            name: $._name,
+            tokenHandler: TokenHandler(address(0)),
+            data: $._data // user specific component data
+        });
+    }
+
+    /// @dev returns the service address for the specified domain
+    /// gets address via lookup from registry using the major version form the linked instance
+    function _getServiceAddress(ObjectType domain) internal view returns (address) {
+        return getRegistry().getServiceAddress(domain, getRelease());
+    }
+}