@etherisc/gif-next 0.0.2-9141c0d → 0.0.2-93de5de-423

package/contracts/instance/service/ProductService.sol

@@ -0,0 +1,233 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IProductComponent} from "../../components/IProductComponent.sol";
+import {Product} from "../../components/Product.sol";
+import {IComponent} from "../../components/IComponent.sol";
+import {IPoolComponent} from "../../components/IPoolComponent.sol";
+import {IDistributionComponent} from "../../components/IDistributionComponent.sol";
+import {IInstance} from "../IInstance.sol";
+import {IPolicy} from "../module/IPolicy.sol";
+import {IRisk} from "../module/IRisk.sol";
+import {IBundle} from "../module/IBundle.sol";
+import {IProductService} from "./IProductService.sol";
+import {ITreasury} from "../module/ITreasury.sol";
+import {ISetup} from "../module/ISetup.sol";
+
+import {TokenHandler} from "../../shared/TokenHandler.sol";
+
+import {IVersionable} from "../../shared/IVersionable.sol";
+import {Versionable} from "../../shared/Versionable.sol";
+
+import {Timestamp, zeroTimestamp} from "../../types/Timestamp.sol";
+import {UFixed, UFixedLib} from "../../types/UFixed.sol";
+import {Blocknumber, blockNumber} from "../../types/Blocknumber.sol";
+import {ObjectType, PRODUCT, POOL, POLICY} from "../../types/ObjectType.sol";
+import {APPLIED, UNDERWRITTEN, ACTIVE, KEEP_STATE} from "../../types/StateId.sol";
+import {NftId, NftIdLib, zeroNftId} from "../../types/NftId.sol";
+import {Fee, FeeLib} from "../../types/Fee.sol";
+import {ReferralId} from "../../types/Referral.sol";
+import {RiskId} from "../../types/RiskId.sol";
+import {StateId} from "../../types/StateId.sol";
+import {Version, VersionLib} from "../../types/Version.sol";
+import {RoleId, PRODUCT_OWNER_ROLE} from "../../types/RoleId.sol";
+
+import {IService} from "../../shared/IService.sol";
+import {Service} from "../../shared/Service.sol";
+import {ComponentService} from "../base/ComponentService.sol";
+import {IProductService} from "./IProductService.sol";
+import {InstanceReader} from "../InstanceReader.sol";
+import {IPoolService} from "./PoolService.sol";
+
+// TODO or name this ProtectionService to have Product be something more generic (loan, savings account, ...)
+contract ProductService is ComponentService, IProductService {
+    using NftIdLib for NftId;
+
+    IPoolService internal _poolService;
+
+    event LogProductServiceSender(address sender);
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        initializer
+        virtual override
+    {
+        address registryAddress;
+        address initialOwner;
+        (registryAddress, initialOwner) = abi.decode(data, (address, address));
+
+        initializeService(registryAddress, owner);
+
+        _poolService = IPoolService(getRegistry().getServiceAddress(POOL(), getMajorVersion()));
+
+        registerInterface(type(IProductService).interfaceId);
+    }
+
+
+    function register(address productAddress) 
+        external
+        returns(NftId productNftId)
+    {
+        (
+            IComponent component,
+            address owner,
+            IInstance instance,
+            NftId instanceNftId
+        ) = _checkComponentForRegistration(
+            productAddress,
+            PRODUCT(),
+            PRODUCT_OWNER_ROLE());
+
+        IProductComponent product = IProductComponent(productAddress);
+        IRegistry.ObjectInfo memory productInfo = getRegistryService().registerProduct(product, owner);
+        productNftId = productInfo.nftId;
+        _createProductSetup(
+            instance, 
+            product, 
+            productNftId);
+    }
+
+
+    function _createProductSetup(
+        IInstance instance, 
+        IProductComponent product, 
+        NftId productNftId 
+    )
+        internal
+        returns (string memory name)
+    {
+        // wire distribution and pool components to product component
+        ISetup.ProductSetupInfo memory setup = product.getSetupInfo();
+        IComponent distribution = IComponent(getRegistry().getObjectInfo(setup.distributionNftId).objectAddress);
+        IComponent pool = IComponent(getRegistry().getObjectInfo(setup.poolNftId).objectAddress);
+
+        distribution.setProductNftId(productNftId);
+        pool.setProductNftId(productNftId);
+        product.setProductNftId(productNftId);
+        product.linkToRegisteredNftId();
+
+        // create product setup in instance
+        instance.createProductSetup(productNftId, product.getSetupInfo());
+
+        // create target for instane access manager
+        getInstanceService().createGifTarget(
+            getRegistry().getNftId(address(instance)), 
+            address(product), 
+            product.getName());
+        getInstanceService().grantProductDefaultPermissions(instance.getNftId(), address(product), product.getName());
+    }
+
+    function getDomain() public pure override(IService, Service) returns(ObjectType) {
+        return PRODUCT();
+    }
+
+
+    function _decodeAndVerifyProductData(bytes memory data) 
+        internal 
+        returns(string memory name, ISetup.ProductSetupInfo memory setup)
+    {
+        (name, setup) = abi.decode(
+            data,
+            (string, ISetup.ProductSetupInfo)
+        );
+
+        // TODO add checks
+        // if(wallet == address(0)) {
+        //     revert WalletIsZero();
+        // }
+
+        // IRegistry.ObjectInfo memory tokenInfo = getRegistry().getObjectInfo(address(info.token));
+
+        // if(tokenInfo.objectType != TOKEN()) {
+        //     revert InvalidToken();
+        // } 
+
+        // IRegistry.ObjectInfo memory poolInfo = getRegistry().getObjectInfo(info.poolNftId);
+
+        // if(poolInfo.objectType != POOL()) {
+        //     revert InvalidPool();
+        // }
+
+        // if(poolInfo.parentNftId != instanceNftId) {
+        //     revert InvalidPoolsInstance();
+        // }
+        // // TODO pool have the same token
+        // //ITreasury.PoolSetup memory poolSetup = instance.getPoolSetup(info.poolNftId);
+        // //require(tokenInfo.objectAddress == address(poolSetup.token), "ERROR:COS-018:PRODUCT_POOL_TOKEN_MISMATCH");
+        // // TODO pool is not linked
+
+        // IRegistry.ObjectInfo memory distributionInfo = getRegistry().getObjectInfo(info.distributionNftId);
+
+        // if(distributionInfo.objectType != DISTRIBUTION()) {
+        //     revert  InvalidDistribution();
+        // } 
+
+        // if(distributionInfo.parentNftId != instanceNftId) {
+        //     revert InvalidDistributionsInstance();
+        // }
+        // // TODO distribution have the same token
+        // // TODO distribution is not linked
+    }
+
+    function setFees(
+        Fee memory productFee,
+        Fee memory processingFee
+    )
+        external
+    {
+        // TODO check args 
+
+        (
+            IRegistry.ObjectInfo memory productInfo, 
+            IInstance instance
+        ) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+
+        InstanceReader instanceReader = instance.getInstanceReader();
+        NftId productNftId = productInfo.nftId;
+        ISetup.ProductSetupInfo memory productSetupInfo = instanceReader.getProductSetupInfo(productNftId);
+
+        productSetupInfo.productFee = productFee;
+        productSetupInfo.processingFee = processingFee;
+        
+        instance.updateProductSetup(productNftId, productSetupInfo, KEEP_STATE());
+    }
+
+    function createRisk(
+        RiskId riskId,
+        bytes memory data
+    ) external override {
+        (
+            IRegistry.ObjectInfo memory productInfo, 
+            IInstance instance
+        ) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+        NftId productNftId = productInfo.nftId;
+        IRisk.RiskInfo memory riskInfo = IRisk.RiskInfo(productNftId, data);
+        instance.createRisk(
+            riskId,
+            riskInfo
+        );
+    }
+
+    function updateRisk(
+        RiskId riskId,
+        bytes memory data
+    ) external {
+        (, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+        InstanceReader instanceReader = instance.getInstanceReader();
+        IRisk.RiskInfo memory riskInfo = instanceReader.getRiskInfo(riskId);
+        riskInfo.data = data;
+        instance.updateRisk(riskId, riskInfo, KEEP_STATE());
+    }
+
+    function updateRiskState(
+        RiskId riskId,
+        StateId state
+    ) external {
+        (, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+        instance.updateRiskState(riskId, state);
+    }
+}

package/contracts/instance/service/ProductServiceManager.sol

@@ -0,0 +1,54 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IVersionable} from "../../shared/IVersionable.sol";
+import {ProxyManager} from "../../shared/ProxyManager.sol";
+import {ProductService} from "./ProductService.sol";
+import {Registry} from "../../registry/Registry.sol";
+import {RegistryService} from "../../registry/RegistryService.sol";
+import {VersionLib} from "../../types/Version.sol";
+
+contract ProductServiceManager is ProxyManager {
+
+    ProductService private _productService;
+
+    /// @dev initializes proxy manager with product service implementation 
+    constructor(
+        address registryAddress
+    )
+        ProxyManager(registryAddress)
+    {
+        ProductService svc = new ProductService();
+        bytes memory data = abi.encode(registryAddress, address(this));
+        IVersionable versionable = deploy(
+            address(svc), 
+            data);
+
+        _productService = ProductService(address(versionable));
+
+        // Registry registry = Registry(registryAddress);
+        // address registryServiceAddress = registry.getServiceAddress("RegistryService", VersionLib.toVersion(3, 0, 0).toMajorPart());
+        // RegistryService registryService = RegistryService(registryServiceAddress);
+        // TODO this must have a role or own nft to register service
+        //registryService.registerService(_productService);
+        
+        // TODO no nft to link yet
+        // link ownership of instance service manager ot nft owner of instance service
+        //_linkToNftOwnable(
+        //    address(registryAddress),
+        //    address(_productService));
+
+        // implies that after this constructor call only upgrade functionality is available
+        // _isDeployed = true;
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getProductService()
+        external
+        view
+        returns (ProductService productService)
+    {
+        return _productService;
+    }
+
+}

package/contracts/registry/ChainNft.sol

@@ -0,0 +1,202 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ERC721, ERC721Enumerable} from "@openzeppelin/contracts/token/ERC721/extensions/ERC721Enumerable.sol";
+import {IERC721} from "@openzeppelin/contracts/token/ERC721/IERC721.sol";
+
+import {ITransferInterceptor} from "./ITransferInterceptor.sol";
+
+contract ChainNft is ERC721Enumerable {
+
+    // constants
+    string public constant NAME = "Dezentralized Insurance Protocol NFT";
+    string public constant SYMBOL = "DIPNFT";
+
+    uint256 public constant PROTOCOL_NFT_ID = 1101;
+    uint256 public constant GLOBAL_REGISTRY_ID = 2101;
+
+    // custom errors
+    error CallerNotRegistry(address caller);
+    error RegistryAddressZero();
+    error NftUriEmpty();
+    error NftUriAlreadySet();
+
+    // contract state
+
+    // remember interceptors
+    mapping(uint256 tokenId => address interceptor) private _interceptor;
+
+    // remember token uri
+    mapping(uint256 tokenId => string uri) private _uri;
+
+    // remember registry
+    address private _registry;
+
+    // only used for _getNextTokenId
+    uint256 internal _chainIdInt;
+    uint256 internal _chainIdDigits;
+    uint256 internal _chainIdMultiplier;
+    uint256 internal _idNext;
+    uint256 internal _totalMinted;
+
+    modifier onlyRegistry() {
+        if (msg.sender != _registry) { revert CallerNotRegistry(msg.sender); }
+        _;
+    }
+
+    constructor(address registry) ERC721(NAME, SYMBOL) {
+        if (registry == address(0)) { revert RegistryAddressZero(); }
+
+        _registry = registry;
+        _chainIdInt = block.chainid;
+        _chainIdDigits = 0;
+
+        // count digis
+        uint256 num = _chainIdInt;
+        while (num != 0) {
+            _chainIdDigits++;
+            num /= 10;
+        }
+
+        _chainIdMultiplier = 10 ** _chainIdDigits;
+        _idNext = 3;
+    }
+
+    /**
+    * @dev mints a token for a specified token id
+    * not part of the IRegistry interface only needed for
+    * initial registry setup (protocol and global registry objects)
+    */
+    function mint(address to, uint256 tokenId) external onlyRegistry {
+        _totalMinted++;
+        _safeMint(to, tokenId);
+    }
+
+
+    /**
+    * @dev mints the next token to register new objects
+    * non-zero transferInterceptors are recorded and called during nft token transfers.
+    * the contract receiving such a notification may decides to revert or record the transfer
+    */
+    function mint(
+        address to,
+        address interceptor,
+        string memory uri
+    ) public onlyRegistry returns (uint256 tokenId) {
+        tokenId = _getNextTokenId();
+
+        if (interceptor != address(0)) {
+            _interceptor[tokenId] = interceptor;
+        }
+
+        if (bytes(uri).length > 0) {
+            _uri[tokenId] = uri;
+        }
+
+        _totalMinted++;
+        _safeMint(to, tokenId);
+    }
+
+
+    /**
+     * @dev amend the open zeppelin transferFrom function by an interceptor call if such an interceptor is defined for the nft token id
+     * this allows distribution, product and pool components to be notified when distributors, policies and bundles are transferred.
+     */
+    function transferFrom(address from, address to, uint256 tokenId) public override (ERC721, IERC721) {
+        super.transferFrom(from, to, tokenId);
+
+        if (_interceptor[tokenId] != address(0)) {
+            ITransferInterceptor(_interceptor[tokenId]).nftTransferFrom(from, to, tokenId);
+        }
+    }
+
+
+    function burn(uint256 tokenId) external onlyRegistry {
+        _requireOwned(tokenId);
+        _burn(tokenId);
+        delete _uri[tokenId];
+    }
+
+    function setURI(
+        uint256 tokenId,
+        string memory uri
+    ) external onlyRegistry {
+        if (bytes(uri).length == 0) { revert NftUriEmpty(); }
+        if (bytes(_uri[tokenId]).length > 0) { revert NftUriAlreadySet(); }
+
+        _requireOwned(tokenId);
+        _uri[tokenId] = uri;
+    }
+
+    function exists(uint256 tokenId) external view returns (bool) {
+        return _ownerOf(tokenId) != address(0);
+    }
+
+    function tokenURI(
+        uint256 tokenId
+    ) public view override returns (string memory) {
+        // gif generally does not revert for view functions
+        // this is an exception to keep the openzeppelin nft semantics
+        _requireOwned(tokenId);
+        return _uri[tokenId];
+    }
+
+    function getInterceptor(uint256 tokenId) external view returns (address) {
+        return _interceptor[tokenId];
+    }
+
+    function getRegistryAddress() external view returns (address) {
+        return _registry;
+    }
+
+    function totalMinted() external view returns (uint256) {
+        return _totalMinted;
+    }
+
+    /**
+    * @dev token id calculation based on an index value that is supposed
+    * to increase with every minted token
+    *
+    * requirement: each chain registry produces token ids that
+    * are guaranteed to not collide with any token id genereated
+    * on a different chain
+    *
+    * format concat(counter,chainid,2 digits for len-of-chain-id)
+    * restriction chainid up to 99 digits
+    * decode: from right to left:
+    * - 2 right most digits encode length of chainid
+    * - move number of digits to left as determined above (-> chainid)
+    * - the reminder to the left is the counter
+    *
+    * special cases
+    * 1101 -> decentralized insurance protocol
+    * 2102 -> global registry
+    * 2xxxxx -> chain registry, where xxxxx = <chain-part> 
+    *
+    * examples
+    * 1101
+    * ^^ ^
+    * || +- 1-digit chain id
+    * |+-- chain id = 1 (mainnet)
+    * +-- 1st token id on mainnet
+    * (1 * 10 ** 1 + 1) * 100 + 1
+    * 42987654321010
+    * ^ ^          ^
+    * | |          +- 10-digit chain id
+    * | +-- chain id = 9876543210 (hypothetical chainid)
+    * +-- 42nd token id on this chain
+    * (42 * 10 ** 10 + 9876543210) * 100 + 10
+    * (index * 10 ** digits + chainid) * 100 + digits (1 < digits < 100)
+    */
+    function calculateTokenId(uint256 idIndex) public view returns (uint256 id) {
+        id =
+            (idIndex * _chainIdMultiplier + _chainIdInt) *
+            100 +
+            _chainIdDigits;
+    }
+
+    function _getNextTokenId() private returns (uint256 id) {
+        id = calculateTokenId(_idNext);
+        _idNext++;
+    }
+}

package/contracts/registry/IRegistry.sol

@@ -0,0 +1,99 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+
+import {NftId} from "../types/NftId.sol";
+import {ObjectType} from "../types/ObjectType.sol";
+import {VersionPart} from "../types/Version.sol";
+import {Timestamp} from "../types/Timestamp.sol";
+
+interface IRegistry is IERC165 {
+
+    event LogRegistration(NftId nftId, NftId parentNftId, ObjectType objectType, bool isInterceptor, address objectAddress, address initialOwner);
+    event LogServiceRegistration(VersionPart majorVersion, ObjectType domain);
+
+    // registerService()
+    error CallerNotReleaseManager();
+    error ServiceAlreadyRegistered(address service);
+
+    // register()
+    error CallerNotRegistryService();
+    error ServiceRegistration();
+
+    // registerWithCustomTypes()
+    error CoreTypeRegistration();
+
+    // _register()
+    error ZeroParentAddress();
+    error InvalidTypesCombination(ObjectType objectType, ObjectType parentType);
+    error ContractAlreadyRegistered(address objectAddress);
+
+    struct ObjectInfo {
+        NftId nftId;
+        NftId parentNftId;
+        ObjectType objectType;
+        bool isInterceptor;
+        address objectAddress;
+        address initialOwner;
+        bytes data;
+    }// TODO delete nftId and initialOwner(if not used) from struct
+    // TODO strong disagree, keep nftId there (lets keep get object info return object consistent)
+
+    struct ReleaseInfo {
+        ObjectType[] domains;
+        Timestamp createdAt;
+        //Timestamp updatedAt;
+    }
+
+    function registerService(
+        ObjectInfo memory serviceInfo, 
+        VersionPart serviceVersion, 
+        ObjectType serviceDomain
+    ) external returns(NftId nftId);
+
+    function register(ObjectInfo memory info) external returns (NftId nftId);
+
+    function registerWithCustomType(ObjectInfo memory info) external returns (NftId nftId);
+
+    function getInitialVersion() external view returns (VersionPart);
+
+    function getNextVersion() external view returns (VersionPart);
+
+    function getLatestVersion() external view returns (VersionPart);
+
+    function getReleaseInfo(VersionPart version) external view returns (ReleaseInfo memory);
+
+    function getObjectCount() external view returns (uint256);
+
+    function getNftId() external view returns (NftId nftId);
+
+    function getNftId(address objectAddress) external view returns (NftId nftId);
+
+    function ownerOf(NftId nftId) external view returns (address);
+
+    function ownerOf(address contractAddress) external view returns (address);
+
+    function getObjectInfo(NftId nftId) external view returns (ObjectInfo memory info);
+
+    function getObjectInfo(address object) external view returns (ObjectInfo memory info);
+
+    function isRegistered(NftId nftId) external view returns (bool);
+
+    function isRegistered(address contractAddress) external view returns (bool);
+
+    function isRegisteredService(address contractAddress) external view returns (bool);
+
+    function isValidRelease(VersionPart version) external view returns (bool);
+
+    function getServiceAddress(
+        ObjectType serviceDomain, 
+        VersionPart releaseVersion
+    ) external view returns (address serviceAddress);
+
+    function getReleaseManagerAddress() external view returns (address);
+
+    function getChainNftAddress() external view returns (address);
+
+    function getOwner() external view returns (address);
+}

package/contracts/registry/IRegistryService.sol

@@ -0,0 +1,67 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAccessManaged} from "@openzeppelin/contracts/access/manager/IAccessManaged.sol";
+
+import {NftId} from "../types/NftId.sol";
+import {ObjectType} from "../types/ObjectType.sol";
+import {RoleId} from "../types/RoleId.sol";
+import {IService} from "../shared/IService.sol";
+import {IRegistry} from "./IRegistry.sol";
+
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {IComponent} from "../components/IComponent.sol";
+
+interface IRegistryService is 
+     IService, 
+     IAccessManaged 
+{
+     error SelfRegistration();
+     error NotRegistryOwner();
+
+     error NotService();
+     error NotInstance();
+     error NotProduct();
+     error NotPool();
+     error NotDistribution();
+
+     error UnexpectedRegisterableType(ObjectType expected, ObjectType found);
+     error NotRegisterableOwner(address expectedOwner);
+     error RegisterableOwnerIsZero();   
+     error RegisterableOwnerIsRegistered();
+     error InvalidInitialOwner(address initialOwner);
+     error InvalidAddress(address registerableAddress);
+
+     struct FunctionConfig
+     {
+          ObjectType serviceDomain;
+          bytes4[] selectors;
+     }
+
+     function getFunctionConfigs()
+          external
+          pure
+          returns(
+               FunctionConfig[] memory config
+          );
+
+     // TODO used by service -> add owner arg 
+     function registerInstance(IRegisterable instance, address owner)
+          external returns(IRegistry.ObjectInfo memory info); 
+
+     function registerProduct(IComponent product, address owner)
+          external returns(IRegistry.ObjectInfo memory info);
+
+     function registerPool(IComponent pool, address owner)
+          external returns(IRegistry.ObjectInfo memory info);
+
+     function registerDistribution(IComponent distribution, address owner)
+          external returns(IRegistry.ObjectInfo memory info);
+
+     function registerDistributor(IRegistry.ObjectInfo memory info) external returns(NftId nftId);
+
+     function registerPolicy(IRegistry.ObjectInfo memory info) external returns(NftId nftId);
+
+     function registerBundle(IRegistry.ObjectInfo memory info) external returns(NftId nftId); 
+}
+

package/contracts/registry/ITransferInterceptor.sol

@@ -0,0 +1,6 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+interface ITransferInterceptor {
+    function nftTransferFrom(address from, address to, uint256 tokenId) external;
+}