@etherisc/gif-next 0.0.2-9141c0d → 0.0.2-91f98cf-477

package/contracts/experiment/statemachine/SimpleStateMachine.sol

@@ -0,0 +1,31 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {StateId, toStateId} from "../../types/StateId.sol";
+import {SM} from "./SM.sol";
+
+contract SimpleStateMachine is SM {
+    uint8 public constant STATE_ACTIVE = 10;
+    uint8 public constant STATE_PAUSED = 20;
+    uint8 public constant STATE_ARCHIVED = 30;
+
+    constructor() {
+        addTransition(ACTIVE(), PAUSED());
+        addTransition(PAUSED(), ACTIVE());
+        addTransition(PAUSED(), ARCHIVED());
+
+        setInitialState(ACTIVE());
+    }
+
+    function ACTIVE() public pure returns (StateId stateId) {
+        return toStateId(STATE_ACTIVE);
+    }
+
+    function PAUSED() public pure returns (StateId stateId) {
+        return toStateId(STATE_PAUSED);
+    }
+
+    function ARCHIVED() public pure returns (StateId stateId) {
+        return toStateId(STATE_ARCHIVED);
+    }
+}

package/contracts/experiment/types/TypeA.sol

@@ -0,0 +1,47 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+/*
+# chisel session for user defined types
+
+import {TypeA, toTypeA} from "./contracts/experiment/types/TypeA.sol";
+TypeA a = toTypeA(1);
+TypeA b = toTypeA(2);
+uint(a.toInt())
+uint(b.toInt())
+a == b
+a != b
+
+import {TypeB, toTypeB} from "./contracts/experiment/types/TypeB.sol";
+TypeB x = toTypeB(33);
+uint(x.toInt())
+a == x; // -> error
+a.toInt() == x.toInt() // -> no error
+ */
+
+// bytes5 allows for chain ids up to 13 digits
+type TypeA is uint248;
+
+// type bindings
+using {eqTypeA as ==, neTypeA as !=, TypeALib.toInt} for TypeA global;
+
+// general pure free functions
+function toTypeA(uint256 typeA) pure returns (TypeA) {
+    return TypeA.wrap(uint248(typeA));
+}
+
+// pure free functions for operators
+function eqTypeA(TypeA a, TypeA b) pure returns (bool isSame) {
+    return TypeA.unwrap(a) == TypeA.unwrap(b);
+}
+
+function neTypeA(TypeA a, TypeA b) pure returns (bool isDifferent) {
+    return TypeA.unwrap(a) != TypeA.unwrap(b);
+}
+
+// library functions that operate on user defined type
+library TypeALib {
+    function toInt(TypeA typeA) internal pure returns (uint256) {
+        return uint256(TypeA.unwrap(typeA));
+    }
+}

package/contracts/experiment/types/TypeB.sol

@@ -0,0 +1,29 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+// bytes5 allows for chain ids up to 13 digits
+type TypeB is uint248;
+
+// type bindings
+using {eqTypeB as ==, addTypeB as +, TypeBLib.toInt} for TypeB global;
+
+// general pure free functions
+function toTypeB(uint256 x) pure returns (TypeB) {
+    return TypeB.wrap(uint248(x));
+}
+
+// pure free functions for operators
+function eqTypeB(TypeB a, TypeB b) pure returns (bool isSame) {
+    return TypeB.unwrap(a) == TypeB.unwrap(b);
+}
+
+function addTypeB(TypeB a, TypeB b) pure returns (TypeB sum) {
+    return TypeB.wrap(TypeB.unwrap(a) + TypeB.unwrap(b));
+}
+
+// library functions that operate on user defined type
+library TypeBLib {
+    function toInt(TypeB b) internal pure returns (uint256) {
+        return uint256(TypeB.unwrap(b));
+    }
+}

package/contracts/instance/IInstance.sol

@@ -0,0 +1,53 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+
+import {IVersionable} from "../shared/IVersionable.sol";
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {IOwnable} from "../shared/IOwnable.sol";
+import {RoleId} from "../types/RoleId.sol";
+
+import {IAccessModule} from "./module/access/IAccess.sol";
+import {IBundleModule} from "./module/bundle/IBundle.sol";
+import {IDistributionModule} from "./module/distribution/IDistribution.sol";
+import {IComponentModule} from "./module/component/IComponent.sol";
+import {IPolicyModule} from "./module/policy/IPolicy.sol";
+import {IPoolModule} from "./module/pool/IPoolModule.sol";
+import {IRiskModule} from "./module/risk/IRisk.sol";
+import {ITreasuryModule} from "./module/treasury/ITreasury.sol";
+
+import {IKeyValueStore} from "./base/IKeyValueStore.sol";
+import {IRegistry, IRegistryLinked} from "../registry/IRegistryLinked.sol";
+
+import {IComponentOwnerService} from "./service/IComponentOwnerService.sol";
+import {IDistributionService} from "./service/IDistributionService.sol";
+import {IProductService} from "./service/IProductService.sol";
+import {IPoolService} from "./service/IPoolService.sol";
+import {IInstanceBase} from "./base/IInstanceBase.sol";
+
+// solhint-disable-next-line no-empty-blocks
+interface IInstance is
+    IERC165,
+    IVersionable,
+    IRegisterable,
+    IAccessModule,
+    IPolicyModule,
+    IPoolModule,
+    IRiskModule,
+    IBundleModule,
+    IComponentModule,
+    ITreasuryModule,
+    IDistributionModule,
+    IInstanceBase
+{
+    function getRegistry() external view override (IPolicyModule, IRegisterable) returns (IRegistry registry);
+    function getOwner() external view override (IOwnable, IAccessModule) returns(address owner);
+
+    function getKeyValueStore() external view override (IInstanceBase) returns (IKeyValueStore keyValueStore);
+    function getComponentOwnerService() external view override (IInstanceBase, IComponentModule) returns(IComponentOwnerService);
+    function getDistributionService() external view override returns(IDistributionService);
+    function getProductService() external view override (IInstanceBase, IBundleModule, IPolicyModule) returns(IProductService);
+    function getPoolService() external view override (IInstanceBase, IBundleModule, IPoolModule) returns(IPoolService);
+
+}

package/contracts/instance/IInstanceLinked.sol

@@ -0,0 +1,8 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IInstance} from "./IInstance.sol";
+
+interface IInstanceLinked {
+    function getInstance() external view returns (IInstance instance);
+}

package/contracts/instance/Instance.sol

@@ -0,0 +1,74 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../types/NftId.sol";
+import {RoleId} from "../types/RoleId.sol";
+
+import {InstanceBase} from "./base/InstanceBase.sol";
+import {AccessModule} from "./module/access/Access.sol";
+import {ComponentModule} from "./module/component/ComponentModule.sol";
+import {DistributionModule} from "./module/distribution/DistributionModule.sol";
+import {PolicyModule} from "./module/policy/PolicyModule.sol";
+import {PoolModule} from "./module/pool/PoolModule.sol";
+import {RiskModule} from "./module/risk/RiskModule.sol";
+import {BundleModule} from "./module/bundle/BundleModule.sol";
+import {TreasuryModule} from "./module/treasury/TreasuryModule.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {Registerable} from "../shared/Registerable.sol";
+import {IAccessModule} from "./module/access/IAccess.sol";
+import {IBundleModule} from "./module/bundle/IBundle.sol";
+import {IComponentModule} from "./module/component/IComponent.sol";
+import {IPoolModule} from "./module/pool/IPoolModule.sol";
+import {IPolicyModule} from "./module/policy/IPolicy.sol";
+import {IInstanceBase} from "./base/IInstanceBase.sol";
+
+import {IComponentOwnerService} from "./service/IComponentOwnerService.sol";
+import {IDistributionService} from "./service/IDistributionService.sol";
+import {IProductService} from "./service/IProductService.sol";
+import {IPoolService} from "./service/IPoolService.sol";
+
+import {IKeyValueStore} from "./base/IKeyValueStore.sol";
+
+contract Instance is
+    InstanceBase,
+    AccessModule,
+    BundleModule,
+    ComponentModule,
+    DistributionModule,
+    PolicyModule,
+    PoolModule,
+    RiskModule,
+    TreasuryModule
+{
+    constructor(
+        address registry,
+        NftId registryNftId
+    )
+        InstanceBase(registry, registryNftId)
+        AccessModule()
+        BundleModule()
+        DistributionModule()
+        ComponentModule()
+        PolicyModule()
+        PoolModule()
+        TreasuryModule()
+    {
+        initializeBundleModule(_keyValueStore);
+        initializeComponentModule(_keyValueStore);
+        initializeDistributionModule(_keyValueStore);
+        initializePolicyModule(_keyValueStore);
+        initializePoolModule(_keyValueStore);
+        initializeRiskModule(_keyValueStore);
+    }
+
+    function getRegistry() public view override (Registerable, IPolicyModule) returns (IRegistry registry) { return super.getRegistry(); }
+    function getKeyValueStore() public view override (InstanceBase) returns (IKeyValueStore keyValueStore) { return super.getKeyValueStore(); }
+
+    function getComponentOwnerService() external view override (IComponentModule, IInstanceBase) returns(IComponentOwnerService service) { return _componentOwnerService; }
+    function getDistributionService() external view override (IInstanceBase) returns(IDistributionService service) { return _distributionService; }
+    function getProductService() external view override (IBundleModule, IPolicyModule, IInstanceBase) returns(IProductService service) { return _productService; }
+    function getPoolService() external view override (IBundleModule, IPoolModule, IInstanceBase) returns(IPoolService service) { return _poolService; }
+
+    function getOwner() public view override (IAccessModule, Registerable) returns(address owner) { return super.getOwner(); }
+}

package/contracts/instance/base/ComponentServiceBase.sol

@@ -0,0 +1,42 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IInstance} from "../../instance/IInstance.sol";
+import {ObjectType, INSTANCE, PRODUCT, POOL} from "../../types/ObjectType.sol";
+import {NftId, NftIdLib} from "../../types/NftId.sol";
+
+import {ServiceBase} from "./ServiceBase.sol";
+
+abstract contract ComponentServiceBase is ServiceBase {
+
+    constructor(
+        address registry,
+        NftId registryNftId
+    )
+        ServiceBase(registry, registryNftId)
+    // solhint-disable-next-line no-empty-blocks
+    {
+    }
+
+
+    function _getAndVerifyComponentInfoAndInstance(
+        ObjectType objectType
+    )
+        internal
+        view
+        returns(
+            IRegistry.ObjectInfo memory info, 
+            IInstance instance
+        )
+    {
+        NftId componentNftId = _registry.getNftId(msg.sender);
+        require(componentNftId.gtz(), "ERROR_COMPONENT_UNKNOWN");
+
+        info = _registry.getObjectInfo(componentNftId);
+        require(info.objectType == objectType, "OBJECT_TYPE_INVALID");
+
+        address instanceAddress = _registry.getObjectInfo(info.parentNftId).objectAddress;
+        instance = IInstance(instanceAddress);
+    }
+}

package/contracts/instance/base/IInstanceBase.sol

@@ -0,0 +1,22 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Key32} from "../../types/Key32.sol";
+import {StateId} from "../../types/StateId.sol";
+
+import {IKeyValueStore} from "./IKeyValueStore.sol";
+import {IComponentOwnerService} from "../service/IComponentOwnerService.sol";
+import {IDistributionService} from "../service/IDistributionService.sol";
+import {IProductService} from "../service/IProductService.sol";
+import {IPoolService} from "../service/IPoolService.sol";
+
+interface IInstanceBase {
+    function getKeyValueStore() external view returns (IKeyValueStore keyValueStore);
+    function updateState(Key32 key, StateId state) external;
+    function getState(Key32 key) external view returns (StateId state);
+
+    function getComponentOwnerService() external view returns(IComponentOwnerService service);
+    function getDistributionService() external view returns(IDistributionService);
+    function getProductService() external view returns(IProductService service);
+    function getPoolService() external view returns(IPoolService service);
+}

package/contracts/instance/base/IKeyValueStore.sol

@@ -0,0 +1,50 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Blocknumber, blockBlocknumber, zeroBlocknumber} from "../../types/Blocknumber.sol";
+import {Key32, KeyId} from "../../types/Key32.sol";
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId} from "../../types/StateId.sol";
+
+import {ILifecycle} from "./ILifecycle.sol";
+
+interface IKeyValueStore is ILifecycle {
+
+    struct Key {
+        ObjectType objectType;
+        KeyId id;
+    }
+
+    struct Value {
+        Metadata metadata;
+        bytes data;
+    }
+
+    struct Metadata {
+        ObjectType objectType;
+        StateId state;
+        address updatedBy;
+        Blocknumber updatedIn;
+        Blocknumber createdIn;
+    }
+
+    event LogInfoCreated(Key key, StateId state, address createdBy, address txOrigin);
+    event LogInfoUpdated(Key key, StateId state, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
+    event LogStateUpdated(Key key, StateId stateOld, StateId stateNew, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
+
+    // generic state changing functions
+    function create(Key32 key, ObjectType objectType, bytes memory data) external;
+    function update(Key32 key, StateId state, bytes memory data) external;
+    function updateData(Key32 key, bytes memory data) external;
+    function updateState(Key32 key, StateId state) external;
+
+    function exists(Key32 key) external view returns (bool);
+    function get(Key32 key) external view returns (Value memory value);
+    function getData(Key32 key) external view returns (bytes memory data);
+    function getMetadata(Key32 key) external view returns (Metadata memory metadata);
+    function getState(Key32 key) external view returns (StateId state);
+
+    function toKey32(ObjectType objectType, KeyId id) external pure returns(Key32);
+    function toKey(Key32 key32) external pure returns(Key memory key);
+}

package/contracts/instance/base/ILifecycle.sol

@@ -0,0 +1,30 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId, toStateId, zeroStateId} from "../../types/StateId.sol";
+import {NftId} from "../../types/NftId.sol";
+
+interface ILifecycle {
+
+    error ErrorNoLifecycle(NftId nftId, ObjectType objectType);
+    error ErrorInvalidStateTransition(
+        ObjectType objectType,
+        StateId fromStateId,
+        StateId toStateId
+    );
+
+    function hasLifecycle(
+        ObjectType objectType
+    ) external view returns (bool);
+
+    function getInitialState(
+        ObjectType objectType
+    ) external view returns (StateId);
+
+    function isValidTransition(
+        ObjectType objectType,
+        StateId fromId,
+        StateId toId
+    ) external view returns (bool);
+}

package/contracts/instance/base/IService.sol

@@ -0,0 +1,15 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {VersionPart} from "../../types/Version.sol";
+
+import {IRegisterable} from "../../shared/IRegisterable.sol";
+import {IVersionable} from "../../shared/IVersionable.sol";
+
+interface IService is 
+    IRegisterable,
+    IVersionable
+{
+    function getName() external pure returns(string memory name);
+    function getMajorVersion() external view returns(VersionPart majorVersion);
+}

package/contracts/instance/base/InstanceBase.sol

@@ -0,0 +1,91 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Versionable} from "../../shared/Versionable.sol";
+import {Registerable} from "../../shared/Registerable.sol";
+
+import {ObjectType, INSTANCE} from "../../types/ObjectType.sol";
+import {Key32} from "../../types/Key32.sol";
+import {NftId} from "../../types/NftId.sol";
+import {StateId} from "../../types/StateId.sol";
+import {Version, VersionPart, VersionLib} from "../../types/Version.sol";
+
+import {IComponentOwnerService} from "../service/IComponentOwnerService.sol";
+import {IDistributionService} from "../service/IDistributionService.sol";
+import {IProductService} from "../service/IProductService.sol";
+import {IPoolService} from "../service/IPoolService.sol";
+
+import {IKeyValueStore} from "./IKeyValueStore.sol";
+import {IInstance} from "../IInstance.sol";
+import {IInstanceBase} from "./IInstanceBase.sol";
+
+import {KeyValueStore} from "./KeyValueStore.sol";
+
+abstract contract InstanceBase is
+    Versionable,
+    Registerable,
+    IInstanceBase
+{
+    IKeyValueStore internal _keyValueStore;
+
+    IComponentOwnerService internal _componentOwnerService;
+    IDistributionService internal _distributionService;
+    IProductService internal _productService;
+    IPoolService internal _poolService;
+
+    constructor(
+        address registry,
+        NftId registryNftId
+    )
+        Registerable(registry, registryNftId)
+        Versionable()
+    {
+        _keyValueStore = new KeyValueStore();
+
+        _registerInterface(type(IInstance).interfaceId);
+        _linkToServicesInRegistry();
+    }
+
+    function getKeyValueStore() public view virtual override returns (IKeyValueStore keyValueStore) { return _keyValueStore; }
+
+    function updateState(Key32 key, StateId state) external override {
+        _keyValueStore.updateState(key, state);
+    }
+
+    function getState(Key32 key) external view override returns (StateId state) {
+        return _keyValueStore.getState(key);
+    }
+
+    // from versionable
+    function getVersion()
+        public 
+        pure 
+        virtual override
+        returns(Version)
+    {
+        return VersionLib.toVersion(3,0,0);
+    }
+
+    // from registerable
+    function getType() external pure override returns (ObjectType objectType) {
+        return INSTANCE();
+    }
+
+
+    // internal / private functions
+    function _linkToServicesInRegistry() internal {
+        VersionPart majorVersion = getVersion().toMajorPart();
+        _componentOwnerService = IComponentOwnerService(_getAndCheck("ComponentOwnerService", majorVersion));
+        _distributionService = IDistributionService(_getAndCheck("DistributionService", majorVersion));
+        _productService = IProductService(_getAndCheck("ProductService", majorVersion));
+        _poolService = IPoolService(_getAndCheck("PoolService", majorVersion));
+    }
+
+    function _getAndCheck(string memory serviceName, VersionPart majorVersion) internal view returns (address serviceAddress) {
+        serviceAddress = _registry.getServiceAddress(serviceName, majorVersion);
+        require(
+            serviceAddress != address(0),
+            "ERROR:INS-001:NOT_REGISTERED"
+        );
+    }
+}

package/contracts/instance/base/KeyValueStore.sol

@@ -0,0 +1,161 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Blocknumber, blockBlocknumber, zeroBlocknumber} from "../../types/Blocknumber.sol";
+import {Key32, KeyId, Key32Lib} from "../../types/Key32.sol";
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId, ACTIVE} from "../../types/StateId.sol";
+import {Timestamp, blockTimestamp, zeroTimestamp} from "../../types/Timestamp.sol";
+
+import {Lifecycle} from "./Lifecycle.sol";
+import {IKeyValueStore} from "./IKeyValueStore.sol";
+
+contract KeyValueStore is Lifecycle, IKeyValueStore {
+
+    mapping(Key32 key32 => Value value) private _value;
+    address private _owner;
+
+    modifier onlyOwner() {
+        require(
+            msg.sender == _owner,
+            "ERROR:KVS-001:NOT_OWNER");
+        _;
+    }
+
+    constructor() {
+        _owner = msg.sender;
+    }
+
+    function create(
+        Key32 key32, 
+        ObjectType objectType, 
+        bytes memory data
+    )
+        public
+        onlyOwner
+    {
+        require(objectType.gtz(), "ERROR:KVS-010:TYPE_UNDEFINED");
+
+        Metadata storage metadata = _value[key32].metadata;
+        require(metadata.state.eqz(), "ERROR:KVS-012:ALREADY_CREATED");
+
+        address createdBy = msg.sender;
+        Blocknumber blocknumber = blockBlocknumber();
+        StateId initialState = hasLifecycle(objectType) ? getInitialState(objectType) : ACTIVE();
+
+        // set metadata
+        metadata.objectType = objectType;
+        metadata.state = initialState;
+        metadata.updatedBy = createdBy;
+        metadata.updatedIn = blocknumber;
+        metadata.createdIn = blocknumber;
+
+        // set data
+        _value[key32].data = data;
+
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogInfoCreated(toKey(key32), initialState, createdBy, tx.origin);
+    }
+
+    function update(Key32 key32, StateId state, bytes memory data) 
+        public
+        onlyOwner
+    {
+        require(state.gtz(), "ERROR:KVS-020:STATE_UNDEFINED");
+        Metadata storage metadata = _value[key32].metadata;
+        StateId stateOld = metadata.state;
+        require(stateOld.gtz(), "ERROR:KVS-021:NOT_EXISTING");
+
+        // update data
+        _value[key32].data = data;
+
+        // update metadata (and state)
+        address updatedBy = msg.sender;
+        Blocknumber lastUpdatedIn = metadata.updatedIn;
+        metadata.state = state;
+        metadata.updatedBy = updatedBy;
+        metadata.updatedIn = blockBlocknumber();
+
+        // create log entries
+        Key memory key = toKey(key32);
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogStateUpdated(key, state, stateOld, updatedBy, tx.origin, lastUpdatedIn);
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogInfoUpdated(key, state, updatedBy, tx.origin, lastUpdatedIn);
+    }
+
+    function updateData(Key32 key32, bytes memory data) 
+        public
+        onlyOwner
+    {
+        Metadata storage metadata = _value[key32].metadata;
+        StateId state = metadata.state;
+        require(state.gtz(), "ERROR:KVS-030:NOT_EXISTING");
+
+        // update data
+        _value[key32].data = data;
+
+        // update metadata
+        address updatedBy = msg.sender;
+        Blocknumber lastUpdatedIn = metadata.updatedIn;
+        metadata.updatedBy = updatedBy;
+        metadata.updatedIn = blockBlocknumber();
+
+        // create log entry
+        Key memory key = toKey(key32);
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogInfoUpdated(key, state, updatedBy, tx.origin, lastUpdatedIn);
+    }
+
+    function updateState(Key32 key32, StateId state)
+        public
+        onlyOwner
+    {
+        require(state.gtz(), "ERROR:KVS-040:STATE_UNDEFINED");
+        Metadata storage metadata = _value[key32].metadata;
+        StateId stateOld = metadata.state;
+        require(stateOld.gtz(), "ERROR:KVS-041:NOT_EXISTING");
+
+        // update metadata (and state)
+        address updatedBy = msg.sender;
+        Blocknumber lastUpdatedIn = metadata.updatedIn;
+        metadata.state = state;
+        metadata.updatedBy = updatedBy;
+        metadata.updatedIn = blockBlocknumber();
+
+        // create log entry
+        Key memory key = toKey(key32);
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogStateUpdated(key, state, stateOld, updatedBy, tx.origin, lastUpdatedIn);
+    }
+
+    function exists(Key32 key32) public view returns (bool) {
+        return _value[key32].metadata.state.gtz();
+    }
+
+    function get(Key32 key32) public view returns (Value memory value) {
+        return _value[key32];
+    }
+
+    function getMetadata(Key32 key32) public view returns (Metadata memory metadata) {
+        return _value[key32].metadata;
+    }
+
+    function getData(Key32 key32) public view returns (bytes memory data) {
+        return _value[key32].data;
+    }
+
+    function getState(Key32 key32) public view returns (StateId state) {
+        return _value[key32].metadata.state;
+    }
+
+    function toKey32(ObjectType objectType, KeyId id) external pure override returns(Key32) {
+        return Key32Lib.toKey32(objectType, id);
+    }
+
+    function toKey(Key32 key32) public pure override returns (Key memory key) {
+        (ObjectType objectType, KeyId id) = key32.toKey();
+        return Key(objectType, id);
+    }
+}