@etherisc/gif-next 0.0.2-9141c0d → 0.0.2-91b514c-961

package/contracts/registry/RegistryService.sol

@@ -0,0 +1,241 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IComponent} from "../../contracts/shared/IComponent.sol";
+import {IDistributionComponent} from "../../contracts/distribution/IDistributionComponent.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {IPoolComponent} from "../../contracts/pool/IPoolComponent.sol";
+import {IProductComponent} from "../../contracts/product/IProductComponent.sol";
+import {IRegisterable} from "../../contracts/shared/IRegisterable.sol";
+import {IRegistry} from "./IRegistry.sol";
+import {IRegistryService} from "./IRegistryService.sol";
+
+import {ObjectType, REGISTRY, SERVICE, PRODUCT, ORACLE, POOL, INSTANCE, COMPONENT, DISTRIBUTION, DISTRIBUTOR, APPLICATION, POLICY, CLAIM, BUNDLE, STAKE, STAKING, PRICE} from "../../contracts/type/ObjectType.sol";
+import {NftId, NftIdLib} from "../../contracts/type/NftId.sol";
+import {Service} from "../shared/Service.sol";
+
+contract RegistryService is
+    Service,
+    IRegistryService
+{
+    // TODO update to real hash when registry is stable
+    bytes32 public constant REGISTRY_CREATION_CODE_HASH = bytes32(0);
+
+    // from Versionable
+
+    /// @dev top level initializer
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        virtual override
+        initializer()
+    {
+        (
+            address authority,
+            address registry
+        ) = abi.decode(data, (address, address));
+
+        __Service_init(authority, registry, owner);
+        _registerInterface(type(IRegistryService).interfaceId);
+    }
+
+
+    function registerStaking(IRegisterable staking, address owner)
+        external
+        virtual
+        restricted()
+        returns(
+            IRegistry.ObjectInfo memory info
+        )
+    {
+        info = _getAndVerifyContractInfo(staking, STAKING(), owner);
+        info.nftId = getRegistry().register(info);
+    }
+
+
+    function registerInstance(IRegisterable instance, address owner)
+        external
+        virtual
+        restricted()
+        returns(
+            IRegistry.ObjectInfo memory info
+        ) 
+    {
+        if(!instance.supportsInterface(type(IInstance).interfaceId)) {
+            revert ErrorRegistryServiceNotInstance(address(instance));
+        }
+
+        info = _getAndVerifyContractInfo(instance, INSTANCE(), owner);
+        info.nftId = getRegistry().register(info);
+
+        instance.linkToRegisteredNftId(); // asume safe
+    }
+
+    function registerProduct(
+        IComponent product, 
+        address initialOwner
+    )
+        external
+        virtual
+        restricted()
+        returns(
+            IRegistry.ObjectInfo memory info
+        ) 
+    {
+        if(!product.supportsInterface(type(IProductComponent).interfaceId)) {
+            revert ErrorRegistryServiceNotProduct(address(product));
+        }
+
+        info = _getAndVerifyContractInfo(product, PRODUCT(), initialOwner);
+        info.nftId = getRegistry().register(info);
+    }
+
+    function registerProductLinkedComponent(
+        IComponent component, 
+        ObjectType objectType,
+        address initialOwner
+    )
+        external
+        virtual
+        restricted()
+        returns(
+            IRegistry.ObjectInfo memory info
+        ) 
+    {
+        // CAN revert if no ERC165 support -> will revert with empty message 
+        if(!component.supportsInterface(type(IComponent).interfaceId)) {
+            revert ErrorRegistryServiceNotComponent(address(component));
+        }
+
+        if (!(objectType == DISTRIBUTION() || objectType == ORACLE() || objectType == POOL())) {
+            revert ErrorRegistryServiceNotProductLinkedComponent(address(component));
+        }
+
+        info = _getAndVerifyContractInfo(component, objectType, initialOwner);
+        info.nftId = getRegistry().register(info);
+    }
+
+    function registerDistributor(IRegistry.ObjectInfo memory info)
+        external
+        virtual
+        restricted()
+        returns(NftId nftId) 
+    {
+        _verifyObjectInfo(info, DISTRIBUTOR());
+        nftId = getRegistry().register(info);
+    }
+
+    function registerPolicy(IRegistry.ObjectInfo memory info)
+        external
+        virtual
+        restricted()
+        returns(NftId nftId) 
+    {
+        _verifyObjectInfo(info, POLICY());
+        nftId = getRegistry().register(info);
+    }
+
+    function registerBundle(IRegistry.ObjectInfo memory info)
+        external
+        virtual
+        restricted()
+        returns(NftId nftId) 
+    {
+        _verifyObjectInfo(info, BUNDLE());
+        nftId = getRegistry().register(info);
+    }
+
+    function registerStake(IRegistry.ObjectInfo memory info)
+        external
+        virtual
+        restricted()
+        returns(NftId nftId) 
+    {
+        _verifyObjectInfo(info, STAKE());
+        nftId = getRegistry().register(info);
+    }
+
+    // Internal
+
+    function _getAndVerifyContractInfo(
+        IRegisterable registerable,
+        ObjectType expectedType, // assume can be valid only
+        address expectedOwner // assume can be 0 when given by other service
+    )
+        internal
+        virtual
+        view
+        returns(
+            IRegistry.ObjectInfo memory info 
+        )
+    {
+        info = registerable.getInitialInfo();
+
+        if(info.objectAddress != address(registerable)) {
+            revert ErrorRegistryServiceRegisterableAddressInvalid(registerable, info.objectAddress);
+        }
+
+        if(info.objectType != expectedType) {// type is checked in registry anyway...but service logic may depend on expected value
+            revert ErrorRegistryServiceRegisterableTypeInvalid(registerable, expectedType, info.objectType);
+        }
+
+        address owner = info.initialOwner;
+
+        if(owner != expectedOwner) { // registerable owner protection
+            revert ErrorRegistryServiceRegisterableOwnerInvalid(registerable, expectedOwner, owner);
+        }
+
+        if(owner == address(registerable)) {
+            revert ErrorRegistryServiceRegisterableSelfRegistration(registerable);
+        }
+
+        if(owner == address(0)) {
+            revert ErrorRegistryServiceRegisterableOwnerZero(registerable);
+        }
+        
+        if(getRegistry().isRegistered(owner)) { 
+            revert ErrorRegistryServiceRegisterableOwnerRegistered(registerable, owner);
+        }
+    }
+
+    function _verifyObjectInfo(
+        IRegistry.ObjectInfo memory info,
+        ObjectType expectedType
+    )
+        internal
+        virtual
+        view
+    {
+        if(info.objectAddress > address(0)) {
+            revert ErrorRegistryServiceObjectAddressNotZero(info.objectType);
+        }
+
+        if(info.objectType != expectedType) {// type is checked in registry anyway...but service logic may depend on expected value
+            revert ErrorRegistryServiceObjectTypeInvalid(expectedType, info.objectType);
+        }
+
+        address owner = info.initialOwner;
+
+        if(owner == address(0)) {
+            revert ErrorRegistryServiceObjectOwnerZero(info.objectType);
+        }
+
+        if(owner == msg.sender) {
+            revert ErrorRegistryServiceInvalidInitialOwner(owner);
+        }
+
+        if(getRegistry().isRegistered(owner)) {
+            ObjectType ownerType = getRegistry().getObjectInfo(owner).objectType;
+            if(ownerType == REGISTRY() || ownerType == STAKING() || ownerType == SERVICE() || ownerType == INSTANCE()) {
+                revert ErrorRegistryServiceObjectOwnerRegistered(info.objectType, owner);
+            }
+        }
+    }
+
+    // From IService
+    function _getDomain() internal override pure returns(ObjectType serviceDomain) {
+        return REGISTRY(); 
+    }
+}

package/contracts/registry/RegistryServiceManager.sol

@@ -0,0 +1,53 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IVersionable} from "../upgradeability/IVersionable.sol";
+import {ProxyManager} from "../upgradeability/ProxyManager.sol";
+import {RegistryService} from "./RegistryService.sol";
+
+contract RegistryServiceManager is
+    ProxyManager
+{
+    error ErrorRegistryAccessManagerAuthorityZero();
+    error ErrorRegistryAccessManagerRegistryZero();
+
+    bytes32 constant public ACCESS_MANAGER_CREATION_CODE_HASH = 0x0;
+
+    RegistryService private immutable _registryService;
+
+    /// @dev initializes proxy manager with registry service implementation and deploys registry
+    constructor(
+        address authority, // used by implementation 
+        address registry, // used by implementation 
+        bytes32 salt
+    ) 
+    {
+        if(authority == address(0)) {
+            revert ErrorRegistryAccessManagerAuthorityZero();
+        }
+
+        if(registry == address(0)) {
+            revert ErrorRegistryAccessManagerRegistryZero();
+        }
+        
+        RegistryService srv = new RegistryService{ salt: salt }();
+        bytes memory data = abi.encode(authority, registry);
+        IVersionable versionable = initialize(
+            registry,
+            address(srv), 
+            data,
+            salt);
+
+        _registryService = RegistryService(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+
+    function getRegistryService()
+        external
+        view
+        returns (RegistryService registryService)
+    {
+        return _registryService;
+    }
+}

package/contracts/registry/ReleaseAdmin.sol

@@ -0,0 +1,253 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessAdmin} from "../authorization/AccessAdmin.sol";
+import {AccessAdminLib} from "../authorization/AccessAdminLib.sol";
+import {AccessManagerCloneable} from "../authorization/AccessManagerCloneable.sol";
+import {IAccess} from "../authorization/IAccess.sol";
+import {IService} from "../shared/IService.sol";
+import {IServiceAuthorization} from "../authorization/IServiceAuthorization.sol";
+import {ObjectType, ObjectTypeLib, ALL} from "../type/ObjectType.sol";
+import {RoleId, RoleIdLib, ADMIN_ROLE, RELEASE_REGISTRY_ROLE, PUBLIC_ROLE} from "../type/RoleId.sol";
+import {VersionPart} from "../type/Version.sol";
+
+/// @dev The ReleaseAdmin contract implements the central authorization for the services of a specific release.
+/// There is one ReleaseAdmin contract per major GIF release.
+/// Locking/unlocking of all services of a release is implemented in function setReleaseLocked.
+contract ReleaseAdmin is
+    AccessAdmin
+{
+    event LogReleaseAdminReleaseLockChanged(VersionPart release, bool locked);
+    event LogReleaseAdminServiceLockChanged(VersionPart release, address service, bool locked);
+
+    error ErrorReleaseAdminCallerNotReleaseRegistry(address caller);
+    error ErrorReleaseAdminNotService(address notService);
+    error ErrorReleaseAdminReleaseLockAlreadySetTo(bool locked);
+
+    /// @dev release core roles
+    string public constant RELEASE_REGISTRY_ROLE_NAME = "ReleaseRegistryRole";
+
+    /// @dev release core targets
+    string public constant RELEASE_ADMIN_TARGET_NAME = "ReleaseAdmin";
+
+
+    modifier onlyReleaseRegistry() {
+        (bool isMember, ) = _authority.hasRole(RELEASE_REGISTRY_ROLE().toInt(), msg.sender);
+        if(!isMember) {
+            revert ErrorReleaseAdminCallerNotReleaseRegistry(msg.sender);
+        }
+        _;
+    }
+
+    // @dev Only used for master release admin
+    constructor(address accessManager) {
+        initialize(
+            accessManager,
+            "MasterReleaseAdmin");
+    }
+
+
+    function completeSetup(
+        address registry,
+        address releaseRegistry,
+        VersionPart release
+    )
+        external
+        reinitializer(uint64(release.toInt()))
+    {
+
+        // checks
+        _checkRegistry(registry);
+
+        AccessManagerCloneable(
+            authority()).completeSetup(
+                registry, 
+                release); 
+
+        // link nft ownability to registry
+        _linkToNftOwnable(registry);
+
+        _setupReleaseRegistry(releaseRegistry);
+    }
+
+    /// @dev Sets up authorizaion for specified service.
+    /// For all authorized services its authorized functions are enabled.
+    /// Permissioned function: Access is restricted to release registry.
+    function authorizeService(
+        IServiceAuthorization serviceAuthorization,
+        IService service,
+        ObjectType serviceDomain,
+        VersionPart release
+    )
+        external
+        restricted()
+    {
+        _createServiceTargetAndRole(service, serviceDomain, release);
+        _authorizeServiceFunctions(serviceAuthorization, service, serviceDomain, release);
+    }
+
+    /// @dev Locks/unlocks all release targets.
+    /// For all authorized services of release its authorized functions are disabled/enabled.
+    /// Permissioned function: Access is restricted to release registry.
+    /// Note: onlyReleaseRegistry() modifier is used to prevent dead lock.
+    function setReleaseLocked(bool locked)
+        external
+        onlyReleaseRegistry()
+    {
+        // checks
+        AccessManagerCloneable accessManager = AccessManagerCloneable(authority());
+        if(accessManager.isLocked() == locked) {
+            revert ErrorReleaseAdminReleaseLockAlreadySetTo(locked);
+        }
+
+        // effects
+        accessManager.setLocked(locked);
+
+        emit LogReleaseAdminReleaseLockChanged(getRelease(), locked);
+    }
+
+    /// @dev Lock/unlock specific service of release.
+    /// Permissioned function: Access is restricted to release registry.
+    function setServiceLocked(IService service, bool locked)
+        external
+        restricted()
+    {
+        // assume all targets except release admin are services
+        // ensure release admin can not be locked
+        if(address(service) == address(this)) {
+            revert ErrorReleaseAdminNotService(address(service));
+        }
+
+        _setTargetLocked(address(service), locked);
+
+        emit LogReleaseAdminServiceLockChanged(service.getRelease(), address(service), locked);
+    }
+
+    //--- view functions ----------------------------------------------------//
+
+/*
+    function getReleaseAdminRole() external view returns (RoleId) {
+        return GIF_ADMIN_ROLE();
+    }
+*/
+    //--- private functions -------------------------------------------------//
+
+    function _createServiceTargetAndRole(
+        IService service, 
+        ObjectType serviceDomain, 
+        VersionPart release
+    )
+        private
+    {
+        string memory baseName = ObjectTypeLib.toName(serviceDomain);
+
+        // create service target
+        string memory serviceTargetName = ObjectTypeLib.toVersionedName(
+            baseName, "Service", release);
+
+        _createTarget(
+            address(service), 
+            serviceTargetName,
+            true,
+            false);
+
+        // create service role
+        RoleId serviceRoleId = RoleIdLib.roleForTypeAndVersion(
+            serviceDomain, 
+            release);
+
+        if(!roleExists(serviceRoleId)) {
+            _createRole(
+                serviceRoleId, 
+                AccessAdminLib.toRole({
+                    adminRoleId: ADMIN_ROLE(),
+                    roleType: RoleType.Contract,
+                    maxMemberCount: 1,
+                    name: ObjectTypeLib.toVersionedName(
+                        baseName, 
+                        "ServiceRole", 
+                        release)}));
+        }
+
+        _grantRoleToAccount( 
+            serviceRoleId,
+            address(service)); 
+    }
+
+
+    function _authorizeServiceFunctions(
+        IServiceAuthorization serviceAuthorization,
+        IService service,
+        ObjectType serviceDomain, 
+        VersionPart release
+    )
+        private
+    {
+        ObjectType authorizedDomain;
+        RoleId authorizedRoleId;
+
+        ObjectType[] memory authorizedDomains = serviceAuthorization.getAuthorizedDomains(serviceDomain);
+
+        for (uint256 i = 0; i < authorizedDomains.length; i++) {
+            authorizedDomain = authorizedDomains[i];
+
+            // derive authorized role from authorized domain
+            if (authorizedDomain == ALL()) {
+                authorizedRoleId = PUBLIC_ROLE();
+            } else {
+                authorizedRoleId = RoleIdLib.roleForTypeAndVersion(
+                authorizedDomain, 
+                release);
+            }
+
+            if(!roleExists(authorizedRoleId)) {
+                // create role for authorized domain
+                _createRole(
+                    authorizedRoleId, 
+                    AccessAdminLib.toRole({
+                        adminRoleId: ADMIN_ROLE(),
+                        roleType: RoleType.Contract,
+                        maxMemberCount: 1,
+                        name: ObjectTypeLib.toVersionedName(
+                            ObjectTypeLib.toName(authorizedDomain), 
+                            "Role", 
+                            release)}));
+            }
+
+            // get authorized functions for authorized domain
+            IAccess.FunctionInfo[] memory authorizatedFunctions = serviceAuthorization.getAuthorizedFunctions(
+                serviceDomain, 
+                authorizedDomain);
+
+            _authorizeTargetFunctions(
+                    address(service), 
+                    authorizedRoleId, 
+                    authorizatedFunctions);
+        }
+    }
+
+    //--- private initialization functions -------------------------------------------//
+
+    function _setupReleaseRegistry(address releaseRegistry)
+        private 
+        onlyInitializing()
+    {
+        _createTarget(address(this), RELEASE_ADMIN_TARGET_NAME, false, false);
+
+        _createRole(
+            RELEASE_REGISTRY_ROLE(), 
+            AccessAdminLib.toRole({
+                adminRoleId: ADMIN_ROLE(),
+                roleType: RoleType.Contract,
+                maxMemberCount: 1,
+                name: RELEASE_REGISTRY_ROLE_NAME}));
+
+        FunctionInfo[] memory functions;
+        functions = new FunctionInfo[](2);
+        functions[0] = AccessAdminLib.toFunction(ReleaseAdmin.authorizeService.selector, "authorizeService");
+        functions[1] = AccessAdminLib.toFunction(ReleaseAdmin.setServiceLocked.selector, "setServiceLocked");
+        _authorizeTargetFunctions(address(this), RELEASE_REGISTRY_ROLE(), functions);
+
+        _grantRoleToAccount(RELEASE_REGISTRY_ROLE(), releaseRegistry);
+    }
+}

package/contracts/registry/ReleaseLifecycle.sol

@@ -0,0 +1,32 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {RELEASE} from "../type/ObjectType.sol";
+import {SCHEDULED, DEPLOYING, DEPLOYED, SKIPPED, ACTIVE, PAUSED, CLOSED} from "../type/StateId.sol";
+import {Lifecycle} from "../shared/Lifecycle.sol";
+
+/// @dev Release lifeycle state machine.
+/// Helper contract for ReleaseRegistry.
+contract ReleaseLifecycle is
+    Lifecycle
+{
+    constructor() {
+        _setupLifecycle();
+    }
+
+    function _setupLifecycle()
+        internal 
+        override
+    {
+        setInitialState(RELEASE(), SCHEDULED());
+
+        setStateTransition(RELEASE(), SCHEDULED(), SKIPPED());
+        setStateTransition(RELEASE(), SCHEDULED(), DEPLOYING());
+        setStateTransition(RELEASE(), DEPLOYING(), SKIPPED());
+        setStateTransition(RELEASE(), DEPLOYING(), DEPLOYED());
+        setStateTransition(RELEASE(), DEPLOYED(), SKIPPED());
+        setStateTransition(RELEASE(), DEPLOYED(), ACTIVE());
+        setStateTransition(RELEASE(), ACTIVE(), PAUSED());
+        setStateTransition(RELEASE(), PAUSED(), ACTIVE());
+    }
+}