@etherisc/gif-next 0.0.2-8eb96a8-113 → 0.0.2-9105e58-225

package/contracts/shared/Versionable.sol

@@ -0,0 +1,148 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
+
+import {Blocknumber, blockNumber} from "../types/Blocknumber.sol";
+import {Timestamp, TimestampLib} from "../types/Timestamp.sol";
+import {Version, VersionPart, VersionLib} from "../types/Version.sol";
+
+import {IVersionable} from "./IVersionable.sol";
+
+
+
+abstract contract Versionable is 
+    Initializable,
+    IVersionable 
+{
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.shared.Versionable.sol")) - 1)) & ~bytes32(uint256(0xff))
+    bytes32 private constant VERSIONABLE_LOCATION_V1 = 0x4f61291a8ac3d020d0a7d919a76b8592aa88385744dee3f8b4f3873b969ed900;
+
+
+    /// @custom:storage-location erc7201:gif-next.contracts.shared.Versionable.sol
+    struct VersionableStorage {
+        mapping(Version version => VersionInfo info) _versionHistory;
+        Version [] _versions;
+        Version _v1;
+    }
+
+
+    constructor() {
+        _disableInitializers();
+    }
+    // TODO write test where new version of private _updateVersionHistory is added and used... 
+
+    function initializeVersionable(
+        address implementation,
+        address activatedBy,
+        bytes memory data
+    )
+        public
+        initializer
+    {
+        _updateVersionHistory(implementation, activatedBy);
+        _initialize(activatedBy, data);
+    }
+
+    // TODO activatedBy MUST ALWAYS be an owner?
+    function upgradeVersionable(
+        address implementation,
+        address activatedBy,
+        bytes memory data
+    )
+        external
+        reinitializer(VersionLib.toUint64(getVersion()))
+    {
+        _updateVersionHistory(implementation, activatedBy);
+        _upgrade(data);
+    }
+
+    function isInitialized(Version _version) public override view returns(bool) {
+        return _getVersionableStorage()._versionHistory[_version].activatedIn.toInt() > 0;
+    }
+
+    function getVersion() public pure virtual returns(Version);
+
+    function getVersionCount() public view override returns(uint256) {
+        return _getVersionableStorage()._versions.length;
+    }
+
+    function getVersion(uint256 idx) public view override returns(Version) {
+        return _getVersionableStorage()._versions[idx];
+    }
+
+    function getVersionInfo(Version _version) public override view returns(VersionInfo memory) {
+        return _getVersionableStorage()._versionHistory[_version];
+    }
+
+    function getInitializedVersion() public view returns(uint64) {
+        return _getInitializedVersion();
+    }
+
+
+
+    // IMPORTANT each version must implement this function 
+    // each implementation MUST use onlyInitialising modifier
+    // each implementation MUST call intializers of all base contracts...
+    function _initialize(address owner, bytes memory data) 
+        internal
+        onlyInitializing
+        virtual 
+    {
+        revert();
+    }
+
+
+    // IMPORTANT each version except version "1" must implement this function 
+    // each implementation MUST use onlyInitialising modifier
+    function _upgrade(bytes memory data)
+        internal
+        onlyInitializing
+        virtual
+    {
+        revert();
+    }
+
+    function _getVersionableStorage() private pure returns (VersionableStorage storage $) {
+        assembly {
+            $.slot := VERSIONABLE_LOCATION_V1
+        }
+    }
+
+    // can only be called once per contract
+    // needs to be called inside the proxy upgrade tx
+    // TODO run reinitializer(version().toUint64()) modifier after "version()" is checked, 
+    function _updateVersionHistory(
+        address implementation,
+        address activatedBy
+    )
+        private
+        onlyInitializing
+    {
+        VersionableStorage storage $ = _getVersionableStorage();
+
+        uint64 version = _getInitializedVersion();
+
+        Version thisVersion = getVersion();
+
+        if(version == 1) {
+            // thisVersion is alias to version "1"
+            $._v1 = thisVersion;
+        }
+        else {
+            require(thisVersion > $._v1, "INVALID VERSION");
+        }
+
+        // update version history
+        $._versions.push(thisVersion);
+        $._versionHistory[thisVersion] = VersionInfo(
+            thisVersion,
+            implementation,
+            activatedBy,
+            TimestampLib.blockTimestamp(),
+            blockNumber()
+        );
+
+        emit LogVersionableInitialized(thisVersion, implementation, activatedBy);
+    }
+}

package/contracts/test/TestFee.sol

@@ -0,0 +1,25 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {UFixed, UFixedLib} from "../types/UFixed.sol";
+import {Fee, FeeLib} from "../types/Fee.sol";
+
+contract TestFee {
+
+    function createFee(
+        uint256 fractionalValue,
+        int8 exponent,
+        uint256 fixedValue
+    )
+        external 
+        pure 
+        returns(Fee memory fee)
+    {
+        return FeeLib.toFee(UFixedLib.toUFixed(fractionalValue, exponent), fixedValue);
+    }
+
+    function getZeroFee() external pure returns(Fee memory fee) {
+        return FeeLib.zeroFee();
+    }
+
+}

package/contracts/test/TestRegisterable.sol

@@ -0,0 +1,18 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../../contracts/types/NftId.sol";
+import {ObjectType, TOKEN} from "../../contracts/types/ObjectType.sol";
+import {IRegistry} from "../../contracts/registry/IRegistry.sol";
+import {Registerable} from "../../contracts/shared/Registerable.sol";
+
+contract TestRegisterable is Registerable {
+
+    constructor(address registry, NftId registryNftId, ObjectType objectType, bool isInterceptor, address initialOwner)
+        //Registerable(registry, registryNftId)
+    // solhint-disable-next-line no-empty-blocks
+    {
+        bytes memory data = "";
+        initializeRegisterable(registry, registryNftId, objectType, isInterceptor, initialOwner, data);
+    }
+}

package/contracts/test/TestRoleId.sol

@@ -0,0 +1,14 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {RoleId, RoleIdLib, PRODUCT_OWNER_ROLE_NAME, PRODUCT_OWNER_ROLE, POOL_OWNER_ROLE_NAME, POOL_OWNER_ROLE} from "../../contracts/types/RoleId.sol";
+
+contract TestRoleId {
+    function getRole(uint256 roleNum) external pure returns (RoleId) { return RoleIdLib.toRoleId(roleNum); }
+
+    function getProductOwnerRoleName() external pure returns (string memory) { return PRODUCT_OWNER_ROLE_NAME(); }
+    function getProductOwnerRole() external pure returns (RoleId) { return PRODUCT_OWNER_ROLE(); } 
+
+    function getPoolOwnerRoleName() external pure returns (string memory) { return POOL_OWNER_ROLE_NAME(); }
+    function getPoolOwnerRole() external pure returns (RoleId) { return POOL_OWNER_ROLE(); } 
+}

package/contracts/test/TestService.sol

@@ -0,0 +1,25 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {ObjectType, PRODUCT} from "../../contracts/types/ObjectType.sol";
+import {NftId} from "../../contracts/types/NftId.sol";
+import {Version, VersionLib} from "../../contracts/types/Version.sol";
+import {Service} from "../../contracts/shared/Service.sol";
+
+import {IVersionable} from "../../contracts/shared/IVersionable.sol";
+import {Versionable} from "../../contracts/shared/Versionable.sol";
+
+contract TestService is Service {
+
+    string public constant NAME = "TestService";
+
+    constructor(address registry, NftId registryNftId, address initialOwner)
+    // solhint-disable-next-line no-empty-blocks
+    {
+        initializeService(registry, initialOwner);
+    }
+
+    function getDomain() public pure override returns(ObjectType) {
+        return PRODUCT();
+    }
+}

package/contracts/test/TestToken.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
+
+contract TestUsdc is ERC20 {
+
+    // https://etherscan.io/token/0xc719d010b63e5bbf2c0551872cd5316ed26acd83#readContract
+    string public constant NAME = "USDC - Test";
+    string public constant SYMBOL = "USDC";
+    uint8 public constant DECIMALS = 6;
+    uint256 public constant INITIAL_SUPPLY = 10**9 * 10**DECIMALS; // 1 Billion 1'000'000'000
+    // decimals == 18 (openzeppelin erc20 default)
+    constructor()
+        ERC20(NAME, SYMBOL)
+    {
+        _mint(
+            _msgSender(),
+            INITIAL_SUPPLY
+        );   
+    }
+
+    function decimals() public pure override returns(uint8) {
+        return DECIMALS;
+    }
+}

package/contracts/test/TestVersion.sol

@@ -0,0 +1,44 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Version, VersionPart, VersionLib} from "../types/Version.sol";
+
+contract TestVersion {
+
+    function createVersion(uint major, uint minor, uint patch) external pure returns(Version) {
+        return VersionLib.toVersion(major, minor, patch);
+    }
+
+    function createVersionPart(uint versionPart) external pure returns(VersionPart) {
+        return VersionLib.toVersionPart(uint8(versionPart));
+    }
+
+    function getVersionParts(Version version)
+        external
+        pure
+        returns(
+            VersionPart major,
+            VersionPart minor,
+            VersionPart patch
+        )
+    {
+        return version.toVersionParts();
+    }
+
+    function getMajorPart(Version version) external pure returns(VersionPart major) {
+        return version.toMajorPart();
+    }
+
+    function getZeroVersion() external pure returns(Version) {
+        return VersionLib.zeroVersion();
+    }
+
+    function isSameVersion(Version a, Version b) external pure returns(bool) {
+        return a == b;
+    }
+
+    function isLargerVersion(Version a, Version b) external pure returns(bool) {
+        return a > b;
+    }
+
+}

package/contracts/test/TestVersionable.sol

@@ -0,0 +1,17 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Version, VersionLib} from "../../contracts/types/Version.sol";
+import {Versionable} from "../../contracts/shared/Versionable.sol";
+
+contract TestVersionable is Versionable {
+
+    function getVersion()
+        public 
+        pure 
+        virtual override
+        returns(Version)
+    {
+        return VersionLib.toVersion(3,0,0);
+    }
+}

package/contracts/test/Usdc.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
+
+contract USDC is ERC20 {
+
+    // https://etherscan.io/token/0xc719d010b63e5bbf2c0551872cd5316ed26acd83#readContract
+    string public constant NAME = "USDC - DUMMY";
+    string public constant SYMBOL = "USDC";
+    uint8 public constant DECIMALS = 6;
+    uint256 public constant INITIAL_SUPPLY = 10**9 * 10**DECIMALS; // 1 Billion 1'000'000'000
+    // decimals == 18 (openzeppelin erc20 default)
+    constructor()
+        ERC20(NAME, SYMBOL)
+    {
+        _mint(
+            _msgSender(),
+            INITIAL_SUPPLY
+        );   
+    }
+
+    function decimals() public pure override returns(uint8) {
+        return DECIMALS;
+    }
+}

package/contracts/types/AddressSet.sol

@@ -0,0 +1,58 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+// based on https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/utils/structs/EnumerableSet.sol
+library LibAddressSet {
+
+    struct Set {
+        address[] elements;
+        mapping(address element => uint256 index) at;
+    }
+
+    function add(Set storage set, address element) external returns(bool added) {
+        if (set.at[element] == 0) {
+            set.elements.push(element);
+            set.at[element] = set.elements.length;
+            return true;
+        } else {
+            return false;
+        }
+    }
+
+    function remove(Set storage set, address element) external returns(bool removed) {
+        uint256 elementIndex = set.at[element];
+
+        if (elementIndex > 0) {
+            uint256 toDeleteIndex = elementIndex - 1;
+            uint256 lastIndex = set.elements.length - 1;
+
+            if (lastIndex != toDeleteIndex) {
+                address lastElement = set.elements[lastIndex];
+                set.elements[toDeleteIndex] = lastElement;
+                set.at[lastElement] = elementIndex; // Replace lastValue's index to valueIndex
+            }
+
+            set.elements.pop();
+            delete set.at[element];
+            return true;
+        }
+        
+        return false;
+    }
+
+    function isEmpty(Set storage set) external view returns(bool empty) {
+        return set.elements.length == 0;
+    }
+
+    function contains(Set storage set, address element) external view returns(bool inSet) {
+        return set.at[element] > 0;
+    }
+
+    function getLength(Set storage set) external view returns(uint256 length) {
+        return set.elements.length;
+    }
+
+    function getElementAt(Set storage set, uint256 index) external view returns(address element) {
+        return set.elements[index];
+    }
+}

package/contracts/types/ClaimId.sol

@@ -0,0 +1,52 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+// uint16 allows for 65'535 claims per policy
+type ClaimId is uint16;
+
+// type bindings
+using {
+    eqClaimId as ==, 
+    neClaimId as !=, 
+    ClaimIdLib.eqz,
+    ClaimIdLib.gtz,
+    ClaimIdLib.toInt
+} for ClaimId global;
+
+
+// pure free functions for operators
+function eqClaimId(ClaimId a, ClaimId b) pure returns (bool isSame) {
+    return ClaimId.unwrap(a) == ClaimId.unwrap(b);
+}
+
+function neClaimId(ClaimId a, ClaimId b) pure returns (bool isDifferent) {
+    return ClaimId.unwrap(a) != ClaimId.unwrap(b);
+}
+
+// library functions that operate on user defined type
+library ClaimIdLib {
+    /// @dev Converts the ClaimId to a uint.
+    function zero() public pure returns (ClaimId) {
+        return ClaimId.wrap(0);
+    }
+
+    /// @dev Converts an uint into a ClaimId.
+    function toClaimId(uint256 a) public pure returns (ClaimId) {
+        return ClaimId.wrap(uint16(a));
+    }
+
+    /// @dev Converts the ClaimId to a uint.
+    function toInt(ClaimId a) public pure returns (uint16) {
+        return uint16(ClaimId.unwrap(a));
+    }
+
+    /// @dev Returns true if the value is non-zero (> 0).
+    function gtz(ClaimId a) public pure returns (bool) {
+        return ClaimId.unwrap(a) > 0;
+    }
+
+    /// @dev Returns true if the value is zero (== 0).
+    function eqz(ClaimId a) public pure returns (bool) {
+        return ClaimId.unwrap(a) == 0;
+    }
+}

package/contracts/types/DistributorType.sol

@@ -0,0 +1,55 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {NftId} from "./NftId.sol";
+import {DISTRIBUTOR_TYPE} from "./ObjectType.sol";
+
+type DistributorType is bytes8;
+
+// type bindings
+using {
+    eqDistributorType as ==,
+    neDistributorType as !=,
+    DistributorTypeLib.toKey32
+} for DistributorType global;
+
+// general pure free functions
+
+// pure free functions for operators
+function eqDistributorType(
+    DistributorType a, 
+    DistributorType b
+) pure returns (bool isSame) {
+    return DistributorType.unwrap(a) == DistributorType.unwrap(b);
+}
+
+function neDistributorType(
+    DistributorType a,
+    DistributorType b
+) pure returns (bool isDifferent) {
+    return DistributorType.unwrap(a) != DistributorType.unwrap(b);
+}
+
+// library functions that operate on user defined type
+library DistributorTypeLib {
+
+    function zero() public pure returns (DistributorType) {
+        return DistributorType.wrap(bytes8(0));
+    }
+
+    // @dev Converts a referral string into an id.
+    function toDistributorType(NftId distributionNftId, string memory name) public pure returns (DistributorType) {
+        return DistributorType.wrap(bytes8(keccak256(abi.encode(distributionNftId, name))));
+    }
+
+    /// @dev Returns the key32 value for the specified nft id and object type.
+    function toKey32(DistributorType id) public pure returns (Key32 key) {
+        return Key32Lib.toKey32(DISTRIBUTOR_TYPE(), toKeyId(id));
+    }
+
+    /// @dev Returns the key id value for the specified nft id
+    function toKeyId(DistributorType id) public pure returns (KeyId keyId) {
+        return KeyId.wrap(bytes31(DistributorType.unwrap(id)));
+    }
+}

package/contracts/types/Fee.sol

@@ -1,32 +1,56 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.19;
 
-import {UFixed} from "./UFixed.sol";
+import {UFixed, UFixedLib} from "./UFixed.sol";
 
 struct Fee {
     UFixed fractionalFee;
     uint256 fixedFee;
 }
 
-// general pure free functions
-/// @dev Converts the uint256 to a NftId.
-function toFee(
-    UFixed fractionalFee,
-    uint256 fixedFee
-) pure returns (Fee memory fee) {
-    return Fee(fractionalFee, fixedFee);
-}
+library FeeLib {
 
-/// @dev Return the NftId zero (0)
-function zeroFee() pure returns (Fee memory fee) {
-    return Fee(UFixed.wrap(0), 0);
-}
+    function calculateFee(
+        Fee memory fee,
+        uint256 amount
+    )
+        public
+        pure
+        returns (
+            uint256 feeAmount, 
+            uint256 netAmount
+        )
+    {
+        UFixed fractionalAmount = UFixedLib.toUFixed(amount) *
+            fee.fractionalFee;
+        feeAmount = fractionalAmount.toInt() + fee.fixedFee;
+        netAmount = amount - feeAmount;
+    }
 
-// pure free functions for operators
-function feeIsSame(Fee memory a, Fee memory b) pure returns (bool isSame) {
-    return a.fixedFee == b.fixedFee && a.fractionalFee == b.fractionalFee;
-}
+    /// @dev Converts the uint256 to a fee struct.
+    function toFee(
+        UFixed fractionalFee,
+        uint256 fixedFee
+    ) public pure returns (Fee memory fee) {
+        return Fee(fractionalFee, fixedFee);
+    }
 
-function feeIsZero(Fee memory fee) pure returns (bool) {
-    return fee.fixedFee == 0 && UFixed.unwrap(fee.fractionalFee) == 0;
-}
+    /// @dev Return the percent fee struct (x%, 0)
+    function percentageFee(uint8 percent) public pure returns (Fee memory fee) {
+        return Fee(UFixedLib.toUFixed(percent, -2), 0);
+    }
+
+    /// @dev Return a zero fee struct (0, 0)
+    function zeroFee() public pure returns (Fee memory fee) {
+        return Fee(UFixed.wrap(0), 0);
+    }
+
+    // pure free functions for operators
+    function feeIsSame(Fee memory a, Fee memory b) public pure returns (bool isSame) {
+        return a.fixedFee == b.fixedFee && a.fractionalFee == b.fractionalFee;
+    }
+
+    function feeIsZero(Fee memory fee) public pure returns (bool) {
+        return fee.fixedFee == 0 && UFixed.unwrap(fee.fractionalFee) == 0;
+    }
+}

package/contracts/types/Key32.sol

@@ -0,0 +1,50 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ObjectType} from "./ObjectType.sol";
+
+type Key32 is bytes32;
+type KeyId is bytes31;
+
+// type bindings
+using {
+    eqKey32 as ==, 
+    neKey32 as !=,
+    Key32Lib.toKeyId,
+    Key32Lib.toObjectType
+} for Key32 global;
+
+// @dev Returns true iff keys are identical
+function eqKey32(Key32 a, Key32 b) pure returns (bool isSame) {
+    return Key32.unwrap(a) == Key32.unwrap(b);
+}
+
+// @dev Returns true iff keys are different
+function neKey32(Key32 a, Key32 b) pure returns (bool isDifferent) {
+    return Key32.unwrap(a) != Key32.unwrap(b);
+}
+
+library Key32Lib {
+
+    uint8 public constant TYPE_SHIFT = 31 * 8;
+    uint8 public constant ID_SHIFT = uint8(32 * 8 - TYPE_SHIFT);
+    bytes32 public constant TYPE_MASK = bytes32(bytes1(type(uint8).max)); // first byte in bytes32
+    bytes32 public constant ID_MASK = bytes32(~TYPE_MASK); // remaining bytes in bytes32
+
+    function toKey32(ObjectType objectType, KeyId id) public pure returns (Key32) {
+        uint256 uintObjectType = ObjectType.unwrap(objectType);
+        uint256 uintId = uint248(KeyId.unwrap(id));
+        uint256 uintKey = (uintObjectType << TYPE_SHIFT) + uintId;
+        return Key32.wrap(bytes32(uintKey));
+    }
+
+    function toObjectType(Key32 key) public pure returns (ObjectType objectType) {
+        bytes32 key32 = Key32.unwrap(key);
+        objectType = ObjectType.wrap(uint8(uint256(key32 & TYPE_MASK) >> TYPE_SHIFT));
+    }
+
+    function toKeyId(Key32 key) public pure returns (KeyId id) {
+        bytes32 key32 = Key32.unwrap(key);
+        id = KeyId.wrap(bytes31((key32 & ID_MASK) << ID_SHIFT));
+    }
+}

package/contracts/types/NftId.sol

@@ -1,11 +1,22 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.19;
 
+import {Key32, KeyId, Key32Lib} from "./Key32.sol";
+import {ObjectType} from "./ObjectType.sol";
+
 // uint96 allows for chain ids up to 13 digits
 type NftId is uint96;
 
 // type bindings
-using {eqNftId as ==, neNftId as !=, NftIdLib.toInt} for NftId global;
+using {
+    eqNftId as ==, 
+    neNftId as !=, 
+    NftIdLib.toInt,
+    NftIdLib.gtz,
+    NftIdLib.eqz,
+    NftIdLib.toKeyId,
+    NftIdLib.toKey32
+} for NftId global;
 
 // general pure free functions
 /// @dev Converts the uint256 to a NftId.
@@ -48,4 +59,14 @@ library NftIdLib {
     function eq(NftId a, NftId b) public pure returns (bool isSame) {
         return eqNftId(a, b);
     }
+
+    /// @dev Returns the key32 value for the specified nft id and object type.
+    function toKey32(NftId id, ObjectType objectType) public pure returns (Key32 key) {
+        return Key32Lib.toKey32(objectType, toKeyId(id));
+    }
+
+    /// @dev Returns the key id value for the specified nft id
+    function toKeyId(NftId id) public pure returns (KeyId keyId) {
+        return KeyId.wrap(bytes31(uint248(NftId.unwrap(id))));
+    }
 }