@etherisc/gif-next 0.0.2-8d47fa1-080 → 0.0.2-8d69bcd-543

package/contracts/authorization/IAuthorization.sol

@@ -0,0 +1,66 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAccess} from "../authorization/IAccess.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {RoleId} from "../type/RoleId.sol";
+import {Str} from "../type/String.sol";
+import {VersionPart} from "../type/Version.sol";
+
+interface IAuthorization is 
+     IAccess 
+{
+
+     error ErrorAuthorizationMainTargetNameEmpty();
+     error ErrorAuthorizationTargetDomainZero();
+
+     /// @dev Returns the list of service targets.
+     function getServiceDomains() external view returns(ObjectType[] memory serviceDomains);
+
+     /// @dev Returns the service role for the specified service domain.
+     function getServiceRole(ObjectType serviceDomain) external pure returns (RoleId serviceRoleId);
+
+     /// @dev Returns the service target for the specified domain.
+     function getServiceTarget(ObjectType serviceDomain) external view returns(Str serviceTarget);
+
+     /// @dev Returns the component role for the specified domain.
+     function getComponentRole(ObjectType componentDomain) external view returns(RoleId componentRoleId);
+
+     /// @dev Returns the list of involved roles.
+     function getRoles() external view returns(RoleId[] memory roles);
+
+     /// @dev Returns the name for the provided role id.
+     function getRoleInfo(RoleId roleId) external view returns (RoleInfo memory roleInfo);
+
+     /// @dev Returns true iff the specified role id exists.
+     function roleExists(RoleId roleId) external view returns(bool exists);
+
+     /// @dev Returns the main target id name as string.
+     /// This name is used to derive the target id and a corresponding target role name
+     /// Overwrite this function to change the basic pool target name.
+     function getMainTargetName() external view returns (string memory name);
+
+     /// @dev Returns the main target.
+     function getMainTarget() external view returns(Str target);
+
+     /// @dev Returns the complete list of targets.
+     function getTargets() external view returns(Str[] memory targets);
+
+     /// @dev Returns true iff the specified target exists.
+     function targetExists(Str target) external view returns(bool exists);
+
+     /// @dev Returns the role id associated with the target.
+     /// If no role is associated with the target the zero role id is returned.
+     function getTargetRole(Str target) external view returns(RoleId roleId);
+
+     /// @dev For the given target the list of authorized role ids is returned
+     function getAuthorizedRoles(Str target) external view returns(RoleId[] memory roleIds);
+
+     /// @dev For the given target and role id the list of authorized functions is returned
+     function getAuthorizedFunctions(Str target, RoleId roleId) external view returns(FunctionInfo[] memory authorizatedFunctions);
+
+     /// @dev Returns the release (VersionPart) for which the authorizations are defined by this contract.
+     /// Matches with the release returned by the linked service authorization.
+     function getRelease() external view returns(VersionPart release);
+}
+

package/contracts/authorization/IServiceAuthorization.sol

@@ -0,0 +1,40 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+
+import {IAccess} from "../authorization/IAccess.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {VersionPart} from "../type/Version.sol";
+
+interface IServiceAuthorization is IERC165 {
+
+     /// @dev Returns the commit hash representing the deployed release
+     function getCommitHash()
+          external
+          view
+          returns(string memory commitHash);
+
+     /// @dev Returns the release (VersionPart) for which the service authorizations are defined by this contract.
+     function getRelease()
+          external
+          view
+          returns(VersionPart release);
+
+     /// @dev Returns the service domain for the provided index.
+     function getServiceDomain(uint idx) external view returns(ObjectType serviceDomain);
+
+     /// @dev Returns the full list of service domains for this release.
+     /// Services need to be registered for the release in revers order of this list.
+     function getServiceDomains() external view returns(ObjectType[] memory serviceDomains);
+
+     /// @dev Returns the expected service address for the provided domain.
+     function getServiceAddress(ObjectType serviceDomain) external view returns(address service);
+
+     /// @dev Given the service domain this function returns the list of other service domains that are authorized to access this service.
+     function getAuthorizedDomains(ObjectType serviceDomain) external view returns(ObjectType[] memory authorizatedDomains);
+
+     /// @dev For the given service domain and authorized domain the function returns the list of authorized functions
+     function getAuthorizedFunctions(ObjectType serviceDomain, ObjectType authorizedDomain) external view returns(IAccess.FunctionInfo[] memory authorizatedFunctions);
+}
+

package/contracts/authorization/ServiceAuthorization.sol

@@ -0,0 +1,106 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+
+import {IAccess} from "../authorization/IAccess.sol";
+import {ObjectType} from "../type/ObjectType.sol";
+import {IServiceAuthorization} from "./IServiceAuthorization.sol";
+import {SelectorLib} from "../type/Selector.sol";
+import {StrLib} from "../type/String.sol";
+import {TimestampLib} from "../type/Timestamp.sol";
+import {VersionPart, VersionPartLib} from "../type/Version.sol";
+
+/// @dev Base contract for release specific service authorization contracts.
+contract ServiceAuthorization is 
+     IServiceAuthorization
+{
+     uint256 public constant COMMIT_HASH_LENGTH = 40;
+     uint256 public constant GIF_INITIAL_VERSION = 3;
+
+     uint256 public immutable VERSION;
+     string public COMMIT_HASH;
+
+     ObjectType[] internal _serviceDomains;
+     mapping(ObjectType domain => address service) internal _serviceAddress;
+     mapping(ObjectType domain => ObjectType[] authorizedDomains) internal _authorizedDomains;
+     mapping(ObjectType domain => mapping(ObjectType authorizedDomain => IAccess.FunctionInfo[] functions)) internal _authorizedFunctions;
+
+     constructor(string memory commitHash, uint256 version) {
+          assert(bytes(commitHash).length == COMMIT_HASH_LENGTH);
+          assert(version >= GIF_INITIAL_VERSION);
+
+          COMMIT_HASH = commitHash;
+          VERSION = version;
+          _setupDomains();
+          _setupDomainAuthorizations();
+     }
+
+     function getCommitHash() external view returns(string memory commitHash) {
+          return COMMIT_HASH;
+     }
+
+     function getRelease() external view returns(VersionPart release) {
+          return VersionPartLib.toVersionPart(VERSION);
+     }
+
+     function getServiceDomains() external view returns(ObjectType[] memory serviceDomains) {
+          return _serviceDomains;
+     }
+
+     function getServiceDomain(uint idx) external view returns(ObjectType serviceDomain) {
+          return _serviceDomains[idx];
+     }
+
+     function getServiceAddress(ObjectType serviceDomain) external view returns(address service) {
+          return _serviceAddress[serviceDomain];
+     }
+
+     function getAuthorizedDomains(ObjectType serviceDomain) external view returns(ObjectType[] memory authorizatedDomains) {
+          return _authorizedDomains[serviceDomain];
+     }
+
+     function getAuthorizedFunctions(ObjectType serviceDomain, ObjectType authorizedDomain) external view returns(IAccess.FunctionInfo[] memory authorizatedFunctions) {
+          return _authorizedFunctions[serviceDomain][authorizedDomain];
+     }
+
+     // ERC165
+     function supportsInterface(bytes4 interfaceId) public pure returns (bool) {
+          return (
+               interfaceId == type(IServiceAuthorization).interfaceId || 
+               interfaceId == type(IERC165).interfaceId
+          );
+     }
+
+
+     /// @dev Overwrite this function for a specific realease.
+     function _setupDomains() internal virtual {}
+
+     /// @dev Overwrite this function for a specific realease.
+     function _setupDomainAuthorizations() internal virtual {}
+
+     /// @dev Use this method to to add an authorized domain.
+     /// The services will need to be registered in the order they are added using this function.
+     function _authorizeDomain(ObjectType serviceDomain, address serviceAddress) internal {
+          _serviceDomains.push(serviceDomain);
+          _serviceAddress[serviceDomain] = serviceAddress;
+     }
+
+     /// @dev Use this method to authorize the specified domain to access the service domain.
+     function _authorizeForService(ObjectType serviceDomain, ObjectType authorizedDomain)
+          internal
+          returns (IAccess.FunctionInfo[] storage authorizatedFunctions)
+     {
+          _authorizedDomains[serviceDomain].push(authorizedDomain);
+          return _authorizedFunctions[serviceDomain][authorizedDomain];
+     }
+
+     /// @dev Use this method to authorize a specific function authorization
+     function _authorize(IAccess.FunctionInfo[] storage functions, bytes4 selector, string memory name) internal {
+          functions.push(
+               IAccess.FunctionInfo({
+                    selector: SelectorLib.toSelector(selector),
+                    name: StrLib.toStr(name),
+                    createdAt: TimestampLib.blockTimestamp()}));
+     }
+}

package/contracts/distribution/BasicDistribution.sol

@@ -0,0 +1,139 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Distribution} from "./Distribution.sol";
+import {DISTRIBUTOR} from "../type/ObjectType.sol";
+import {IAuthorization} from "../authorization/IAuthorization.sol";
+import {NftId} from "../type/NftId.sol";
+import {ReferralId} from "../type/Referral.sol";
+import {Fee} from "../type/Fee.sol";
+import {UFixed} from "../type/UFixed.sol";
+import {DistributorType} from "../type/DistributorType.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+
+contract BasicDistribution is
+    Distribution
+{
+
+    function setFees(
+        Fee memory distributionFee,
+        Fee memory minDistributionOwnerFee
+    )
+        external
+        virtual
+        onlyOwner()
+        restricted()
+    {
+        _setFees(
+            distributionFee, 
+            minDistributionOwnerFee);
+    }
+
+
+    function createDistributorType(
+        string memory name,
+        UFixed minDiscountPercentage,
+        UFixed maxDiscountPercentage,
+        UFixed commissionPercentage,
+        uint32 maxReferralCount,
+        uint32 maxReferralLifetime,
+        bool allowSelfReferrals,
+        bool allowRenewals,
+        bytes memory data
+    )
+        external
+        virtual
+        restricted()
+        onlyOwner()
+        returns (DistributorType distributorType)
+    {
+        return _createDistributorType(
+            name,
+            minDiscountPercentage,
+            maxDiscountPercentage,
+            commissionPercentage,
+            maxReferralCount,
+            maxReferralLifetime,
+            allowSelfReferrals,
+            allowRenewals,
+            data);
+    }
+
+    function createDistributor(
+        address distributor,
+        DistributorType distributorType,
+        bytes memory data
+    )
+        external
+        virtual
+        restricted()
+        onlyOwner()
+        returns(NftId distributorNftId)
+    {
+        return _createDistributor(distributor, distributorType, data);
+    }
+
+    function changeDistributorType(
+        NftId distributorNftId,
+        DistributorType distributorType,
+        bytes memory data
+    )
+        external
+        virtual
+        restricted()
+        onlyOwner()
+        onlyNftOfType(distributorNftId, DISTRIBUTOR())
+    {
+        _changeDistributorType(distributorNftId, distributorType, data);
+    }
+
+    /**
+     * @dev lets distributors create referral codes.
+     * referral codes need to be unique
+     */
+    function createReferral(
+        string memory code,
+        UFixed discountPercentage,
+        uint32 maxReferrals,
+        Timestamp expiryAt,
+        bytes memory data
+    )
+        external
+        virtual
+        restricted()
+        onlyDistributor()
+        returns (ReferralId referralId)
+    {
+        NftId distributorNftId = getDistributorNftId(msg.sender);
+        return _createReferral(
+            distributorNftId,
+            code,
+            discountPercentage,
+            maxReferrals,
+            expiryAt,
+            data); // data
+    }
+
+    function _initializeBasicDistribution(
+        address registry,
+        NftId instanceNftId,
+        IAuthorization authorization, 
+        address initialOwner,
+        string memory name,
+        address token
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+        _initializeDistribution(
+            registry, 
+            instanceNftId, 
+            authorization,
+            initialOwner, 
+            name, 
+            token, 
+            ""); // component specifc data
+    }
+}

package/contracts/distribution/BasicDistributionAuthorization.sol

@@ -0,0 +1,39 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Authorization} from "../authorization/Authorization.sol";
+import {BasicDistribution} from "./BasicDistribution.sol"; 
+import {Distribution} from "./Distribution.sol";
+import {DISTRIBUTION} from "../type/ObjectType.sol";
+import {IAccess} from "../authorization/IAccess.sol";
+import {IInstanceLinkedComponent} from "../shared/IInstanceLinkedComponent.sol";
+import {PUBLIC_ROLE} from "../../contracts/type/RoleId.sol";
+
+
+contract BasicDistributionAuthorization
+     is Authorization
+{
+
+     constructor(string memory distributionlName)
+          Authorization(distributionlName, DISTRIBUTION())
+     {}
+
+     function _setupTargetAuthorizations()
+          internal
+          virtual override
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          // authorize public role (open access to any account, only allows to lock target)
+          functions = _authorizeForTarget(getMainTargetName(), PUBLIC_ROLE());
+          _authorize(functions, BasicDistribution.setFees.selector, "setFees");
+          _authorize(functions, BasicDistribution.createDistributorType.selector, "createDistributorType");
+          _authorize(functions, BasicDistribution.createDistributor.selector, "createDistributor");
+          _authorize(functions, BasicDistribution.changeDistributorType.selector, "changeDistributorType");
+          _authorize(functions, BasicDistribution.createReferral.selector, "createReferral");
+          
+          _authorize(functions, IInstanceLinkedComponent.withdrawFees.selector, "withdrawFees");
+          _authorize(functions, Distribution.withdrawCommission.selector, "withdrawCommission");
+     }
+}
+

package/contracts/distribution/Distribution.sol

@@ -0,0 +1,287 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Amount} from "../type/Amount.sol";
+import {COMPONENT, DISTRIBUTION, DISTRIBUTOR} from "../type/ObjectType.sol";
+import {IAuthorization} from "../authorization/IAuthorization.sol";
+import {IDistributionService} from "./IDistributionService.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {ReferralId, ReferralStatus, ReferralLib} from "../type/Referral.sol";
+import {Fee} from "../type/Fee.sol";
+import {InstanceLinkedComponent} from "../shared/InstanceLinkedComponent.sol";
+import {IComponentService} from "../shared/IComponentService.sol";
+import {IDistributionComponent} from "./IDistributionComponent.sol";
+import {UFixed} from "../type/UFixed.sol";
+import {DistributorType} from "../type/DistributorType.sol";
+import {Timestamp} from "../type/Timestamp.sol";
+
+
+abstract contract Distribution is
+    InstanceLinkedComponent,
+    IDistributionComponent
+{
+    // keccak256(abi.encode(uint256(keccak256("etherisc.storage.Distribution")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant DISTRIBUTION_STORAGE_LOCATION_V1 = 0xaab7c5ea03d290056d6c060e0833d3ebcbe647f7694616a2ec52738a64b2f900;
+
+    struct DistributionStorage {
+        IComponentService _componentService;
+        IDistributionService _distributionService;
+        mapping(address distributor => NftId distributorNftId) _distributorNftId;
+    }
+
+    modifier onlyDistributor() {
+        if (!isDistributor(msg.sender)) {
+            revert ErrorDistributionNotDistributor(msg.sender);
+        }
+        _;
+    }
+
+
+    function processRenewal(
+        ReferralId referralId,
+        uint256 feeAmount
+    )
+        external
+        virtual
+        restricted()
+    {
+        // default is no action
+    }
+
+
+    /// @inheritdoc IDistributionComponent
+    function withdrawCommission(NftId distributorNftId, Amount amount) 
+        external 
+        virtual
+        restricted()
+        onlyDistributor()
+        onlyNftOfType(distributorNftId, DISTRIBUTOR())
+        onlyNftOwner(distributorNftId)
+        returns (Amount withdrawnAmount) 
+    {
+        return _withdrawCommission(distributorNftId, amount);
+    }
+
+
+    function isDistributor(address candidate)
+        public
+        view
+        returns (bool)
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        return $._distributorNftId[candidate].gtz();
+    }
+
+
+    function getDistributorNftId(address distributor)
+        public
+        view
+        returns (NftId distributorNftId)
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        return $._distributorNftId[distributor];
+    }
+
+
+    function getDiscountPercentage(string memory referralCode)
+        external
+        view
+        returns (
+            UFixed discountPercentage, 
+            ReferralStatus status
+        )
+    {
+        ReferralId referralId = getReferralId(referralCode);
+        return _getInstanceReader().getDiscountPercentage(referralId);
+    }
+
+
+    function getReferralId(
+        string memory referralCode
+    )
+        public
+        view 
+        returns (ReferralId referralId)
+    {
+        return ReferralLib.toReferralId(
+            getNftId(), 
+            referralCode);      
+    }
+
+
+    function calculateRenewalFeeAmount(
+        ReferralId referralId,
+        uint256 netPremiumAmount
+    )
+        external
+        view
+        virtual override
+        returns (uint256 feeAmount)
+    {
+        // default is no fees
+        return 0 * netPremiumAmount;
+    }
+
+
+    /// @dev Returns true iff the component needs to be called when selling/renewing policis
+    function isVerifying() external pure returns (bool verifying) {
+        return true;
+    }
+
+
+    function _initializeDistribution(
+        address registry,
+        NftId productNftId,
+        IAuthorization authorization, 
+        address initialOwner,
+        string memory name,
+        address token,
+        bytes memory componentData // component specifidc data 
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+        _initializeInstanceLinkedComponent(
+            registry, 
+            productNftId, 
+            name, 
+            token, 
+            DISTRIBUTION(), 
+            authorization,
+            true, 
+            initialOwner, 
+            componentData);
+
+        DistributionStorage storage $ = _getDistributionStorage();
+        $._distributionService = IDistributionService(_getServiceAddress(DISTRIBUTION())); 
+        $._componentService = IComponentService(_getServiceAddress(COMPONENT())); 
+
+        _registerInterface(type(IDistributionComponent).interfaceId);
+    }
+
+    /// @dev Sets the distribution fees to the provided values.
+    function _setFees(
+        Fee memory distributionFee,
+        Fee memory minDistributionOwnerFee
+    )
+        internal
+        virtual
+    {
+        _getDistributionStorage()._componentService.setDistributionFees(
+            distributionFee, 
+            minDistributionOwnerFee);
+    }
+
+    /// @dev Creates a new distributor type using the provided parameters.
+    function _createDistributorType(
+        string memory name,
+        UFixed minDiscountPercentage,
+        UFixed maxDiscountPercentage,
+        UFixed commissionPercentage,
+        uint32 maxReferralCount,
+        uint32 maxReferralLifetime,
+        bool allowSelfReferrals,
+        bool allowRenewals,
+        bytes memory data
+    )
+        internal
+        virtual
+        returns (DistributorType distributorType)
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        distributorType = $._distributionService.createDistributorType(
+            name,
+            minDiscountPercentage,
+            maxDiscountPercentage,
+            commissionPercentage,
+            maxReferralCount,
+            maxReferralLifetime,
+            allowSelfReferrals,
+            allowRenewals,
+            data);
+    }
+
+    /// @dev Turns the provided account into a new distributor of the specified type.
+    function _createDistributor(
+        address distributor,
+        DistributorType distributorType,
+        bytes memory data
+    )
+        internal
+        virtual
+        returns(NftId distributorNftId)
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        if($._distributorNftId[distributor].gtz()) {
+            revert ErrorDistributionAlreadyDistributor(distributor, $._distributorNftId[distributor]);
+        }
+
+        distributorNftId = $._distributionService.createDistributor(
+            distributor,
+            distributorType,
+            data);
+
+        $._distributorNftId[distributor] = distributorNftId;
+    }
+
+    /// @dev Uptates the distributor type for the specified distributor.
+    function _changeDistributorType(
+        NftId distributorNftId,
+        DistributorType distributorType,
+        bytes memory data
+    )
+        internal
+        virtual
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        $._distributionService.changeDistributorType(
+            distributorNftId,
+            distributorType,
+            data);
+    }
+
+    /// @dev Create a new referral code for the provided distributor.
+    function _createReferral(
+        NftId distributorNftId,
+        string memory code,
+        UFixed discountPercentage,
+        uint32 maxReferrals,
+        Timestamp expiryAt,
+        bytes memory data
+    )
+        internal
+        virtual
+        returns (ReferralId referralId)
+    {
+        DistributionStorage storage $ = _getDistributionStorage();
+        referralId = $._distributionService.createReferral(
+            distributorNftId,
+            code,
+            discountPercentage,
+            maxReferrals,
+            expiryAt,
+            data);
+    }
+
+    function _withdrawCommission(NftId distributorNftId, Amount amount) 
+        internal
+        returns (Amount withdrawnAmount) 
+    {
+        return _getDistributionStorage()._distributionService.withdrawCommission(distributorNftId, amount);
+    }
+
+    function _nftTransferFrom(address from, address to, uint256 tokenId, address operator) internal virtual override {
+        // keep track of distributor nft owner
+        emit LogDistributorUpdated(to, operator);
+        DistributionStorage storage $ = _getDistributionStorage();
+        $._distributorNftId[from] = NftIdLib.zero();
+        $._distributorNftId[to] = NftIdLib.toNftId(tokenId);
+    }
+
+    function _getDistributionStorage() private pure returns (DistributionStorage storage $) {
+        assembly {
+            $.slot := DISTRIBUTION_STORAGE_LOCATION_V1
+        }
+    }
+}