@etherisc/gif-next 0.0.2-8872ac5 → 0.0.2-8d47fa1-080

package/contracts/shared/ProxyManager.sol

@@ -0,0 +1,115 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Ownable} from "@openzeppelin5/contracts/access/Ownable.sol";
+import {ProxyAdmin} from "@openzeppelin5/contracts/proxy/transparent/ProxyAdmin.sol";
+import {ITransparentUpgradeableProxy} from "@openzeppelin5/contracts/proxy/transparent/TransparentUpgradeableProxy.sol";
+
+import {IVersionable} from "./IVersionable.sol";
+import {UpgradableProxyWithAdmin} from "./UpgradableProxyWithAdmin.sol";
+import {IVersionable} from "./IVersionable.sol";
+
+/// @dev manages proxy deployments for upgradable contracs of type IVersionable
+contract ProxyManager is Ownable {
+
+    event LogProxyDeployed(address indexed proxy, address initialImplementation);
+    event LogProxyDeployedWithSalt(address indexed proxy, address initialImplementation);
+    event LogProxyUpgraded(address indexed proxy, address upgradedImplementation);
+
+    error ErrorAlreadyDeployed();
+    error ErrorAlreadyDeployedWithSalt();
+    error ErrorNotYetDeployed();
+
+    UpgradableProxyWithAdmin private _proxy;
+    bool private _isDeployed;
+
+    /// @dev only used to capture proxy owner
+    constructor()
+        Ownable(msg.sender)
+    { }
+
+    /// @dev deploy initial contract
+    function deploy(address initialImplementation, bytes memory initializationData)
+        public
+        onlyOwner()
+        returns (IVersionable versionable)
+    {
+        if (_isDeployed) { revert ErrorAlreadyDeployed(); }
+
+        address currentProxyOwner = owner(); // used by implementation
+        address initialProxyAdminOwner = address(this); // used by proxy
+        bytes memory data = getDeployData(initialImplementation, currentProxyOwner, initializationData);
+        
+        _proxy = new UpgradableProxyWithAdmin(
+            initialImplementation,
+            initialProxyAdminOwner,
+            data
+        );
+
+        _isDeployed = true;
+        versionable = IVersionable(address(_proxy));
+
+        emit LogProxyDeployed(address(_proxy), initialImplementation);
+    }
+
+    function deployWithSalt(address initialImplementation, bytes memory initializationData, bytes32 salt)
+        public
+        onlyOwner()
+        returns (IVersionable versionable)
+    {
+        if (_isDeployed) { revert ErrorAlreadyDeployedWithSalt(); }
+
+        address currentProxyOwner = owner(); // used by implementation
+        address initialProxyAdminOwner = address(this); // used by proxy
+        bytes memory data = getDeployData(initialImplementation, currentProxyOwner, initializationData);
+
+        // via create2
+        _proxy = new UpgradableProxyWithAdmin{salt: salt}(
+            initialImplementation,
+            initialProxyAdminOwner,
+            data
+        );
+
+        _isDeployed = true;
+        versionable = IVersionable(address(_proxy));
+
+        emit LogProxyDeployedWithSalt(address(_proxy), initialImplementation);
+    }
+
+    /// @dev upgrade existing contract
+    function upgrade(address newImplementation, bytes memory upgradeData)
+        public
+        virtual
+        onlyOwner()
+        returns (IVersionable versionable)
+    {
+        if (!_isDeployed) { revert ErrorNotYetDeployed(); }
+
+        address currentProxyOwner = owner();
+        ProxyAdmin proxyAdmin = getProxyAdmin();
+        ITransparentUpgradeableProxy proxy = ITransparentUpgradeableProxy(address(_proxy));
+        bytes memory data = getUpgradeData(newImplementation, currentProxyOwner, upgradeData);
+
+        proxyAdmin.upgradeAndCall(
+            proxy,
+            newImplementation, 
+            data);
+
+        versionable = IVersionable(address(_proxy));
+
+        emit LogProxyUpgraded(address(_proxy), newImplementation);
+
+    }
+
+    function getDeployData(address implementation, address proxyOwner, bytes memory deployData) public pure returns (bytes memory data) {
+        return abi.encodeWithSelector(IVersionable.initialize.selector, implementation, proxyOwner, deployData);
+    }
+
+    function getUpgradeData(address implementation, address proxyOwner, bytes memory upgradeData) public pure returns (bytes memory data) {
+        return abi.encodeWithSelector(IVersionable.upgrade.selector, implementation, proxyOwner, upgradeData);
+    }
+
+    function getProxyAdmin() public returns (ProxyAdmin) {
+        return _proxy.getProxyAdmin();
+    }
+}

package/contracts/shared/Registerable.sol

@@ -0,0 +1,117 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin5/contracts/proxy/utils/Initializable.sol"; 
+
+import {NftId, zeroNftId} from "../types/NftId.sol";
+import {ObjectType} from "../types/ObjectType.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IRegisterable} from "./IRegisterable.sol";
+import {Versionable} from "./Versionable.sol";
+
+import {ERC165} from "./ERC165.sol";
+
+abstract contract Registerable is
+    ERC165,
+    IRegisterable,
+    Initializable
+{
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.shared.Registerable.sol")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant REGISTERABLE_LOCATION_V1 = 0x6548007c3f4340f82f348c576c0ff69f4f529cadd5ad41f96aae61abceeaa300;
+
+    struct RegisterableStorage {
+        IRegistry _registry;
+        NftId _parentNftId;
+        address _initialOwner;
+        ObjectType _objectType;
+        bool _isInterceptor;
+        bytes _data;
+    }
+
+    function _getRegisterableStorage() private pure returns (RegisterableStorage storage $) {
+        assembly {
+            $.slot := REGISTERABLE_LOCATION_V1
+        }
+    }
+
+    modifier onlyOwner() virtual {
+        require(
+            msg.sender == getOwner(),
+            "ERROR:RGB-001:NOT_OWNER"
+        );
+        _;
+    }
+
+    function _initializeRegisterable(
+        address registryAddress,
+        NftId parentNftId,
+        ObjectType objectType,
+        bool isInterceptor,
+        address initialOwner,
+        bytes memory data
+    )
+        internal
+        //onlyInitializing//TODO uncomment when "fully" upgradeable
+        virtual
+    {
+        require(
+            registryAddress != address(0),
+            "ERROR:RGB-010:REGISTRY_ZERO"
+        );
+
+        // TODO check parentNftId -> registry.isRegistered(parentNftId)
+        // TODO check object-parent type pair -> registry.isValidTypeCombo() or something...verify with registry that setup will be able to register...
+
+        IRegistry registry = IRegistry(registryAddress);
+        require(
+            registry.supportsInterface(type(IRegistry).interfaceId),
+            "ERROR:RGB-011:NOT_REGISTRY"
+        );
+
+        RegisterableStorage storage $ = _getRegisterableStorage();
+        $._registry = registry;
+        $._parentNftId = parentNftId;
+        $._objectType = objectType;
+        $._isInterceptor = isInterceptor;
+        $._initialOwner = initialOwner;// not msg.sender because called in proxy constructor where msg.sender is proxy deployer
+        $._data = data;
+
+        _registerInterface(type(Registerable).interfaceId);
+    }
+
+    // from IOwnable
+    function getOwner() public view virtual returns (address) {
+        return _getRegisterableStorage()._registry.ownerOf(address(this));
+    }
+
+    // from IRegisterable
+    function getRegistry() public view virtual returns (IRegistry registry) {
+        return _getRegisterableStorage()._registry;
+    }
+
+    function getNftId() public view virtual returns (NftId nftId) {
+        return _getRegisterableStorage()._registry.getNftId(address(this));
+    }
+
+    function getInitialInfo() 
+        public 
+        view 
+        virtual 
+        returns (IRegistry.ObjectInfo memory, bytes memory data) 
+    {
+        RegisterableStorage storage $ = _getRegisterableStorage();
+        return (
+            IRegistry.ObjectInfo(
+                zeroNftId(),
+                $._parentNftId,
+                $._objectType,
+                $._isInterceptor,
+                address(this), 
+                $._initialOwner,
+                $._data
+            ),
+            bytes("")
+        );
+    }
+}

package/contracts/shared/UpgradableProxyWithAdmin.sol

@@ -0,0 +1,16 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ProxyAdmin} from "@openzeppelin5/contracts/proxy/transparent/ProxyAdmin.sol";
+import {TransparentUpgradeableProxy, ITransparentUpgradeableProxy} from "@openzeppelin5/contracts/proxy/transparent/TransparentUpgradeableProxy.sol";
+
+import {IVersionable} from "./IVersionable.sol";
+
+contract UpgradableProxyWithAdmin is TransparentUpgradeableProxy {
+
+    constructor(address implementation, address initialProxyAdminOwner, bytes memory data)
+        TransparentUpgradeableProxy(implementation, initialProxyAdminOwner, data)
+    {}
+
+    function getProxyAdmin() external returns (ProxyAdmin) { return ProxyAdmin(_proxyAdmin()); }
+}

package/contracts/shared/Versionable.sol

@@ -0,0 +1,147 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin5/contracts/proxy/utils/Initializable.sol";
+
+import {Blocknumber, blockNumber} from "../types/Blocknumber.sol";
+import {Timestamp, blockTimestamp} from "../types/Timestamp.sol";
+import {Version, VersionPart, VersionLib} from "../types/Version.sol";
+
+import {IVersionable} from "./IVersionable.sol";
+
+
+
+abstract contract Versionable is 
+    Initializable,
+    IVersionable 
+{
+    // keccak256(abi.encode(uint256(keccak256("gif-next.contracts.shared.Versionable.sol")) - 1)) & ~bytes32(uint256(0xff))
+    bytes32 private constant VERSIONABLE_LOCATION_V1 = 0x4f61291a8ac3d020d0a7d919a76b8592aa88385744dee3f8b4f3873b969ed900;
+
+
+    /// @custom:storage-location erc7201:gif-next.contracts.shared.Versionable.sol
+    struct VersionableStorage {
+        mapping(Version version => VersionInfo info) _versionHistory;
+        Version [] _versions;
+        Version _v1;
+    }
+
+
+    constructor() {
+        _disableInitializers();
+    }
+    // TODO write test where new version of private _updateVersionHistory is added and used... 
+    function initialize(
+        address implementation,
+        address activatedBy,
+        bytes memory data
+    )
+        public
+        initializer
+    {
+        _updateVersionHistory(implementation, activatedBy);
+        _initialize(activatedBy, data);
+    }
+
+    // TODO activatedBy MUST ALWAYS be an owner?
+    function upgrade(
+        address implementation,
+        address activatedBy,
+        bytes memory data
+    )
+        external
+        reinitializer(VersionLib.toUint64(getVersion()))
+    {
+        _updateVersionHistory(implementation, activatedBy);
+        _upgrade(data);
+    }
+
+    function isInitialized(Version _version) public override view returns(bool) {
+        return _getVersionableStorage()._versionHistory[_version].activatedIn.toInt() > 0;
+    }
+
+    function getVersion() public pure virtual returns(Version);
+
+    function getVersionCount() public view override returns(uint256) {
+        return _getVersionableStorage()._versions.length;
+    }
+
+    function getVersion(uint256 idx) public view override returns(Version) {
+        return _getVersionableStorage()._versions[idx];
+    }
+
+    function getVersionInfo(Version _version) public override view returns(VersionInfo memory) {
+        return _getVersionableStorage()._versionHistory[_version];
+    }
+
+    function getInitializedVersion() public view returns(uint64) {
+        return _getInitializedVersion();
+    }
+
+
+
+    // IMPORTANT each version must implement this function 
+    // each implementation MUST use onlyInitialising modifier
+    // each implementation MUST call intializers of all base contracts...
+    function _initialize(address owner, bytes memory data) 
+        internal
+        onlyInitializing
+        virtual 
+    {
+        revert();
+    }
+
+
+    // IMPORTANT each version except version "1" must implement this function 
+    // each implementation MUST use onlyInitialising modifier
+    function _upgrade(bytes memory data)
+        internal
+        onlyInitializing
+        virtual
+    {
+        revert();
+    }
+
+    function _getVersionableStorage() private pure returns (VersionableStorage storage $) {
+        assembly {
+            $.slot := VERSIONABLE_LOCATION_V1
+        }
+    }
+
+    // can only be called once per contract
+    // needs to be called inside the proxy upgrade tx
+    // TODO run reinitializer(version().toUint64()) modifier after "version()" is checked, 
+    function _updateVersionHistory(
+        address implementation,
+        address activatedBy
+    )
+        private
+        onlyInitializing
+    {
+        VersionableStorage storage $ = _getVersionableStorage();
+
+        uint64 version = _getInitializedVersion();
+
+        Version thisVersion = getVersion();
+
+        if(version == 1) {
+            // thisVersion is alias to version "1"
+            $._v1 = thisVersion;
+        }
+        else {
+            require(thisVersion > $._v1, "INVALID VERSION");
+        }
+
+        // update version history
+        $._versions.push(thisVersion);
+        $._versionHistory[thisVersion] = VersionInfo(
+            thisVersion,
+            implementation,
+            activatedBy,
+            blockTimestamp(),
+            blockNumber()
+        );
+
+        emit LogVersionableInitialized(thisVersion, implementation, activatedBy);
+    }
+}

package/contracts/test/TestDistribution.sol

@@ -0,0 +1,22 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Fee} from "../../contracts/types/Fee.sol";
+import {NftId} from "../../contracts/types/NftId.sol";
+import {Distribution} from "../../contracts/components/Distribution.sol";
+
+
+contract TestDistribution is Distribution {
+
+    constructor(
+        address registry,
+        NftId instanceNftid,
+        address token,
+        bool isVerifying,
+        Fee memory distributionFee,
+        address initialOwner
+    )
+        Distribution(registry, instanceNftid, token, isVerifying, distributionFee, initialOwner)
+    // solhint-disable-next-line no-empty-blocks
+    {}
+}

package/contracts/test/TestFee.sol

@@ -0,0 +1,25 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {UFixed, UFixedMathLib} from "../types/UFixed.sol";
+import {Fee, FeeLib} from "../types/Fee.sol";
+
+contract TestFee {
+
+    function createFee(
+        uint256 fractionalValue,
+        int8 exponent,
+        uint256 fixedValue
+    )
+        external 
+        pure 
+        returns(Fee memory fee)
+    {
+        return FeeLib.toFee(UFixedMathLib.toUFixed(fractionalValue, exponent), fixedValue);
+    }
+
+    function getZeroFee() external pure returns(Fee memory fee) {
+        return FeeLib.zeroFee();
+    }
+
+}

package/contracts/test/TestPool.sol

@@ -0,0 +1,27 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../../contracts/types/NftId.sol";
+import {UFixed} from "../../contracts/types/UFixed.sol";
+import {Fee} from "../../contracts/types/Fee.sol";
+import {Pool} from "../../contracts/components/Pool.sol";
+
+
+contract TestPool is Pool {
+
+    constructor(
+        address registry,
+        NftId instanceNftid,
+        address token,
+        bool isInterceptor,
+        bool isVerifying,
+        UFixed collateralizationLevel,
+        Fee memory poolFee,
+        Fee memory stakingFee,
+        Fee memory performanceFee,
+        address initialOwner
+    )
+        Pool(registry, instanceNftid, token, isInterceptor, isVerifying, collateralizationLevel, poolFee, stakingFee, performanceFee, initialOwner)
+    // solhint-disable-next-line no-empty-blocks
+    {}
+}

package/contracts/test/TestProduct.sol

@@ -0,0 +1,74 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Product} from "../../contracts/components/Product.sol";
+import {NftId, toNftId} from "../../contracts/types/NftId.sol";
+import {ReferralId} from "../types/ReferralId.sol";
+import {RiskId} from "../../contracts/types/RiskId.sol";
+import {Timestamp, blockTimestamp} from "../../contracts/types/Timestamp.sol";
+import {Fee} from "../../contracts/types/Fee.sol";
+
+contract TestProduct is Product {
+
+    event LogTestProductSender(address sender);
+
+    string public constant DEFAULT_RISK_NAME = "DEFAULT_RISK";
+    bool private defaultRiskCreated;
+
+    constructor(
+        address registry,
+        NftId instanceNftid,
+        address token,
+        bool isInterceptor,
+        address pool,
+        address distribution,
+        Fee memory productFee,
+        Fee memory processingFee,
+        address initialOwner
+    )
+        Product(registry, instanceNftid, token, isInterceptor, pool, distribution, productFee, processingFee, initialOwner)
+    // solhint-disable-next-line no-empty-blocks
+    {
+    }
+
+    function getDefaultRiskId() public pure returns (RiskId) {
+        return _toRiskId(DEFAULT_RISK_NAME);
+    }
+
+    function applyForPolicy(
+        uint256 sumInsuredAmount,
+        uint256 lifetime,
+        NftId bundleNftId,
+        ReferralId referralId
+    )
+        external
+        returns(NftId nftId)
+    {
+        RiskId riskId = getDefaultRiskId();
+        bytes memory applicationData = "";
+
+        if (!defaultRiskCreated) {
+            _createRisk(riskId, "");
+            defaultRiskCreated = true;
+        }
+
+        nftId = _createApplication(
+            msg.sender, // policy holder
+            riskId,
+            sumInsuredAmount,
+            lifetime,
+            applicationData,
+            bundleNftId,
+            referralId
+        );
+    }
+
+    function underwrite(NftId nftId, bool requirePremiumPayment, Timestamp activateAt) external {
+        emit LogTestProductSender(msg.sender);
+        _underwrite(nftId, requirePremiumPayment, activateAt);
+    }
+
+    function collectPremium(NftId nftId, Timestamp activateAt) external {
+        _collectPremium(nftId, activateAt);
+    }
+}

package/contracts/test/TestRegisterable.sol

@@ -0,0 +1,18 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../../contracts/types/NftId.sol";
+import {ObjectType, TOKEN} from "../../contracts/types/ObjectType.sol";
+import {IRegistry} from "../../contracts/registry/IRegistry.sol";
+import {Registerable} from "../../contracts/shared/Registerable.sol";
+
+contract TestRegisterable is Registerable {
+
+    constructor(address registry, NftId registryNftId, ObjectType objectType, bool isInterceptor, address initialOwner)
+        //Registerable(registry, registryNftId)
+    // solhint-disable-next-line no-empty-blocks
+    {
+        bytes memory data = "";
+        _initializeRegisterable(registry, registryNftId, objectType, isInterceptor, initialOwner, data);
+    }
+}

package/contracts/test/TestRoleId.sol

@@ -0,0 +1,14 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {RoleId, RoleIdLib, PRODUCT_OWNER_ROLE_NAME, PRODUCT_OWNER_ROLE, POOL_OWNER_ROLE_NAME, POOL_OWNER_ROLE} from "../../contracts/types/RoleId.sol";
+
+contract TestRoleId {
+    function getRole(string memory roleName) external pure returns (RoleId) { return RoleIdLib.toRoleId(roleName); }
+
+    function getProductOwnerRoleName() external pure returns (string memory) { return PRODUCT_OWNER_ROLE_NAME(); }
+    function getProductOwnerRole() external pure returns (RoleId) { return PRODUCT_OWNER_ROLE(); } 
+
+    function getPoolOwnerRoleName() external pure returns (string memory) { return POOL_OWNER_ROLE_NAME(); }
+    function getPoolOwnerRole() external pure returns (RoleId) { return POOL_OWNER_ROLE(); } 
+}

package/contracts/test/TestService.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../../contracts/types/NftId.sol";
+import {Version, VersionLib} from "../../contracts/types/Version.sol";
+import {ServiceBase} from "../../contracts/instance/base/ServiceBase.sol";
+
+import {IVersionable} from "../../contracts/shared/IVersionable.sol";
+import {Versionable} from "../../contracts/shared/Versionable.sol";
+
+//import {IService} from "../../contracts/instance/base/IService.sol";
+
+contract TestService is ServiceBase {
+
+    string public constant NAME = "TestService";
+
+    constructor(address registry, NftId registryNftId, address initialOwner)
+    // solhint-disable-next-line no-empty-blocks
+    {
+        _initializeServiceBase(registry, registryNftId, initialOwner);
+    }
+
+    function getName() public pure override returns(string memory name) {
+        return NAME;
+    }
+}

package/contracts/test/TestToken.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
+
+contract TestUsdc is ERC20 {
+
+    // https://etherscan.io/token/0xc719d010b63e5bbf2c0551872cd5316ed26acd83#readContract
+    string public constant NAME = "USDC - Test";
+    string public constant SYMBOL = "USDC";
+    uint8 public constant DECIMALS = 6;
+    uint256 public constant INITIAL_SUPPLY = 10**9 * 10**DECIMALS; // 1 Billion 1'000'000'000
+    // decimals == 18 (openzeppelin erc20 default)
+    constructor()
+        ERC20(NAME, SYMBOL)
+    {
+        _mint(
+            _msgSender(),
+            INITIAL_SUPPLY
+        );   
+    }
+
+    function decimals() public pure override returns(uint8) {
+        return DECIMALS;
+    }
+}

package/contracts/test/TestVersion.sol

@@ -0,0 +1,44 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Version, VersionPart, VersionLib} from "../types/Version.sol";
+
+contract TestVersion {
+
+    function createVersion(uint major, uint minor, uint patch) external pure returns(Version) {
+        return VersionLib.toVersion(major, minor, patch);
+    }
+
+    function createVersionPart(uint versionPart) external pure returns(VersionPart) {
+        return VersionLib.toVersionPart(uint8(versionPart));
+    }
+
+    function getVersionParts(Version version)
+        external
+        pure
+        returns(
+            VersionPart major,
+            VersionPart minor,
+            VersionPart patch
+        )
+    {
+        return version.toVersionParts();
+    }
+
+    function getMajorPart(Version version) external pure returns(VersionPart major) {
+        return version.toMajorPart();
+    }
+
+    function getZeroVersion() external pure returns(Version) {
+        return VersionLib.zeroVersion();
+    }
+
+    function isSameVersion(Version a, Version b) external pure returns(bool) {
+        return a == b;
+    }
+
+    function isLargerVersion(Version a, Version b) external pure returns(bool) {
+        return a > b;
+    }
+
+}