@etherisc/gif-next 0.0.2-86e23a6-752 → 0.0.2-86fb77b-888

package/contracts/experiment/statemachine/SimpleStateMachine.sol

@@ -1,31 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {StateId, toStateId} from "../../types/StateId.sol";
-import {SM} from "./SM.sol";
-
-contract SimpleStateMachine is SM {
-    uint8 public constant STATE_ACTIVE = 10;
-    uint8 public constant STATE_PAUSED = 20;
-    uint8 public constant STATE_ARCHIVED = 30;
-
-    constructor() {
-        addTransition(ACTIVE(), PAUSED());
-        addTransition(PAUSED(), ACTIVE());
-        addTransition(PAUSED(), ARCHIVED());
-
-        setInitialState(ACTIVE());
-    }
-
-    function ACTIVE() public pure returns (StateId stateId) {
-        return toStateId(STATE_ACTIVE);
-    }
-
-    function PAUSED() public pure returns (StateId stateId) {
-        return toStateId(STATE_PAUSED);
-    }
-
-    function ARCHIVED() public pure returns (StateId stateId) {
-        return toStateId(STATE_ARCHIVED);
-    }
-}

package/contracts/experiment/types/TypeA.sol

@@ -1,47 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-/*
-# chisel session for user defined types
-
-import {TypeA, toTypeA} from "./contracts/experiment/types/TypeA.sol";
-TypeA a = toTypeA(1);
-TypeA b = toTypeA(2);
-uint(a.toInt())
-uint(b.toInt())
-a == b
-a != b
-
-import {TypeB, toTypeB} from "./contracts/experiment/types/TypeB.sol";
-TypeB x = toTypeB(33);
-uint(x.toInt())
-a == x; // -> error
-a.toInt() == x.toInt() // -> no error
- */
-
-// bytes5 allows for chain ids up to 13 digits
-type TypeA is uint248;
-
-// type bindings
-using {eqTypeA as ==, neTypeA as !=, TypeALib.toInt} for TypeA global;
-
-// general pure free functions
-function toTypeA(uint256 typeA) pure returns (TypeA) {
-    return TypeA.wrap(uint248(typeA));
-}
-
-// pure free functions for operators
-function eqTypeA(TypeA a, TypeA b) pure returns (bool isSame) {
-    return TypeA.unwrap(a) == TypeA.unwrap(b);
-}
-
-function neTypeA(TypeA a, TypeA b) pure returns (bool isDifferent) {
-    return TypeA.unwrap(a) != TypeA.unwrap(b);
-}
-
-// library functions that operate on user defined type
-library TypeALib {
-    function toInt(TypeA typeA) internal pure returns (uint256) {
-        return uint256(TypeA.unwrap(typeA));
-    }
-}

package/contracts/experiment/types/TypeB.sol

@@ -1,29 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-// bytes5 allows for chain ids up to 13 digits
-type TypeB is uint248;
-
-// type bindings
-using {eqTypeB as ==, addTypeB as +, TypeBLib.toInt} for TypeB global;
-
-// general pure free functions
-function toTypeB(uint256 x) pure returns (TypeB) {
-    return TypeB.wrap(uint248(x));
-}
-
-// pure free functions for operators
-function eqTypeB(TypeB a, TypeB b) pure returns (bool isSame) {
-    return TypeB.unwrap(a) == TypeB.unwrap(b);
-}
-
-function addTypeB(TypeB a, TypeB b) pure returns (TypeB sum) {
-    return TypeB.wrap(TypeB.unwrap(a) + TypeB.unwrap(b));
-}
-
-// library functions that operate on user defined type
-library TypeBLib {
-    function toInt(TypeB b) internal pure returns (uint256) {
-        return uint256(TypeB.unwrap(b));
-    }
-}

package/contracts/instance/BundleManager.sol

@@ -1,125 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {IInstance} from "./IInstance.sol";
-import {INSTANCE} from "../types/ObjectType.sol";
-import {InstanceReader} from "./InstanceReader.sol";
-import {IPolicy} from "../instance/module/IPolicy.sol";
-import {IRegistry} from "../registry/IRegistry.sol";
-import {LibNftIdSet} from "../types/NftIdSet.sol";
-import {NftId} from "../types/NftId.sol";
-import {TimestampLib} from "../types/Timestamp.sol";
-
-import {ObjectManager} from "./ObjectManager.sol";
-
-contract BundleManager is 
-    ObjectManager
-{
-
-    event LogBundleManagerPolicyLinked(NftId bundleNftId, NftId policyNftId);
-    event LogBundleManagerPolicyUnlinked(NftId bundleNftId, NftId policyNftId);
-
-    event LogBundleManagerBundleAdded(NftId poolNftId, NftId bundleNftId);
-    event LogBundleManagerBundleUnlocked(NftId poolNftId, NftId bundleNftId);
-    event LogBundleManagerBundleLocked(NftId poolNftId, NftId bundleNftId);
-
-    error ErrorBundleManagerErrorPolicyAlreadyActivated(NftId policyNftId);
-    error ErrorBundleManagerErrorBundleLocked(NftId bundleNftId, NftId policyNftId);
-    error ErrorBundleManagerPolicyWithOpenClaims(NftId policyNftId, uint256 openClaimsCount);
-    error ErrorBundleManagerPolicyNotCloseable(NftId policyNftId);
-    error ErrorBundleManagerBundleUnknown(NftId bundleNftId);
-    error ErrorBundleManagerBundleNotRegistered(NftId bundleNftId);
-
-    mapping(NftId bundleNftId => LibNftIdSet.Set policies) internal _activePolicies;
-
-    /// @dev links a policy with its bundle
-    // to link a policy it MUST NOT yet have been activated
-    // the bundle MUST be unlocked (active) for linking (underwriting) and registered with this instance
-    function linkPolicy(NftId policyNftId) external restricted() {
-        NftId bundleNftId = _instance.getInstanceReader().getPolicyInfo(policyNftId).bundleNftId;
-        // decision will likely depend on the decision what to check here and what in the service
-        NftId poolNftId = _instance.getInstanceReader().getBundleInfo(bundleNftId).poolNftId;
-
-        // ensure bundle is unlocked (in active set) and registered with this instance
-        if (!_isActive(poolNftId, bundleNftId)) {
-            revert ErrorBundleManagerErrorBundleLocked(bundleNftId, policyNftId);
-        }
-
-        LibNftIdSet.add(_activePolicies[bundleNftId], policyNftId);
-        emit LogBundleManagerPolicyLinked(bundleNftId, policyNftId);
-    }
-
-
-    /// @dev unlinks a policy from its bundle
-    // to unlink a policy it must closable, ie. meet one of the following criterias
-    // - the policy MUST be past its expiry period and it MUST NOT have any open claims
-    // - the policy's payoutAmount MUST be equal to its sumInsuredAmount and MUST NOT have any open claims
-    function unlinkPolicy(NftId policyNftId) external restricted() {
-        IPolicy.PolicyInfo memory policyInfo = _instance.getInstanceReader().getPolicyInfo(policyNftId);
-
-        NftId bundleNftId = policyInfo.bundleNftId;
-        // decision will likely depend on the decision what to check here and what in the service
-        NftId poolNftId = _instance.getInstanceReader().getBundleInfo(bundleNftId).poolNftId;
-
-        // ensure bundle is registered with this instance
-        if (!_contains(poolNftId, bundleNftId)) {
-            revert ErrorBundleManagerBundleUnknown(bundleNftId);
-        }
-
-        LibNftIdSet.remove(_activePolicies[bundleNftId], policyNftId);
-        emit LogBundleManagerPolicyUnlinked(policyInfo.bundleNftId, policyNftId);
-    }
-
-
-    /// @dev add a new bundle to a riskpool registerd with this instance
-    // the corresponding pool is fetched via instance reader
-    function add(NftId bundleNftId) external restricted() {
-        NftId poolNftId = _instance.getInstanceReader().getBundleInfo(bundleNftId).poolNftId;
-
-        // ensure pool is registered with instance
-        if(poolNftId.eqz()) {
-            revert ErrorBundleManagerBundleNotRegistered(bundleNftId);
-        }
-
-        _add(poolNftId, bundleNftId);
-        emit LogBundleManagerBundleAdded(poolNftId, bundleNftId);
-    }
-
-    /// @dev unlocked (active) bundles are available to underwrite new policies
-    function unlock(NftId bundleNftId) external restricted() {
-        NftId poolNftId = _instance.getInstanceReader().getBundleInfo(bundleNftId).poolNftId;
-        _activate(poolNftId, bundleNftId);
-        emit LogBundleManagerBundleUnlocked(poolNftId, bundleNftId);
-    }
-
-    /// @dev locked (deactivated) bundles may not underwrite any new policies
-    function lock(NftId bundleNftId) external restricted() {
-        NftId poolNftId = _instance.getInstanceReader().getBundleInfo(bundleNftId).poolNftId;
-        _deactivate(poolNftId, bundleNftId);
-        emit LogBundleManagerBundleLocked(poolNftId, bundleNftId);
-    }
-
-    function bundles(NftId poolNftId) external view returns(uint256) {
-        return _objects(poolNftId);
-    }
-
-    function getBundleNftId(NftId poolNftId, uint256 idx) external view returns(NftId bundleNftId) {
-        return _getObject(poolNftId, idx);
-    }
-
-    function activeBundles(NftId poolNftId) external view returns(uint256) {
-        return _activeObjs(poolNftId);
-    }
-
-    function getActiveBundleNftId(NftId poolNftId, uint256 idx) external view returns(NftId bundleNftId) {
-        return _getActiveObject(poolNftId, idx);
-    }
-
-    function activePolicies(NftId bundleNftId) external view returns(uint256) {
-        return LibNftIdSet.size(_activePolicies[bundleNftId]);
-    }
-
-    function getActivePolicy(NftId bundleNftId, uint256 idx) external view returns(NftId policyNftId) {
-        return LibNftIdSet.getElementAt(_activePolicies[bundleNftId], idx);
-    }
-}

package/contracts/instance/InstanceAccessManager.sol

@@ -1,297 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {AccessManager} from "@openzeppelin/contracts/access/manager/AccessManager.sol";
-import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
-import {EnumerableSet} from "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
-import {ShortString, ShortStrings} from "@openzeppelin/contracts/utils/ShortStrings.sol";
-
-import {RoleId, RoleIdLib } from "../types/RoleId.sol";
-import {TimestampLib} from "../types/Timestamp.sol";
-import {IAccess} from "./module/IAccess.sol";
-
-contract InstanceAccessManager is
-    AccessManagedUpgradeable
-{
-    using RoleIdLib for RoleId;
-
-    string public constant ADMIN_ROLE_NAME = "AdminRole";
-    string public constant PUBLIC_ROLE_NAME = "PublicRole";
-
-    uint64 public constant CUSTOM_ROLE_ID_MIN = 10000;
-    uint32 public constant EXECUTION_DELAY = 0;
-
-    // role specific state
-    mapping(RoleId roleId => IAccess.RoleInfo info) internal _role;
-    mapping(RoleId roleId => EnumerableSet.AddressSet roleMembers) internal _roleMembers; 
-    mapping(ShortString name => RoleId roleId) internal _roleForName;
-    RoleId [] internal _roles;
-
-    // target specific state
-    mapping(address target => IAccess.TargetInfo info) internal _target;
-    mapping(ShortString name => address target) internal _targetForName;
-    address [] internal _targets;
-
-    AccessManager internal _accessManager;
-
-    function initialize(address initialAdmin) external initializer
-    {
-        // if size of the contract gets too large, this can be externalized which will reduce the contract size considerably
-        _accessManager = new AccessManager(address(this));
-        // this service required admin rights to access manager to be able to grant/revoke roles
-        _accessManager.grantRole(_accessManager.ADMIN_ROLE(), initialAdmin, 0);
-
-        __AccessManaged_init(address(_accessManager));
-
-        _createRole(RoleIdLib.toRoleId(_accessManager.ADMIN_ROLE()), ADMIN_ROLE_NAME, false, false);
-        _createRole(RoleIdLib.toRoleId(_accessManager.PUBLIC_ROLE()), PUBLIC_ROLE_NAME, false, false);
-    }
-
-    //--- Role ------------------------------------------------------//
-    function createGifRole(RoleId roleId, string memory name) external restricted() {
-        _createRole(roleId, name, false, true);
-    }
-
-    function createRole(RoleId roleId, string memory name) external restricted() {
-        _createRole(roleId, name, true, true);
-    }
-
-    function setRoleLocked(RoleId roleId, bool locked) external restricted() {
-        if (!roleExists(roleId)) {
-            revert IAccess.ErrorIAccessRoleIdInvalid(roleId);
-        }
-
-        _role[roleId].isLocked = locked;
-        _role[roleId].updatedAt = TimestampLib.blockTimestamp();
-    }
-
-    function roleExists(RoleId roleId) public view returns (bool exists) {
-        return _role[roleId].createdAt.gtz();
-    }
-
-    function grantRole(RoleId roleId, address member) external restricted() returns (bool granted) {
-        if (!roleExists(roleId)) {
-            revert IAccess.ErrorIAccessRoleIdInvalid(roleId);
-        }
-
-        if (_role[roleId].isLocked) {
-            revert IAccess.ErrorIAccessRoleIdNotActive(roleId);
-        }
-
-        if (!EnumerableSet.contains(_roleMembers[roleId], member)) {
-            _accessManager.grantRole(roleId.toInt(), member, EXECUTION_DELAY);
-            EnumerableSet.add(_roleMembers[roleId], member);
-            return true;
-        }
-
-        return false;
-    }
-
-    function revokeRole(RoleId roleId, address member) external restricted() returns (bool revoked) {
-        if (!roleExists(roleId)) {
-            revert IAccess.ErrorIAccessRevokeNonexstentRole(roleId);
-        }
-
-        if (EnumerableSet.contains(_roleMembers[roleId], member)) {
-            _accessManager.revokeRole(roleId.toInt(), member);
-            EnumerableSet.remove(_roleMembers[roleId], member);
-            return true;
-        }
-
-        return false;
-    }
-
-    /// @dev not restricted function by intention
-    /// the restriction to role members is already enforced by the call to the access manger
-    function renounceRole(RoleId roleId) external returns (bool revoked) {
-        address member = msg.sender;
-
-        if (!roleExists(roleId)) {
-            revert IAccess.ErrorIAccessRenounceNonexstentRole(roleId);
-        }
-
-        if (EnumerableSet.contains(_roleMembers[roleId], member)) {
-            // cannot use accessManger.renounce as it directly checks against msg.sender
-            _accessManager.revokeRole(roleId.toInt(), member);
-            EnumerableSet.remove(_roleMembers[roleId], member);
-            return true;
-        }
-
-        return false;
-    }
-
-    function roles() external view returns (uint256 numberOfRoles) {
-        return _roles.length;
-    }
-
-    function getRoleId(uint256 idx) external view returns (RoleId roleId) {
-        return _roles[idx];
-    }
-
-    function getRoleIdForName(string memory name) external view returns (RoleId roleId) {
-        return _roleForName[ShortStrings.toShortString(name)];
-    }
-
-    function getRole(RoleId roleId) external view returns (IAccess.RoleInfo memory role) {
-        return _role[roleId];
-    }
-
-    function hasRole(RoleId roleId, address account) external view returns (bool accountHasRole) {
-        (accountHasRole, ) = _accessManager.hasRole(roleId.toInt(), account);
-    }
-
-    function roleMembers(RoleId roleId) external view returns (uint256 numberOfMembers) {
-        return EnumerableSet.length(_roleMembers[roleId]);
-    }
-
-    function getRoleMember(RoleId roleId, uint256 idx) external view returns (address roleMember) {
-        return EnumerableSet.at(_roleMembers[roleId], idx);
-    }
-
-    //--- Target ------------------------------------------------------//
-    function createGifTarget(address target, string memory name) external restricted() {
-        _createTarget(target, name, false, true);
-    }
-
-    function createTarget(address target, string memory name) external restricted() {
-        _createTarget(target, name, true, true);
-    }
-
-    function setTargetLocked(string memory targetName, bool locked) external restricted() {
-        address target = _targetForName[ShortStrings.toShortString(targetName)];
-        
-        if (target == address(0)) {
-            revert IAccess.ErrorIAccessTargetDoesNotExist(ShortStrings.toShortString(targetName));
-        }
-
-        _target[target].isLocked = locked;
-        _accessManager.setTargetClosed(target, locked);
-    }
-
-    function targetExists(address target) public view returns (bool exists) {
-        return _target[target].createdAt.gtz();
-    }
-
-    //--- internal view/pure functions --------------------------------------//
-
-    function _createRole(RoleId roleId, string memory name, bool isCustom, bool validateParameters) internal {
-        if (validateParameters) {
-            _validateRoleParameters(roleId, name, isCustom);
-        }
-
-        IAccess.RoleInfo memory role = IAccess.RoleInfo(
-            ShortStrings.toShortString(name), 
-            isCustom,
-            false, // role un-locked,
-            TimestampLib.blockTimestamp(),
-            TimestampLib.blockTimestamp());
-
-        _role[roleId] = role;
-        _roleForName[role.name] = roleId;
-        _roles.push(roleId);
-    }
-
-    function _validateRoleParameters(
-        RoleId roleId, 
-        string memory name, 
-        bool isCustom
-    )
-        internal
-        view 
-        returns (IAccess.RoleInfo memory existingRole)
-    {
-        // check role id
-        uint64 roleIdInt = RoleId.unwrap(roleId);
-        if(roleIdInt == _accessManager.ADMIN_ROLE() || roleIdInt == _accessManager.PUBLIC_ROLE()) {
-            revert IAccess.ErrorIAccessRoleIdInvalid(roleId); 
-        }
-
-        // prevent changing isCustom for existing roles
-        existingRole = _role[roleId];
-
-        if (existingRole.createdAt.gtz() && isCustom != existingRole.isCustom) {
-            revert IAccess.ErrorIAccessRoleIsCustomIsImmutable(roleId, isCustom, existingRole.isCustom); 
-        }
-
-        if (isCustom && roleIdInt < CUSTOM_ROLE_ID_MIN) {
-            revert IAccess.ErrorIAccessRoleIdTooSmall(roleId); 
-        } else if (!isCustom && roleIdInt >= CUSTOM_ROLE_ID_MIN) {
-            revert IAccess.ErrorIAccessRoleIdTooBig(roleId); 
-        }
-
-        // role name checks
-        ShortString nameShort = ShortStrings.toShortString(name);
-        if (ShortStrings.byteLength(nameShort) == 0) {
-            revert IAccess.ErrorIAccessRoleNameEmpty(roleId);
-        }
-
-        if (_roleForName[nameShort] != RoleIdLib.zero() && _roleForName[nameShort] != roleId) {
-            revert IAccess.ErrorIAccessRoleNameNotUnique(_roleForName[nameShort], nameShort);
-        }
-    }
-
-    function _createTarget(address target, string memory name, bool isCustom, bool validateParameters) internal {
-        if (validateParameters) {
-            _validateTargetParameters(target, name, isCustom);
-        }
-
-        if (_target[target].createdAt.gtz()) {
-            revert IAccess.ErrorIAccessTargetExists(target, _target[target].name);
-        }
-        if (_targetForName[ShortStrings.toShortString(name)] != address(0)) {
-            revert IAccess.ErrorIAccessTargetNameExists(target, _targetForName[ShortStrings.toShortString(name)], ShortStrings.toShortString(name));
-        }
-
-        IAccess.TargetInfo memory info = IAccess.TargetInfo(
-            ShortStrings.toShortString(name), 
-            isCustom,
-            _accessManager.isTargetClosed(target), // sync with state in access manager
-            TimestampLib.blockTimestamp(),
-            TimestampLib.blockTimestamp());
-
-        _target[target] = info;
-        _targetForName[info.name] = target;
-        _targets.push(target);
-    }
-
-    function _validateTargetParameters(address target, string memory name, bool isCustom) internal view {
-        // TODO: implement
-    }
-
-    function setTargetFunctionRole(
-        string memory targetName,
-        bytes4[] calldata selectors,
-        RoleId roleId
-    ) public virtual restricted() {
-        address target = _targetForName[ShortStrings.toShortString(targetName)];
-        
-        if (target == address(0)) {
-            revert IAccess.ErrorIAccessTargetDoesNotExist(ShortStrings.toShortString(targetName));
-        }
-        if (! roleExists(roleId)) {
-            revert IAccess.ErrorIAccessRoleIdInvalid(roleId);
-        }
-        uint64 roleIdInt = RoleId.unwrap(roleId);
-        _accessManager.setTargetFunctionRole(target, selectors, roleIdInt);
-    }
-
-    function setTargetClosed(string memory targetName, bool closed) public restricted() {
-        address target = _targetForName[ShortStrings.toShortString(targetName)];
-        if (target == address(0)) {
-            revert IAccess.ErrorIAccessTargetDoesNotExist(ShortStrings.toShortString(targetName));
-        }
-        _accessManager.setTargetClosed(target, closed);
-    }
-
-    function isTargetLocked(address target) public view returns (bool locked) {
-        return _accessManager.isTargetClosed(target);
-    }
-
-    function canCall(
-        address caller,
-        address target,
-        bytes4 selector
-    ) public view virtual returns (bool immediate, uint32 delay) {
-        return _accessManager.canCall(caller, target, selector);
-    }
-}

package/contracts/instance/ObjectManager.sol

@@ -1,84 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {Cloneable} from "./Cloneable.sol";
-
-import {IInstance} from "./IInstance.sol";
-import {INSTANCE} from "../types/ObjectType.sol";
-import {InstanceReader} from "./InstanceReader.sol";
-import {IRegistry} from "../registry/IRegistry.sol";
-import {LibNftIdSet} from "../types/NftIdSet.sol";
-import {NftId} from "../types/NftId.sol";
-
-contract ObjectManager is
-    Cloneable
-{
-
-    event LogObjectManagerInitialized(address instance);
-
-    error ErrorObjectManagerNftIdInvalid(NftId instanceNftId);
-    error ErrorObjectManagerAlreadyAdded(NftId componentNftId, NftId objectNftId);
-
-    mapping(NftId compnentNftId => LibNftIdSet.Set objects) internal _activeObjects;
-    mapping(NftId compnentNftId => LibNftIdSet.Set objects) internal _allObjects;
-    IInstance internal _instance; // store instance address -> more flexible, instance may not be registered during ObjectManager initialization
-
-    /// @dev call to initialize MUST be made in the same transaction as cloning of the contract
-    function initialize(
-        address authority,
-        address registry,
-        address instance
-    )
-        external 
-    {
-        initialize(authority, registry);
-
-        _instance = IInstance(instance);
-        
-        emit LogObjectManagerInitialized(instance);
-    }
-
-    function getInstance() external view returns (IInstance) {
-        return _instance;
-    }
-
-    function _add(NftId componentNftId, NftId objectNftId) internal {
-        LibNftIdSet.Set storage allSet = _allObjects[componentNftId];
-        LibNftIdSet.Set storage activeSet = _activeObjects[componentNftId];
-
-        LibNftIdSet.add(allSet, objectNftId);
-        LibNftIdSet.add(activeSet, objectNftId);
-    }
-
-    function _activate(NftId componentNftId, NftId objectNftId) internal {
-        LibNftIdSet.add(_activeObjects[componentNftId], objectNftId);
-    }
-
-    function _deactivate(NftId componentNftId, NftId objectNftId) internal {
-        LibNftIdSet.remove(_activeObjects[componentNftId], objectNftId);
-    }
-
-    function _objects(NftId componentNftId) internal view returns (uint256) {
-        return LibNftIdSet.size(_allObjects[componentNftId]);
-    }
-
-    function _contains(NftId componentNftId, NftId objectNftId) internal view returns (bool) {
-        return LibNftIdSet.contains(_allObjects[componentNftId], objectNftId);
-    }
-
-    function _getObject(NftId componentNftId, uint256 idx) internal view returns (NftId) {
-        return LibNftIdSet.getElementAt(_allObjects[componentNftId], idx);
-    }
-
-    function _activeObjs(NftId componentNftId) internal view returns (uint256)  {
-        return LibNftIdSet.size(_activeObjects[componentNftId]);
-    }
-
-    function _isActive(NftId componentNftId, NftId objectNftId) internal view returns (bool) {
-        return LibNftIdSet.contains(_activeObjects[componentNftId], objectNftId);
-    }
-
-    function _getActiveObject(NftId componentNftId, uint256 idx) internal view returns (NftId) {
-        return LibNftIdSet.getElementAt(_activeObjects[componentNftId], idx);
-    }
-}