@etherisc/gif-next 0.0.2-82c6d88-499 → 0.0.2-8311e70-020

package/contracts/instance/RiskSet.sol

@@ -0,0 +1,118 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Key32} from "../type/Key32.sol";
+import {LibNftIdSet} from "../type/NftIdSet.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectSet} from "./base/ObjectSet.sol";
+import {ObjectSetHelperLib} from "./base/ObjectSetHelperLib.sol";
+import {RiskIdLib, RiskId} from "../type/RiskId.sol";
+
+/// @dev RiskSet manages the risks and its active policies per product.
+contract RiskSet is
+    ObjectSet
+{
+
+    event LogRiskSetPolicyLinked(RiskId riskId, NftId policyNftId);
+    event LogRiskSetPolicyUnlinked(RiskId riskId, NftId policyNftId);
+
+    event LogRiskSetRiskAdded(NftId productNftId, RiskId riskId);
+    event LogRiskSetRiskActive(NftId poolNftId,  RiskId riskId);
+    event LogRiskSetRiskPaused(NftId poolNftId,  RiskId riskId);
+    event LogRiskSetRiskArchived(NftId poolNftId,  RiskId riskId);
+
+    error ErrorRiskSetRiskLocked(RiskId riskId, NftId policyNftId); 
+    error ErrorRiskSetRiskUnknown(RiskId riskId);
+    error ErrorRiskSetRiskNotRegistered(RiskId riskId);
+
+    mapping(RiskId riskId => LibNftIdSet.Set policies) internal _activePolicies;
+
+    /// @dev links a policy to its bundle
+    function linkPolicy(NftId productNftId, RiskId riskId, NftId policyNftId) external restricted() {
+
+        // ensure risk is active (in active set) and registered with this instance
+        if (!_isActive(productNftId, riskId.toKey32())) {
+            revert ErrorRiskSetRiskLocked(riskId, policyNftId);
+        }
+
+        LibNftIdSet.add(_activePolicies[riskId], policyNftId);
+        emit LogRiskSetPolicyLinked(riskId, policyNftId);
+    }
+
+    /// @dev Unlinks a policy from its risk.
+    function unlinkPolicy(NftId productNftId, RiskId riskId, NftId policyNftId) external restricted() {
+
+        // ensure risk is registered with this instance
+        if (!_contains(productNftId, riskId.toKey32())) {
+            revert ErrorRiskSetRiskUnknown(riskId);
+        }
+
+        LibNftIdSet.remove(_activePolicies[riskId], policyNftId);
+        emit LogRiskSetPolicyUnlinked(riskId, policyNftId);
+    }
+
+    /// @dev add a new risk to a product registered with this instance
+    // the corresponding product is fetched via instance reader
+    function add(RiskId riskId) external restricted() {
+        NftId productNftId = ObjectSetHelperLib.getProductNftId(_instanceAddress, riskId);
+
+        // ensure product is registered with instance
+        if(productNftId.eqz()) {
+            revert ErrorRiskSetRiskNotRegistered(riskId);
+        }
+
+        _add(productNftId, riskId.toKey32());
+        emit LogRiskSetRiskAdded(productNftId, riskId);
+    }
+
+    /// @dev Applications linked to active risks may be underwritten
+    function activate(RiskId riskId) external restricted() {
+        NftId productNftId = ObjectSetHelperLib.getProductNftId(_instanceAddress, riskId);
+        _activate(productNftId, riskId.toKey32());
+        emit LogRiskSetRiskActive(productNftId, riskId);
+    }
+
+    /// @dev Applications linked to paused/archived risks may not be underwritten
+    function pause(RiskId riskId) external restricted() {
+        NftId productNftId = ObjectSetHelperLib.getProductNftId(_instanceAddress, riskId);
+        _deactivate(productNftId, riskId.toKey32());
+        emit LogRiskSetRiskPaused(productNftId, riskId);
+    }
+
+    function checkRisk(NftId productNftId, RiskId riskId)
+        public
+        view 
+        returns (bool exists, bool active)
+    {
+        Key32 riskKey32 = riskId.toKey32();
+        exists = _contains(productNftId, riskKey32);
+
+        if (exists) {
+            active = _isActive(productNftId, riskKey32);
+        }
+    }
+
+    function risks(NftId productNftId) external view returns(uint256) {
+        return _objects(productNftId);
+    }
+
+    function getRiskId(NftId productNftId, uint256 idx) external view returns(RiskId riskId) {
+        return RiskIdLib.toRiskId(_getObject(productNftId, idx).toKeyId());
+    }
+    
+    function activeRisks(NftId productNftId) external view returns(uint256) {
+        return _activeObjs(productNftId);
+    }
+
+    function getActiveRiskId(NftId productNftId, uint256 idx) external view returns(RiskId riskId) {
+        return RiskIdLib.toRiskId(_getActiveObject(productNftId, idx).toKeyId());
+    }
+
+    function linkedPolicies(RiskId riskId) external view returns(uint256) {
+        return LibNftIdSet.size(_activePolicies[riskId]);
+    }
+
+    function getLinkedPolicyNftId(RiskId riskId, uint256 idx) external view returns(NftId policyNftId) {
+        return LibNftIdSet.getElementAt(_activePolicies[riskId], idx);
+    }
+}

package/contracts/instance/base/ObjectCounter.sol

@@ -11,9 +11,8 @@ contract ObjectCounter {
     // TODO refactor risk id
     // mapping(NftId productNftId => uint64 risks) private _riskCounter;
 
-    uint256 private _requestCounter;
+    uint256 private _requestCounter = 0;
 
-    // TODO introduce RequestId (uint64)
     function _createNextRequestId() internal returns (RequestId requestId) {
         _requestCounter++;
         requestId = RequestIdLib.toRequestId(_requestCounter);

package/contracts/instance/base/ObjectLifecycle.sol

@@ -0,0 +1,113 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol"; 
+
+import {COMPONENT, BUNDLE, POLICY, REQUEST, RISK, CLAIM, PAYOUT, POOL, PREMIUM, PRODUCT, DISTRIBUTION, DISTRIBUTOR, DISTRIBUTOR_TYPE, REFERRAL, FEE} from "../../type/ObjectType.sol";
+import {ACTIVE, PAUSED, ARCHIVED, CLOSED, APPLIED, COLLATERALIZED, REVOKED, SUBMITTED, CONFIRMED, DECLINED, EXPECTED, PAID, FULFILLED, FAILED, CANCELLED} from "../../type/StateId.sol";
+import {Lifecycle} from "../../shared/Lifecycle.sol";
+
+contract ObjectLifecycle is
+    Lifecycle,
+    Initializable
+{
+    function _initializeLifecycle() internal onlyInitializing
+    {
+        _setupLifecycle();
+    }
+
+    function _setupLifecycle()
+        internal
+        override
+    {
+        _setupBundleLifecycle();
+        _setupComponentLifecycle();
+        _setupPolicyLifecycle();
+        _setupPremiumLifecycle();
+        _setupClaimLifecycle();
+        _setupPayoutLifecycle();
+        _setupRiskLifecycle();
+        _setupRequestLifecycle();
+
+        // setup dummy lifecycles to manage with key value store 
+        _setUpPoolLifecycle();
+        _setUpProductLifecycle();
+        _setUpDistributionLifecycle();
+    }
+
+    function _setupComponentLifecycle() private {
+        setInitialState(COMPONENT(), ACTIVE());
+        setStateTransition(COMPONENT(), ACTIVE(), PAUSED());
+        setStateTransition(COMPONENT(), PAUSED(), ACTIVE());
+        setStateTransition(COMPONENT(), PAUSED(), ARCHIVED());
+    }
+
+    function _setupBundleLifecycle() private {
+        setInitialState(BUNDLE(), ACTIVE());
+        setStateTransition(BUNDLE(), ACTIVE(), PAUSED());
+        setStateTransition(BUNDLE(), ACTIVE(), CLOSED());
+        setStateTransition(BUNDLE(), PAUSED(), ACTIVE());
+        setStateTransition(BUNDLE(), PAUSED(), CLOSED());
+    }
+
+    function _setupPolicyLifecycle() private {
+        setInitialState(POLICY(), APPLIED());
+        setStateTransition(POLICY(), APPLIED(), REVOKED());
+        setStateTransition(POLICY(), APPLIED(), DECLINED());
+        setStateTransition(POLICY(), APPLIED(), COLLATERALIZED());
+        setStateTransition(POLICY(), COLLATERALIZED(), CLOSED());
+    }
+
+    function _setupPremiumLifecycle() private {
+        setInitialState(PREMIUM(), EXPECTED());
+        setStateTransition(PREMIUM(), EXPECTED(), PAID());
+    }
+
+    function _setupClaimLifecycle() private {
+        setInitialState(CLAIM(), SUBMITTED());
+        setStateTransition(CLAIM(), SUBMITTED(), REVOKED());
+        setStateTransition(CLAIM(), SUBMITTED(), CONFIRMED());
+        setStateTransition(CLAIM(), SUBMITTED(), DECLINED());
+        setStateTransition(CLAIM(), CONFIRMED(), CLOSED());
+    }
+
+    function _setupPayoutLifecycle() private {
+        setInitialState(PAYOUT(), EXPECTED());
+        setStateTransition(PAYOUT(), EXPECTED(), PAID());
+        setStateTransition(PAYOUT(), EXPECTED(), CANCELLED());
+    }
+
+    function _setupRiskLifecycle() private {
+        setInitialState(RISK(), ACTIVE());
+        setStateTransition(RISK(), ACTIVE(), PAUSED());
+        setStateTransition(RISK(), PAUSED(), ACTIVE());
+        setStateTransition(RISK(), PAUSED(), ARCHIVED());
+    }
+
+    function _setupRequestLifecycle() private {
+        setInitialState(REQUEST(), ACTIVE());
+        setStateTransition(REQUEST(), ACTIVE(), FULFILLED());
+        setStateTransition(REQUEST(), ACTIVE(), FAILED());
+        setStateTransition(REQUEST(), FAILED(), FULFILLED());
+        setStateTransition(REQUEST(), ACTIVE(), CANCELLED());
+    }
+
+    // dummy lifecycle only
+    function _setUpPoolLifecycle() private {
+        setInitialState(POOL(), ACTIVE());
+    }
+
+    // dummy lifecycle only
+    function _setUpProductLifecycle() private {
+        setInitialState(PRODUCT(), ACTIVE());
+        setInitialState(FEE(), ACTIVE());
+    }
+
+    // dummy lifecycles only
+    function _setUpDistributionLifecycle() private {
+        setInitialState(DISTRIBUTION(), ACTIVE());
+        setInitialState(DISTRIBUTOR(), ACTIVE());
+        setInitialState(DISTRIBUTOR_TYPE(), ACTIVE());
+        setInitialState(REFERRAL(), ACTIVE());
+    }
+}

package/contracts/instance/base/ObjectSet.sol

@@ -0,0 +1,77 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Cloneable} from "./Cloneable.sol";
+
+import {LibKey32Set} from "../../type/Key32Set.sol";
+import {NftId} from "../../type/NftId.sol";
+import {Key32} from "../../type/Key32.sol";
+
+contract ObjectSet is
+    Cloneable
+{
+    using LibKey32Set for LibKey32Set.Set;
+
+    event LogObjectSetInitialized(address instance);
+
+    error ErrorObjectSetNftIdInvalid(NftId instanceNftId);
+
+    mapping(NftId compnentNftId => LibKey32Set.Set objects) internal _activeObjects;
+    mapping(NftId compnentNftId => LibKey32Set.Set objects) internal _allObjects;
+    address internal _instanceAddress;
+
+    /// @dev This initializer needs to be called from the instance itself.
+    function initialize(address authority, address registry) 
+        external
+        initializer()
+    {
+        _instanceAddress = msg.sender;
+        __Cloneable_init(authority, registry);
+        
+        emit LogObjectSetInitialized(address(_instanceAddress));
+    }
+
+    function getInstanceAddress() external view returns (address) {
+        return _instanceAddress;
+    }
+
+    function _add(NftId componentNftId, Key32 key) internal {
+        LibKey32Set.Set storage allSet = _allObjects[componentNftId];
+        LibKey32Set.Set storage activeSet = _activeObjects[componentNftId];
+
+        allSet.add(key);
+        activeSet.add(key);
+    }
+
+    function _activate(NftId componentNftId, Key32 key) internal {
+        _activeObjects[componentNftId].add(key);
+    }
+
+    function _deactivate(NftId componentNftId, Key32 key) internal {
+        _activeObjects[componentNftId].remove(key);
+    }
+
+    function _objects(NftId componentNftId) internal view returns (uint256) {
+        return _allObjects[componentNftId].size();
+    }
+
+    function _contains(NftId componentNftId, Key32 key) internal view returns (bool) {
+        return _allObjects[componentNftId].contains(key);
+    }
+
+    function _getObject(NftId componentNftId, uint256 idx) internal view returns (Key32) {
+        return _allObjects[componentNftId].getElementAt(idx);
+    }
+
+    function _activeObjs(NftId componentNftId) internal view returns (uint256)  {
+        return _activeObjects[componentNftId].size();
+    }
+
+    function _isActive(NftId componentNftId, Key32 key) internal view returns (bool) {
+        return _activeObjects[componentNftId].contains(key);
+    }
+
+    function _getActiveObject(NftId componentNftId, uint256 idx) internal view returns (Key32) {
+        return _activeObjects[componentNftId].getElementAt(idx);
+    }
+}

package/contracts/instance/base/ObjectSetHelperLib.sol

@@ -0,0 +1,30 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IBundle} from "../module/IBundle.sol";
+import {IInstance} from "../IInstance.sol";
+import {IRisk} from "../module/IRisk.sol";
+import {NftId} from "../../type/NftId.sol";
+import {RiskId} from "../../type/RiskId.sol";
+
+
+library ObjectSetHelperLib {
+
+    function getRiskInfo(address instanceAddress, RiskId riskId) public view returns (IRisk.RiskInfo memory) {
+
+        return IInstance(instanceAddress).getInstanceReader().getRiskInfo(riskId);
+    }
+
+    function getProductNftId(address instanceAddress, RiskId riskId) public view returns (NftId) {
+        return getRiskInfo(instanceAddress, riskId).productNftId;
+    }
+
+    function getBundleInfo(address instanceAddress, NftId bundleNftId) public view returns (IBundle.BundleInfo memory) {
+        return IInstance(instanceAddress).getInstanceReader().getBundleInfo(bundleNftId);
+    }
+
+    function getPoolNftId(address instanceAddress, NftId bundleNftId) public view returns (NftId) {
+        return getBundleInfo(instanceAddress, bundleNftId).poolNftId;
+    }
+
+}

package/contracts/instance/module/IBundle.sol

@@ -13,7 +13,7 @@ interface IBundle {
         NftId poolNftId;
         Fee fee; // bundle fee on net premium amounts
         bytes filter; // required conditions for applications to be considered for collateralization by this bundle
-        Seconds lifetime; // lifetime of bundle after creation
+        Timestamp activatedAt; 
         Timestamp expiredAt; // no new policies starting with this timestamp
         Timestamp closedAt; // no open policies, locked amount = 0
     }

package/contracts/instance/module/IComponents.sol

@@ -6,7 +6,6 @@ import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IER
 import {Amount} from "../../type/Amount.sol";
 import {Fee} from "../../type/Fee.sol";
 import {NftId} from "../../type/NftId.sol";
-import {RoleId} from "../../type/RoleId.sol";
 import {TokenHandler} from "../../shared/TokenHandler.sol";
 import {UFixed} from "../../type/UFixed.sol";
 
@@ -14,17 +13,23 @@ interface IComponents {
 
     struct ComponentInfo {
         string name; // component name (needs to be unique per instance)
-        NftId productNftId;
         IERC20Metadata token;
         TokenHandler tokenHandler;
-        address wallet;
         bytes data; // will hold component type specific additional info (eg encoded pool info)
     }
 
-
     struct ProductInfo {
-        NftId distributionNftId;
-        NftId poolNftId;
+        bool isProcessingFundedClaims; // custom logic to react to pool events for funded claims
+        bool isInterceptingPolicyTransfers; // custom logic for policy nft transfers
+        bool hasDistribution; // flag to indicate if distribution is enabled
+        uint8 expectedNumberOfOracles; // expected number of oracles
+        uint8 numberOfOracles; // actual number of oracles
+        NftId poolNftId; // mandatory
+        NftId distributionNftId; // 0..1 (optional)
+        NftId [] oracleNftId; // 0..n (optional)
+    }
+
+    struct FeeInfo {
         Fee productFee; // product fee on net premium
         Fee processingFee; // product fee on payout amounts        
         Fee distributionFee; // distribution fee for sales that do not include commissions
@@ -34,19 +39,13 @@ interface IComponents {
         Fee performanceFee; // pool fee on profits from capital investors
     }
 
-
     struct PoolInfo {
-        NftId productNftId; // the nft of the product this pool is linked to
-        RoleId bundleOwnerRole; // the required role for bundle owners
-        // TODO maxCapitalAmount -> maxBalanceAmount
-        Amount maxCapitalAmount; // max capital amount allowed for pool
-        bool isInterceptingBundleTransfers; // intercepts nft transfers for bundles
+        Amount maxBalanceAmount; // max balance amount allowed for pool
+        bool isInterceptingBundleTransfers; // custom logic for bundle nft transfers
+        bool isProcessingConfirmedClaims; // custom logic for claims confirmation
         bool isExternallyManaged; // funding bundles is restricted to book keeping, actual funds may be provided as needed to support payouts
         bool isVerifyingApplications; // underwriting requires the pool component checks/confirms the applications 
         UFixed collateralizationLevel; // factor to calculate collateral for sum insurance (default 100%)
         UFixed retentionLevel; // amount of collateral held in pool (default 100%)
-        Fee poolFee; // pool fee on net premium
-        Fee stakingFee; // pool fee on staked capital from investor
-        Fee performanceFee; // pool fee on profits from capital investors
     }
 }

package/contracts/instance/module/IDistribution.sol

@@ -25,7 +25,6 @@ interface IDistribution {
         DistributorType distributorType;
         bool active;
         bytes data;
-        Amount commissionAmount;
         uint32 numPoliciesSold;
     }
 

package/contracts/instance/module/IPolicy.sol

@@ -11,7 +11,7 @@ import {Timestamp} from "../../type/Timestamp.sol";
 
 interface IPolicy {
 
-    struct Premium {
+    struct PremiumInfo {
         // premium splitting per target wallet
         Amount productFeeAmount;
         Amount distributionFeeAndCommissionAmount;
@@ -19,40 +19,40 @@ interface IPolicy {
 
         // detailed positions
         // this is the net premium calculated by the product 
-        uint256 netPremiumAmount;
+        Amount netPremiumAmount;
         // fullPremium = netPremium + all fixed amounts + all variable amounts (excl commission and minDistribtuionOwnerFee variable part)
-        uint256 fullPremiumAmount;
-        // premium = fullPremium - discount
-        uint256 premiumAmount;
-        uint256 productFeeFixAmount;
-        uint256 poolFeeFixAmount;
-        uint256 bundleFeeFixAmount;
-        uint256 distributionFeeFixAmount;
-        uint256 productFeeVarAmount;
-        uint256 poolFeeVarAmount;
-        uint256 bundleFeeVarAmount;
-        uint256 distributionFeeVarAmount;
-        uint256 distributionOwnerFeeFixAmount;
+        Amount fullPremiumAmount;
+        // effective premium = fullPremium - discount 
+        Amount premiumAmount;
+        Amount productFeeFixAmount;
+        Amount poolFeeFixAmount;
+        Amount bundleFeeFixAmount;
+        Amount distributionFeeFixAmount;
+        Amount productFeeVarAmount;
+        Amount poolFeeVarAmount;
+        Amount bundleFeeVarAmount;
+        Amount distributionFeeVarAmount;
+        Amount distributionOwnerFeeFixAmount;
         // this is the remaining amount when the commission and discount are subtracted from the distribution fee variable part (must be at least the minDistributionOwnerFee)
-        uint256 distributionOwnerFeeVarAmount;
+        Amount distributionOwnerFeeVarAmount;
         // this value is based on distributor type referenced in the referral 
-        uint256 commissionAmount;
+        Amount commissionAmount;
         // this is based on referral used
-        uint256 discountAmount;
+        Amount discountAmount;
     }
 
     /// @dev policy data for the full policy lifecycle
     struct PolicyInfo {
+        // application data, no changes after applying for a policy
         NftId productNftId;
         NftId bundleNftId;
         ReferralId referralId;
         RiskId riskId;
         Amount sumInsuredAmount;
         Amount premiumAmount; // expected premium at application time
-        Amount premiumPaidAmount; // actual paid premium 
         Seconds lifetime;
-        // policy application data, no changes after applying for a policy
         bytes applicationData;
+        // policy data that may change during the lifecycle
         bytes processData;
         uint16 claimsCount;
         uint16 openClaimsCount;
@@ -67,10 +67,10 @@ interface IPolicy {
     struct ClaimInfo {
         Amount claimAmount;
         Amount paidAmount;
-        uint8 payoutsCount;
-        uint8 openPayoutsCount;
-        bytes submissionData; // claim submission data, no changes after submitting the claim
-        bytes processData; // data that may include information supporting confirm or decline
+        uint24 payoutsCount;
+        uint24 openPayoutsCount;
+        bytes submissionData; // use case specific claim submission data, no changes after submitting the claim
+        bytes processData; // use case specific data that may include information supporting confirm or decline
         Timestamp closedAt; // payment of confirmed claim amount (or declinedAt)
     }
 
@@ -78,7 +78,8 @@ interface IPolicy {
     struct PayoutInfo {
         ClaimId claimId;
         Amount amount;
-        bytes data;
-        Timestamp paidAt; // payoment of confirmed claim amount (or declinedAt)
+        address beneficiary; // for address(0) beneficiary is policy nft owner
+        bytes data; // use case specific supporting data
+        Timestamp paidAt; // timestamp for actual payout
     }
 }

package/contracts/instance/module/IRisk.sol

@@ -2,10 +2,13 @@
 pragma solidity ^0.8.20;
 
 import {NftId} from "../../type/NftId.sol";
+import {Timestamp} from "../../type/Timestamp.sol";
 
 interface IRisk {
+
     struct RiskInfo {
         NftId productNftId;
+        Timestamp createdAt;
         bytes data;
     }
 }

package/contracts/mock/Dip.sol

@@ -1,7 +1,7 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.20;
 
-import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
+import {ERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
 
 contract Dip is ERC20 {
 

package/contracts/oracle/BasicOracle.sol

@@ -0,0 +1,47 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IAuthorization} from "../../contracts/authorization/IAuthorization.sol";
+import {NftId} from "../../contracts/type/NftId.sol";
+import {Oracle} from "../../contracts/oracle/Oracle.sol";
+import {RequestId} from "../../contracts/type/RequestId.sol";
+
+contract BasicOracle is
+    Oracle
+{
+
+    /// Function to provide reponse data releated to request id.
+    function respond(
+        RequestId requestId,
+        bytes memory responseData
+    )
+        external
+        virtual
+        restricted()
+    {
+        _respond(requestId, responseData);
+    }
+
+    function _initializeBasicOracle(
+        address registry,
+        NftId instanceNftId,
+        IAuthorization authorization,
+        address initialOwner,
+        string memory name,
+        address token
+    )
+        internal
+        virtual
+        onlyInitializing()
+    {
+
+        _initializeOracle(
+            registry,
+            instanceNftId,
+            authorization,
+            initialOwner,
+            name,
+            token,
+            "");
+    }
+}

package/contracts/oracle/BasicOracleAuthorization.sol

@@ -0,0 +1,46 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Authorization} from "../authorization/Authorization.sol";
+import {BasicOracle} from "./BasicOracle.sol"; 
+import {ORACLE} from "../type/ObjectType.sol";
+import {IAccess} from "../authorization/IAccess.sol";
+import {IOracle} from "./IOracle.sol"; 
+import {PUBLIC_ROLE} from "../../contracts/type/RoleId.sol";
+import {RoleId} from "../type/RoleId.sol";
+
+
+contract BasicOracleAuthorization
+     is Authorization
+{
+
+     constructor(string memory componentName)
+          Authorization(componentName)
+     {}
+
+     function _setupTargets()
+          internal
+          virtual override
+     {
+          // basic component target
+          _addComponentTargetWithRole(ORACLE()); 
+     }
+
+
+     function _setupTargetAuthorizations()
+          internal
+          virtual override
+     {
+          IAccess.FunctionInfo[] storage functions;
+
+          // authorize public role (open access to any account, only allows to lock target)
+          functions = _authorizeForTarget(getTargetName(), getServiceRole(ORACLE()));
+          _authorize(functions, IOracle.request.selector, "request");
+          _authorize(functions, IOracle.cancel.selector, "cancel");
+
+          // authorize public role (open access to any account, only allows to lock target)
+          functions = _authorizeForTarget(getTargetName(), PUBLIC_ROLE());
+          _authorize(functions, BasicOracle.respond.selector, "respond");
+     }
+}
+

package/contracts/oracle/IOracle.sol

@@ -2,6 +2,7 @@
 pragma solidity ^0.8.20;
 
 import {NftId} from "../type/NftId.sol";
+import {RequestId} from "../type/RequestId.sol";
 import {Timestamp} from "../type/Timestamp.sol";
 
 
@@ -17,4 +18,19 @@ interface IOracle {
         Timestamp expiredAt; // expiry timestamp
         bool isCancelled;
     }
+
+
+    /// @dev Callback function for oracle service to notify this oracle component to retreive some oracle data.
+    function request(
+        RequestId requestId,
+        NftId requesterId,
+        bytes calldata requestData,
+        Timestamp expiryAt
+    ) external;
+
+
+    /// @dev Callback function for oracle service to notify this oracle component that the specified oracle request has ben cancelled by the requestor.
+    function cancel(
+        RequestId requestId
+    ) external;
 }