@etherisc/gif-next 0.0.2-7f39e38-904 → 0.0.2-7fbee0d-269

package/contracts/instance/ProductStore.sol

@@ -0,0 +1,290 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+
+import {IComponents} from "./module/IComponents.sol";
+import {IInstance} from "./IInstance.sol";
+import {IPolicy} from "./module/IPolicy.sol";
+import {IRisk} from "./module/IRisk.sol";
+
+import {BalanceStore} from "./base/BalanceStore.sol";
+import {BaseStore} from "./BaseStore.sol";
+import {Blocknumber} from "../type/Blocknumber.sol";
+import {ClaimId} from "../type/ClaimId.sol";
+import {Key32} from "../type/Key32.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectCounter} from "./base/ObjectCounter.sol";
+import {ObjectLifecycle} from "./base/ObjectLifecycle.sol";
+import {ObjectType, FEE, POLICY, PREMIUM, PRODUCT} from "../type/ObjectType.sol";
+import {PayoutId} from "../type/PayoutId.sol";
+import {RiskId} from "../type/RiskId.sol";
+import {StateId, KEEP_STATE} from "../type/StateId.sol";
+
+
+contract ProductStore is
+    AccessManagedUpgradeable, 
+    BalanceStore,
+    BaseStore,
+    ObjectCounter,
+    ObjectLifecycle
+{
+    event LogProductStoreProductInfoCreated(NftId productNftId, StateId state, address createdBy, address txOrigin);
+    event LogProductStoreProductInfoUpdated(NftId productNftId, StateId oldState, StateId newState, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
+    event LogProductStoreFeeInfoCreated(NftId productNftId, StateId state, address createdBy, address txOrigin);
+    event LogProductStoreFeeInfoUpdated(NftId productNftId, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
+    event LogProductStoreRiskInfoCreated(RiskId riskId, StateId state, address createdBy, address txOrigin);
+    event LogProductStoreRiskInfoUpdated(RiskId riskId, StateId oldState, StateId newState, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
+    event LogProductStorePolicyInfoCreated(NftId policyNftId, StateId state, address createdBy, address txOrigin);
+    event LogProductStorePolicyInfoUpdated(NftId policyNftId, StateId oldState, StateId newState, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
+    event LogProductStorePremiumInfoCreated(NftId policyNftId, StateId state, address createdBy, address txOrigin);
+    event LogProductStorePremiumInfoUpdated(NftId policyNftId, StateId oldState, StateId newState, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
+    event LogProductStoreClaimInfoCreated(NftId policyNftId, ClaimId claimId, StateId state, address createdBy, address txOrigin);
+    event LogProductStoreClaimInfoUpdated(NftId policyNftId, ClaimId claimId, StateId oldState, StateId newState, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
+    event LogProductStorePayoutInfoCreated(NftId policyNftId, PayoutId payoutId, StateId state, address createdBy, address txOrigin);
+    event LogProductStorePayoutInfoUpdated(NftId policyNftId, PayoutId payoutId, StateId oldState, StateId newState, address updatedBy, address txOrigin, Blocknumber lastUpdatedIn);
+
+    mapping(Key32 key32 => IComponents.ProductInfo) private _products;
+    mapping(Key32 key32 => IComponents.FeeInfo) private _fees;
+    mapping(Key32 key32 => IRisk.RiskInfo) private _risks;
+    mapping(Key32 key32 => IPolicy.PolicyInfo) private _policies;
+    mapping(Key32 key32 => IPolicy.PremiumInfo) private _premiums;
+    mapping(Key32 key32 => IPolicy.ClaimInfo) private _claims;
+    mapping(Key32 key32 => IPolicy.PayoutInfo) private _payouts;
+
+
+    /// @dev This initializer needs to be called from the instance itself.
+    function initialize()
+        public 
+        initializer()
+    {
+        address instance = msg.sender;
+        address authority = IInstance(instance).authority();
+
+        __AccessManaged_init(authority);
+        // double initialization, safe
+        _initializeLifecycle();
+    }
+
+
+    //--- Product -----------------------------------------------------------//
+
+    function createProduct(NftId productNftId, IComponents.ProductInfo memory info) external restricted() {
+        Key32 key = _toNftKey32(productNftId, PRODUCT());
+        _createMetadata(key);
+        _products[key] = info;
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStoreProductInfoCreated(productNftId, getState(key), msg.sender, tx.origin);
+    }
+
+    function updateProduct(NftId productNftId, IComponents.ProductInfo memory info, StateId newState) external restricted() {
+        Key32 key = _toNftKey32(productNftId, PRODUCT());
+        (Blocknumber lastUpdatedIn, StateId oldState) = _updateState(key, newState);
+        _products[key] = info;
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStoreProductInfoUpdated(productNftId, oldState, newState, msg.sender, tx.origin, lastUpdatedIn);
+    }
+
+    function getProductInfo(NftId productNftId) external view returns (IComponents.ProductInfo memory info) {
+        return _products[_toNftKey32(productNftId, PRODUCT())];
+    }
+
+    //--- Fee -----------------------------------------------------------//
+
+    function createFee(NftId productNftId, IComponents.FeeInfo memory info) external restricted() {
+        Key32 key = _toNftKey32(productNftId, FEE());
+        _createMetadata(key);
+        _fees[key] = info;
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStoreFeeInfoCreated(productNftId, getState(key), msg.sender, tx.origin);
+    }
+
+    // Fee only has one state, so no change change possible
+    function updateFee(NftId productNftId, IComponents.FeeInfo memory info) external restricted() {
+        Key32 key = _toNftKey32(productNftId, FEE());
+        (Blocknumber lastUpdatedIn,) = _updateState(key, KEEP_STATE());
+        _fees[key] = info;
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStoreFeeInfoUpdated(productNftId, msg.sender, tx.origin, lastUpdatedIn);
+    }
+
+    function getFeeInfo(NftId productNftId) external view returns (IComponents.FeeInfo memory info) {
+        return _fees[_toNftKey32(productNftId, FEE())];
+    }
+
+    //--- Risk --------------------------------------------------------------//
+    function createRisk(RiskId riskId, IRisk.RiskInfo memory info) external restricted() {
+        Key32 key = riskId.toKey32();
+        _createMetadata(key);
+        _risks[key] = info;
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStoreRiskInfoCreated(riskId, getState(key), msg.sender, tx.origin);
+    }
+
+    function updateRisk(RiskId riskId, IRisk.RiskInfo memory info, StateId newState) external restricted() {
+        Key32 key = riskId.toKey32();
+        (Blocknumber lastUpdatedIn, StateId oldState) = _updateState(key, newState);
+        _risks[key] = info;
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStoreRiskInfoUpdated(riskId, oldState, newState, msg.sender, tx.origin, lastUpdatedIn);
+    }
+
+    function updateRiskState(RiskId riskId, StateId newState) external restricted() {
+        // _updateState(riskId.toKey32(), newState);
+        Key32 key = riskId.toKey32();
+        (Blocknumber lastUpdatedIn, StateId oldState) = _updateState(key, newState);
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStoreRiskInfoUpdated(riskId, oldState, newState, msg.sender, tx.origin, lastUpdatedIn);
+    }
+
+    function getRiskInfo(RiskId riskId) external view returns (IRisk.RiskInfo memory info) {
+        return _risks[riskId.toKey32()];
+    }
+
+    //--- Application (Policy) ----------------------------------------------//
+
+    function createApplication(NftId applicationNftId, IPolicy.PolicyInfo memory policy) external restricted() {
+        _registerBalanceTarget(applicationNftId);
+        Key32 key = _toNftKey32(applicationNftId, POLICY());
+        _createMetadata(key);
+        _policies[key] = policy;
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStorePolicyInfoCreated(applicationNftId, getState(key), msg.sender, tx.origin);
+    }
+
+    function updateApplication(NftId applicationNftId, IPolicy.PolicyInfo memory policy, StateId newState) external restricted() {
+        Key32 key = _toNftKey32(applicationNftId, POLICY());
+        (Blocknumber lastUpdatedIn, StateId oldState) = _updateState(key, newState);
+        _policies[key] = policy;
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStorePolicyInfoUpdated(applicationNftId, oldState, newState, msg.sender, tx.origin, lastUpdatedIn);
+    }
+
+    function updateApplicationState(NftId applicationNftId, StateId newState) external restricted() {
+        Key32 key = _toNftKey32(applicationNftId, POLICY());
+        (Blocknumber lastUpdatedIn, StateId oldState) = _updateState(key, newState);
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStorePolicyInfoUpdated(applicationNftId, oldState, newState, msg.sender, tx.origin, lastUpdatedIn);
+    }
+
+    //--- Policy ------------------------------------------------------------//
+
+    function updatePolicy(NftId policyNftId, IPolicy.PolicyInfo memory policy, StateId newState) external restricted() {
+        Key32 key = _toNftKey32(policyNftId, POLICY());
+        (Blocknumber lastUpdatedIn, StateId oldState) = _updateState(key, newState);
+        _policies[key] = policy;
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStorePolicyInfoUpdated(policyNftId, oldState, newState, msg.sender, tx.origin, lastUpdatedIn);
+    }
+
+    function updatePolicyClaims(NftId policyNftId, IPolicy.PolicyInfo memory policy, StateId newState) external restricted() {
+        Key32 key = _toNftKey32(policyNftId, POLICY());
+        (Blocknumber lastUpdatedIn, StateId oldState) = _updateState(key, newState);
+        _policies[key] = policy;
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStorePolicyInfoUpdated(policyNftId, oldState, newState, msg.sender, tx.origin, lastUpdatedIn);
+    }
+
+    function updatePolicyState(NftId policyNftId, StateId newState) external restricted() {
+        Key32 key = _toNftKey32(policyNftId, POLICY());
+        (Blocknumber lastUpdatedIn, StateId oldState) = _updateState(key, newState);
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStorePolicyInfoUpdated(policyNftId, oldState, newState, msg.sender, tx.origin, lastUpdatedIn);
+    }
+
+    function getPolicyInfo(NftId policyNftId) external view returns (IPolicy.PolicyInfo memory policy) {
+        return _policies[_toNftKey32(policyNftId, POLICY())];
+    }
+
+    //--- Premium (Policy) ----------------------------------------------//
+
+    function createPremium(NftId policyNftId, IPolicy.PremiumInfo memory premium) external restricted() {
+        Key32 key = _toNftKey32(policyNftId, PREMIUM());
+        _createMetadata(key);
+        _premiums[key] = premium;
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStorePremiumInfoCreated(policyNftId, getState(key), msg.sender, tx.origin);
+    }
+
+    function updatePremiumState(NftId policyNftId, StateId newState) external restricted() {
+        Key32 key = _toNftKey32(policyNftId, PREMIUM());
+        (Blocknumber lastUpdatedIn, StateId oldState) = _updateState(key, newState);
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStorePremiumInfoUpdated(policyNftId, oldState, newState, msg.sender, tx.origin, lastUpdatedIn);
+    }
+
+    function getPremiumInfo(NftId policyNftId) external view returns (IPolicy.PremiumInfo memory premium) {
+        return _premiums[_toNftKey32(policyNftId, PREMIUM())];
+    }
+
+    //--- Claim -------------------------------------------------------------//
+
+    function createClaim(NftId policyNftId, ClaimId claimId, IPolicy.ClaimInfo memory claim) external restricted() {
+        Key32 key = _toClaimKey32(policyNftId, claimId);
+        _createMetadata(key);
+        _claims[key] = claim;
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStoreClaimInfoCreated(policyNftId, claimId, getState(key), msg.sender, tx.origin);
+    }
+
+    function updateClaim(NftId policyNftId, ClaimId claimId, IPolicy.ClaimInfo memory claim, StateId newState) external restricted() {
+        Key32 key = _toClaimKey32(policyNftId, claimId);
+        (Blocknumber lastUpdatedIn, StateId oldState) = _updateState(key, newState);
+        _claims[key] = claim;
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStoreClaimInfoUpdated(policyNftId, claimId, oldState, newState, msg.sender, tx.origin, lastUpdatedIn);
+    }
+
+    function updateClaimState(NftId policyNftId, ClaimId claimId, StateId newState) external restricted() {
+        Key32 key = _toClaimKey32(policyNftId, claimId);
+        (Blocknumber lastUpdatedIn, StateId oldState) = _updateState(key, newState);
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStoreClaimInfoUpdated(policyNftId, claimId, oldState, newState, msg.sender, tx.origin, lastUpdatedIn);
+    }
+
+    function getClaimInfo(NftId policyNftId, ClaimId claimId) external view returns (IPolicy.ClaimInfo memory claim) {
+        return _claims[_toClaimKey32(policyNftId, claimId)];
+    }
+
+    //--- Payout ------------------------------------------------------------//
+
+    function createPayout(NftId policyNftId, PayoutId payoutId, IPolicy.PayoutInfo memory payout) external restricted() {
+        Key32 key = _toPayoutKey32(policyNftId, payoutId);
+        _createMetadata(key);
+        _payouts[key] = payout;
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStorePayoutInfoCreated(policyNftId, payoutId, getState(key), msg.sender, tx.origin);
+    }
+
+    function updatePayout(NftId policyNftId, PayoutId payoutId, IPolicy.PayoutInfo memory payout, StateId newState) external restricted() {
+        Key32 key = _toPayoutKey32(policyNftId, payoutId);
+        (Blocknumber lastUpdatedIn, StateId oldState) = _updateState(key, newState);
+        _payouts[key] = payout;
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStorePayoutInfoUpdated(policyNftId, payoutId, oldState, newState, msg.sender, tx.origin, lastUpdatedIn);
+    }
+
+    function updatePayoutState(NftId policyNftId, PayoutId payoutId, StateId newState) external restricted() {
+        Key32 key = _toPayoutKey32(policyNftId, payoutId);
+        (Blocknumber lastUpdatedIn, StateId oldState) = _updateState(key, newState);
+        // solhint-disable-next-line avoid-tx-origin
+        emit LogProductStorePayoutInfoUpdated(policyNftId, payoutId, oldState, newState, msg.sender, tx.origin, lastUpdatedIn);
+    }
+
+    function getPayoutInfo(NftId policyNftId, PayoutId payoutId) external view returns (IPolicy.PayoutInfo memory payout) {
+        return _payouts[_toPayoutKey32(policyNftId, payoutId)];
+    }
+
+    //--- internal view/pure functions --------------------------------------//
+    function _toNftKey32(NftId nftId, ObjectType objectType) private pure returns (Key32) {
+        return nftId.toKey32(objectType);
+    }
+
+    function _toClaimKey32(NftId policyNftId, ClaimId claimId) private pure returns (Key32) {
+        return claimId.toKey32(policyNftId);
+    }
+
+    function _toPayoutKey32(NftId policyNftId, PayoutId payoutId) private pure returns (Key32) {
+        return payoutId.toKey32(policyNftId);
+    }
+}

package/contracts/instance/RiskSet.sol

@@ -0,0 +1,126 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Key32} from "../type/Key32.sol";
+import {LibNftIdSet} from "../type/NftIdSet.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectSet} from "./base/ObjectSet.sol";
+import {ObjectSetHelperLib} from "./base/ObjectSetHelperLib.sol";
+import {RiskIdLib, RiskId} from "../type/RiskId.sol";
+
+/// @dev RiskSet manages the risks and its active policies per product.
+contract RiskSet is
+    ObjectSet
+{
+
+    event LogRiskSetPolicyLinked(RiskId riskId, NftId policyNftId);
+    event LogRiskSetPolicyUnlinked(RiskId riskId, NftId policyNftId);
+
+    event LogRiskSetRiskAdded(NftId productNftId, RiskId riskId);
+    event LogRiskSetRiskActive(NftId poolNftId,  RiskId riskId);
+    event LogRiskSetRiskPaused(NftId poolNftId,  RiskId riskId);
+
+    error ErrorRiskSetRiskLocked(RiskId riskId, NftId policyNftId); 
+    error ErrorRiskSetRiskUnknown(RiskId riskId);
+    error ErrorRiskSetRiskNotRegistered(RiskId riskId);
+
+    mapping(RiskId riskId => LibNftIdSet.Set policies) internal _activePolicies;
+
+    /// @dev links a policy to its bundle
+    function linkPolicy(NftId productNftId, RiskId riskId, NftId policyNftId) external restricted() {
+
+        // ensure risk is active (in active set) and registered with this instance
+        if (!_isActive(productNftId, riskId.toKey32())) {
+            revert ErrorRiskSetRiskLocked(riskId, policyNftId);
+        }
+
+        LibNftIdSet.add(_activePolicies[riskId], policyNftId);
+        emit LogRiskSetPolicyLinked(riskId, policyNftId);
+    }
+
+    /// @dev Unlinks a policy from its risk.
+    function unlinkPolicy(NftId productNftId, RiskId riskId, NftId policyNftId) external restricted() {
+
+        // ensure risk is registered with this instance
+        if (!_contains(productNftId, riskId.toKey32())) {
+            revert ErrorRiskSetRiskUnknown(riskId);
+        }
+
+        LibNftIdSet.remove(_activePolicies[riskId], policyNftId);
+        emit LogRiskSetPolicyUnlinked(riskId, policyNftId);
+    }
+
+    /// @dev add a new risk to a product registered with this instance
+    // the corresponding product is fetched via instance reader
+    function add(RiskId riskId) external restricted() {
+        NftId productNftId = ObjectSetHelperLib.getProductNftId(_instanceAddress, riskId);
+
+        // ensure product is registered with instance
+        if(productNftId.eqz()) {
+            revert ErrorRiskSetRiskNotRegistered(riskId);
+        }
+
+        _add(productNftId, riskId.toKey32());
+        emit LogRiskSetRiskAdded(productNftId, riskId);
+    }
+
+    /// @dev Applications linked to active risks may be underwritten
+    function activate(RiskId riskId) external restricted() {
+        NftId productNftId = ObjectSetHelperLib.getProductNftId(_instanceAddress, riskId);
+        _activate(productNftId, riskId.toKey32());
+        emit LogRiskSetRiskActive(productNftId, riskId);
+    }
+
+    /// @dev Applications linked to paused/archived risks may not be underwritten
+    function deactivate(RiskId riskId) external restricted() {
+        NftId productNftId = ObjectSetHelperLib.getProductNftId(_instanceAddress, riskId);
+        _deactivate(productNftId, riskId.toKey32());
+        emit LogRiskSetRiskPaused(productNftId, riskId);
+    }
+
+    function checkRisk(NftId productNftId, RiskId riskId)
+        public
+        view 
+        returns (bool exists, bool active)
+    {
+        Key32 riskKey32 = riskId.toKey32();
+        exists = _contains(productNftId, riskKey32);
+
+        if (exists) {
+            active = _isActive(productNftId, riskKey32);
+        }
+    }
+
+    function hasRisk(NftId productNftId, RiskId riskId)
+        public
+        view 
+        returns (bool)
+    {
+        Key32 riskKey32 = riskId.toKey32();
+        return _contains(productNftId, riskKey32);
+    }
+
+    function risks(NftId productNftId) external view returns(uint256) {
+        return _objects(productNftId);
+    }
+
+    function getRiskId(NftId productNftId, uint256 idx) external view returns(RiskId riskId) {
+        return RiskIdLib.toRiskId(_getObject(productNftId, idx).toKeyId());
+    }
+    
+    function activeRisks(NftId productNftId) external view returns(uint256) {
+        return _activeObjs(productNftId);
+    }
+
+    function getActiveRiskId(NftId productNftId, uint256 idx) external view returns(RiskId riskId) {
+        return RiskIdLib.toRiskId(_getActiveObject(productNftId, idx).toKeyId());
+    }
+
+    function linkedPolicies(RiskId riskId) external view returns(uint256) {
+        return LibNftIdSet.size(_activePolicies[riskId]);
+    }
+
+    function getLinkedPolicyNftId(RiskId riskId, uint256 idx) external view returns(NftId policyNftId) {
+        return LibNftIdSet.getElementAt(_activePolicies[riskId], idx);
+    }
+}

package/contracts/instance/TargetNames.sol

@@ -0,0 +1,10 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+string constant INSTANCE_TARGET_NAME = "Instance";
+string constant INSTANCE_ADMIN_TARGET_NAME = "InstanceAdmin";
+string constant INSTANCE_STORE_TARGET_NAME = "InstanceStore";
+string constant PRODUCT_STORE_TARGET_NAME = "ProductStore";
+string constant BUNDLE_SET_TARGET_NAME = "BundleSet";
+string constant RISK_SET_TARGET_NAME = "RiskSet";
+

package/contracts/instance/base/BalanceStore.sol

@@ -24,13 +24,12 @@ contract BalanceStore {
     mapping(NftId nftId => Amount balance) private _balanceAmount;
     mapping(NftId nftId => Amount locked) private _lockedAmount;
     mapping(NftId nftId => Amount fees) private _feeAmount;
-    mapping(NftId nftId => bool isRegistered) private _isRegistered;
 
-    // TODO check if this is made redundant by *Info struct updates
+    // used to indicate if the target has been registered as well as when it was last updated (not used externally atm)    
     mapping(NftId nftId => Blocknumber lastUpdatedIn) private _lastUpdatedIn;
 
     modifier onlyRegisteredTarget(NftId targetNftId) {
-        if (!_isRegistered[targetNftId]) {
+        if (!_lastUpdatedIn[targetNftId].gtz()) {
             revert ErrorBalanceStoreTargetNotRegistered(targetNftId);
         }
         _;
@@ -55,12 +54,11 @@ contract BalanceStore {
     }
 
     function _registerBalanceTarget(NftId targetNftId) internal {
-        if (_isRegistered[targetNftId]) {
+        if (_lastUpdatedIn[targetNftId].gtz()) {
             revert ErrorBalanceStoreTargetAlreadyRegistered(targetNftId);
         }
 
-        _isRegistered[targetNftId] = true;
-        _lastUpdatedIn[targetNftId] = BlocknumberLib.currentBlocknumber();
+        _setLastUpdatedIn(targetNftId);
 
         emit LogBalanceStoreTargetRegistered(targetNftId);
     }
@@ -71,7 +69,7 @@ contract BalanceStore {
         _feeAmount[targetNftId] = newBalance;
 
         emit LogBalanceStoreFeesIncreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
-        _lastUpdatedIn[targetNftId] = BlocknumberLib.currentBlocknumber();
+        _setLastUpdatedIn(targetNftId);
     }
 
     function _decreaseFees(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
@@ -79,7 +77,7 @@ contract BalanceStore {
         _feeAmount[targetNftId] = newBalance;
 
         emit LogBalanceStoreFeesDecreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
-        _lastUpdatedIn[targetNftId] = BlocknumberLib.currentBlocknumber();
+        _setLastUpdatedIn(targetNftId);
     }
 
     //--- locked management -------------------------------------------------//
@@ -88,7 +86,7 @@ contract BalanceStore {
         _lockedAmount[targetNftId] = newBalance;
 
         emit LogBalanceStoreLockedIncreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
-        _lastUpdatedIn[targetNftId] = BlocknumberLib.currentBlocknumber();
+        _setLastUpdatedIn(targetNftId);
     }
 
     function _decreaseLocked(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
@@ -96,7 +94,7 @@ contract BalanceStore {
         _lockedAmount[targetNftId] = newBalance;
 
         emit LogBalanceStoreLockedDecreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
-        _lastUpdatedIn[targetNftId] = BlocknumberLib.currentBlocknumber();
+        _setLastUpdatedIn(targetNftId);
     }
 
     //--- balance management ------------------------------------------------//
@@ -105,7 +103,7 @@ contract BalanceStore {
         _balanceAmount[targetNftId] = newBalance;
 
         emit LogBalanceStoreBalanceIncreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
-        _lastUpdatedIn[targetNftId] = BlocknumberLib.currentBlocknumber();
+        _setLastUpdatedIn(targetNftId);
     }
 
     function _decreaseBalance(NftId targetNftId, Amount amount) internal onlyRegisteredTarget(targetNftId) returns (Amount newBalance) {
@@ -113,6 +111,11 @@ contract BalanceStore {
         _balanceAmount[targetNftId] = newBalance;
 
         emit LogBalanceStoreBalanceDecreased(targetNftId, amount, newBalance, _lastUpdatedIn[targetNftId]);
-        _lastUpdatedIn[targetNftId] = BlocknumberLib.currentBlocknumber();
+        _setLastUpdatedIn(targetNftId);
+    }
+
+    //--- internal/private functions ----------------------------------------//
+    function _setLastUpdatedIn(NftId targetNftId) internal {
+        _lastUpdatedIn[targetNftId] = BlocknumberLib.current();
     }
 }

package/contracts/instance/base/Cloneable.sol

@@ -2,47 +2,24 @@
 pragma solidity ^0.8.20;
 
 import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
-import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
 
 import {IRegistry} from "../../registry/IRegistry.sol";
 
 abstract contract Cloneable is 
     AccessManagedUpgradeable
 {
-    event CloneableInitialized(address authority, address registry);
-    
-    error CloneableAuthorityZero();
-    error CloneableRegistryInvalid(address registry);
-
     IRegistry internal _registry;
 
-    constructor() {
-        _registry = IRegistry(address(0));
-    }
-
     /// @dev call to initialize MUST be made in the same transaction as cloning of the contract
-    function initialize(
+    function __Cloneable_init(
         address authority,
         address registry
     )
-        public 
+        internal 
         onlyInitializing
     {
-        // check/handle access managed
-        if(authority == address(0)) {
-            revert CloneableAuthorityZero();
-        }
-        
         __AccessManaged_init(authority);
-
-        // check/handle registry
-        if (registry.code.length == 0) {
-            revert CloneableRegistryInvalid(registry);
-        }
-
         _registry = IRegistry(registry);
-
-        emit CloneableInitialized(authority, registry);
     }
 
     function getRegistry() external view returns (IRegistry) {

package/contracts/instance/base/ObjectCounter.sol

@@ -0,0 +1,20 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Blocknumber, BlocknumberLib} from "../../type/Blocknumber.sol";
+import {NftId} from "../../type/NftId.sol";
+import {Amount} from "../../type/Amount.sol";
+import {RequestId, RequestIdLib} from "../../type/RequestId.sol";
+
+contract ObjectCounter {
+
+    // TODO refactor risk id
+    // mapping(NftId productNftId => uint64 risks) private _riskCounter;
+
+    uint256 private _requestCounter = 0;
+
+    function _createNextRequestId() internal returns (RequestId requestId) {
+        _requestCounter++;
+        requestId = RequestIdLib.toRequestId(_requestCounter);
+    }
+}