@etherisc/gif-next 0.0.2-7edd44f → 0.0.2-7ee1666-376

package/contracts/examples/fire/FirePoolAuthorization.sol

@@ -0,0 +1,34 @@
+
+
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {BasicPoolAuthorization} from "../../pool/BasicPoolAuthorization.sol";
+import {FirePool} from "./FirePool.sol";
+import {IAccess} from "../../../contracts/authorization/IAccess.sol";
+import {PUBLIC_ROLE} from "../../../contracts/type/RoleId.sol";
+
+contract FirePoolAuthorization
+    is BasicPoolAuthorization
+{
+
+    constructor(string memory poolName)
+        BasicPoolAuthorization(poolName)
+    {}
+
+
+    function _setupTargetAuthorizations()
+        internal
+        virtual override
+    {
+        super._setupTargetAuthorizations();
+        IAccess.FunctionInfo[] storage functions;
+
+        // authorize public role (open access to any account, only allows to lock target)
+        functions = _authorizeForTarget(getTargetName(), PUBLIC_ROLE());
+        // TODO: FirePool.createBundle must require a custom role (e.g. INVESTOR) instead of PUBLIC_ROLE
+        _authorize(functions, FirePool.createBundle.selector, "createBundle");
+    }
+
+}
+

package/contracts/examples/fire/FireProduct.sol

@@ -0,0 +1,432 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ACTIVE, COLLATERALIZED, PAUSED} from "../../type/StateId.sol";
+import {Amount, AmountLib} from "../../type/Amount.sol";
+import {BasicProduct} from "../../product/BasicProduct.sol";
+import {ClaimId} from "../../type/ClaimId.sol";
+import {DamageLevel, DamageLevelLib, DAMAGE_SMALL, DAMAGE_MEDIUM, DAMAGE_HIGH} from "./DamageLevel.sol";
+import {IAuthorization} from "../../authorization/IAuthorization.sol";
+import {IPolicy} from "../../instance/module/IPolicy.sol";
+import {NftId} from "../../type/NftId.sol";
+import {ReferralLib} from "../../type/Referral.sol";
+import {RiskId, RiskIdLib} from "../../type/RiskId.sol";
+import {Seconds} from "../../type/Seconds.sol";
+import {StateId} from "../../type/StateId.sol";
+import {Timestamp, TimestampLib} from "../../type/Timestamp.sol";
+import {UFixed, UFixedLib} from "../../type/UFixed.sol";
+
+uint64 constant SPECIAL_ROLE_INT = 11111;
+
+function HALF_YEAR() pure returns (Seconds) {
+    return Seconds.wrap(180 * 86400);
+}
+
+function ONE_YEAR() pure returns (Seconds) {
+    return Seconds.wrap(360 * 86400);
+}
+
+/// @dev This is the product component for the fire insurance example. 
+/// It show how to insure a house for a given suminsured in a city. 
+/// The risk is based on the city. 
+/// If a fire is reported in the city, the policy holder is able to submit a claim and get a payout. 
+contract FireProduct is 
+    BasicProduct
+{
+    struct Fire {
+        string cityName;
+        DamageLevel damageLevel;
+        Timestamp reportedAt;
+    }
+
+    error ErrorFireProductCityUnknown(string cityName);
+    error ErrorFireProductTimestampTooEarly();
+    error ErrorFireProductFireAlreadyReported();
+    error ErrorFireProductAlreadyClaimed();
+    error ErrorFireProductPolicyNotActive();
+    error ErrorFireProductPolicyNotYetActive(Timestamp activateAt);
+    error ErrorFireProductPolicyExpired(Timestamp expiredAt);
+    error ErrorFireProductUnknownDamageLevel(DamageLevel damageLevel);
+    error ErrorFireProductFireUnknown(uint256 fireId);
+    error ErrorFireProductNotPolicyOwner(NftId nftId, address owner);
+
+    string[] private _cities;
+    // map from city name to the RiskId
+    mapping(string cityName => RiskId risk) private _riskMapping;
+
+    // // map from city name to the damage level and the time of the report
+    mapping(uint256 fireId => Fire) private _fires;
+    mapping(uint256 fireId => mapping (NftId policyId => bool claimed)) private _claimed;
+
+    constructor(
+        address registry,
+        NftId instanceNftid,
+        string memory componentName,
+        address token,
+        address pool,
+        IAuthorization authorization
+    )
+    {
+        address initialOwner = msg.sender;
+        _initialize(
+            registry,
+            instanceNftid,
+            componentName,
+            token,
+            pool,
+            authorization,
+            initialOwner);
+    }
+
+    function _initialize(
+        address registry,
+        NftId instanceNftid,
+        string memory componentName,
+        address token,
+        address pool,
+        IAuthorization authorization,
+        address initialOwner
+    )
+        internal
+        initializer
+    {
+        _initializeBasicProduct(
+            registry,
+            instanceNftid,
+            authorization,
+            initialOwner,
+            componentName,
+            token,
+            false,
+            pool,
+            address(0));  // no distribution
+    }
+    
+    function cities() public view returns (uint256) {
+        return _cities.length;
+    }
+
+    function city(uint256 idx) public view returns (string memory) {
+        return _cities[idx];
+    }
+
+    function riskId(string memory cityName) public view returns (RiskId) {
+        return _riskMapping[cityName];
+    }
+
+    function pauseCity(
+        string memory cityName
+    ) 
+        public 
+        restricted()
+    {
+        if (_riskMapping[cityName].eqz()) {
+            revert ErrorFireProductCityUnknown(cityName);
+        }
+
+        _updateRiskState(
+            _riskMapping[cityName],
+            PAUSED()
+        );
+    }
+
+    function unpauseCity(
+        string memory cityName
+    ) 
+        public 
+        restricted()
+    {
+        if (_riskMapping[cityName].eqz()) {
+            revert ErrorFireProductCityUnknown(cityName);
+        }
+
+        _updateRiskState(
+            _riskMapping[cityName],
+            ACTIVE()
+        );
+    }
+
+    function calculatePremium(
+        string memory cityName,
+        Amount sumInsured,
+        Seconds lifetime,
+        NftId bundleNftId
+    ) 
+        public
+        view
+        returns (Amount premiumAmount)
+    {
+        RiskId riskId = _riskMapping[cityName];
+        if (riskId.eqz()) {
+            revert ErrorFireProductCityUnknown(cityName);
+        }
+        premiumAmount = calculatePremium( 
+            sumInsured,
+            riskId,
+            lifetime,
+            "",
+            bundleNftId,
+            ReferralLib.zero());
+    }
+
+    function calculateNetPremium(
+        Amount sumInsured,
+        RiskId,
+        Seconds lifetime,
+        bytes memory
+    )
+        external
+        view
+        virtual override
+        returns (Amount netPremiumAmount)
+    {
+        UFixed numDays = UFixedLib.toUFixed(lifetime.toInt() / 86400);
+        // to simplify time calculation we assume 360 days per year
+        UFixed pctOfYear = numDays / UFixedLib.toUFixed(360);
+        Amount premiumPerYear = AmountLib.toAmount(sumInsured.toInt() / 20);
+        return  premiumPerYear.multiplyWith(pctOfYear);
+    }
+
+    function createApplication(
+        string memory cityName,
+        Amount sumInsured,
+        Seconds lifetime,
+        NftId bundleNftId
+    )
+        public
+        restricted()
+        returns (NftId policyNftId)
+    {
+        address applicationOwner = msg.sender;
+        RiskId riskId = initializeCity(cityName);
+
+        Amount premiumAmount = calculatePremium(
+            sumInsured,
+            riskId,
+            lifetime,
+            "",
+            bundleNftId,
+            ReferralLib.zero());
+
+        return _createApplication(
+            applicationOwner,
+            riskId,
+            sumInsured,
+            premiumAmount,
+            lifetime,
+            bundleNftId,
+            ReferralLib.zero(),
+            ""
+        );
+    }
+
+    function initializeCity(
+        string memory cityName
+    ) 
+        public
+        returns (RiskId riskId) 
+    {
+        if (! _riskMapping[cityName].eqz()) {
+            return _riskMapping[cityName];
+        }
+        _cities.push(cityName);
+        riskId = RiskIdLib.toRiskId(cityName);
+        _createRisk(riskId, "");
+        _riskMapping[cityName] = riskId;
+    }
+
+    /// @dev Calling this method will lock the sum insured amount in the pool and activate the policy at the given time. 
+    /// It will also collect the tokens payment for the premium. An approval with the correct amount towards the TokenHandler of the product is therefor required. 
+    function createPolicy(
+        NftId policyNftId,
+        Timestamp activateAt
+    ) 
+        public 
+        restricted()
+    {
+        _createPolicy(policyNftId, activateAt);
+        _collectPremium(policyNftId, activateAt);
+    }
+
+    /// @dev Decline the policy application
+    function decline(
+        NftId policyNftId
+    ) 
+        public 
+        restricted()
+    {
+        _decline(policyNftId);
+    }
+
+    function expire(
+        NftId policyNftId,
+        Timestamp expireAt
+    ) 
+        public 
+        restricted()
+        returns (Timestamp)
+    {
+        return _expire(policyNftId, expireAt);
+    }
+
+    function close(
+        NftId policyNftId
+    ) 
+        public 
+        restricted()
+    {
+        _close(policyNftId);
+    }
+
+    function reportFire(
+        uint256 fireId,
+        string memory cityName,
+        DamageLevel damageLevel,
+        Timestamp reportedAt
+    ) 
+        public 
+        restricted()
+    {
+        if (_riskMapping[cityName].eqz()) {
+            revert ErrorFireProductCityUnknown(cityName);
+        }
+
+        if (reportedAt < TimestampLib.blockTimestamp()) {
+            revert ErrorFireProductTimestampTooEarly();
+        }
+
+        if (! _fires[fireId].reportedAt.eqz()) {
+            revert ErrorFireProductFireAlreadyReported();
+        }
+
+        _fires[fireId] = Fire({
+            cityName: cityName,
+            damageLevel: damageLevel,
+            reportedAt: reportedAt
+        });
+    }
+
+    function fire(uint256 fireId) public view returns (Fire memory) {
+        return _fires[fireId];
+    }
+
+    function submitClaim(
+        NftId policyNftId,
+        uint256 fireId
+    ) 
+        public 
+        restricted()
+        onlyNftOwner(policyNftId)
+        returns (ClaimId claimId) 
+    {
+        IPolicy.PolicyInfo memory policyInfo = _getInstanceReader().getPolicyInfo(policyNftId);
+        _checkClaimConditions(policyNftId, fireId, policyInfo);
+        
+        Fire memory fire = _fires[fireId];
+        _claimed[fireId][policyNftId] = true;
+        Amount claimAmount = _getClaimAmount(policyInfo, fire);
+        
+        claimId = _submitClaim(policyNftId, claimAmount, "");
+
+        // TODO: if yes, process payout and close claim
+        // TODO: if no, decline claim
+    }
+
+    function _checkClaimConditions(
+        NftId policyNftId,
+        uint256 fireId,
+        IPolicy.PolicyInfo memory policyInfo
+    ) 
+        internal
+    {
+        // check fire exists
+        if (_fires[fireId].reportedAt.eqz()) {
+            revert ErrorFireProductFireUnknown(fireId);
+        }
+
+        // check policy has not been claimed yet for this fire
+        if (_claimed[fireId][policyNftId]) {
+            revert ErrorFireProductAlreadyClaimed();
+        }
+
+        StateId policyState = _getInstanceReader().getPolicyState(policyNftId);
+        
+        if (! policyState.eq(COLLATERALIZED())) {
+            revert ErrorFireProductPolicyNotActive();
+        }
+
+        Fire memory fire = _fires[fireId];
+
+        if (fire.reportedAt < policyInfo.activatedAt) {
+            revert ErrorFireProductPolicyNotYetActive(policyInfo.activatedAt);
+        }
+
+        if (fire.reportedAt > policyInfo.expiredAt) {
+            revert ErrorFireProductPolicyExpired(policyInfo.expiredAt);
+        }
+    }
+
+    function _getClaimAmount(
+        IPolicy.PolicyInfo memory policyInfo,
+        Fire memory fire
+    ) 
+        internal
+        view
+        returns (Amount)
+    {
+        if (fire.damageLevel.eq(DAMAGE_SMALL())) {
+            return policyInfo.sumInsuredAmount.multiplyWith(UFixedLib.toUFixed(2, -2));
+        } else if (fire.damageLevel.eq(DAMAGE_MEDIUM())) {
+            return policyInfo.sumInsuredAmount.multiplyWith(UFixedLib.toUFixed(5, -2));
+        } else if (fire.damageLevel.eq(DAMAGE_HIGH())) {
+            return policyInfo.sumInsuredAmount;
+        } else {
+            revert ErrorFireProductUnknownDamageLevel(fire.damageLevel);
+        }
+    }
+
+    // TODO: no longer needed? -> remove
+    // function confirmClaim(
+    //     NftId policyNftId,
+    //     ClaimId claimId,
+    //     Amount confirmedAmount,
+    //     bytes memory processData
+    // ) public {
+    //     // TODO: implement confirmClaim
+    //     // _confirmClaim(policyNftId, claimId, confirmedAmount, processData);
+    // }
+
+    // TODO: no longer needed? -> remove
+    // function declineClaim(
+    //     NftId policyNftId,
+    //     ClaimId claimId,
+    //     bytes memory processData
+    // ) public {
+    //     // TODO: implement declineClaim
+    //     // _declineClaim(policyNftId, claimId, processData);
+    // }
+
+    // TODO: no longer needed? -> remove
+    // function createPayout(
+    //     NftId policyNftId,
+    //     ClaimId claimId,
+    //     Amount amount,
+    //     bytes memory data
+    // ) public returns (PayoutId) {
+    //     return _createPayout(policyNftId, claimId, amount, data);
+    // }
+
+    // TODO: add method to report fire per city with a percentage of payout
+
+    
+    // TODO: no longer needed? -> remove
+    // function processPayout(
+    //     NftId policyNftId,
+    //     PayoutId payoutId
+    // ) public {
+        // TODO: implement process all pending payouts for a risk - arguments cityname and payout percentage
+    //     _processPayout(policyNftId, payoutId);
+    // }
+
+
+}

package/contracts/examples/fire/FireProductAuthorization.sol

@@ -0,0 +1,38 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {BasicProductAuthorization} from "../../product/BasicProductAuthorization.sol";
+import {FireProduct} from "./FireProduct.sol";
+import {IAccess} from "../../../contracts/authorization/IAccess.sol";
+import {PRODUCT_OWNER_ROLE, PUBLIC_ROLE} from "../../../contracts/type/RoleId.sol";
+
+
+contract FireProductAuthorization
+    is BasicProductAuthorization
+{
+
+    constructor(string memory poolName)
+        BasicProductAuthorization(poolName)
+    {}
+
+    function _setupTargetAuthorizations()
+        internal
+        virtual override
+    {
+        super._setupTargetAuthorizations();
+        IAccess.FunctionInfo[] storage functions;
+
+        // authorize public role (open access to any account, only allows to lock target)
+        functions = _authorizeForTarget(getTargetName(), PUBLIC_ROLE());
+        _authorize(functions, FireProduct.createApplication.selector, "createApplication");
+
+        functions = _authorizeForTarget(getTargetName(), PRODUCT_OWNER_ROLE());
+        _authorize(functions, FireProduct.createPolicy.selector, "createPolicy");
+        _authorize(functions, FireProduct.decline.selector, "decline");
+        _authorize(functions, FireProduct.expire.selector, "expire");
+        _authorize(functions, FireProduct.close.selector, "close");
+        _authorize(functions, FireProduct.reportFire.selector, "reportFire");
+    }
+
+}
+

package/contracts/examples/fire/FireUSD.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
+
+/// @dev FireUSD is a stablecoin with 6 decimals and an initial supply of 1 Billion tokens. 
+contract FireUSD is ERC20 {
+
+    string public constant NAME = "FireUSD";
+    string public constant SYMBOL = "HOT";
+    uint8 public constant DECIMALS = 6;
+    uint256 public constant INITIAL_SUPPLY = 10**12 * 10**DECIMALS; // 1'000'000'000'000
+    
+    constructor()
+        ERC20(NAME, SYMBOL)
+    {
+        _mint(
+            _msgSender(),
+            INITIAL_SUPPLY
+        );   
+    }
+
+    function decimals() public pure override returns(uint8) {
+        return DECIMALS;
+    }
+}

package/contracts/examples/unpermissioned/SimpleDistribution.sol

@@ -0,0 +1,50 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {BasicDistribution} from "../../distribution/BasicDistribution.sol";
+import {IAuthorization} from "../../authorization/IAuthorization.sol";
+import {NftId} from "../../type/NftId.sol";
+
+
+contract SimpleDistribution is
+    BasicDistribution
+{
+    
+    constructor(
+        address registry,
+        NftId instanceNftId,
+        IAuthorization authorization,
+        address initialOwner,
+        address token
+    ) 
+    {
+        initialize(
+            registry,
+            instanceNftId,
+            authorization,
+            initialOwner,
+            "SimpleDistribution",
+            token);
+    }
+
+    function initialize(
+        address registry,
+        NftId instanceNftId,
+        IAuthorization authorization,
+        address initialOwner,
+        string memory name,
+        address token
+    )
+        public
+        virtual
+        initializer()
+    {
+        _initializeBasicDistribution(
+            registry,
+            instanceNftId,
+            authorization,
+            initialOwner,
+            name,
+            token);
+    }
+}