@etherisc/gif-next 0.0.2-7e684ab-059 → 0.0.2-7e8dbef-751

package/contracts/oracle/Oracle.sol

@@ -0,0 +1,145 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {COMPONENT, ORACLE} from "../type/ObjectType.sol";
+import {IOracleService} from "./IOracleService.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {InstanceLinkedComponent} from "../shared/InstanceLinkedComponent.sol";
+import {IComponentService} from "../shared/IComponentService.sol";
+import {IOracleComponent} from "./IOracleComponent.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {RequestId} from "../type/RequestId.sol";
+import {Timestamp, TimestampLib} from "../type/Timestamp.sol";
+import {ITransferInterceptor} from "../registry/ITransferInterceptor.sol";
+import {UFixed} from "../type/UFixed.sol";
+
+
+abstract contract Oracle is
+    InstanceLinkedComponent,
+    IOracleComponent
+{
+    // keccak256(abi.encode(uint256(keccak256("etherisc.storage.Oracle")) - 1)) & ~bytes32(uint256(0xff));
+    bytes32 public constant ORACLE_STORAGE_LOCATION_V1 = 0xaab7c0ea03d290e56d6c060e0733d3ebcbe647f7694616a2ec52738a64b2f900;
+
+    struct OracleStorage {
+        IComponentService _componentService;
+        IOracleService _oracleService;
+    }
+
+
+    function initializeOracle(
+        address registry,
+        NftId instanceNftId,
+        address initialOwner,
+        string memory name,
+        address token,
+        bytes memory registryData, // writeonly data that will saved in the object info record of the registry
+        bytes memory componentData // component specifidc data 
+    )
+        public
+        virtual
+        onlyInitializing()
+    {
+        initializeInstanceLinkedComponent(registry, instanceNftId, name, token, ORACLE(), true, initialOwner, registryData, componentData);
+
+        OracleStorage storage $ = _getOracleStorage();
+        $._oracleService = IOracleService(_getServiceAddress(ORACLE())); 
+        $._componentService = IComponentService(_getServiceAddress(COMPONENT())); 
+
+        registerInterface(type(IOracleComponent).interfaceId);
+    }
+
+
+    function register()
+        external
+        virtual
+        onlyOwner()
+    {
+        _getOracleStorage()._componentService.registerOracle();
+    }
+
+
+    function isVerifying()
+        external 
+        virtual 
+        view 
+        returns (bool verifying)
+    {
+        return false;
+    }
+
+
+    function request(
+        RequestId requestId,
+        NftId requesterId,
+        bytes calldata requestData,
+        Timestamp expiryAt
+    )
+        external
+        virtual
+        // restricted() // TODO enable: only oracle service
+    {
+        _request(requestId, requesterId, requestData, expiryAt);
+    }
+
+
+    function cancel(
+        RequestId requestId
+    )
+        external
+        virtual
+        // restricted() // TODO enable: only oracle service
+    {
+        _cancel(requestId);
+    }
+
+
+    /// @dev internal function for handling requests.
+    /// empty implementation.
+    /// overwrite this function to implement use case specific handling
+    /// for oracle calls.
+    function _request(
+        RequestId requestId,
+        NftId requesterId,
+        bytes calldata requestData,
+        Timestamp expiryAt
+    )
+        internal
+        virtual
+    {
+    }
+
+
+    /// @dev internal function for cancelling requests.
+    /// empty implementation.
+    /// overwrite this function to implement use case specific cancelling
+    function _cancel(
+        RequestId requestId
+    )
+        internal
+        virtual
+    {
+    }
+
+
+    /// @dev internal function for handling oracle responses.
+    /// use this function in use case specific external/public functions
+    /// to handle use case specific response handling.
+    function _respond(
+        RequestId requestId,
+        bytes memory responseData
+    )
+        internal
+        virtual
+    {
+        _getOracleStorage()._oracleService.respond(
+            requestId, responseData);
+    }
+
+    function _getOracleStorage() private pure returns (OracleStorage storage $) {
+        assembly {
+            $.slot := ORACLE_STORAGE_LOCATION_V1
+        }
+    }
+}

package/contracts/oracle/OracleService.sol

@@ -0,0 +1,221 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {ComponentVerifyingService} from "../shared/ComponentVerifyingService.sol";
+import {IComponent} from "../shared/IComponent.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {IInstanceService} from "../instance/IInstanceService.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+import {IOracle} from "./IOracle.sol";
+import {IOracleComponent} from "./IOracleComponent.sol";
+import {IOracleService} from "./IOracleService.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {NftId} from "../type/NftId.sol";
+import {ObjectType, COMPONENT, ORACLE, INSTANCE} from "../type/ObjectType.sol";
+import {RequestId} from "../type/RequestId.sol";
+import {StateId, ACTIVE, FULFILLED, CANCELLED} from "../type/StateId.sol";
+import {Timestamp, TimestampLib} from "../type/Timestamp.sol";
+
+
+contract OracleService is
+    ComponentVerifyingService,
+    IOracleService
+{
+
+    IInstanceService private _instanceService;
+
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        initializer
+        virtual override
+    {
+        address initialOwner;
+        address registryAddress;
+        (registryAddress, initialOwner) = abi.decode(data, (address, address));
+        initializeService(registryAddress, address(0), owner);
+
+        _instanceService = IInstanceService(_getServiceAddress(INSTANCE()));
+
+        registerInterface(type(IOracleService).interfaceId);
+    }
+
+    function getDomain() public pure override returns(ObjectType) {
+        return ORACLE();
+    }
+
+    function request(
+        NftId oracleNftId,
+        bytes calldata requestData,
+        Timestamp expiryAt,
+        string calldata callbackMethodName
+    )
+        external 
+        virtual 
+        // restricted() // add authz
+        returns (
+            RequestId requestId
+        ) 
+    {
+        (
+            NftId componentNftId,
+            IRegistry.ObjectInfo memory componentInfo, 
+            IInstance instance
+        ) = _getAndVerifyActiveComponent(COMPONENT());
+
+        // oracleNftId exists and is active oracle
+        (
+            IRegistry.ObjectInfo memory oracleInfo, 
+        ) = _getAndVerifyComponentInfo(
+            oracleNftId, 
+            ORACLE(), 
+            true); // only active
+
+        // check that requester and oracle share same instance
+        if (componentInfo.parentNftId != oracleInfo.parentNftId) {
+            revert ErrorOracleServiceInstanceMismatch(componentInfo.parentNftId, oracleInfo.parentNftId);
+        }
+
+        // check expiriyAt >= now
+        if (expiryAt < TimestampLib.blockTimestamp()) {
+            revert ErrorOracleServiceExpiryInThePast(TimestampLib.blockTimestamp(), expiryAt);
+        }
+
+        // check callbackMethodName.length > 0
+        if (bytes(callbackMethodName).length == 0) {
+            revert ErrorOracleServiceCallbackMethodNameEmpty();
+        }
+
+        // create request info
+        IOracle.RequestInfo memory request = IOracle.RequestInfo({
+            requesterNftId: componentNftId,
+            callbackMethodName: callbackMethodName,
+            oracleNftId: oracleNftId,
+            requestData: requestData,
+            responseData: "",
+            respondedAt: TimestampLib.zero(),
+            expiredAt: expiryAt,
+            isCancelled: false
+        });
+
+        // store request with instance
+        requestId = instance.getInstanceStore().createRequest(request);
+
+        // call oracle component
+        IOracleComponent(oracleInfo.objectAddress).request(
+            requestId, 
+            componentNftId, 
+            requestData, 
+            expiryAt);
+
+        emit LogOracleServiceRequestCreated(requestId, componentNftId, oracleNftId, expiryAt);
+    }
+
+
+    /// @dev respond to oracle request by oracle compnent.
+    /// permissioned: only the oracle component linked to the request id may call this method
+    function respond(
+        RequestId requestId,
+        bytes calldata responseData
+    )
+        external
+        virtual
+        // restricted() // add authz
+    {
+        (
+            NftId oracleNftId,
+            IRegistry.ObjectInfo memory componentInfo, 
+            IInstance instance
+        ) = _getAndVerifyActiveComponent(ORACLE());
+
+        bool callerIsOracle = true;
+        IOracle.RequestInfo memory request = _checkAndGetRequestInfo(instance, requestId, oracleNftId, callerIsOracle);
+        request.responseData = responseData;
+        request.respondedAt = TimestampLib.blockTimestamp();
+
+        instance.getInstanceStore().updateRequest(requestId, request, FULFILLED());
+
+        // TODO add callback to requesting compnent
+
+        emit LogOracleRequestFulfilled(requestId, oracleNftId);
+    }
+
+    /// @dev notify the oracle component that the specified request has become invalid
+    /// permissioned: only the originator of the request may cancel a request
+    function cancel(RequestId requestId)
+        external 
+        virtual 
+        // restricted() // add authz
+    {
+        (
+            NftId requesterNftId,
+            IRegistry.ObjectInfo memory componentInfo, 
+            IInstance instance
+        ) = _getAndVerifyActiveComponent(COMPONENT());
+
+        bool callerIsOracle = false;
+        IOracle.RequestInfo memory request = _checkAndGetRequestInfo(instance, requestId, requesterNftId, callerIsOracle);
+        request.isCancelled = true;
+
+        instance.getInstanceStore().updateRequest(requestId, request, CANCELLED());
+
+        // call oracle component
+        // TODO add check that component is active?
+        address oracleAddress = getRegistry().getObjectInfo(request.oracleNftId).objectAddress;
+        IOracleComponent(oracleAddress).cancel(requestId);
+
+        emit LogOracleRequestCancelled(requestId, requesterNftId);
+    }
+
+
+    function _checkAndGetRequestInfo(
+        IInstance instance,
+        RequestId requestId,
+        NftId callerNftId,
+        bool callerIsOracle
+    )
+        internal
+        virtual
+        view
+        returns (IOracle.RequestInfo memory info)
+    {
+        InstanceReader reader = instance.getInstanceReader();
+        StateId state = reader.getState(requestId.toKey32());
+
+        // check request state
+        if (state != ACTIVE()) {
+            revert ErrorOracleServiceRequestStateNotActive(requestId, state);
+        }
+
+        // check caller against resonsible oracle or requester
+        info = reader.getRequestInfo(requestId);
+        if (callerIsOracle) {
+            if (callerNftId != info.oracleNftId) {
+                revert ErrorOracleServiceCallerNotResponsibleOracle(requestId, info.oracleNftId, callerNftId);
+            }
+        } else {
+            if (callerNftId != info.requesterNftId) {
+                revert ErrorOracleServiceCallerNotRequester(requestId, info.requesterNftId, callerNftId);
+            }
+        }
+
+        // check expiry
+        if (info.expiredAt < TimestampLib.blockTimestamp()) {
+            revert ErrorOracleServiceRequestExpired(requestId, info.expiredAt);
+        }
+    }
+
+
+    function _getInstanceForComponent(NftId componentNftId)
+        internal
+        view
+        returns(IInstance instance)
+    {
+        NftId instanceNftId = getRegistry().getObjectInfo(componentNftId).parentNftId;
+        address instanceAddress = getRegistry().getObjectInfo(instanceNftId).objectAddress;
+        return IInstance(instanceAddress);
+    }
+}

package/contracts/oracle/OracleServiceManager.sol

@@ -0,0 +1,42 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IVersionable} from "../shared/IVersionable.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
+import {OracleService} from "./OracleService.sol";
+import {Registry} from "../registry/Registry.sol";
+import {RegistryService} from "../registry/RegistryService.sol";
+import {REGISTRY} from "../type/ObjectType.sol";
+
+contract OracleServiceManager is ProxyManager {
+
+    OracleService private _oracleService;
+
+    /// @dev initializes proxy manager with service implementation and deploys instance
+    constructor(
+        address authority, 
+        address registryAddress,
+        bytes32 salt
+    ) 
+        ProxyManager(registryAddress)
+    {
+        OracleService orclSrv = new OracleService{salt: salt}();
+        bytes memory data = abi.encode(registryAddress, address(this), authority);
+        IVersionable versionable = deployDetermenistic(
+            address(orclSrv), 
+            data,
+            salt);
+
+        _oracleService = OracleService(address(versionable));
+    }
+
+    //--- view functions ----------------------------------------------------//
+    function getOracleService()
+        external
+        view
+        returns (OracleService oracleService)
+    {
+        return _oracleService;
+    }
+
+}

package/contracts/pool/BundleService.sol

@@ -0,0 +1,296 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IBundle} from "../instance/module/IBundle.sol";
+import {IComponents} from "../instance/module/IComponents.sol";
+import {IComponentService} from "../shared/IComponentService.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IInstance} from "../instance/IInstance.sol";
+import {InstanceStore} from "../instance/InstanceStore.sol";
+import {IPolicy} from "../instance/module/IPolicy.sol";
+
+import {IVersionable} from "../shared/IVersionable.sol";
+import {INftOwnable} from "../shared/INftOwnable.sol";
+import {NftId, NftIdLib} from "../type/NftId.sol";
+import {ObjectType, COMPONENT, POOL, BUNDLE, REGISTRY} from "../type/ObjectType.sol";
+import {POOL_OWNER_ROLE, RoleId} from "../type/RoleId.sol";
+import {Pool} from "./Pool.sol";
+
+import {Amount, AmountLib} from "../type/Amount.sol";
+import {Fee, FeeLib} from "../type/Fee.sol";
+import {StateId, ACTIVE, PAUSED, CLOSED, KEEP_STATE} from "../type/StateId.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {TimestampLib, zeroTimestamp} from "../type/Timestamp.sol";
+import {Version, VersionLib} from "../type/Version.sol";
+import {Versionable} from "../shared/Versionable.sol";
+
+import {IService} from "../shared/IService.sol";
+import {Service} from "../shared/Service.sol";
+import {BundleManager} from "../instance/BundleManager.sol";
+import {ComponentVerifyingService} from "../shared/ComponentVerifyingService.sol";
+import {IBundleService} from "./IBundleService.sol";
+import {IRegistryService} from "../registry/IRegistryService.sol";
+import {InstanceService} from "../instance/InstanceService.sol";
+import {InstanceReader} from "../instance/InstanceReader.sol";
+
+string constant BUNDLE_SERVICE_NAME = "BundleService";
+
+contract BundleService is 
+    ComponentVerifyingService, 
+    IBundleService 
+{
+    using NftIdLib for NftId;
+
+    string public constant NAME = "BundleService";
+
+    address private _registryAddress;
+    IRegistryService private _registryService;
+    IComponentService private _componentService;
+
+    function _initialize(
+        address owner, 
+        bytes memory data
+    )
+        internal
+        initializer
+        virtual override
+    {
+        address registryAddress;
+        address initialOwner;
+        (registryAddress, initialOwner) = abi.decode(data, (address, address));
+        // TODO while PoolService is not deployed in PoolServiceManager constructor
+        //      owner is PoolServiceManager deployer
+        initializeService(registryAddress, address(0), owner);
+
+        _registryService = IRegistryService(_getServiceAddress(REGISTRY()));
+        _componentService = IComponentService(_getServiceAddress(COMPONENT()));
+
+        registerInterface(type(IBundleService).interfaceId);
+    }
+
+    function getDomain() public pure override returns(ObjectType) {
+        return BUNDLE();
+    }
+
+
+    function setFee(
+        NftId bundleNftId,
+        Fee memory fee
+    )
+        external
+        virtual
+    {
+        (NftId poolNftId,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+        InstanceReader instanceReader = instance.getInstanceReader();
+        IBundle.BundleInfo memory bundleInfo = instanceReader.getBundleInfo(bundleNftId);
+        if(bundleInfo.poolNftId.eqz()) {
+            revert ErrorBundleServiceBundleUnknown(bundleNftId);
+        }
+
+        if(bundleInfo.poolNftId != poolNftId) {
+            revert ErrorBundleServiceBundlePoolMismatch(bundleNftId, bundleInfo.poolNftId, poolNftId);
+        }
+
+        bundleInfo.fee = fee;
+        instance.getInstanceStore().updateBundle(bundleNftId, bundleInfo, KEEP_STATE());
+    }
+
+
+    function create(
+        IInstance instance,
+        NftId poolNftId,
+        address owner, 
+        Fee memory bundleFee, 
+        Amount stakingAmount, 
+        Seconds lifetime, 
+        bytes calldata filter
+    )
+        external
+        override
+        restricted
+        returns(NftId bundleNftId)
+    {
+        // register bundle with registry
+        bundleNftId = _registryService.registerBundle(
+            IRegistry.ObjectInfo(
+                NftIdLib.zero(), 
+                poolNftId,
+                BUNDLE(),
+                false, // intercepting property for bundles is defined on pool
+                address(0),
+                owner,
+                "" // bundle data to be stored in registry
+            )
+        );
+
+        // create bundle info in instance
+        InstanceStore instanceStore = instance.getInstanceStore();
+        instanceStore.createBundle(
+            bundleNftId, 
+            IBundle.BundleInfo(
+                poolNftId,
+                bundleFee,
+                filter,
+                lifetime,
+                TimestampLib.blockTimestamp().addSeconds(lifetime),
+                zeroTimestamp()));
+
+        // bundle book keeping
+        _componentService.increaseBundleBalance(
+            instanceStore, 
+            bundleNftId, 
+            stakingAmount, 
+            AmountLib.zero()); // fee amount
+
+        // put bundle under bundle managemet
+        BundleManager bundleManager = instance.getBundleManager();
+        bundleManager.add(bundleNftId);
+
+        // TODO add logging
+    }
+
+
+    // the bundle MUST be unlocked (active) for linking (underwriting) and registered with this instance
+    function lockCollateral(
+        IInstance instance,
+        NftId policyNftId, 
+        NftId bundleNftId, 
+        Amount collateralAmount // required local amount to collateralize policy
+    ) 
+        external
+        virtual
+        restricted()
+    {
+        InstanceReader instanceReader = instance.getInstanceReader();
+        StateId bundleState = instanceReader.getMetadata(bundleNftId.toKey32(BUNDLE())).state;
+        IBundle.BundleInfo memory bundleInfo = instanceReader.getBundleInfo(bundleNftId);
+
+        // ensure bundle is active and not yet expired
+        if(bundleState != ACTIVE() || bundleInfo.expiredAt < TimestampLib.blockTimestamp()) {
+            revert ErrorBundleServiceBundleNotOpen(bundleNftId, bundleState, bundleInfo.expiredAt);
+        }
+
+        // ensure bundle capacity is sufficent to collateralize policy
+        InstanceStore instanceStore = instance.getInstanceStore();
+        (
+            Amount balanceAmount,
+            Amount lockedAmount,
+            Amount feeAmount
+        ) = instanceStore.getAmounts(bundleNftId);
+
+        Amount capacity = balanceAmount - (lockedAmount + feeAmount);
+        if(capacity < collateralAmount) {
+            revert ErrorBundleServiceCapacityInsufficient(bundleNftId, capacity, collateralAmount);
+        }
+
+        // updated locked amount
+        instanceStore.increaseLocked(bundleNftId, collateralAmount);
+        
+        // link policy to bundle in bundle manger
+        _linkPolicy(instance, policyNftId);
+    }
+
+
+    function lock(NftId bundleNftId) 
+        external
+        virtual
+    {
+        (,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+
+        // udpate bundle state
+        instance.getInstanceStore().updateBundleState(bundleNftId, PAUSED());
+
+        // update set of active bundles
+        BundleManager bundleManager = instance.getBundleManager();
+        bundleManager.lock(bundleNftId);
+
+        emit LogBundleServiceBundleLocked(bundleNftId);
+    }
+
+
+    function unlock(NftId bundleNftId) 
+        external
+        virtual
+    {
+        (,, IInstance instance) = _getAndVerifyActiveComponent(POOL());
+
+        // udpate bundle state
+        instance.getInstanceStore().updateBundleState(bundleNftId, ACTIVE());
+
+        // update set of active bundles
+        BundleManager bundleManager = instance.getBundleManager();
+        bundleManager.unlock(bundleNftId);
+
+        emit LogBundleServiceBundleActivated(bundleNftId);
+    }
+
+
+    function close(
+        IInstance instance,
+        NftId bundleNftId
+    ) 
+        external
+        virtual
+        restricted
+    {
+        // udpate bundle state
+        instance.getInstanceStore().updateBundleState(bundleNftId, CLOSED());
+
+        // ensure no open policies attached to bundle
+        BundleManager bundleManager = instance.getBundleManager();
+        uint256 openPolicies = bundleManager.activePolicies(bundleNftId);
+        if(openPolicies > 0) {
+            revert ErrorBundleServiceBundleWithOpenPolicies(bundleNftId, openPolicies);
+        }
+
+        // update set of active bundles
+        bundleManager.lock(bundleNftId);
+    }
+
+
+    function releaseCollateral(
+        IInstance instance,
+        NftId policyNftId, 
+        NftId bundleNftId, 
+        Amount collateralAmount
+    ) 
+        external
+        virtual
+        restricted()
+    {
+        instance.getInstanceStore().decreaseLocked(bundleNftId, collateralAmount);
+    }
+
+    /// @dev links policy to bundle
+    function _linkPolicy(IInstance instance, NftId policyNftId) 
+        internal
+    {
+        InstanceReader instanceReader = instance.getInstanceReader();
+        IPolicy.PolicyInfo memory policyInfo = instanceReader.getPolicyInfo(policyNftId);
+
+        // ensure policy has not yet been activated in a previous tx already
+        if (policyInfo.activatedAt.gtz() && policyInfo.activatedAt < TimestampLib.blockTimestamp()) {
+            revert BundleManager.ErrorBundleManagerPolicyAlreadyActivated(policyNftId);
+        }
+        
+        BundleManager bundleManager = instance.getBundleManager();
+        bundleManager.linkPolicy(policyNftId);
+    }
+
+    /// @dev unlinks policy from bundle
+    function unlinkPolicy(
+        IInstance instance, 
+        NftId policyNftId
+    ) 
+        external
+        virtual
+        restricted
+    {
+        // ensure policy is closeable
+        if (!instance.getInstanceReader().policyIsCloseable(policyNftId)) {
+            revert ErrorBundleServicePolicyNotCloseable(policyNftId);
+        }
+
+        instance.getBundleManager().unlinkPolicy(policyNftId);
+    }
+}