@etherisc/gif-next 0.0.2-790d44b-698 → 0.0.2-7acbd99-227

package/contracts/registry/RegistryInstaller.sol

@@ -0,0 +1,100 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity ^0.8.20;
+
+import {IERC721Receiver} from "@openzeppelin5/contracts/token/ERC721/IERC721Receiver.sol";
+import {Ownable} from "@openzeppelin5/contracts/access/Ownable.sol";
+
+import {IChainNft} from "./IChainNft.sol";
+import {IRegistry} from "./IRegistry.sol";
+import {IVersionable} from "../shared/IVersionable.sol";
+import {NftId} from "../types/NftId.sol";
+import {ProxyManager} from "../shared/ProxyManager.sol";
+import {Registry} from "./Registry.sol";
+import {RegistryService} from "./RegistryService.sol";
+
+
+contract RegistryInstaller is
+    Ownable,
+    IERC721Receiver
+{
+    error ErrorProxyManagerWithZeroAddress();
+    error ErrorRegistryServiceWithZeroAddress();
+    error ErrorProxyManagerUnexpectedOwner(address expectedOwner, address actualOwner);
+    error ErrorInstallerNotProxyManagerOwner(address installer, address actualOwner);
+
+    ProxyManager private _proxyManager;
+    address private _implementation;
+    RegistryService private _registryService;
+    IRegistry private _registry;
+    IChainNft private _chainNft;
+
+    /// @dev initializes proxy manager with registry service implementation and deploys registry
+    constructor(
+        address proxyManagerAddress, 
+        address registryServiceImplementationAddress
+    )
+        Ownable(msg.sender)
+    {
+        if (proxyManagerAddress == address(0)) { revert ErrorProxyManagerWithZeroAddress(); }
+        if (registryServiceImplementationAddress == address(0)) { revert ErrorRegistryServiceWithZeroAddress(); }
+
+        _proxyManager = ProxyManager(proxyManagerAddress);
+        // check proxy manager owner is owner of installer
+        if (_proxyManager.owner() != owner()) { revert ErrorProxyManagerUnexpectedOwner(_proxyManager.owner(), owner()); }
+
+        _implementation = registryServiceImplementationAddress;
+    }
+
+    function installRegistryServiceWithRegistry()
+        external
+        onlyOwner()
+    {
+        // check that this contract is now proxy manager owner
+        if (_proxyManager.owner() != address(this)) { revert ErrorInstallerNotProxyManagerOwner(address(this), _proxyManager.owner()); }
+
+        IVersionable versionable = _proxyManager.deploy(_implementation, type(Registry).creationCode);
+        _registryService = RegistryService(address(versionable));
+        _registry = _registryService.getRegistry();
+        _chainNft = _registry.getChainNft();
+
+        // transfer registry ownership back to owner
+        NftId registryNftId = _registry.getNftId(address(_registry));
+        _chainNft.safeTransferFrom(
+            address(this),
+            owner(),
+            registryNftId.toInt(),
+            "");
+
+        // transfer proxy manager back to owner
+        _proxyManager.transferOwnership(owner());
+    }
+
+    function getRegistryService()
+        external
+        view
+        returns (RegistryService registryService)
+    {
+        return _registryService;
+    }
+
+    function getRegistry()
+        external
+        view
+        returns (RegistryService registryService)
+    {
+        return _registryService;
+    }
+
+    //--- IERC721Receiver -----------------------------------//
+    function onERC721Received(
+        address operator,
+        address from,
+        uint256 tokenId,
+        bytes calldata data
+    )
+        external 
+        returns (bytes4)
+    {
+        return IERC721Receiver.onERC721Received.selector;
+    }
+}

package/contracts/registry/RegistryService.sol

@@ -0,0 +1,383 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {IERC20Metadata} from "@openzeppelin5/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IInstance} from "../instance/IInstance.sol";
+
+//import {ITreasury, ITreasuryModule} from "../../contracts/instance/module/treasury/ITreasury.sol";
+//import {TreasuryModule} from "../../contracts/instance/module/treasury/TreasuryModule.sol";
+import {IComponent, IComponentModule} from "../../contracts/instance/module/component/IComponent.sol";
+import {IPool} from "../../contracts/instance/module/pool/IPoolModule.sol";
+import {IBaseComponent} from "../../contracts/components/IBaseComponent.sol";
+import {IPoolComponent} from "../../contracts/components/IPoolComponent.sol";
+import {IProductComponent} from "../../contracts/components/IProductComponent.sol";
+import {IDistributionComponent} from "../../contracts/components/IDistributionComponent.sol";
+
+import {IVersionable} from "../../contracts/shared/IVersionable.sol";
+import {Versionable} from "../../contracts/shared/Versionable.sol";
+import {IRegisterable} from "../../contracts/shared/IRegisterable.sol";
+
+import {RoleId, PRODUCT_OWNER_ROLE, POOL_OWNER_ROLE, ORACLE_OWNER_ROLE} from "../../contracts/types/RoleId.sol";
+import {ObjectType, REGISTRY, TOKEN, SERVICE, PRODUCT, ORACLE, POOL, TOKEN, INSTANCE, DISTRIBUTION, POLICY, BUNDLE} from "../../contracts/types/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED} from "../../contracts/types/StateId.sol";
+import {NftId, NftIdLib, zeroNftId} from "../../contracts/types/NftId.sol";
+import {Fee, FeeLib} from "../../contracts/types/Fee.sol";
+import {Version, VersionPart, VersionLib} from "../../contracts/types/Version.sol";
+//import {UFixed, UFixedMathLib} from "../../contracts/types/UFixed.sol";
+
+
+import {ServiceBase} from "../../contracts/instance/base/ServiceBase.sol";
+import {IService} from "../../contracts/instance/base/IService.sol";
+import {IRegistryService} from "./IRegistryService.sol";
+import {Registry} from "../registry/Registry.sol";
+
+contract RegistryService is
+    ServiceBase,
+    IRegistryService
+{
+    using NftIdLib for NftId;
+
+    error NotRegistryOwner();
+    error MissingAllowance();
+
+    error NotToken();
+    error NotService();
+    error NotComponent();
+    error NotInstance();
+
+    error InvalidAddress(address registerableAddress);
+    error InvalidInitialOwner(address initialOwner);
+    error SelfRegistration();
+    error InvalidType(ObjectType objectType);
+
+    string public constant NAME = "RegistryService";
+
+    bytes32 public constant REGISTRY_CREATIONCODE_HASH = 0x7e569c7200a12c63728b648d78f84be7e32ef6804f9ee723e15363ce34d01251;
+
+    address constant public NFT_LOCK_ADDRESS = address(0x1);
+
+    /// @dev 
+    //  msg.sender - ONLY registry owner
+    //      CAN register ANY non IRegisterable address
+    //      CAN register ONLY valid object-parent types combinations for TOKEN
+    //      CAN NOT register itself
+    // IMPORTANT: MUST NOT call untrusted contract inbetween calls to registry/instance (trusted contracts)
+    // motivation: registry/instance state may change during external call
+    // TODO it may be usefull to have transferable token nft in order to delist token, make it invalid for new beginings
+    // TODO: MUST prohibit registration of precompiles addresses
+    function registerToken(address tokenAddress)
+        external 
+        returns(NftId nftId) 
+    {
+        IRegisterable registerable = IRegisterable(tokenAddress);
+        bool isRegisterable;
+
+        // registryOwner can not register IRegisterable as TOKEN
+        try registerable.supportsInterface(type(IRegisterable).interfaceId) returns(bool result) {
+            isRegisterable = result;
+        } catch {
+            isRegisterable = false;
+        }
+
+        if(isRegisterable) {
+            revert NotToken();
+        } 
+
+        IRegistry registry = getRegistry();
+
+        if(msg.sender != registry.ownerOf(address(registry))) {
+            revert NotRegistryOwner();
+        }
+
+        IRegistry.ObjectInfo memory info = IRegistry.ObjectInfo(
+            zeroNftId(), // any value
+            registry.getNftId(address(registry)),
+            TOKEN(),
+            false, // isInterceptor
+            tokenAddress,
+            NFT_LOCK_ADDRESS,
+            "" // any value
+        );
+
+        nftId = registry.register(info);
+    }
+
+    /// @dev 
+    //  msg.sender - ONLY registry owner
+    //      CAN register ONLY valid object-parent types combinations for SERVICE
+    //      CAN register ONLY IRegisterable address he owns
+    //      CAN NOT register itself
+    // IMPORTANT: MUST NOT check owner before calling external contract
+    function registerService(IService service)
+        external
+        returns(
+            IRegistry.ObjectInfo memory info,
+            bytes memory data
+        ) 
+    {
+        if(service.supportsInterface(type(IService).interfaceId) == false) {
+            revert NotService();
+        } 
+
+        (
+            info, 
+            data
+        ) = _getAndVerifyContractInfo(service, SERVICE(), msg.sender);
+
+        IRegistry registry = getRegistry();
+
+        if(msg.sender != registry.ownerOf(address(registry))) {
+            revert NotRegistryOwner();
+        }
+
+        info.initialOwner = NFT_LOCK_ADDRESS;//registry.getLockAddress();
+        info.nftId = registry.register(info);
+
+        return (
+            info,
+            data
+        );
+    }
+
+    // anybody can register component if instance gives a corresponding role
+    //function registerComponent(IBaseComponent component, ObjectType componentType)
+    function registerComponent(IBaseComponent component, ObjectType componentType, address owner)
+        external
+        returns(
+            IRegistry.ObjectInfo memory info,
+            bytes memory data
+        ) 
+    {
+        if(component.supportsInterface(type(IBaseComponent).interfaceId) == false) {
+            revert NotComponent();
+        }
+
+        (
+            info, 
+            data
+        ) = _getAndVerifyContractInfo(component, componentType, owner);
+
+        IRegistry registry = getRegistry();
+        NftId serviceNftId = registry.getNftId(msg.sender);
+
+        if(registry.allowance(serviceNftId, componentType) == false) {
+            revert MissingAllowance();
+        }      
+
+        info.nftId = registry.register(info);
+
+        return (
+            info,
+            data
+        );  
+    }
+
+    // TODO: when called by approved service: add owner arg (service must pass it's msg.sender as owner) & check service allowance
+    //function registerInstance(IRegisterable instance, address owner)
+    function registerInstance(IRegisterable instance)
+        external 
+        returns(
+            IRegistry.ObjectInfo memory info,
+            bytes memory data
+        ) 
+    {
+        if(instance.supportsInterface(type(IInstance).interfaceId) == false) {
+            revert NotInstance();
+        }
+
+        (
+            info, 
+            data
+        ) = _getAndVerifyContractInfo(instance, INSTANCE(), msg.sender);// owner);
+
+        IRegistry registry = getRegistry();
+
+        //if(registry.allowance(registry.getNftId(msg.sender), INSTANCE()) == false) {
+        //    revert MissingAllowance();
+        //}
+
+        info.nftId = registry.register(info);     
+        
+        return (
+            info,
+            data            
+        );
+    }
+
+    function registerPolicy(IRegistry.ObjectInfo memory info)
+        external 
+        returns(NftId nftId) 
+    {
+        IRegistry registry = getRegistry();
+        NftId senderNftId = registry.getNftId(msg.sender);
+
+        if(registry.allowance(senderNftId, POLICY()) == false) {
+            revert MissingAllowance();
+        }
+
+        _verifyObjectInfo(info, POLICY());
+
+        nftId = registry.register(info);
+    }
+
+    function registerBundle(IRegistry.ObjectInfo memory info)
+        external 
+        returns(NftId nftId) 
+    {
+        IRegistry registry = getRegistry();
+        NftId senderNftId = registry.getNftId(msg.sender);
+
+        if(registry.allowance(senderNftId, BUNDLE()) == false) {
+            revert MissingAllowance();
+        }
+
+        _verifyObjectInfo(info, BUNDLE());
+
+        nftId = registry.register(info);
+    }
+
+
+    // From IService
+    function getName() public pure override(IService, ServiceBase) returns(string memory) {
+        return NAME;
+    }
+
+
+    // from Versionable
+
+    /// @dev top level initializer
+    // 1) registry is non upgradeable -> don't need a proxy and uses constructor !
+    // 2) deploy registry service first -> from its initialization func it is easier to deploy registry then vice versa
+    // 3) deploy registry -> pass registry service address as constructor argument
+    // registry is getting instantiated and locked to registry service address forever
+    function _initialize(address owner, bytes memory registryCreationCode)
+        internal
+        initializer
+        virtual override
+    {
+        // TODO check when stable
+        //require(keccak256(registryCreationCode) == REGISTRY_CREATIONCODE_HASH, "INVALID_REGISTRY_CREATIONCODE");
+
+        bytes memory bytecode = abi.encodePacked(
+            registryCreationCode, 
+            abi.encode(
+                owner,
+                getMajorVersion()
+            )
+        );
+
+        address registryAddress;
+
+        assembly {
+            registryAddress := create(0, add(bytecode, 0x20), mload(bytecode))  
+
+            if iszero(extcodesize(registryAddress)) {
+                revert(0, 0)
+            }
+        }
+
+        IRegistry registry = IRegistry(registryAddress);
+        NftId registryNftId = registry.getNftId(registryAddress);
+
+        _initializeServiceBase(registryAddress, registryNftId, owner);
+
+        _registerInterface(type(IRegistryService).interfaceId);
+    }
+
+    // parent check done in registry because of approve()
+    function _getAndVerifyContractInfo(
+        IRegisterable registerable,
+        ObjectType objectType,
+        address owner
+    )
+        internal
+        returns(
+            IRegistry.ObjectInfo memory info, 
+            bytes memory data
+        )
+    {
+        (
+            info, 
+            data
+        ) = registerable.getInitialInfo();
+
+        if(info.objectAddress != address(registerable)) {
+            revert InvalidAddress(info.objectAddress);
+        }
+
+        if(
+            getRegistry().isRegistered(owner) ||
+            info.initialOwner != owner) { // contract owner protection
+            revert InvalidInitialOwner(info.initialOwner);
+        }
+
+        if(msg.sender == address(registerable)) {
+            revert SelfRegistration();
+        }
+        
+        if(info.objectType != objectType) {
+            revert InvalidType(info.objectType);
+        }
+
+        /*NftId parentNftId = info.parentNftId;
+        IRegistry.ObjectInfo memory parentInfo = getRegistry().getObjectInfo(parentNftId);
+
+        if(parentInfo.objectType != parentType) { // parent registration + type
+            revert InvalidParent(parentNftId);
+        }*/
+
+        return(
+            info,
+            data
+        );
+    }
+
+    // parent checks done in registry because of approve()
+    function _verifyObjectInfo(
+        IRegistry.ObjectInfo memory info,
+        ObjectType objectType
+    )
+        internal
+        view
+    {
+        if(info.objectAddress > address(0)) {
+            revert InvalidAddress(info.objectAddress);
+        }
+
+        if(
+            getRegistry().isRegistered(info.initialOwner) ||
+            info.initialOwner == address(0)) {
+            // TODO non registered address can register object(e.g. POLICY()) and then transfer associated nft to registered contract
+            // what are motivations to do so?
+            // at least registered contract can not register objects by itself, SERVICE, 
+            revert InvalidInitialOwner(info.initialOwner); 
+        }
+
+        // can catch all 3 if check that initialOwner is not registered
+        /*if(info.initialOwner == msg.sender) {
+            revert InitialOwnerIsParent();
+        }
+
+        if(info.initialOwner == address(this)) {
+            revert InitialOwnerIsService();
+        }
+
+        if(info.initialOwner == address(getRegistry())) {
+            revert InitialOwnerIsRegistry();
+        }*/
+
+        
+        if(info.objectType != objectType) {
+            revert InvalidType(info.objectType);
+        }
+
+        /*NftId parentNftId = info.parentNftId;
+        IRegistry.ObjectInfo memory parentInfo = getRegistry().getObjectInfo(parentNftId);
+
+        if(parentInfo.objectType != parentType) { // parent registration + type
+            revert InvalidParent(parentNftId);
+        }*/        
+    }
+}

package/contracts/shared/ERC165.sol

@@ -1,7 +1,7 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity ^0.8.19;
 
-import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+import {IERC165} from "@openzeppelin5/contracts/utils/introspection/IERC165.sol";
 
 contract ERC165 is IERC165 {
     mapping(bytes4 => bool) private _isSupported;

package/contracts/shared/IRegisterable.sol

@@ -1,7 +1,7 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
 
-import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+import {IERC165} from "@openzeppelin5/contracts/utils/introspection/IERC165.sol";
 
 import {IRegistry} from "../registry/IRegistry.sol";
 import {NftId} from "../types/NftId.sol";
@@ -12,13 +12,11 @@ import {IOwnable} from "./IOwnable.sol";
 interface IRegisterable is IERC165, IOwnable {
     function getRegistry() external view returns (IRegistry registry);
 
-    function register() external returns (NftId nftId);
-
-    function getType() external pure returns (ObjectType objectType);
-
     function getNftId() external view returns (NftId nftId);
 
-    function getParentNftId() external view returns (NftId nftId);
+    function getInitialInfo() 
+        external 
+        view
+        returns (IRegistry.ObjectInfo memory, bytes memory data);
 
-    function getData() external view returns (bytes memory data);
-}
+}

package/contracts/shared/IVersionable.sol

@@ -1,5 +1,5 @@
 // SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
+pragma solidity ^0.8.20;
 
 import {Blocknumber} from "../types/Blocknumber.sol";
 import {Timestamp} from "../types/Timestamp.sol";
@@ -13,25 +13,22 @@ import {Version} from "../types/Version.sol";
 // 3) implement internal _initialize() function with onlyInitializing modifier 
 // 4) implement internal _upgrade() function with onlyInitializing modifier (1st version MUST revert)
 // 5) have onlyInitialising modifier for each function callable inside _initialize()/_upgrade() (MUST use different functions for initialization/upgrade and normal operations)
-// 6) use default empty constructor -> _disableInitializer() called from Versionable contructor
+// 6) use default empty constructor -> _disableInitializer() is called from Versionable contructor
 // 7) use namespace storage
+// 8) since now inheritance is used for upgradability, contract MUST BE inherited ONLY by the next version 
+// Upgradeable contract SHOULD:
+// 9) define all non private methods as virtual (in order to be able to upgrade them latter)
+//    otherwise, it is still possible to upgrade contract, but everyone who is using it will have to switch to a new fucntions
+//    in some cases this ok but not in the others...
 //
 // IMPORTANT
 // Each version MUST:
-// 1) ALWAYS define namespace storage struct (even if no changes were introduced)
+// 1) define namespace storage struct if accessing storage
 //      - DO NOT use structs inside, except
 //      - CAN use structs ONLY inside mappings
-// 2) ALWAYS define private getter (even if no changes were introduced)
+// 2) ALWAYS define private getter if accessing storage
 //      - MUST use default implementation, CAN change ONLY return type
 //      - MUST use the same "LOCATION_V1"
-// Optional:
-// 4) implement public initialize() 
-//      - MUST use intializer modifier
-//      - MUST call Versionable._updateVersionHistory()
-// 5) implement public upgrade()
-//      - 1st version MUST revert
-//      - MUST use reinitializer(VersionLib.toUint64(getVersion())) modifier
-//      - MUST call Versionable._updateVersionHistory()
 
 interface IVersionable {
 
@@ -69,7 +66,9 @@ interface IVersionable {
     function isInitialized(Version version) external view returns(bool);
 
     /**
-     * @dev returns currently active version of this contract
+     * @dev returns version of this contract
+     * each new implementation MUST implement this function
+     * version number MUST increase 
      */
     function getVersion() external pure returns(Version);
 
@@ -89,6 +88,9 @@ interface IVersionable {
     function getVersionInfo(Version version) external view returns(VersionInfo memory versionInfo);
 
     // TODO make sure it is needed here
+    /**
+     * @dev returns currently active version
+     */
     function getInitializedVersion() external view returns(uint64);
 
 }

package/contracts/shared/ProxyManager.sol

@@ -0,0 +1,115 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {Ownable} from "@openzeppelin5/contracts/access/Ownable.sol";
+import {ProxyAdmin} from "@openzeppelin5/contracts/proxy/transparent/ProxyAdmin.sol";
+import {ITransparentUpgradeableProxy} from "@openzeppelin5/contracts/proxy/transparent/TransparentUpgradeableProxy.sol";
+
+import {IVersionable} from "./IVersionable.sol";
+import {UpgradableProxyWithAdmin} from "./UpgradableProxyWithAdmin.sol";
+import {IVersionable} from "./IVersionable.sol";
+
+/// @dev manages proxy deployments for upgradable contracs of type IVersionable
+contract ProxyManager is Ownable {
+
+    event LogProxyDeployed(address indexed proxy, address initialImplementation);
+    event LogProxyDeployedWithSalt(address indexed proxy, address initialImplementation);
+    event LogProxyUpgraded(address indexed proxy, address upgradedImplementation);
+
+    error ErrorAlreadyDeployed();
+    error ErrorAlreadyDeployedWithSalt();
+    error ErrorNotYetDeployed();
+
+    UpgradableProxyWithAdmin private _proxy;
+    bool private _isDeployed;
+
+    /// @dev only used to capture proxy owner
+    constructor()
+        Ownable(msg.sender)
+    { }
+
+    /// @dev deploy initial contract
+    function deploy(address initialImplementation, bytes memory initializationData)
+        public
+        onlyOwner()
+        returns (IVersionable versionable)
+    {
+        if (_isDeployed) { revert ErrorAlreadyDeployed(); }
+
+        address currentProxyOwner = owner(); // used by implementation
+        address initialProxyAdminOwner = address(this); // used by proxy
+        bytes memory data = getDeployData(initialImplementation, currentProxyOwner, initializationData);
+        
+        _proxy = new UpgradableProxyWithAdmin(
+            initialImplementation,
+            initialProxyAdminOwner,
+            data
+        );
+
+        _isDeployed = true;
+        versionable = IVersionable(address(_proxy));
+
+        emit LogProxyDeployed(address(_proxy), initialImplementation);
+    }
+
+    function deployWithSalt(address initialImplementation, bytes memory initializationData, bytes32 salt)
+        public
+        onlyOwner()
+        returns (IVersionable versionable)
+    {
+        if (_isDeployed) { revert ErrorAlreadyDeployedWithSalt(); }
+
+        address currentProxyOwner = owner(); // used by implementation
+        address initialProxyAdminOwner = address(this); // used by proxy
+        bytes memory data = getDeployData(initialImplementation, currentProxyOwner, initializationData);
+
+        // via create2
+        _proxy = new UpgradableProxyWithAdmin{salt: salt}(
+            initialImplementation,
+            initialProxyAdminOwner,
+            data
+        );
+
+        _isDeployed = true;
+        versionable = IVersionable(address(_proxy));
+
+        emit LogProxyDeployedWithSalt(address(_proxy), initialImplementation);
+    }
+
+    /// @dev upgrade existing contract
+    function upgrade(address newImplementation, bytes memory upgradeData)
+        public
+        virtual
+        onlyOwner()
+        returns (IVersionable versionable)
+    {
+        if (!_isDeployed) { revert ErrorNotYetDeployed(); }
+
+        address currentProxyOwner = owner();
+        ProxyAdmin proxyAdmin = getProxyAdmin();
+        ITransparentUpgradeableProxy proxy = ITransparentUpgradeableProxy(address(_proxy));
+        bytes memory data = getUpgradeData(newImplementation, currentProxyOwner, upgradeData);
+
+        proxyAdmin.upgradeAndCall(
+            proxy,
+            newImplementation, 
+            data);
+
+        versionable = IVersionable(address(_proxy));
+
+        emit LogProxyUpgraded(address(_proxy), newImplementation);
+
+    }
+
+    function getDeployData(address implementation, address proxyOwner, bytes memory deployData) public pure returns (bytes memory data) {
+        return abi.encodeWithSelector(IVersionable.initialize.selector, implementation, proxyOwner, deployData);
+    }
+
+    function getUpgradeData(address implementation, address proxyOwner, bytes memory upgradeData) public pure returns (bytes memory data) {
+        return abi.encodeWithSelector(IVersionable.upgrade.selector, implementation, proxyOwner, upgradeData);
+    }
+
+    function getProxyAdmin() public returns (ProxyAdmin) {
+        return _proxy.getProxyAdmin();
+    }
+}