@etherisc/gif-next 0.0.2-7878646-744 → 0.0.2-788faba-168

package/contracts/types/NftIdSet.sol

@@ -1,60 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {NftId} from "../types/NftId.sol";
-
-// based on https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/utils/structs/EnumerableSet.sol
-library LibNftIdSet {
-
-    struct Set {
-        NftId[] ids;
-        mapping(NftId nftid => uint256 index) at;
-    }
-
-    function add(Set storage set, NftId nftId) external returns(bool added) {
-        if (set.at[nftId] == 0) {
-            set.ids.push(nftId);
-            set.at[nftId] = set.ids.length;
-            return true;
-        } else {
-            return false;
-        }
-    }
-
-    function remove(Set storage set, NftId nftId) external returns(bool removed) {
-        uint256 nftIdIndex = set.at[nftId];
-
-        if (nftIdIndex > 0) {
-            uint256 toDeleteIndex = nftIdIndex - 1;
-            uint256 lastIndex = set.ids.length - 1;
-
-            if (lastIndex != toDeleteIndex) {
-                NftId lastId = set.ids[lastIndex];
-                set.ids[toDeleteIndex] = lastId;
-                set.at[lastId] = nftIdIndex; // Replace lastValue's index to valueIndex
-            }
-
-            set.ids.pop();
-            delete set.at[nftId];
-            return true;
-        } else {
-            return false;
-        }
-    }
-
-    function isEmpty(Set storage set) external view returns(bool empty) {
-        return set.ids.length == 0;
-    }
-
-    function contains(Set storage set, NftId nftId) external view returns(bool inSet) {
-        return set.at[nftId] > 0;
-    }
-
-    function getLength(Set storage set) external view returns(uint256 length) {
-        return set.ids.length;
-    }
-
-    function getElementAt(Set storage set, uint256 index) external view returns(NftId nftId) {
-        return set.ids[index];
-    }
-}

package/contracts/types/ObjectType.sol

@@ -1,131 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-type ObjectType is uint8;
-
-// type bindings
-using {
-    eqObjectType as ==,
-    neObjectType as !=,
-    ObjectTypeLib.toInt,
-    ObjectTypeLib.gtz
-} for ObjectType global;
-
-// general pure free functions
-
-function PROTOCOL() pure returns (ObjectType) {
-    return toObjectType(10);
-}
-
-function REGISTRY() pure returns (ObjectType) {
-    return toObjectType(20);
-}
-
-function TOKEN() pure returns (ObjectType) {
-    return toObjectType(30);
-}
-
-function SERVICE() pure returns (ObjectType) {
-    return toObjectType(40);
-}
-
-function INSTANCE() pure returns (ObjectType) {
-    return toObjectType(50);
-}
-
-function STAKE() pure returns (ObjectType) {
-    return toObjectType(60);
-}
-
-function COMPONENT() pure returns (ObjectType) {
-    return toObjectType(100);
-}
-
-function TREASURY() pure returns (ObjectType) {
-    return toObjectType(101);
-}
-
-function PRODUCT() pure returns (ObjectType) {
-    return toObjectType(110);
-}
-
-function DISTRIBUTION() pure returns (ObjectType) {
-    return toObjectType(120);
-}
-
-function ORACLE() pure returns (ObjectType) {
-    return toObjectType(130);
-}
-
-function POOL() pure returns (ObjectType) {
-    return toObjectType(140);
-}
-
-function RISK() pure returns (ObjectType) {
-    return toObjectType(200);
-}
-
-function POLICY() pure returns (ObjectType) {
-    return toObjectType(210);
-}
-
-function REFERRAL() pure returns (ObjectType) {
-    return toObjectType(212);
-}
-
-function CLAIM() pure returns (ObjectType) {
-    return toObjectType(214);
-}
-
-function PAYOUT() pure returns (ObjectType) {
-    return toObjectType(216);
-}
-
-function BUNDLE() pure returns (ObjectType) {
-    return toObjectType(220);
-}
-
-/// @dev Converts the uint8 to a ObjectType.
-function toObjectType(uint256 objectType) pure returns (ObjectType) {
-    return ObjectType.wrap(uint8(objectType));
-}
-
-/// @dev Return the ObjectType zero (0)
-function zeroObjectType() pure returns (ObjectType) {
-    return ObjectType.wrap(0);
-}
-
-// pure free functions for operators
-function eqObjectType(ObjectType a, ObjectType b) pure returns (bool isSame) {
-    return ObjectType.unwrap(a) == ObjectType.unwrap(b);
-}
-
-function neObjectType(
-    ObjectType a,
-    ObjectType b
-) pure returns (bool isDifferent) {
-    return ObjectType.unwrap(a) != ObjectType.unwrap(b);
-}
-
-// library functions that operate on user defined type
-library ObjectTypeLib {
-    /// @dev Converts the NftId to a uint256.
-    function toInt(ObjectType objectType) public pure returns (uint96) {
-        return uint96(ObjectType.unwrap(objectType));
-    }
-
-    /// @dev Returns true if the value is non-zero (> 0).
-    function gtz(ObjectType a) public pure returns (bool) {
-        return ObjectType.unwrap(a) > 0;
-    }
-
-    /// @dev Returns true if the value is zero (== 0).
-    function eqz(ObjectType a) public pure returns (bool) {
-        return ObjectType.unwrap(a) == 0;
-    }
-
-    /// @dev Returns true if the values are equal (==).
-    function eq(ObjectType a, ObjectType b) public pure returns (bool isSame) {
-        return eqObjectType(a, b);
-    }
-}

package/contracts/types/ReferralId.sol

@@ -1,48 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {Key32, KeyId, Key32Lib} from "./Key32.sol";
-import {REFERRAL} from "./ObjectType.sol";
-
-type ReferralId is bytes8;
-
-// type bindings
-using {
-    eqReferralId as ==, 
-    neReferralId as !=,
-    ReferralIdLib.toKey32
-} for ReferralId global;
-
-// general pure free functions
-
-// @dev Returns true iff risk ids a and b are identical
-function eqReferralId(ReferralId a, ReferralId b) pure returns (bool isSame) {
-    return ReferralId.unwrap(a) == ReferralId.unwrap(b);
-}
-
-// @dev Returns true iff risk ids a and b are different
-function neReferralId(ReferralId a, ReferralId b) pure returns (bool isDifferent) {
-    return ReferralId.unwrap(a) != ReferralId.unwrap(b);
-}
-
-library ReferralIdLib {
-
-    function zeroReferralId() public pure returns (ReferralId) {
-        return ReferralId.wrap(bytes8(0));
-    }
-
-    // @dev Converts a role string into a role id.
-    function toReferralId(string memory referral) public pure returns (ReferralId) {
-        return ReferralId.wrap(bytes8(keccak256(abi.encode(referral))));
-    }
-
-    /// @dev Returns the key32 value for the specified id
-    function toKey32(ReferralId id) public pure returns (Key32 key) {
-        return Key32Lib.toKey32(REFERRAL(), toKeyId(id));
-    }
-
-    /// @dev Returns the key id value for the specified id
-    function toKeyId(ReferralId id) public pure returns (KeyId keyId) {
-        return KeyId.wrap(bytes31(ReferralId.unwrap(id)));
-    }
-}

package/contracts/types/RiskId.sol

@@ -1,43 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-import {Key32, KeyId, Key32Lib} from "./Key32.sol";
-import {RISK} from "./ObjectType.sol";
-
-type RiskId is bytes8;
-
-// type bindings
-using {
-    eqRiskId as ==, 
-    neRiskId as !=,
-    RiskIdLib.toKey32
-} for RiskId global;
-
-// general pure free functions
-
-// @dev Returns true iff risk ids a and b are identical
-function eqRiskId(RiskId a, RiskId b) pure returns (bool isSame) {
-    return RiskId.unwrap(a) == RiskId.unwrap(b);
-}
-
-// @dev Returns true iff risk ids a and b are different
-function neRiskId(RiskId a, RiskId b) pure returns (bool isDifferent) {
-    return RiskId.unwrap(a) != RiskId.unwrap(b);
-}
-
-library RiskIdLib {
-    // @dev Converts a role string into a role id.
-    function toRiskId(string memory risk) public pure returns (RiskId) {
-        return RiskId.wrap(bytes8(keccak256(abi.encode(risk))));
-    }
-
-    /// @dev Returns the key32 value for the specified nft id and object type.
-    function toKey32(RiskId id) public pure returns (Key32 key) {
-        return Key32Lib.toKey32(RISK(), toKeyId(id));
-    }
-
-    /// @dev Returns the key id value for the specified nft id
-    function toKeyId(RiskId id) public pure returns (KeyId keyId) {
-        return KeyId.wrap(bytes31(RiskId.unwrap(id)));
-    }
-}

package/contracts/types/RoleId.sol

@@ -1,45 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.19;
-
-type RoleId is bytes8;
-
-// type bindings
-using {
-    eqRoleId as ==, 
-    neRoleId as !=
-} for RoleId global;
-
-// general pure free functions
-function DISTRIBUTION_OWNER_ROLE_NAME() pure returns (string memory) { return "DistributionOwnerRole"; }
-function ORACLE_OWNER_ROLE_NAME() pure returns (string memory) { return "OracleOwnerRole"; }
-function POOL_OWNER_ROLE_NAME() pure returns (string memory) { return "PoolOwnerRole"; }
-function PRODUCT_OWNER_ROLE_NAME() pure returns (string memory) { return "ProductOwnerRole"; }
-
-function DISTRIBUTION_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId("DistributionOwnerRole"); }
-function ORACLE_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId("OracleOwnerRole"); }
-function POOL_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId("PoolOwnerRole"); }
-function PRODUCT_OWNER_ROLE() pure returns (RoleId) { return RoleIdLib.toRoleId("ProductOwnerRole"); }
-
-function PRODUCT_REGISTRAR_ROLE() pure returns(uint64 roleId) { return 1; }
-function POOL_REGISTRAR_ROLE() pure returns(uint64 roleId) { return 2; }
-function DISTRIBUTION_REGISTRAR_ROLE() pure returns(uint64 roleId) { return 3; }
-function ORACLE_REGISTRAR_ROLE() pure returns(uint64 roleId) { return 4; }
-function POLICY_REGISTRAR_ROLE() pure returns(uint64 roleId) { return 5; }
-function BUNDLE_REGISTRAR_ROLE() pure returns(uint64 roleId) { return 6; }
-
-// @dev Returns true iff role ids a and b are identical
-function eqRoleId(RoleId a, RoleId b) pure returns (bool isSame) {
-    return RoleId.unwrap(a) == RoleId.unwrap(b);
-}
-
-// @dev Returns true iff role ids a and b are different
-function neRoleId(RoleId a, RoleId b) pure returns (bool isDifferent) {
-    return RoleId.unwrap(a) != RoleId.unwrap(b);
-}
-
-library RoleIdLib {
-    // @dev Converts a role string into a role id.
-    function toRoleId(string memory role) public pure returns (RoleId) {
-        return RoleId.wrap(bytes8(keccak256(abi.encode(role))));
-    }
-}

package/contracts/types/UFixed.sol

@@ -1,325 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-/// @dev UFixed is a fixed point number with 18 decimals precision.
-type UFixed is uint256;
-
-using {
-    addUFixed as +,
-    subUFixed as -,
-    mulUFixed as *,
-    divUFixed as /,
-    gtUFixed as >,
-    gteUFixed as >=,
-    ltUFixed as <,
-    lteUFixed as <=,
-    eqUFixed as ==,
-    neUFixed as !=,
-    UFixedLib.toInt,
-    UFixedLib.gtz
-} for UFixed global;
-
-function zeroUFixed() pure returns (UFixed zero) {
-    return UFixed.wrap(0);
-}
-
-function addUFixed(UFixed a, UFixed b) pure returns (UFixed) {
-    return UFixed.wrap(UFixed.unwrap(a) + UFixed.unwrap(b));
-}
-
-function subUFixed(UFixed a, UFixed b) pure returns (UFixed) {
-    require(a >= b, "ERROR:UFM-010:NEGATIVE_RESULT");
-    return UFixed.wrap(UFixed.unwrap(a) - UFixed.unwrap(b));
-}
-
-function mulUFixed(UFixed a, UFixed b) pure returns (UFixed) {
-    return
-        UFixed.wrap(MathLib.mulDiv(UFixed.unwrap(a), UFixed.unwrap(b), 10 ** 18));
-}
-
-function divUFixed(UFixed a, UFixed b) pure returns (UFixed) {
-    require(UFixed.unwrap(b) > 0, "ERROR:UFM-020:DIVISOR_ZERO");
-
-    return
-        UFixed.wrap(MathLib.mulDiv(UFixed.unwrap(a), 10 ** 18, UFixed.unwrap(b)));
-}
-
-function gtUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
-    return UFixed.unwrap(a) > UFixed.unwrap(b);
-}
-
-function gteUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
-    return UFixed.unwrap(a) >= UFixed.unwrap(b);
-}
-
-function ltUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
-    return UFixed.unwrap(a) < UFixed.unwrap(b);
-}
-
-function lteUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
-    return UFixed.unwrap(a) <= UFixed.unwrap(b);
-}
-
-function eqUFixed(UFixed a, UFixed b) pure returns (bool isEqual) {
-    return UFixed.unwrap(a) == UFixed.unwrap(b);
-}
-
-function neUFixed(UFixed a, UFixed b) pure returns (bool isEqual) {
-    return UFixed.unwrap(a) != UFixed.unwrap(b);
-}
-
-function gtzUFixed(UFixed a) pure returns (bool isZero) {
-    return UFixed.unwrap(a) > 0;
-}
-
-function eqzUFixed(UFixed a) pure returns (bool isZero) {
-    return UFixed.unwrap(a) == 0;
-}
-
-function deltaUFixed(UFixed a, UFixed b) pure returns (UFixed) {
-    if (a > b) {
-        return a - b;
-    }
-
-    return b - a;
-}
-
-/// @dev copied from https://github.com/OpenZeppelin/openzeppelin-contracts/blob/v4.9.3/contracts/utils/math/Math.sol
-library MathLib {
-
-    enum Rounding {
-        Down, // Toward negative infinity
-        Up, // Toward infinity
-        Zero // Toward zero
-    }
-
-    /**
-     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
-     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
-     * with further edits by Uniswap Labs also under MIT license.
-     */
-    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
-        unchecked {
-            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
-            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
-            // variables such that product = prod1 * 2^256 + prod0.
-            uint256 prod0; // Least significant 256 bits of the product
-            uint256 prod1; // Most significant 256 bits of the product
-            assembly {
-                let mm := mulmod(x, y, not(0))
-                prod0 := mul(x, y)
-                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
-            }
-
-            // Handle non-overflow cases, 256 by 256 division.
-            if (prod1 == 0) {
-                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
-                // The surrounding unchecked block does not change this fact.
-                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
-                return prod0 / denominator;
-            }
-
-            // Make sure the result is less than 2^256. Also prevents denominator == 0.
-            require(denominator > prod1, "Math: mulDiv overflow");
-
-            ///////////////////////////////////////////////
-            // 512 by 256 division.
-            ///////////////////////////////////////////////
-
-            // Make division exact by subtracting the remainder from [prod1 prod0].
-            uint256 remainder;
-            assembly {
-                // Compute remainder using mulmod.
-                remainder := mulmod(x, y, denominator)
-
-                // Subtract 256 bit number from 512 bit number.
-                prod1 := sub(prod1, gt(remainder, prod0))
-                prod0 := sub(prod0, remainder)
-            }
-
-            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
-            // See https://cs.stackexchange.com/q/138556/92363.
-
-            // Does not overflow because the denominator cannot be zero at this stage in the function.
-            uint256 twos = denominator & (~denominator + 1);
-            assembly {
-                // Divide denominator by twos.
-                denominator := div(denominator, twos)
-
-                // Divide [prod1 prod0] by twos.
-                prod0 := div(prod0, twos)
-
-                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
-                twos := add(div(sub(0, twos), twos), 1)
-            }
-
-            // Shift in bits from prod1 into prod0.
-            prod0 |= prod1 * twos;
-
-            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
-            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
-            // four bits. That is, denominator * inv = 1 mod 2^4.
-            uint256 inverse = (3 * denominator) ^ 2;
-
-            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
-            // in modular arithmetic, doubling the correct bits in each step.
-            inverse *= 2 - denominator * inverse; // inverse mod 2^8
-            inverse *= 2 - denominator * inverse; // inverse mod 2^16
-            inverse *= 2 - denominator * inverse; // inverse mod 2^32
-            inverse *= 2 - denominator * inverse; // inverse mod 2^64
-            inverse *= 2 - denominator * inverse; // inverse mod 2^128
-            inverse *= 2 - denominator * inverse; // inverse mod 2^256
-
-            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
-            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
-            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
-            // is no longer required.
-            result = prod0 * inverse;
-            return result;
-        }
-    }
-
-    /**
-     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
-     */
-    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
-        uint256 result = mulDiv(x, y, denominator);
-        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
-            result += 1;
-        }
-        return result;
-    }
-
-}
-
-library UFixedLib {
-    int8 public constant EXP = 18;
-    uint256 public constant MULTIPLIER = 10 ** uint256(int256(EXP));
-    uint256 public constant MULTIPLIER_HALF = MULTIPLIER / 2;
-
-    /// @dev returns the rounding mode DOWN - 0.4 becomes 0, 0.5 becomes 0, 0.6 becomes 0
-    function ROUNDING_DOWN() public pure returns (uint8) {
-        return uint8(0);
-    }
-
-    /// @dev returns the rounding mode UP - 0.4 becomes 1, 0.5 becomes 1, 0.6 becomes 1
-    function ROUNDING_UP() public pure returns (uint8) {
-        return uint8(1);
-    }
-
-    /// @dev returns the rounding mode HALF_UP - 0.4 becomes 0, 0.5 becomes 1, 0.6 becomes 1
-    function ROUNDING_HALF_UP() public pure returns (uint8) {
-        return uint8(2);
-    }
-
-    /// @dev Converts the uint256 to a UFixed.
-    function toUFixed(uint256 a) public pure returns (UFixed) {
-        return UFixed.wrap(a * MULTIPLIER);
-    }
-
-    /// @dev Converts the uint256 to a UFixed with given exponent.
-    function toUFixed(uint256 a, int8 exp) public pure returns (UFixed) {
-        require(EXP + exp >= 0, "ERROR:FM-010:EXPONENT_TOO_SMALL");
-        require(EXP + exp <= 64, "ERROR:FM-011:EXPONENT_TOO_LARGE");
-
-        return UFixed.wrap(a * 10 ** uint8(EXP + exp));
-    }
-
-    /// @dev returns the decimals precision of the UFixed type
-    function decimals() public pure returns (uint256) {
-        return uint8(EXP);
-    }
-
-    /// @dev Converts a UFixed to a uint256.
-    function toInt(UFixed a) public pure returns (uint256) {
-        return toIntWithRounding(a, ROUNDING_HALF_UP());
-    }
-
-    /// @dev Converts a UFixed to a uint256 with given rounding mode.
-    function toIntWithRounding(UFixed a, uint8 rounding) public pure returns (uint256) {
-        if (rounding == ROUNDING_HALF_UP()) {
-            return
-                MathLib.mulDiv(
-                    UFixed.unwrap(a) + MULTIPLIER_HALF,
-                    1,
-                    MULTIPLIER,
-                    MathLib.Rounding.Down
-                );
-        } else if (rounding == ROUNDING_DOWN()) {
-            return
-                MathLib.mulDiv(
-                    UFixed.unwrap(a),
-                    1,
-                    MULTIPLIER,
-                    MathLib.Rounding.Down
-                );
-        } else {
-            return
-                MathLib.mulDiv(UFixed.unwrap(a), 1, MULTIPLIER, MathLib.Rounding.Up);
-        }
-    }
-
-    /// @dev adds two UFixed numbers
-    function add(UFixed a, UFixed b) public pure returns (UFixed) {
-        return addUFixed(a, b);
-    }
-
-    /// @dev subtracts two UFixed numbers
-    function sub(UFixed a, UFixed b) public pure returns (UFixed) {
-        return subUFixed(a, b);
-    }
-
-    /// @dev multiplies two UFixed numbers
-    function mul(UFixed a, UFixed b) public pure returns (UFixed) {
-        return mulUFixed(a, b);
-    }
-
-    /// @dev divides two UFixed numbers
-    function div(UFixed a, UFixed b) public pure returns (UFixed) {
-        return divUFixed(a, b);
-    }
-
-    /// @dev return true if UFixed a is greater than UFixed b
-    function gt(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
-        return gtUFixed(a, b);
-    }
-
-    /// @dev return true if UFixed a is greater than or equal to UFixed b
-    function gte(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
-        return gteUFixed(a, b);
-    }
-
-    /// @dev return true if UFixed a is less than UFixed b
-    function lt(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
-        return ltUFixed(a, b);
-    }
-
-    /// @dev return true if UFixed a is less than or equal to UFixed b
-    function lte(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
-        return lteUFixed(a, b);
-    }
-
-    /// @dev return true if UFixed a is equal to UFixed b
-    function eq(UFixed a, UFixed b) public pure returns (bool isEqual) {
-        return eqUFixed(a, b);
-    }
-
-    /// @dev return true if UFixed a is not zero
-    function gtz(UFixed a) public pure returns (bool isZero) {
-        return gtzUFixed(a);
-    }
-
-    /// @dev return true if UFixed a is zero
-    function eqz(UFixed a) public pure returns (bool isZero) {
-        return eqzUFixed(a);
-    }
-
-    function zero() public pure returns (UFixed) {
-        return UFixed.wrap(0);
-    }
-
-    /// @dev return the absolute delta between two UFixed numbers
-    function delta(UFixed a, UFixed b) public pure returns (UFixed) {
-        return deltaUFixed(a, b);
-    }
-}