@etherisc/gif-next 0.0.2-7631288 → 0.0.2-886fd8b

package/contracts/instance/component/ComponentModule.sol

@@ -0,0 +1,246 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {RegistryLinked} from "../../registry/Registry.sol";
+import {IRegistry, IRegistryLinked} from "../../registry/IRegistry.sol";
+import {IAccessComponentTypeRoles, IAccessCheckRole} from "../access/IAccess.sol";
+import {IInstance} from "../IInstance.sol";
+
+import {IComponent, IComponentContract, IComponentModule, IComponentOwnerService} from "./IComponent.sol";
+import {IProductComponent} from "../../components/IProduct.sol";
+import {IPoolModule} from "../pool/IPoolModule.sol";
+import {NftId, gtz, eqNftId} from "../../types/NftId.sol";
+
+abstract contract ComponentModule is 
+    IRegistryLinked,
+    IAccessComponentTypeRoles,
+    IAccessCheckRole,
+    IComponentModule
+{
+
+    mapping(NftId nftId => ComponentInfo info) private _componentInfo;
+    mapping(NftId nftId => NftId poolNftId) private _poolNftIdForProduct;
+    mapping(address cAddress => NftId nftId) private _nftIdByAddress;
+    NftId[] private _nftIds;
+
+    mapping(uint256 cType => bytes32 role) private _componentOwnerRole;
+
+    IComponentOwnerService private _componentOwnerService;
+
+    modifier onlyComponentOwnerService() {
+        require(address(_componentOwnerService) == msg.sender, "ERROR:CMP-001:NOT_OWNER_SERVICE");
+        _;
+    }
+
+    constructor(address componentOwnerService) {
+        _componentOwnerService = ComponentOwnerService(componentOwnerService);
+    }
+
+    function registerComponent(IComponentContract component)
+        external
+        override
+        onlyComponentOwnerService
+        returns(NftId nftId)
+    {
+        bytes32 typeRole = getRoleForType(component.getType());
+        require(
+            this.hasRole(typeRole, component.getInitialOwner()),
+            "ERROR:CMP-004:TYPE_ROLE_MISSING");
+        
+        nftId = this.getRegistry().register(address(component));
+
+        _componentInfo[nftId] = ComponentInfo(
+            nftId,
+            CState.Active);
+
+        // special case product -> persist product - pool assignment
+        if(component.getType() == this.getRegistry().PRODUCT()) {
+            IProductComponent product = IProductComponent(address(component));
+            NftId poolNftId = product.getPoolNftId();
+            require(gtz(poolNftId), "ERROR:CMP-005:POOL_UNKNOWN");
+            // add more validation (type, token, ...)
+
+            _poolNftIdForProduct[nftId] = poolNftId;
+
+            // add creation of productInfo
+        }
+        else if(component.getType() == this.getRegistry().POOL()) {
+            IPoolModule poolModule = IPoolModule(address(this));
+            poolModule.createPoolInfo(
+                nftId,
+                address(component), // set pool as its wallet
+                address(0) // don't deal with token yet
+            );
+        }
+
+        _nftIdByAddress[address(component)] = nftId;
+        _nftIds.push(nftId);
+
+        // add logging
+    }
+
+    function getPoolNftId(NftId productNftId)
+        external
+        view
+        override
+        returns(NftId poolNftId)
+    {
+        poolNftId = _poolNftIdForProduct[productNftId];
+    }
+
+
+    function getComponentOwnerService()
+        external
+        override
+        view
+        returns(IComponentOwnerService)
+    {
+        return _componentOwnerService;
+    }
+
+    function setComponentInfo(ComponentInfo memory info)
+        external
+        onlyComponentOwnerService
+        returns(NftId nftId)
+    {
+        nftId = info.nftId;
+        require(
+            gtz(nftId) && eqNftId(_componentInfo[nftId].nftId, nftId),
+            "ERROR:CMP-006:COMPONENT_UNKNOWN");
+
+        _componentInfo[nftId] = info;
+
+        // add logging
+    }
+
+    function getComponentInfo(NftId nftId)
+        external
+        override
+        view
+        returns(ComponentInfo memory)
+    {
+        return _componentInfo[nftId];
+    }
+
+    function getComponentOwner(NftId nftId)
+        external
+        view
+        returns(address owner)
+    {
+
+    }
+
+    function getComponentId(address componentAddress)
+        external
+        view
+        returns(NftId componentNftId)
+    {
+        return _nftIdByAddress[componentAddress];
+    }
+
+
+    function getComponentId(uint256 idx)
+        external
+        override
+        view
+        returns(NftId componentNftId)
+    {
+        return _nftIds[idx];
+    }
+
+
+    function components()
+        external
+        override
+        view
+        returns(uint256 numberOfCompnents)
+    {
+        return _nftIds.length;
+    }
+
+    function getRoleForType(uint256 cType)
+        public
+        view
+        returns(bytes32 role)
+    {
+        if(cType == this.getRegistry().PRODUCT()) {
+            return this.PRODUCT_OWNER_ROLE();
+        }
+        if(cType == this.getRegistry().POOL()) {
+            return this.POOL_OWNER_ROLE();
+        }
+        if(cType == this.getRegistry().ORACLE()) {
+            return this.ORACLE_OWNER_ROLE();
+        }
+
+    }
+}
+
+
+// this is actually the component owner service
+contract ComponentOwnerService is
+    RegistryLinked,
+    IComponent,
+    IComponentOwnerService
+{
+
+    modifier onlyComponentOwner(IComponentContract component) {
+        NftId nftId = _registry.getNftId(address(component));
+        require(
+            gtz(nftId), 
+            "ERROR:COS-001:COMPONENT_UNKNOWN");
+        require(
+            msg.sender == _registry.getOwner(nftId),
+            "ERROR:COS-002:NOT_OWNER"
+        );
+        _;
+    }
+
+    constructor(address registry)
+        RegistryLinked(registry)
+    { }
+
+    function register(IComponentContract component)
+        external
+        override
+        returns(NftId nftId)
+    {
+        require(
+            msg.sender == component.getInitialOwner(), 
+            "ERROR:COS-003:NOT_OWNER");
+
+        IInstance instance = component.getInstance();
+        nftId = instance.registerComponent(component);
+    }
+
+
+    function lock(IComponentContract component)
+        external
+        override
+        onlyComponentOwner(component)
+    {
+        IInstance instance = component.getInstance();
+        ComponentInfo memory info = instance.getComponentInfo(component.getNftId());
+        require(gtz(info.nftId), "ERROR_COMPONENT_UNKNOWN");
+        // TODO add state change validation
+
+        info.state = CState.Locked;
+        instance.setComponentInfo(info);
+    }
+
+
+    function unlock(IComponentContract component)
+        external
+        override
+        onlyComponentOwner(component)
+    {
+        IInstance instance = component.getInstance();
+        ComponentInfo memory info = instance.getComponentInfo(component.getNftId());
+        require(gtz(info.nftId), "ERROR_COMPONENT_UNKNOWN");
+        // TODO state change validation
+
+        info.state = CState.Active;
+        instance.setComponentInfo(info);
+    }
+
+}

package/contracts/instance/component/IComponent.sol

@@ -0,0 +1,95 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+
+import {IOwnable, IRegistryLinked, IRegisterable} from "../../registry/IRegistry.sol";
+import {IInstance} from "../IInstance.sol";
+import {NftId} from "../../types/NftId.sol";
+
+interface IComponent {
+
+    // TODO decide if enum or uints with constants (as in IRegistry.PRODUCT())
+    enum CState {
+        Undefined,
+        Active,
+        Locked
+    }
+
+    // component dynamic info (static info kept in registry)
+    struct ComponentInfo {
+        NftId nftId;
+        CState state;
+    }
+}
+
+
+interface IInstanceLinked {
+    // function setInstance(address instance) external;
+    function getInstance() external view returns(IInstance instance);
+}
+
+
+interface IComponentContract is
+    IRegisterable,
+    IInstanceLinked,
+    IComponent
+{ }
+
+
+interface IComponentOwnerService is IRegistryLinked{
+
+    function register(IComponentContract component) external returns(NftId nftId);
+    function lock(IComponentContract component) external;
+    function unlock(IComponentContract component) external;
+}
+
+
+interface IComponentModule is
+    IOwnable,
+    IRegistryLinked,
+    IComponent
+{
+
+    function registerComponent(IComponentContract component)
+        external
+        returns(NftId nftId);
+
+    function setComponentInfo(ComponentInfo memory info)
+        external
+        returns(NftId componentNftId);
+
+    function getComponentInfo(NftId nftId)
+        external
+        view
+        returns(ComponentInfo memory info);
+
+    function getComponentOwner(NftId nftId)
+        external
+        view
+        returns(address owner);
+
+    function getComponentId(address componentAddress)
+        external
+        view
+        returns(NftId nftId);
+
+    function getComponentId(uint256 idx)
+        external
+        view
+        returns(NftId nftId);
+
+    function getPoolNftId(NftId productNftId)
+        external
+        view
+        returns(NftId poolNftId);
+
+    function components()
+        external
+        view
+        returns(uint256 numberOfCompnents);
+
+    function getComponentOwnerService()
+        external
+        view
+        returns(IComponentOwnerService);
+}

package/contracts/instance/policy/IPolicy.sol

@@ -0,0 +1,66 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+
+import {IOwnable, IRegistryLinked, IRegisterable, IRegistry} from "../../registry/IRegistry.sol";
+import {IInstance} from "../IInstance.sol";
+import {IProductService} from "../product/IProductService.sol";
+import {NftId} from "../../types/NftId.sol";
+
+// TODO check if there is value to introuce IContract and let IPolicy derive from IContract
+interface IPolicy {
+
+    enum PolicyState {
+        Undefined,
+        Applied,
+        Rejected,
+        Active,
+        Closed
+    }
+
+    struct PolicyInfo {
+        NftId nftId;
+        PolicyState state; // applied, withdrawn, rejected, active, closed
+
+        uint256 sumInsuredAmount;
+        uint256 premiumAmount;
+        uint256 lifetime; // activatedAt + lifetime >= expiredAt
+
+        uint256 createdAt;
+        uint256 activatedAt; // time of underwriting
+        uint256 expiredAt; // no new claims
+        uint256 closedAt; // no locked capital
+    }
+}
+
+interface IPolicyModule is
+    IOwnable,
+    IRegistryLinked,
+    IPolicy
+{
+
+    function createApplication(
+        IRegistry.RegistryInfo memory productInfo,
+        address applicationOwner,
+        uint256 sumInsuredAmount,
+        uint256 premiumAmount,
+        uint256 lifetime,
+        NftId bundleNftId
+    )
+        external
+        returns(NftId nftId);
+
+    function activate(NftId nftId)
+        external;
+
+    function getBundleNftForPolicy(NftId nftId)
+        external
+        view
+        returns(NftId bundleNft);
+
+    function getPolicyInfo(NftId nftId)
+        external
+        view
+        returns(PolicyInfo memory info);
+
+}

package/contracts/instance/policy/PolicyModule.sol

@@ -0,0 +1,106 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+
+// import {IOwnable, IRegistryLinked, IRegisterable} from "../../registry/IRegistry.sol";
+import {IRegistry, IRegistryLinked} from "../../registry/IRegistry.sol";
+
+import {IProductService} from "../product/IProductService.sol";
+import {IPolicy, IPolicyModule} from "./IPolicy.sol";
+import {NftId, gtz} from "../../types/NftId.sol";
+
+abstract contract PolicyModule is
+    IRegistryLinked,
+    IPolicyModule
+{
+
+    mapping(NftId nftId => PolicyInfo info) private _policyInfo;
+    mapping(NftId nftId => NftId bundleNftId) private _bundleForPolicy;
+
+    IProductService private _productService;
+
+    // TODO find a better place to avoid dupliation
+    modifier onlyProductService2() {
+        require(address(_productService) == msg.sender, "ERROR:POL-001:NOT_PRODUCT_SERVICE");
+        _;
+    }
+
+    constructor(address productService) {
+        _productService = IProductService(productService);
+    }
+
+
+    function createApplication(
+        IRegistry.RegistryInfo memory productInfo,
+        address applicationOwner,
+        uint256 sumInsuredAmount,
+        uint256 premiumAmount,
+        uint256 lifetime,
+        NftId bundleNftId
+    )
+        external
+        override
+        onlyProductService2
+        returns(NftId nftId)
+    {
+        // TODO add parameter validation
+        if(gtz(bundleNftId)) {
+            IRegistry.RegistryInfo memory bundleInfo = this.getRegistry().getInfo(bundleNftId);
+            IRegistry.RegistryInfo memory poolInfo = this.getRegistry().getInfo(bundleInfo.parentNftId);
+        }
+
+        nftId = this.getRegistry().registerObjectForInstance(
+            productInfo.nftId,
+            this.getRegistry().POLICY(),
+            applicationOwner);
+
+        _policyInfo[nftId] = PolicyInfo(
+            nftId,
+            PolicyState.Applied,
+            sumInsuredAmount,
+            premiumAmount,
+            lifetime,
+            block.timestamp,
+            0, // activatedAt
+            0, // expiredAt
+            0 // closedAt
+        );
+
+        _bundleForPolicy[nftId] = bundleNftId;
+
+        // add logging
+    }
+
+
+    function activate(NftId nftId)
+        external
+        override
+        onlyProductService2
+    {
+        PolicyInfo storage info = _policyInfo[nftId];
+        info.activatedAt = block.timestamp;
+        info.expiredAt = block.timestamp + info.lifetime;
+        info.state = PolicyState.Active;
+
+        // add logging
+    }
+
+
+
+    function getBundleNftForPolicy(NftId nftId)
+        external
+        view
+        returns(NftId bundleNft)
+    {
+        return _bundleForPolicy[nftId];
+    }
+
+
+    function getPolicyInfo(NftId nftId)
+        external
+        view
+        returns(PolicyInfo memory info)
+    {
+        return _policyInfo[nftId];
+    }
+}

package/contracts/instance/pool/IPoolModule.sol

@@ -0,0 +1,41 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IOwnable, IRegistry, IRegistryLinked} from "../../registry/IRegistry.sol";
+import {NftId} from "../../types/NftId.sol";
+
+interface IPool {
+
+    struct PoolInfo {
+        NftId nftId;
+        address wallet;
+        address token;
+        uint256 capital;
+        uint256 lockedCapital;
+    }
+}
+
+interface IPoolModule is
+    IOwnable,
+    IRegistryLinked,
+    IPool
+{
+    
+    function underwrite(
+        NftId poolNftId,
+        NftId policyNftId
+    )
+        external;
+
+    function createPoolInfo(
+        NftId nftId,
+        address wallet,
+        address token
+    )
+        external;
+
+    function getPoolInfo(NftId nftId)
+        external
+        view
+        returns(PoolInfo memory info);
+}

package/contracts/instance/pool/PoolModule.sol

@@ -0,0 +1,84 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IOwnable, IRegistry, IRegistryLinked} from "../../registry/IRegistry.sol";
+import {IProductService} from "../product/IProductService.sol";
+import {IPolicy, IPolicyModule} from "../policy/IPolicy.sol";
+import {IPoolModule} from "./IPoolModule.sol";
+import {NftId, eqz} from "../../types/NftId.sol";
+
+abstract contract PoolModule is
+    IPoolModule
+{
+    uint256 public constant INITIAL_CAPITAL = 10000*10**6;
+
+    mapping(NftId nftId => PoolInfo info) private _poolInfo;
+
+    IProductService private _productService;
+
+    modifier onlyProductService() {
+        require(address(_productService) == msg.sender, "ERROR:POL-001:NOT_PRODUCT_SERVICE");
+        _;
+    }
+
+    constructor(address productService) {
+        _productService = IProductService(productService);
+    }
+
+    function createPoolInfo(
+        NftId nftId,
+        address wallet,
+        address token
+    )
+        public
+        override
+    {
+        require(
+            eqz(_poolInfo[nftId].nftId),
+            "ERROR:PL-001:ALREADY_CREATED");
+
+        _poolInfo[nftId] = PoolInfo(
+            nftId,
+            wallet,
+            token,
+            INITIAL_CAPITAL,
+            0 // locked capital
+        );
+
+    }
+
+
+    function underwrite(
+        NftId poolNftId,
+        NftId policyNftId
+    )
+        external
+        override
+        onlyProductService
+    {
+        PoolInfo storage poolInfo = _poolInfo[poolNftId];
+        require(
+            poolInfo.nftId == poolNftId,
+            "ERROR:PL-002:POOL_UNKNOWN");
+
+        IPolicyModule policyModule = IPolicyModule(address(this));
+        IPolicy.PolicyInfo memory policyInfo = policyModule.getPolicyInfo(policyNftId);
+
+        require(
+            poolInfo.capital - poolInfo.lockedCapital >= policyInfo.sumInsuredAmount,
+            "ERROR:PL-003:CAPACITY_TOO_LOW");
+
+        poolInfo.lockedCapital += policyInfo.sumInsuredAmount;
+    }
+
+
+    function getPoolInfo(NftId nftId)
+        external
+        view
+        override
+        returns(PoolInfo memory info)
+    {
+        info = _poolInfo[nftId];
+    }
+
+}

package/contracts/instance/product/IProductService.sol

@@ -0,0 +1,46 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+
+import {IOwnable, IRegistryLinked, IRegisterable} from "../../registry/IRegistry.sol";
+import {IInstance} from "../IInstance.sol";
+import {NftId} from "../../types/NftId.sol";
+
+
+// TODO or name this IProtectionService to have Product be something more generic (loan, savings account, ...)
+interface IProductService is
+    IRegistryLinked
+{
+
+    function createApplication(
+        address applicationOwner,
+        uint256 sumInsuredAmount,
+        uint256 premiumAmount,
+        uint256 lifetime,
+        NftId bundleNftId
+    )
+        external 
+        returns(NftId nftId);
+
+    // function revoke(unit256 nftId) external;
+
+    function underwrite(NftId nftId) external;
+    // function decline(uint256 nftId) external;
+    // function expire(uint256 nftId) external;
+    function close(NftId nftId) external;
+
+    // function collectPremium(uint256 nftId, uint256 premiumAmount) external;
+
+    // function createClaim(uint256 nftId, uint256 claimAmount) external;
+    // function confirmClaim(uint256 nftId, uint256 claimId, uint256 claimAmount) external;
+    // function declineClaim(uint256 nftId, uint256 claimId) external;
+    // function closeClaim(uint256 nftId, uint256 claimId) external;
+}
+
+
+interface IProductModule is
+    IOwnable,
+    IRegistryLinked
+{
+    function getProductService() external view returns(IProductService);
+}