@etherisc/gif-next 0.0.2-76249b0-812 → 0.0.2-764b9d9-026

package/contracts/shared/ComponentVerifyingService.sol

@@ -1,117 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {IInstance} from "../instance/IInstance.sol";
-import {InstanceReader} from "../instance/InstanceReader.sol";
-import {IRegistry} from "../registry/IRegistry.sol";
-import {NftId} from "../type/NftId.sol";
-import {ObjectType, COMPONENT, DISTRIBUTION, ORACLE, POOL, PRODUCT} from "../type/ObjectType.sol";
-import {Service} from "../shared/Service.sol";
-
-
-abstract contract ComponentVerifyingService is 
-    Service
-{
-
-    error ErrorComponentVerifyingServiceComponentTypeInvalid(NftId componentNftId, ObjectType expectedType, ObjectType actualType);
-    error ErrorComponentVerifyingServiceComponentIsLocked(NftId componentNftId);
-
-    /// @dev based on the sender address returns the corresponding components nft id, info and instance.
-    /// the function reverts iff:
-    /// - there is no such component
-    /// - the component has the wrong object type
-    /// - the component is locked
-    function _getAndVerifyActiveComponent(
-        ObjectType expectedType // assume always of `component` type
-    )
-        internal
-        view
-        returns(
-            NftId componentNftId,
-            IRegistry.ObjectInfo memory componentInfo, 
-            IInstance instance
-        )
-    {
-        componentNftId = getRegistry().getNftId(msg.sender);
-        (componentInfo, instance) = _getAndVerifyComponentInfo(
-            componentNftId, 
-            expectedType,
-            true); // only active
-    }
-
-
-    /// @dev returns the component info and instance contract reference given a component nft id
-    /// the function reverts iff:
-    /// - there is no such component
-    /// - the component has the wrong object type
-    function _getAndVerifyComponentInfo(
-        NftId componentNftId,
-        ObjectType expectedType, // assume always of `component` type
-        bool onlyActive
-    )
-        internal
-        virtual
-        view
-        returns(
-            IRegistry.ObjectInfo memory info, 
-            IInstance instance
-        )
-    {
-        IRegistry registry = getRegistry();
-        info = registry.getObjectInfo(componentNftId);
-
-        // if not COMPONENT require exact match
-        if(expectedType != COMPONENT()) {
-            // ensure component is of expected type
-            if(info.objectType != expectedType) {
-                revert ErrorComponentVerifyingServiceComponentTypeInvalid(
-                    componentNftId,
-                    expectedType,
-                    info.objectType);
-            }
-        } else {
-            if(!(info.objectType == PRODUCT()
-                || info.objectType == POOL()
-                || info.objectType == DISTRIBUTION()
-                || info.objectType == ORACLE()
-            ))
-            {
-                revert ErrorComponentVerifyingServiceComponentTypeInvalid(
-                    componentNftId,
-                    expectedType,
-                    info.objectType);
-            }
-        }
-
-        instance = _getInstance(info.parentNftId);
-
-        // ensure component is not locked
-        if (onlyActive) {
-            if (instance.getInstanceAccessManager().isTargetClosed(info.objectAddress)) {
-                revert ErrorComponentVerifyingServiceComponentIsLocked(componentNftId);
-            }
-        }
-    }
-
-
-    /// @dev returns the linked product nft id for the specified component
-    function _getProductNftId(
-        InstanceReader instanceReader,
-        NftId componentNftId
-    )
-        internal
-        virtual
-        view
-        returns (NftId productNftId)
-    {
-        return instanceReader.getComponentInfo(componentNftId).productNftId;
-    }
-
-
-    /// @dev returns an IInstance contract reference for the specified instance nft id
-    function _getInstance(NftId instanceNftId) internal view returns (IInstance) {
-        return IInstance(
-            getRegistry().getObjectInfo(
-                instanceNftId).objectAddress);
-    }
-}

package/contracts/shared/IAccessManagerExtended.sol

@@ -1,74 +0,0 @@
-// SPDX-License-Identifier: MIT
-// OpenZeppelin Contracts (last updated v5.0.0) (access/manager/IAccessManager.sol)
-
-pragma solidity ^0.8.20;
-
-import {IAccessManager} from "@openzeppelin/contracts/access/manager/IAccessManager.sol";
-
-import {Timestamp} from "../type/Timestamp.sol";
-
-interface IAccessManagerExtended is IAccessManager {
-    // Structure that stores the details for a target contract.
-    struct TargetInfo {
-        address taddress;
-        //IAccess.Type ttype;
-        string name;
-        Timestamp createdAt;
-        //Timestamp updatedAt;
-    }
-
-    // Structure that stores the details of a role.
-    struct RoleInfo {
-        uint64 id;
-        //IAccess.Type rtype;
-        string name;
-        Timestamp createdAt;
-    }
-
-    event LogRoleCreation(uint64 roleId, string name);// IAccess.Type rtype);
-    event LogTargetCreation(address target, string name);// IAccess.Type ttype);
-
-    error AccessManagerRoleIdNotExists(uint64 roleId);
-    error AccessManagerRoleIdAlreadyExists(uint64 roleId);
-    error AccessManagerRoleNameAlreadyExists(uint64 newRoleId, uint64 existingRoleId, string duplicateName);
-    error AccessManagerRoleIdZero();
-    error AccessManagerRoleNameEmpty(uint64 roleId);
-    error AccessManagerRoleIdTooBig(uint64 roleId);
-
-    error AccessManagerTargetAlreadyExists(address target);
-    error AccessManagerTargetNotExists(address target);
-    error AccessManagerTargetNameAlreadyExists(address newTarget, address existingTarget, string duplicateName);
-    error AccessManagerTargetAddressZero();
-    error AccessManagerTargetNameEmpty(address target);
-    error AccessManagerTargetAuthorityInvalid(address target, address targetAuthority);
-
-    function getRoleMembers(uint64 roleId) external view returns (uint256 numberOfMembers);
-
-    function getRoleMember(uint64 roleId, uint256 idx) external view returns (address member);
-
-    function getRoleId(uint256 idx) external view returns (uint64 roleId);
-
-    // TODO returns ADMIN_ROLE id for non existent name
-    function getRoleId(string memory name) external view returns (uint64 roleId);
-
-    function getRoles() external view returns (uint256 numberOfRoles);
-
-    function isRoleExists(uint64 roleId) external view returns (bool exists);
-
-    function getRoleInfo(uint64 roleId) external view returns (RoleInfo memory);
-
-    function isRoleNameExists(string memory name) external view returns (bool);
-
-    function isTargetExists(address target) external view returns (bool);
-
-    function isTargetNameExists(string memory name) external view returns (bool);
-    
-    function getTargetAddress(string memory name) external view returns(address targetAddress);
-
-    function getTargetInfo(address target) external view returns (TargetInfo memory);
-
-
-    function createRole(uint64 roleId, string memory roleName/*, IAccess.Type rtype*/) external;
-
-    function createTarget(address target, string memory name/*, IAccess.Type.Custom*/) external;
-}

package/contracts/shared/IAccessManagerExtendedWithDisable.sol

@@ -1,18 +0,0 @@
-// SPDX-License-Identifier: MIT
-
-pragma solidity ^0.8.20;
-
-import {IAccessManagerExtended} from "./IAccessManagerExtended.sol";
-
-import {Timestamp} from "../type/Timestamp.sol";
-import {VersionPart} from "../type/Version.sol";
-import {Seconds} from "../type/Seconds.sol";
-
-interface IAccessManagerExtendedWithDisable is IAccessManagerExtended {
-
-    error AccessManagerDisabled();
-
-    function disable(Seconds delay) external;
-    function enable() external;
-    function getVersion() external view returns (VersionPart version);
-}

package/contracts/shared/InitializableCustom.sol

@@ -1,177 +0,0 @@
-// SPDX-License-Identifier: MIT
-
-pragma solidity ^0.8.20;
-
-/**
- * @dev This is copy of OpenZeppelin's Contracts (last updated v5.0.0) (proxy/utils/Initializable.sol)
- * Changes:
- * 1. name is InitializableCustom
- * 2. no longer abstract
- * 3. have $._initializeOwner
- * 4. have constructor where sets _initializeOwner 
- * 5. initializer() in addition checks for _initializeOwner
- * 6. reinitializer() is deleted
- */
-abstract contract InitializableCustom {
-    /**
-     * @dev Storage of the initializable contract.
-     *
-     * It's implemented on a custom ERC-7201 namespace to reduce the risk of storage collisions
-     * when using with upgradeable contracts.
-     *
-     * @custom:storage-location erc7201:openzeppelin.storage.Initializable
-     */
-    struct InitializableCustomStorage {
-        /**
-         * @dev Indicates that the contract has been initialized.
-         */
-        uint64 _initialized;
-        /**
-         * @dev Indicates that the contract is in the process of being initialized.
-         */
-        bool _initializing;
-        /**
-         * @dev Indicates address that can call function with initializer() modifier.
-         */
-        address _initializeOwner;
-    }
-
-    // keccak256(abi.encode(uint256(keccak256("openzeppelin.storage.InitializableCustom")) - 1)) & ~bytes32(uint256(0xff))
-    bytes32 private constant INITIALIZABLE_CUSTOM_STORAGE = 0x46cd1d813423aaf613c34c7f348d15b2b5e71215e9145b09467e257ea2805a00;
-
-    /**
-     * @dev The contract is already initialized.
-     */
-    error InvalidInitialization();
-
-    /**
-     * @dev The contract initialization function caller is not authorized.
-     */
-    error InvalidInitializationCaller();
-
-    /**
-     * @dev The contract is not initializing.
-     */
-    error NotInitializing();
-
-    /**
-     * @dev Triggered when the contract has been initialized or reinitialized.
-     */
-    event Initialized(uint64 version);
-
-    /**
-     * @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
-     * `onlyInitializing` functions can be used to initialize parent contracts.
-     *
-     * Similar to `reinitializer(1)`, except that in the context of a constructor an `initializer` may be invoked any
-     * number of times. This behavior in the constructor can be useful during testing and is not expected to be used in
-     * production.
-     *
-     * Emits an {Initialized} event.
-     */
-    modifier initializer() virtual {
-        // solhint-disable-next-line var-name-mixedcase
-        InitializableCustomStorage storage $ = _getInitializableCustomStorage();
-
-        if($._initializeOwner != msg.sender) {
-            revert InvalidInitializationCaller();
-        }
-
-        // Cache values to avoid duplicated sloads
-        bool isTopLevelCall = !$._initializing;
-        uint64 initialized = $._initialized;
-
-        // Allowed calls:
-        // - initialSetup: the contract is not in the initializing state and no previous version was
-        //                 initialized
-        // - construction: the contract is initialized at version 1 (no reininitialization) and the
-        //                 current contract is just being deployed
-        bool initialSetup = initialized == 0 && isTopLevelCall;
-        bool construction = initialized == 1 && address(this).code.length == 0;
-
-        if (!initialSetup && !construction) {
-            revert InvalidInitialization();
-        }
-        $._initialized = 1;
-        if (isTopLevelCall) {
-            $._initializing = true;
-        }
-        _;
-        if (isTopLevelCall) {
-            $._initializing = false;
-            emit Initialized(1);
-        }
-    }
-
-    /**
-     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
-     * {initializer} and {reinitializer} modifiers, directly or indirectly.
-     */
-    modifier onlyInitializing() {
-        _checkInitializing();
-        _;
-    }
-
-    /**
-     * @dev Constructor sets the caller of protected initializer function.
-    */
-    constructor() {
-        // solhint-disable-previous-line var-name-mixedcase
-        InitializableCustomStorage storage $ = _getInitializableCustomStorage();
-        $._initializeOwner = msg.sender;
-    }
-
-    /**
-     * @dev Reverts if the contract is not in an initializing state. See {onlyInitializing}.
-     */
-    function _checkInitializing() internal view virtual {
-        if (!_isInitializing()) {
-            revert NotInitializing();
-        }
-    }
-
-    /**
-     * @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
-     * Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
-     * to any version. It is recommended to use this to lock implementation contracts that are designed to be called
-     * through proxies.
-     *
-     * Emits an {Initialized} event the first time it is successfully executed.
-     */
-    function _disableInitializers() internal virtual {
-        // solhint-disable-next-line var-name-mixedcase
-        InitializableCustomStorage storage $ = _getInitializableCustomStorage();
-
-        if ($._initializing) {
-            revert InvalidInitialization();
-        }
-        if ($._initialized != type(uint64).max) {
-            $._initialized = type(uint64).max;
-            emit Initialized(type(uint64).max);
-        }
-    }
-
-    /**
-     * @dev Returns the highest version that has been initialized. See {reinitializer}.
-     */
-    function _getInitializedVersion() internal view returns (uint64) {
-        return _getInitializableCustomStorage()._initialized;
-    }
-
-    /**
-     * @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
-     */
-    function _isInitializing() internal view returns (bool) {
-        return _getInitializableCustomStorage()._initializing;
-    }
-
-    /**
-     * @dev Returns a pointer to the storage namespace.
-     */
-    // solhint-disable-next-line var-name-mixedcase
-    function _getInitializableCustomStorage() private pure returns (InitializableCustomStorage storage $) {
-        assembly {
-            $.slot := INITIALIZABLE_CUSTOM_STORAGE
-        }
-    }
-}

package/contracts/staking/StakeManagerLib.sol

@@ -1,179 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.20;
-
-import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
-
-import {Amount, AmountLib} from "../type/Amount.sol";
-import {Component} from "../shared/Component.sol";
-import {IRegistry} from "../registry/IRegistry.sol";
-import {IRegistryService} from "../registry/IRegistryService.sol";
-import {IStaking} from "./IStaking.sol";
-import {Key32} from "../type/Key32.sol";
-import {NftId} from "../type/NftId.sol";
-import {ObjectType, INSTANCE, PROTOCOL, TARGET} from "../type/ObjectType.sol";
-import {Seconds, SecondsLib} from "../type/Seconds.sol";
-import {StakingReader} from "./StakingReader.sol";
-import {Timestamp, TimestampLib} from "../type/Timestamp.sol";
-import {UFixed, UFixedLib} from "../type/UFixed.sol";
-
-
-library StakeManagerLib {
-
-
-    function checkCreateParameters(
-        StakingReader stakingReader,
-        NftId targetNftId, 
-        Amount dipAmount
-    )
-        external
-        view
-        returns (
-            Timestamp lockedUntil
-        )
-    {
-        Seconds lockingPeriod = checkTarget(stakingReader, targetNftId);
-        checkDipAmount(stakingReader, targetNftId, dipAmount);
-
-        Timestamp currentTime = TimestampLib.blockTimestamp();
-        lockedUntil = currentTime.addSeconds(lockingPeriod);
-    }
-
-
-    function checkStakeParameters(
-        StakingReader stakingReader,
-        NftId stakeNftId
-    )
-        public
-        view
-        returns (
-            UFixed rewardRate,
-            Seconds lockingPeriod
-        )
-    {
-        NftId targetNftId = stakingReader.getTargetNftId(stakeNftId);
-
-        // only accept stakes for active targets
-        if (!stakingReader.isActive(targetNftId)) {
-            revert IStaking.ErrorStakingTargetNotActive(targetNftId);
-        }
-
-        IStaking.TargetInfo memory info = stakingReader.getTargetInfo(targetNftId);
-        rewardRate = info.rewardRate;
-        lockingPeriod = info.lockingPeriod;
-    }
-
-
-    function checkTarget(
-        StakingReader stakingReader,
-        NftId targetNftId
-    )
-        public
-        view
-        returns (Seconds lockingPeriod)
-    {
-        // target nft id must be registered
-        if (!stakingReader.isTarget(targetNftId)) {
-            revert IStaking.ErrorStakingNotTarget(targetNftId);
-        }
-
-        // only accept stakes for active targets
-        if (!stakingReader.isActive(targetNftId)) {
-            revert IStaking.ErrorStakingTargetNotActive(targetNftId);
-        }
-
-        lockingPeriod = stakingReader.getTargetInfo(targetNftId).lockingPeriod;
-    }
-
-
-    function checkDipAmount(
-        StakingReader stakingReader,
-        NftId targetNftId, 
-        Amount dipAmount
-    )
-        public 
-        pure 
-    {
-        // check stake amount > 0
-        if (dipAmount.eqz()) {
-            revert IStaking.ErrorStakingStakeAmountZero(targetNftId);
-        }
-
-        // TODO add check for target specific max dip amount (min stake + tvl * stake rate + buffer)
-    }
-
-
-    function checkDipBalanceAndAllowance(
-        IERC20Metadata dip, 
-        address owner, 
-        address tokenHandlerAddress, 
-        Amount dipAmount
-    )
-        public
-        view
-    {
-        // check balance
-        uint256 amount = dipAmount.toInt();
-        uint256 dipBalance = dip.balanceOf(owner);
-        if (dipBalance < amount) {
-            revert IStaking.ErrorStakingDipBalanceInsufficient(owner, amount, dipBalance);
-        }
-
-        // check allowance
-        uint256 dipAllowance = dip.allowance(owner, tokenHandlerAddress);
-        if (dipAllowance < amount) {
-            revert IStaking.ErrorStakingDipAllowanceInsufficient(owner, tokenHandlerAddress, amount, dipAllowance);
-        }
-    }
-
-
-    function calculateRewardIncrease(
-        StakingReader stakingReader,
-        NftId stakeNftId,
-        UFixed rewardRate
-    )
-        public
-        view
-        returns (
-            Amount rewardIncreaseAmount,
-            Amount totalDipAmount
-        )
-    {
-        (
-            Amount stakeAmount,
-            Amount rewardAmount,
-            Timestamp lastUpdatedAt
-        ) = stakingReader.getStakeBalances(stakeNftId);
-
-        Seconds duration = SecondsLib.toSeconds(
-            block.timestamp - lastUpdatedAt.toInt());
-        
-        rewardIncreaseAmount = calculateRewardAmount(
-            rewardRate,
-            duration,
-            stakeAmount);
-
-        totalDipAmount = stakeAmount + rewardAmount + rewardIncreaseAmount;
-    }
-
-
-    function calculateRewardAmount(
-        UFixed rewardRate,
-        Seconds duration, 
-        Amount stakeAmount
-    )
-        public 
-        pure 
-        returns(
-            Amount rewardAmount
-        )
-    {
-        UFixed rewardRateFraction = getYearFraction(duration) * rewardRate;
-        rewardAmount = stakeAmount.multiplyWith(rewardRateFraction);
-    }
-
-
-    function getYearFraction(Seconds duration) public pure returns (UFixed yearFraction) {
-        return UFixedLib.toUFixed(duration.toInt()) / UFixedLib.toUFixed(SecondsLib.oneYear().toInt());
-    }
-
-}